X-Git-Url: https://ruderich.org/simon/gitweb/?a=blobdiff_plain;f=shell%2Fbin%2Fbattery.pl;fp=shell%2Fbin%2Fbattery.pl;h=c7e812ea505798b07702cd6e5567be56c58b8991;hb=29fe133e2b4ca2a25342fa9a4c3e661bc38895f2;hp=0000000000000000000000000000000000000000;hpb=3e17e82d591782b4750382b00c5bf6ee96eddedf;p=config%2Fdotfiles.git

diff --git a/shell/bin/battery.pl b/shell/bin/battery.pl
new file mode 100755
index 0000000..c7e812e
--- /dev/null
+++ b/shell/bin/battery.pl
@@ -0,0 +1,94 @@
+#!/usr/bin/perl
+
+# Copyright (C) 2011-2013  Simon Ruderich
+#
+# This program is free software: you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation, either version 3 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+
+use strict;
+use warnings;
+
+
+if (scalar @ARGV != 1 and (scalar @ARGV != 2 or not $ARGV[0] =~ /-[st]/)) {
+    print STDERR "Usage: $0 [-s | -t] <path/to/device>\n";
+    print STDERR "\n";
+    print STDERR "Normally this is /sys/class/power_supply/BAT*.\n";
+    exit 1;
+}
+if (scalar @ARGV == 1) {
+    @ARGV = ('', $ARGV[0]);
+}
+
+my $path = "$ARGV[1]/uevent";
+
+# No battery available.
+if (not -e $path) {
+    print STDERR "'$path' not found.\n";
+    exit 1;
+}
+
+my $screen_mode = ($ARGV[0] eq '-s');
+my $tmux_mode   = ($ARGV[0] eq '-t');
+
+my %battery;
+
+open my $file, '<', $path or die $!;
+while (<$file>) {
+    /^POWER_SUPPLY_([A-Z_]+)=(.+)$/;
+    $battery{$1} = $2;
+}
+close $file or die $!;
+
+# New names ...
+if (defined $battery{ENERGY_NOW}) {
+    $battery{CHARGE_NOW}  = $battery{ENERGY_NOW};
+    $battery{CHARGE_FULL} = $battery{ENERGY_FULL};
+}
+
+my $charge = int($battery{CHARGE_NOW} / $battery{CHARGE_FULL} * 100);
+my $charging = '';
+if ($battery{STATUS} eq 'Charging' or $battery{STATUS} eq 'Full') {
+    $charging = '^';
+}
+
+# GNU screen mode with colors: 0-20 red, 20-40 yellow, 40-100 green.
+if ($screen_mode) {
+    my $color;
+    if ($charge < 20) {
+        $color = 'b r';
+    } elsif ($charge < 40) {
+        $color = 'b y';
+    } else {
+        $color = 'b g';
+    }
+
+    print "\005{+$color}$charge%\005{-}$charging\n";
+
+# Same in tmux mode.
+} elsif ($tmux_mode) {
+    my $color;
+    if ($charge < 20) {
+        $color = 'red';
+    } elsif ($charge < 40) {
+        $color = 'yellow';
+    } else {
+        $color = 'green';
+    }
+
+    print "#[fg=$color,bold]$charge%#[default]$charging\n";
+
+# Plain text output.
+} else {
+    print "$charge%$charging\n";
+}