zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Be paranoid, new files are readable/writable by me only.
   9 umask 077
  10
  11 # Disable beeps.
  12 setopt nobeep
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # KEY BINDINGS
  34
  35 # Not all bindings are done here, only those not specific to a given section.
  36
  37 # Use Vi(m) style key bindings.
  38 bindkey -v
  39
  40 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  41 bindkey -M viins -r '^[OA'
  42 bindkey -M viins -r '^[OB'
  43 bindkey -M viins -r '^[OC'
  44 bindkey -M viins -r '^[OD'
  45 bindkey -M viins -r '^[[A'
  46 bindkey -M viins -r '^[[B'
  47 bindkey -M viins -r '^[[C'
  48 bindkey -M viins -r '^[[D'
  49 # Also not in Vi mode.
  50 bindkey -M vicmd -r '^[OA'
  51 bindkey -M vicmd -r '^[OB'
  52 bindkey -M vicmd -r '^[OC'
  53 bindkey -M vicmd -r '^[OD'
  54 bindkey -M vicmd -r '^[[A'
  55 bindkey -M vicmd -r '^[[B'
  56 bindkey -M vicmd -r '^[[C'
  57 bindkey -M vicmd -r '^[[D'
  58
  59
  60 # FUNCTION SETTINGS
  61
  62 # Make sure every entry in $fpath is unique.
  63 typeset -U fpath
  64 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  65 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  66 if [[ -d ~/.zsh/functions/completion ]]; then
  67     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  68 fi
  69 # Set correct fpath to allow loading my functions (including completion
  70 # functions).
  71 fpath=(~/.zsh/functions $fpath)
  72 # Autoload my functions (except completion functions and hidden files). Thanks
  73 # to caphuso from the Zsh example files for this idea.
  74 if [[ -d ~/.zsh/functions ]]; then
  75     autoload ${fpath[1]}/^_*(^/:t)
  76 fi
  77
  78 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  79 # the moment only precmd(), preexec() and chpwd() are simulated.
  80 #
  81 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  82 # so the compatibility version is used there too.
  83 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  84     # Provide add-zsh-hook which was added in 4.3.4.
  85     fpath=(~/.zsh/functions/compatibility $fpath)
  86
  87     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  88     # arrays.
  89     function precmd() {
  90         for function in $precmd_functions; do
  91             $function $@
  92         done
  93     }
  94     function preexec() {
  95         for function in $preexec_functions; do
  96             $function $@
  97         done
  98     }
  99     function chpwd() {
 100         for function in $chpwd_functions; do
 101             $function $@
 102         done
 103     }
 104 fi
 105
 106 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
 107 autoload -Uz add-zsh-hook
 108
 109 # Load zmv (zsh move) which is powerful to rename files.
 110 autoload zmv
 111
 112
 113 # HISTORY SETTINGS
 114
 115 # Use history and store it in ~/.zsh/history.
 116 HISTSIZE=50000
 117 SAVEHIST=50000
 118 HISTFILE=~/.zsh/history
 119 # Append to the history file instead of overwriting it and do it immediately
 120 # when a command is executed.
 121 setopt appendhistory
 122 setopt incappendhistory
 123 # If the same command is run multiple times store it only once in the history.
 124 setopt histignoredups
 125 # Vim like completions of previous executed commands (also enter Vi-mode). If
 126 # called at the beginning it just recalls old commands (like cursor up), if
 127 # called after typing something, only lines starting with the typed are
 128 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 129 # on Freenode (2010-01-17 12:47) for the information how to a use function
 130 # with bindkey.
 131 zle -N my-vi-history-beginning-search-backward
 132 my-vi-history-beginning-search-backward() {
 133     local not_at_beginning_of_line
 134     if [[ $CURSOR -ne 0 ]]; then
 135         not_at_beginning_of_line=yes
 136     fi
 137
 138     zle history-beginning-search-backward
 139
 140     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 141     # this counters it).
 142     zle vi-cmd-mode
 143     if [[ -n $not_at_beginning_of_line ]]; then
 144         zle vi-forward-char
 145     fi
 146 }
 147 bindkey '^P' my-vi-history-beginning-search-backward
 148 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 149 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 150 # after calling ^P.
 151 bindkey -a '^N' history-beginning-search-forward
 152
 153
 154 # PROMPT SETTINGS
 155
 156 # Use colorized output, necessary for prompts and completions.
 157 autoload -U colors && colors
 158
 159 # Some shortcuts for colors.
 160 local red="%{${fg[red]}%}"
 161 local blue="%{${fg[blue]}%}"
 162 local green="%{${fg[green]}%}"
 163 local yellow="%{${fg[yellow]}%}"
 164 local default="%{${fg[default]}%}"
 165
 166 # Set the default prompt. The current host and working directory is displayed,
 167 # the exit code of the last command if it wasn't 0, the number of running jobs
 168 # if not 0.
 169 #
 170 # The prompt is in green and blue to make easily detectable, the error exit
 171 # code in red and bold and the job count in yellow.
 172 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 173 %(1j.$yellow%j$default.)%# \
 174 %(?..($red%B%?%b$default%) )"
 175
 176 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 177 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 178 # symbolic link to current checkout of Zsh's sources).
 179 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 180       -d ~/.zsh/functions/vcs_info ]]; then
 181     # Update fpath to allow loading the vcs_info functions.
 182     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 183        fpath=(~/.zsh/functions/vcs_info/
 184               ~/.zsh/functions/vcs_info/Backends
 185               $fpath)
 186     fi
 187
 188     # Allow substitutions and expansions in the prompt, necessary for
 189     # vcs_info.
 190     setopt promptsubst
 191     # Load vcs_info to display information about version control repositories.
 192     autoload -Uz vcs_info
 193     # Only look for git and mercurial repositories; the only I use.
 194     zstyle ':vcs_info:*' enable git hg
 195     # Check the repository for changes so they can be used in %u/%c (see
 196     # below). This comes with a speed penalty for bigger repositories.
 197     zstyle ':vcs_info:*' check-for-changes true
 198
 199     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 200     # is displayed. If there is an special action going on (merge, rebase)
 201     # it's also displayed (red). Also display if there are unstaged or staged
 202     # (%u/%c) changes.
 203     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 204           -d ~/.zsh/functions/vcs_info ]]; then
 205         zstyle ':vcs_info:*' formats \
 206             "($green%b%u%c$default:$blue%s$default)"
 207         zstyle ':vcs_info:*' actionformats \
 208             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 209     else
 210         # In older versions %u and %c are not defined yet and are not
 211         # correctly expanded.
 212         zstyle ':vcs_info:*' formats \
 213             "($green%b$default:$blue%s$default)"
 214         zstyle ':vcs_info:*' actionformats \
 215             "($green%b$default/$red%a$default:$blue%s$default)"
 216     fi
 217     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 218     # changes are detected in the repository; check-for-changes must be set to
 219     # true for this to work. Thanks to Bart Trojanowski
 220     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 221     # (2010-03-11 00:20).
 222     zstyle ':vcs_info:*' unstagedstr '¹'
 223     zstyle ':vcs_info:*' stagedstr   '²'
 224
 225     # Call vcs_info as precmd before every prompt.
 226     prompt_precmd() {
 227         vcs_info
 228     }
 229     add-zsh-hook precmd prompt_precmd
 230
 231     # Display the VCS information in the right prompt.
 232     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 233         RPROMPT='${vcs_info_msg_0_}'
 234     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 235     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 236     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 237     else
 238         RPROMPT='${vcs_info_msg_0_:- }'
 239     fi
 240 fi
 241
 242 unset red blue green yellow default
 243
 244 # When screen, xterm or rxvt is used set the name of the window to the
 245 # currently running program.
 246 #
 247 # When a program is started preexec() sets the window's name to it; when it
 248 # stops precmd() resets the window's name to 'zsh'.
 249 #
 250 # It works with screen, xterm and rxvt.
 251 #
 252 # If a command is run with sudo or if the shell is running as root then a ! is
 253 # added at the beginning of the command to make this clear. If a command is
 254 # running on a different computer with ssh a @ is added at the beginning. If
 255 # screen is running on the remote machine instead of @screen @:hostname
 256 # (hostname replaced by the machine's hostname) is displayed. This only works
 257 # if the .zshrc on the server also uses this command.
 258 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 259     # Is set to a non empty value to reset the window name in the next
 260     # precmd() call.
 261     window_reset=yes
 262     # Is set to a non empty value when the shell is running as root.
 263     if [[ $(id -u) -eq 0 ]]; then
 264         window_root=yes
 265     fi
 266
 267     window_preexec() {
 268         # Get the program name with its arguments.
 269         local program_name=$1
 270
 271         # When sudo is used use real program name instead, but with an
 272         # exclamation mark at the beginning (handled below).
 273         local program_sudo=
 274         if [[ $program_name == sudo* ]]; then
 275             program_name=${program_name#sudo }
 276             program_sudo=yes
 277         fi
 278         # Remove all arguments from the program name.
 279         program_name=${program_name%% *}
 280
 281         # Ignore often used commands which are only running for a very short
 282         # time. This prevents a "blinking" name when it's changed to "cd" for
 283         # example and then some milliseconds later back to "zsh".
 284         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 285
 286         # Change my shortcuts so the real name of the program is displayed.
 287         case $program_name in
 288             e)
 289                 program_name=elinks
 290                 ;;
 291             g)
 292                 program_name=git
 293                 ;;
 294             m)
 295                 program_name=mutt
 296                 ;;
 297             v|vi)
 298                 program_name=vim
 299                 ;;
 300         esac
 301
 302         # Add an exclamation mark at the beginning if running with sudo or if
 303         # running zsh as root.
 304         if [[ -n $program_sudo || -n $window_root ]]; then
 305             program_name=!$program_name
 306         fi
 307
 308         # Add an at mark at the beginning if running through ssh on a
 309         # different computer.
 310         if [[ -n $SSH_CONNECTION ]]; then
 311             program_name="@$program_name"
 312
 313             # If screen is running in SSH then display "@:hostname" as title
 314             # in the term/outer screen.
 315             if [[ $program_name == @screen ]]; then
 316                 program_name="@:${$(hostname)//.*/}"
 317             fi
 318         fi
 319
 320         # Set the window name to the currently running program.
 321         window_title "$program_name"
 322
 323         # Tell precmd() to reset the window name when the program stops.
 324         window_reset=yes
 325     }
 326
 327     window_precmd() {
 328         # Abort if no window name reset is necessary.
 329         [[ -z $window_reset ]] && return
 330
 331         # Reset the window name to 'zsh'.
 332         local name=zsh
 333         # If the function was called with an argument then reset the window
 334         # name to '.zsh' (used by clear alias).
 335         if [[ -n $1 ]]; then
 336             name=.zsh
 337         fi
 338
 339         # Prepend prefixes like in window_preexec().
 340         if [[ -n $SSH_CONNECTION ]]; then
 341             window_title "@$name"
 342         elif [[ -n $window_root ]]; then
 343             window_title "!$name"
 344         else
 345             window_title $name
 346         fi
 347
 348         # Just reset the name, so no screen reset necessary for the moment.
 349         window_reset=
 350     }
 351
 352     # Sets the window title. Works with screen, xterm and rxvt.
 353     if [[ $TERM == screen* ]]; then
 354         window_title() {
 355             print -n "\ek$1\e\\"
 356         }
 357     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 358         window_title() {
 359             print -n "\e]2;$1\e\\"
 360         }
 361     fi
 362
 363     # Add the preexec() and precmd() hooks.
 364     add-zsh-hook preexec window_preexec
 365     add-zsh-hook precmd window_precmd
 366 fi
 367
 368
 369 # COMPLETION SETTINGS
 370
 371 # Load the complist module which provides additions to completion lists
 372 # (coloring, scrollable).
 373 zmodload zsh/complist
 374 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 375 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 376 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 377 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 378
 379 # Use cache to speed up completions.
 380 zstyle ':completion:*' use-cache on
 381 zstyle ':completion:*' cache-path ~/.zsh/cache
 382
 383 # Complete arguments and fix spelling mistakes when possible.
 384 zstyle ':completion:*' completer _complete _match _correct _approximate
 385
 386 # Make sure the list of possible completions is displayed after pressing <TAB>
 387 # the first time.
 388 setopt nolistambiguous
 389 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 390 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 391 bindkey '^I' expand-or-complete-prefix
 392 # Try uppercase if the currently typed string doesn't match. This allows
 393 # typing in lowercase most of the time and completion fixes the case.
 394 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 395
 396 # Use ls like colors for completions.
 397 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 398
 399 # Make completion lists scrollable so "do you wish to see all n possibilities"
 400 # is no longer displayed.
 401 zstyle ':completion:*' list-prompt '%p'
 402 # Display group name (like 'external command', 'alias', etc.) when there are
 403 # multiple matches in bold.
 404 zstyle ':completion:*' format '    %B%d%b:'
 405 # Display different types of matches separately.
 406 zstyle ':completion:*' group-name ''
 407
 408 # Ignore completion functions.
 409 zstyle ':completion:*:functions' ignored-patterns '_*'
 410 # Ignore parent directory.
 411 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 412 # When unsetting variables make sure every variable name is only suggested
 413 # once.
 414 zstyle ':completion:*:unset:*' ignore-line yes
 415 # When working with Mercurial and Git don't complete the same file multiple
 416 # times. Very useful when completing file names.
 417 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 418
 419
 420 # CUSTOM ALIASES AND FUNCTIONS
 421
 422 # If ^C is pressed while typing a command, add it to the history so it can be
 423 # easily retrieved later and then abort like ^C normally does. This is useful
 424 # when I want to abort an command to do something in between and then finish
 425 # typing the command.
 426 #
 427 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 428 # starting with - don't cause errors.
 429 TRAPINT() {
 430     # Store the current buffer in the history.
 431     zle && print -s -- $BUFFER
 432
 433     # Return the default exit code so Zsh aborts the current command.
 434     return $1
 435 }
 436
 437 # Colorize stderr. Very useful when looking for errors. Thanks to
 438 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 439 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 440 # perfect and doesn't work with su and git for example, but it can handle most
 441 # interactive output quite well (even with no trailing new line) and in those
 442 # cases the E alias can be used as workaround.
 443 exec 2>>(while read -r -k -u 0 line; do
 444     printf '\e[91m%s\e[0m' "$line";
 445     print -n $'\0';
 446 done &)
 447
 448 # Load aliases and similar functions also used by other shells.
 449 if [[ -f ~/.shell/aliases ]]; then
 450     . ~/.shell/aliases
 451 fi
 452
 453 # Make sure aliases are expanded when using sudo.
 454 alias sudo='sudo '
 455
 456 # Global aliases for often used commands in the command line.
 457 alias -g E='2>&1'
 458 alias -g L='E | less'
 459 alias -g D='E | colordiff L'
 460 alias -g G='| grep'
 461 alias -g S='| sort'
 462 alias -g U='| uniq'
 463 alias -g H='| head'
 464 alias -g T='| tail'
 465
 466 # Make going up directories simple.
 467 alias -g ...='../..'
 468 alias -g ....='../../..'
 469 alias -g .....='../../../..'
 470
 471 # If the window naming feature is used (see above) then use ".zsh" (leading
 472 # dot) as title name after running clear so it's clear to me that the window
 473 # is empty. I open so much windows that I don't know in which I have something
 474 # important. This helps me to remember which windows are empty (I run clear
 475 # after I finished my work in a window).
 476 if [[ -n $window_reset ]]; then
 477     alias clear='clear; window_reset=yes; window_precmd reset'
 478 fi
 479
 480 # Display all branches (except stash) in gitk but only 200 commits as this is
 481 # much faster. Also put in the background and disown. Thanks to sitaram in
 482 # #git on Freenode (2009-04-20 15:51).
 483 gitk() {
 484     command gitk \
 485         --max-count=200 \
 486         $(git rev-parse --symbolic-full-name --remotes --branches) \
 487         $@ &
 488     disown %command
 489 }
 490 # Same for tig (except the disown part as it's no GUI program).
 491 tig() {
 492     command tig \
 493         --max-count=200 \
 494         $(git rev-parse --symbolic-full-name --remotes --branches) \
 495         $@
 496 }
 497
 498
 499 # OS SPECIFIC SETTINGS
 500
 501 if [[ $(uname) == Linux ]]; then
 502     # Settings when creating Debian packages.
 503     DEBEMAIL=simon@ruderich.org
 504     export DEBEMAIL
 505     DEBFULLNAME='Simon Ruderich'
 506     export DEBFULLNAME
 507
 508 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 509     # Store the current clipboard in CLIPBOARD before every command so it can
 510     # be used in commands.
 511     os_darwin_preexec() {
 512         export CLIPBOARD="$(pbpaste)"
 513     }
 514     # Add the function as preexec hook.
 515     add-zsh-hook preexec os_darwin_preexec
 516
 517     # Initialize CLIPBOARD so it's available for completion directly after
 518     # startup.
 519     CLIPBOARD=""
 520     export CLIPBOARD
 521
 522     # Fetch current URL in clipboard with wget.
 523     alias wnc='wget --no-proxy $CLIPBOARD'
 524 fi
 525
 526
 527 # LOAD ADDITIONAL CONFIGURATION FILES
 528
 529 # Load rc file for current hostname (first part before a dot) or rc.local.
 530 source_config ~/.zsh host rc ${$(hostname)//.*/}
 531
 532
 533 # RUN COMMANDS
 534
 535 # If not already in screen reattach to a running session or create a new one.
 536 #
 537 # screen* is necessary as `screen` uses screen.linux for example for a linux
 538 # console which would otherwise cause an infinite loop.
 539 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 540     # Get running detached sessions.
 541     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 542     # Create a new session if none is running.
 543     if [[ -z $session ]]; then
 544         screen
 545     # Reattach to a running session.
 546     else
 547         screen -r $session
 548     fi
 549 fi
 550
 551
 552 source_debug "finished sourcing ~/.zsh/rc"
 553
 554 # vim: ft=zsh