X-Git-Url: https://ruderich.org/simon/gitweb/?a=blobdiff_plain;f=bin%2Fblhc;h=880d24df4d2599f6cae394595bb1eafd6fce4665;hb=50b731db501c79ad33cb40845c16638703a4ea15;hp=c4aefd29ad15d50efe165112eb0d72359baa88a6;hpb=cf83d58fd04f141f4552050b285e2fbfc8189bcb;p=blhc%2Fblhc.git

diff --git a/bin/blhc b/bin/blhc
index c4aefd2..880d24d 100755
--- a/bin/blhc
+++ b/bin/blhc
@@ -22,16 +22,196 @@ use strict;
 use warnings;
 
 use Getopt::Long ();
+use Term::ANSIColor ();
 
 our $VERSION = '0.01';
 
 
+# FUNCTIONS
+
+sub error_flags {
+    my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
+
+    # Rename flags if requested.
+    my @missing_flags = map {
+        (exists $flag_renames_ref->{$_})
+            ? $flag_renames_ref->{$_}
+            : $_
+    } @{$missing_flags_ref};
+
+    my $flags = join ' ', @missing_flags;
+    printf "%s (%s)%s %s",
+           error_color($message, 'red'), $flags, error_color(':', 'yellow'),
+           $line;
+}
+sub error_non_verbose_build {
+    my ($line) = @_;
+
+    printf "%s%s %s",
+           error_color('NONVERBOSE BUILD', 'red'),
+           error_color(':', 'yellow'),
+           $line;
+}
+sub error_color {
+    my ($message, $color) = @_;
+
+    # Use colors when writing to a terminal.
+    if (-t STDOUT) {
+        return Term::ANSIColor::colored($message, $color);
+    } else {
+        return $message;
+    }
+}
+
+sub any_flags_used {
+    my ($line, @flags) = @_;
+
+    foreach my $flag (@flags) {
+        return 1 if $line =~ /\s$flag(?:\s|\\|$)/;
+    }
+
+    return 0;
+}
+sub all_flags_used {
+    my ($line, $missing_flags_ref, @flags) = @_;
+
+    my @missing_flags = ();
+    foreach my $flag (@flags) {
+        if ($line !~ /\s$flag(?:\s|\\|$)/) {
+            push @missing_flags, $flag;
+        }
+    }
+
+    if (scalar @missing_flags == 0) {
+        return 1;
+    }
+
+    @{$missing_flags_ref} = @missing_flags;
+    return 0;
+}
+
+# Modifies $missing_flags_ref array.
+sub pic_pie_conflict {
+    my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
+
+    return 0 if not $pie;
+    return 0 if not any_flags_used($line, ('-fPIC', '-fpic'));
+
+    my %flags = map { $_ => 1 } @flags_pie;
+
+    # Remove all PIE flags from @missing_flags as they are not required with
+    # -fPIC.
+    my @result = grep {
+        not exists $flags{$_}
+    } @{$missing_flags_ref};
+    @{$missing_flags_ref} = @result;
+
+    # We got a conflict when no flags are left, thus only PIE flags were
+    # missing. If other flags were missing abort because the conflict is not
+    # the problem.
+    return scalar @result == 0;
+}
+
+sub is_non_verbose_build {
+    my ($line, $next_line, $cc_regex, $skip_ref) = @_;
+
+    if (not ($line =~ /^checking if you want to see long compiling messages\.\.\. no/
+                or $line =~ /^\s*(?:CC|CCLD)\s+(.+?)$/
+                or $line =~ /^\s*(?:C|c)ompiling\s+(.+?)(?:\.\.\.)?$/
+                or $line =~ /^\s*(?:B|b)uilding (?:program|shared library)\s+(.+?)$/
+                or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
+        return 0;
+    }
+
+    my $file = $1;
+
+    # On the first pass we only check if this line is verbose or not.
+    return 1 if not defined $next_line;
+
+    # Second pass, we have access to the next line.
+    ${$skip_ref} = 0;
+
+    # CMake and other build systems print the non-verbose messages also when
+    # building verbose. If a compiler and the file name occurs in the next
+    # line, treat it as verbose build.
+    if (defined $file) {
+        # Get filename, we can't use the complete path as only parts of it are
+        # used in the real compiler command.
+        $file =~ m{/([a-zA-Z0-9._-]+)$};
+        $file = $1;
+
+        if ($next_line =~ /\Q$file\E/ and $next_line =~ /$cc_regex/) {
+            # We still have to skip the current line as it doesn't contain any
+            # compiler commands.
+            ${$skip_ref} = 1;
+            return 0;
+        }
+    }
+
+    return 1;
+}
+
+
+# CONSTANTS/VARIABLES
+
+# Regex to catch compiler commands.
+my $cc_regex = qr/(?:x86_64-linux-gnu-)?(?:(?<!\.)cc|gcc|g\+\+|c\+\+)(?:-[\d.]+)?/;
+# Regex to catch (GCC) compiler warnings.
+my $warning_regex = qr/^(.+?):([0-9]+):[0-9]+: warning: (.+?) \[(.+?)\]$/;
+
+# Expected hardening flags. All flags are used as regexps.
+my @cflags = (
+    '-g',
+    '-O2',
+    '-fstack-protector',
+    '--param=ssp-buffer-size=4',
+    '-Wformat',
+    '-Wformat-security',
+    '-Werror=format-security',
+);
+my @cflags_pie = (
+    '-fPIE',
+);
+my @cppflags = (
+    '-D_FORTIFY_SOURCE=2',
+);
+my @ldflags = (
+    '-Wl,(-z,)?relro',
+);
+my @ldflags_pie = (
+    '-fPIE',
+    '-pie',
+);
+my @ldflags_bindnow = (
+    '-Wl,(-z,)?now',
+);
+# All (hardening) flags.
+my @flags = (@cflags, @cflags_pie,
+             @cppflags,
+             @ldflags, @ldflags_pie, @ldflags_bindnow);
+# Renaming rules for the output so the regex parts are not visible.
+my %flag_renames = (
+    '-Wl,(-z,)?relro' => '-Wl,-z,relro',
+    '-Wl,(-z,)?now'   => '-Wl,-z,now',
+);
+
+
+# MAIN
+
+# Additional hardening options.
+my $pie     = 0;
+my $bindnow = 0;
+
 # Parse command line arguments.
+my $option_all     = 0;
 my $option_help    = 0;
 my $option_version = 0;
 if (not Getopt::Long::GetOptions(
             'help|h|?' => \$option_help,
             'version'  => \$option_version,
+            'pie'      => \$pie,
+            'bindnow'  => \$bindnow,
+            'all'      => \$option_all,
         )) {
     require Pod::Usage;
     Pod::Usage::pod2usage(2);
@@ -59,6 +239,154 @@ along with this program.  If not, see <http://www.gnu.org/licenses/>.
     exit 0;
 }
 
+if ($option_all) {
+    $pie     = 1;
+    $bindnow = 1;
+}
+
+# Final exit code.
+my $exit = 0;
+
+# Input lines, contain only the lines with compiler commands.
+my @input = ();
+
+my $start = 0;
+my $continuation = 0;
+while (my $line = <>) {
+    # We skip over unimportant lines at the beginning to prevent false
+    # positives.
+    $start = 1 if $line =~ /^dpkg-buildpackage:/;
+    next if not $start;
+
+    # Ignore compiler warnings for now.
+    next if $line =~ /$warning_regex/;
+
+    # Check if this line indicates a non verbose build.
+    my $non_verbose = is_non_verbose_build($line);
+
+    # One line may contain multiple commands (";"). Treat each one as single
+    # line.
+    my @line = split /(?<!\\);/, $line;
+    foreach $line (@line) {
+        # Add newline, drop all other whitespace at the end of a line.
+        $line =~ s/\s+$//;
+        $line .= "\n";
+
+        if ($continuation) {
+            $continuation = 0;
+
+            # Join lines, but leave the "\" in place so it's clear where the
+            # original line break was.
+            chomp $input[-1];
+            $input[-1] .= ' ' . $line;
+
+        } else {
+            # Ignore lines with no compiler commands.
+            next if $line !~ /\b$cc_regex(?:\s|\\)/ and not $non_verbose;
+
+            # Ignore false positives.
+            #
+            # `./configure` output.
+            next if not $non_verbose and $line =~ /^checking /;
+
+            push @input, $line;
+        }
+
+        # Line continuation, line ends with "\".
+        if ($line =~ /\\\s*$/) {
+            $continuation = 1;
+        }
+    }
+}
+
+if (scalar @input == 0) {
+    print "No compiler commands!\n";
+    $exit |= 1;
+    exit $exit;
+}
+
+# Check if additional hardening options were used. Used to ensure they are
+# used for the complete build.
+foreach my $line (@input) {
+    $pie     = 1 if any_flags_used($line, @cflags_pie, @ldflags_pie);
+    $bindnow = 1 if any_flags_used($line, @ldflags_bindnow);
+}
+
+if ($pie) {
+    @cflags  = (@cflags,  @cflags_pie);
+    @ldflags = (@ldflags, @ldflags_pie);
+}
+if ($bindnow) {
+    @ldflags = (@ldflags, @ldflags_bindnow);
+}
+
+for (my $i = 0; $i < scalar @input; $i++) {
+    my $line = $input[$i];
+
+    my $skip = 0;
+    if (is_non_verbose_build($line, $input[$i + 1], $cc_regex, \$skip)) {
+        error_non_verbose_build($line);
+        $exit |= 1 << 2;
+        next;
+    }
+    # Even if it's a verbose build, we might have to skip this line.
+    next if $skip;
+
+    # Ignore false positives.
+    #
+    # ./configure summary.
+    next if $line =~ /^\s*(?:C|c)ompiler[\s.]*:\s+$cc_regex(?:\s-std=[a-z0-9:+]+)?\s*$/
+            or $line =~ /^\s*- (?:CC|CXX)\s*=\s*$cc_regex\s*$/
+            or $line =~ /^\s*-- Check for working (?:C|CXX) compiler: /;
+
+    # Is this a compiler or linker command?
+    my $compiler = 1;
+    my $linker   = 0;
+
+    # Linker commands.
+    if ($line =~ m{\s-o                        # -o
+                   [\s\\]*\s+                  # possible line continuation
+                   (?:[/.A-Za-z0-9~_-]+/)?     # path to file
+                        [A-Za-z0-9~_-]+        # binary name (no dots!)
+                   (?:[0-9.]*\.so[0-9.]*[a-z]? # library (including version)
+                    |\.la)?
+                   (?:\s|\\|$)                 # end of file name
+                  }x
+            or $line =~ /^libtool: link: /
+            or $line =~ m{\s*/bin/bash .+?libtool\s+(.+?\s+)?--mode=(re)?link}) {
+        $compiler = 0;
+        $linker   = 1;
+    }
+
+    # If there are source files then it's compiling/linking in one step and we
+    # must check both.
+    if ($line =~ /\.(?:c|cc|cpp)\b/) {
+        $compiler = 1;
+    }
+
+    # Check hardening flags.
+    my @missing;
+    if ($compiler and not all_flags_used($line, \@missing, @cflags)
+            # Libraries linked with -fPIC don't have to (and can't) be linked
+            # with -fPIE as well. It's no error if only PIE flags are missing.
+            and not pic_pie_conflict($line, $pie, \@missing, @cflags_pie)) {
+        error_flags('CFLAGS missing', \@missing, \%flag_renames, $line);
+        $exit |= 1 << 3;
+    }
+    if ($compiler and not all_flags_used($line, \@missing, @cppflags)) {
+        error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $line);
+        $exit |= 1 << 3;
+    }
+    if ($linker and not all_flags_used($line, \@missing, @ldflags)
+            # Same here, -fPIC conflicts with -fPIE.
+            and not pic_pie_conflict($line, $pie, \@missing, @ldflags_pie)) {
+        error_flags('LDFLAGS missing', \@missing, \%flag_renames, $line);
+        $exit |= 1 << 3;
+    }
+}
+
+exit $exit;
+
 
 __END__
 
