From: Simon Ruderich <simon@ruderich.org>
Date: Sat, 19 Nov 2011 11:01:43 +0000 (+0100)
Subject: vimrc: Add new text-objects ii ai for indented text.
X-Git-Url: https://ruderich.org/simon/gitweb/?a=commitdiff_plain;h=1c420fe0d57fd9e8bfbe59ab3fccca48f2f9ae2b;p=config%2Fdotfiles.git

vimrc: Add new text-objects ii ai for indented text.
---

diff --git a/vimrc b/vimrc
index e48c219..e209796 100644
--- a/vimrc
+++ b/vimrc
@@ -489,3 +489,52 @@ if has('autocmd')
 
     augroup END
 endif
+
+
+" CUSTOM FUNCTIONS
+
+if has('eval')
+    " New text-objects ii and ai to work on text with the same indentation.
+    " Thanks to
+    " http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
+    " (visited on 2011-11-19).
+    onoremap <silent>ai :<C-u>call IndTxtObj(0)<CR>
+    onoremap <silent>ii :<C-u>call IndTxtObj(1)<CR>
+    vnoremap <silent>ai :<C-u>call IndTxtObj(0)<CR><Esc>gv
+    vnoremap <silent>ii :<C-u>call IndTxtObj(1)<CR><Esc>gv
+
+    function! IndTxtObj(inner)
+        let curline = line(".")
+        let lastline = line("$")
+        let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
+        let i = i < 0 ? 0 : i
+        if getline(".") !~ "^\\s*$"
+            let p = line(".") - 1
+            let nextblank = getline(p) =~ "^\\s*$"
+            while p > 0
+                    \ && ((i == 0 && !nextblank)
+                        \ || (i > 0 && ((indent(p) >= i
+                            \ && !(nextblank && a:inner))
+                            \ || (nextblank && !a:inner))))
+                -
+                let p = line(".") - 1
+                let nextblank = getline(p) =~ "^\\s*$"
+            endwhile
+            normal! 0V
+            call cursor(curline, 0)
+            let p = line(".") + 1
+            let nextblank = getline(p) =~ "^\\s*$"
+            while p <= lastline
+                    \ && ((i == 0 && !nextblank)
+                        \ || (i > 0 && ((indent(p) >= i
+                            \ && !(nextblank && a:inner))
+                            \ || (nextblank && !a:inner))))
+                +
+                let p = line(".") + 1
+                let nextblank = getline(p) =~ "^\\s*$"
+            endwhile
+            normal! $
+        endif
+    endfunction
+
+endif