" Vim main configuration file.


" Make sure Vim (and not Vi) settings are enabled.
set nocompatible

" Load my scripts from ~/.vim (my scripts), ~/.vim/plugins (plugins) and
" ~/.vim/runtime (checkout of Vim runtime files).
set runtimepath-=~/.vim
set runtimepath^=~/.vim,~/.vim/plugins,~/.vim/runtime


" EDIT SETTINGS

" Enable automatic file detection, plugin and indention.
if has("autocmd")
    filetype plugin indent on
endif

" Use UTF-8 file encoding for all files.
set fileencodings=utf-8

" Wrap text after 78 characters.
set textwidth=78

" Set tabs to 4 spaces, use softtabs.
set shiftwidth=4
set softtabstop=4
set expandtab
" When < and > is used indent/deindent to the next shiftwidth boundary.
set shiftround
" Use the default value for real tabs.
set tabstop=8

" Enable auto indention.
set autoindent

" When joining lines only add one space after a sentence.
set nojoinspaces

" Allow backspacing over autoindent and line breaks.
set backspace=indent,eol

" Start a comment when hitting enter after a commented line (r) and when using
" o or O around a commented line (o).
set formatoptions+=ro
" Don't break a line if was already longer then 'textwidth' when insert mode
" started.
set formatoptions+=l

" Allow virtual editing (cursor can be positioned anywhere, even when there is
" no character) in visual block mode.
set virtualedit=block

" Already display matches while typing the search command. This makes spotting
" errors easily.
set incsearch

" Activate syntax folding.
if has("folding")
    set foldmethod=syntax
    set foldcolumn=2
    set foldlevel=99 " no folding at default
endif

" Only check for case if the searched word contains a capital character.
set ignorecase
set smartcase

" Activate spell checking, use English as default.
if v:version >= 700
    set spell
    set spelllang=en_us
endif


" DISPLAY SETTINGS

" Use a dark background.
set background=dark

" Activate lines display.
set number
" Display the ruler with current line/file position.
set ruler
" Display partial commands in the status line.
set showcmd

" Visualize the line the cursor is currently in.
if v:version >= 700
    set cursorline
endif

" Display tabs as "^I" and trailing space as "-".
set list
set listchars=trail:-


" EDITOR SETTINGS

" When completing paths first use the longest path then display a list of all
" possible files.
set wildmode=longest,list

" Increase number of tabs which can be opened with the -p option.
if v:version >= 700
    set tabpagemax=50
endif


" MAPPINGS (except for plugins, see PLUGIN SETTINGS below)

" Use <space> to move down a page and - to move up one like in mutt.
nnoremap <Space> <C-f>
nnoremap - <C-b>

" Maps to change spell language between English and German.
map <Leader>se :set spelllang=en_us<CR>
map <Leader>sd :set spelllang=de_de<CR>

" Add semicolon to the end of the line. Thanks to
" http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
" for an improved version which doesn't clobber any marks.
nnoremap <silent> ; :call setline(line('.'), getline('.') . ';')<CR>

" I often type "W" instead of "w" when trying to save a file. Fix my mistake.
" Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
" mailing list for the commands.
if v:version < 700
    cnoreabbrev W w
    cnoreabbrev Wq wq
    cnoreabbrev Wqa wqa
else
    cnoreabbrev <expr> W
        \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
    cnoreabbrev <expr> Wq
        \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
    cnoreabbrev <expr> Wqa
        \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
endif
" Also fix my typo with "Q".
if v:version < 700
    cnoreabbrev Q q
    cnoreabbrev Qa qa
else
    cnoreabbrev <expr> Q
        \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
    cnoreabbrev <expr> Qa
        \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
endif

" Make sure xa0 (alt + space) is automatically changed to a normal whitespace
" if pressed accidentally while in insert mode (happens on Mac sometimes).
if has("mac")
    imap <Char-0xa0> <Space>
endif

" Disable Apple style movements in MacVim.
if has("gui_macvim") && has("eval")
    let macvim_skip_cmd_opt_movement = 1
endif


" SYNTAX SETTINGS

" Activate syntax coloring.
if has("syntax")
    syntax enable

" Highlight text longer then 78 characters. Thanks to Tony Mechelynck
" <antoine.mechelynck@gmail.com> from the Vim mailing list.
    if v:version >= 700
        2match Todo /\%>78v./
    else
        match Todo /\%>78v./
    endif
endif


" PLUGIN SETTINGS

" Settings for the NERD commenter.
" Don't create any mappings I don't want to use.
if has("eval")
    let NERDCreateDefaultMappings = 0
endif
" Map toggle comment.
map <Leader><Leader> <plug>NERDCommenterToggle


" AUTO COMMANDS

" Use a custom auto group to prevent problems when the vimrc files is sourced
" twice.
if has("autocmd")
    augroup vimrc
        autocmd!

" Use diff filetype for mercurial patches in patch queue.
        autocmd BufReadPost */.hg/patches/* set filetype=diff

    augroup END
endif