@@ -70,8 +398,13 @@ blhc - build log hardening check, checks build logs for missing hardening flags
 
 B<blhc> [-h -? --help]
 
+B<blhc> [--pie] [--bindnow] [--all]
+
     --help                  available options
     --version               version number and license
+    --pie                   force +pie check
+    --bindnow               force +bindbow check
+    --all                   force +all (+pie, +bindnow) check
 
 =head1 DESCRIPTION
 
@@ -90,6 +423,51 @@ Print available options.
 
 Print version number and license.
 
+=item B<--pie>
+
+Force check for all +pie hardening flags. By default it's auto detected.
+
+=item B<--bindnow>
+
+Force check for all +bindnow hardening flags. By default it's auto detected.
+
+=item B<--all>
+
+Force check for all +all (+pie, +bindnow) hardening flags. By default it's
+auto detected.
+
+=back
+
+Auto detection only works if at least one command uses the required hardening
+flag (e.g. -fPIE). Then it's required for all other commands as well.
+
+=head1 EXIT STATUS
+
+The exit status is a "bit mask", each listed status is ORed when the error
+condition occurs to get the result.
+
+=over 8
+
+=item B<0>
+
+Success.
+
+=item B<1>
+
+No compiler commands were found.
+
+=item B<2>
+
+Invalid arguments/options given to blhc.
+
+=item B<4>
+
+Non verbose build.
+
+=item B<8>
+
+Missing hardening flags.
+
 =back
 
 =head1 AUTHOR