" Vim main configuration file.


" EDITOR SETTINGS

" Prevent editing as root as it may cause security problems. Use sudoedit
" instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21).
if $HOME == '/root' || exists('$SUDO_USER')
    echomsg 'Running as root is forbidden! Use sudoedit.'
    qa
endif


" Reset all options (except 'term, 'lines' and 'columns'). This makes sure a
" system wide configuration file doesn't change default values.
set all&

" Make sure Vim (and not Vi) settings are used.
set nocompatible

" Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
" runtime files).
set runtimepath-=~/.vim
set runtimepath^=~/.vim,~/.vim/runtime

" Disable modelines as they may cause security problems. Instead use
" securemodelines (Vim script #1876).
set nomodeline

" When completing paths first use the longest path then display a list of all
" possible files.
set wildmode=longest,list


" EDIT SETTINGS

" Enable automatic file detection, plugin and indention support.
if has('autocmd')
    filetype plugin indent on
endif

" Use UTF-8 file encoding for all files. Automatically recognize latin1 in
" existing files.
set fileencodings=utf-8,latin1

" Wrap text after 78 characters.
set textwidth=78

" Set tabs to 4 spaces, use softtabs.
set shiftwidth=4
set softtabstop=4
set expandtab
" When < and > is used indent/deindent to the next 'shiftwidth' boundary.
set shiftround
" Use the default value for real tabs.
set tabstop=8

" Enable auto indention.
set autoindent

" When joining lines only add one space after a sentence.
set nojoinspaces

" Allow backspacing over autoindent and line breaks.
set backspace=indent,eol

" Start a comment when hitting enter after a commented line (r) and when using
" o or O around a commented line (o).
set formatoptions+=ro
" Don't break a line if was already longer then 'textwidth' when insert mode
" started.
set formatoptions+=l

" Allow virtual editing (cursor can be positioned anywhere, even when there is
" no character) in visual block mode.
set virtualedit=block

" Already display matches while typing the search command. This makes spotting
" errors easy.
set incsearch

" Activate syntax folding.
if has('folding')
    set foldmethod=syntax
    set foldcolumn=2
    set foldlevel=99 " no closed folds at default, 'foldenable' would disable
                     " folding which is not what I want
endif

" Only check for case if the searched word contains a capital character.
set ignorecase
set smartcase

" Activate spell checking, use English as default. Don't use spell checking
" when diffing.
if v:version >= 700 && has('syntax') && !&diff
    set spell
    set spelllang=en_us
endif

" Allow buffers with changes to be hidden. Very important for effective
" editing with multiple buffers.
set hidden


" DISPLAY SETTINGS

" Use a dark background. Doesn't change the background color, only sets text
" colors for a dark terminal.
set background=dark

" Display line numbers.
set number
" Display the ruler with current line/file position. If 'statusline' is used
" then this only affects <C-g>.
set ruler
" Display partial commands in the status line.
set showcmd

" Visualize the line the cursor is currently in.
if v:version >= 700
    set cursorline
endif

" Display tabs, trailing space, non breakable spaces and long lines (when
" wrapping is enabled).
set list
set listchars=trail:-,extends:>
if v:version >= 700
    set listchars+=nbsp:!
endif

if has('statusline')
    " Always display the status line even if there is only one window.
    set laststatus=2

    set statusline=
    " on the left
    set statusline+=%02n: " buffer number
    set statusline+=%f\   " path to current file in buffer
    set statusline+=%h    " [help] if buffer is help file
    set statusline+=%w    " [Preview] if buffer is preview buffer
    set statusline+=%m    " [+] if buffer was modified,
                          " [-] if 'modifiable' is off
    set statusline+=%r    " [RO] if buffer is read only

    " on the right
    set statusline+=%=                " right align
    set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
                                      " column number (%c),
                                      " virtual column number if different
                                      "                       than %c (%V)
    set statusline+=%P                " position in file in percent
endif


" MAPPINGS (except for plugins, see PLUGIN SETTINGS below)

" Use <space> to move down a page and - to move up one like in mutt.
nnoremap <Space> <C-f>
nnoremap - <C-b>

" Fast access to buffers.
nnoremap <Leader>1 :1b<CR>
nnoremap <Leader>2 :2b<CR>
nnoremap <Leader>3 :3b<CR>
nnoremap <Leader>4 :4b<CR>
nnoremap <Leader>5 :5b<CR>
nnoremap <Leader>6 :6b<CR>
nnoremap <Leader>7 :7b<CR>
nnoremap <Leader>8 :8b<CR>
nnoremap <Leader>9 :9b<CR>
nnoremap <Leader>0 :10b<CR>

" Make last active window the only window. Similar to <C-w> o.
nnoremap <C-w>O <C-w>p<C-w>o

" Maps to change spell language between English and German and disable spell
" checking.
if v:version >= 700
    map <Leader>sn :set nospell<CR>
    map <Leader>se :set spell spelllang=en_us<CR>
    map <Leader>sd :set spell spelllang=de_de<CR>
endif

" Add semicolon to the end of the line. Thanks to
" http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
" on Freenode for an improved version which doesn't clobber any marks.
nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>

" I often type "W" instead of "w" when trying to save a file. Fix my mistake.
" Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
" mailing list for the commands.
if v:version < 700
    cnoreabbrev W w
    cnoreabbrev Wa wa
    cnoreabbrev Wq wq
    cnoreabbrev Wqa wqa
else
    cnoreabbrev <expr> W
        \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
    cnoreabbrev <expr> Wa
        \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
    cnoreabbrev <expr> Wq
        \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
    cnoreabbrev <expr> Wqa
        \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
endif
" Also fix my typo with "Q".
if v:version < 700
    cnoreabbrev Q q
    cnoreabbrev Qa qa
else
    cnoreabbrev <expr> Q
        \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
    cnoreabbrev <expr> Qa
        \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
endif

" Make sure xa0 (alt + space) is automatically changed to a normal whitespace
" if pressed accidentally while in insert mode (happens on Mac when alt
" doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
" no longer set on the console.
if has('mac') || filereadable('/Users/.localized')
    inoremap <Char-0xa0> <Space>
endif

" Disable Apple style movements in MacVim.
if has('gui_macvim') && has('eval')
    let macvim_skip_cmd_opt_movement = 1
endif


" SYNTAX SETTINGS

" Activate syntax coloring.
if has('syntax')
    syntax enable

" Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
" <antoine.mechelynck@gmail.com> from the Vim mailing list.
" It can easily be disabled if necessary with :2match (in Vim >= 700).
    if v:version >= 700
        2match Todo /\%>78v./
    else
        match Todo /\%>78v./
    endif

" Highlight TODO, FIXME, CHANGED and XXX in all documents.
    if v:version > 701 || (v:version == 701 && has('patch42'))
        call matchadd('Todo', '\(TODO\|FIXME\|CHANGED\|XXX\)')
    endif
endif


" PLUGIN SETTINGS

" Settings for the NERD commenter.
" Don't create any mappings I don't want to use.
if has('eval')
    let NERDCreateDefaultMappings = 0
endif
" Map toggle comment.
map <Leader><Leader> <plug>NERDCommenterToggle


" AUTO COMMANDS

" Use a custom auto group to prevent problems when the vimrc files is sourced
" twice.
if has('autocmd')
    augroup vimrc
        autocmd!

" Go to last position of opened files. Taken from :help last-position-jump.
        autocmd BufReadPost *
            \ if line("'\"") > 1 && line("'\"") <= line("$") |
            \     execute "normal! g'\"" |
            \ endif
" But not for Git commits, go to beginning of the file.
        autocmd BufReadPost COMMIT_EDITMSG normal! gg

" Make sure 'list' and 'number' is disabled in help files. This is necessary
" when switching to a help buffer which is in the background with :buffer as
" these options are local to windows (and not only to buffers). This happens
" because I often want to use only one window and thus the help buffer is in
" the background.
        autocmd BufWinEnter *.txt
            \ if &filetype == 'help' |
            \     setlocal nolist |
            \     setlocal nonumber |
            \ endif

" AFTER/FTPLUGIN AUTO COMMANDS

" Disable spell checking for files which don't need it.
        autocmd FileType deb  setlocal nospell
        autocmd FileType diff setlocal nospell
        autocmd FileType tar  setlocal nospell
" Fix to allow Vim edit crontab files as crontab doesn't work with
" backupcopy=auto.
        autocmd FileType crontab setlocal backupcopy=yes
" Don't use the modeline in git commits as the diff created by `git commit -v`
" may contain one which could change the filetype or other settings of the
" commit buffer. Also make sure we use only 72 characters per line which is
" the recommendation for git commit messages (http://tpope.net/node/106).
        autocmd FileType gitcommit setlocal nomodeline |
                                 \ let g:secure_modelines_allowed_items = [] |
                                 \ setlocal textwidth=72
" Allow folding in perl.
        autocmd FileType perl let perl_fold = 1 |
                            \ let perl_fold_blocks = 1
" Use the same comment string as for Vim files in Vimperator files.
        autocmd FileType vimperator setlocal commentstring=\"%s

" FTDETECT AUTO COMMANDS

" Recognize .md as markdown files (Vim default is .mkd).
        autocmd BufRead,BufNewFile *.md set filetype=mkd
" Recognize .test as Tcl files.
        autocmd BufRead,BufNewFile *.test set filetype=tcl

" OTHER AUTO COMMANDS

" Use diff filetype for mercurial patches in patch queue.
        autocmd BufReadPost */.hg/patches/* set filetype=diff

    augroup END
endif