From 6cdb1f0d39808c9a819fc7ac279469c40bfd8d82 Mon Sep 17 00:00:00 2001
From: Simon Ruderich <simon@ruderich.org>
Date: Mon, 19 Jan 2009 10:43:27 +0100
Subject: [PATCH] When using screen use current command as window name.

This makes finding the correct screen window much easier.

Doesn't work with ^Z and fg yet; fg is then displayed as command instead the
real running command.
---
 zsh/rc | 39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

diff --git a/zsh/rc b/zsh/rc
index f3bebe8..14c3c16 100644
--- a/zsh/rc
+++ b/zsh/rc
@@ -91,6 +91,45 @@ add-zsh-hook precmd prompt_precmd
 # Display the vcs information in the right prompt.
 RPROMPT='${vcs_info_msg_0_}'
 
+# When screen is used set the name of the window to the currently running
+# program.
+#
+# When a program is started preexec() sets the window's name to it; when it
+# stops precmd() resets the windows' name to 'zsh'.
+if [[ $TERM == screen ]]; then
+    # Set to a non empty value to reset the window name in the next precmd()
+    # call.
+    screen_name_reset=yes
+
+    screen_preexec() {
+        # Ignore often used commands which are only running for a very short
+        # time. This prevents a "blinking" name when it's changed to "cd" for
+        # example and then some milliseconds later back to "zsh".
+        [[ ${1%% *} == (cd*|ls|la|ll|clear) ]] && return
+
+        # Set the window name to the currently running program.
+        print -n "\ek${1%% *}\e\\"
+
+        # Tell precmd() to reset the window name when the program stops.
+        screen_name_reset=yes
+    }
+
+    screen_precmd() {
+        # Abort if no window name reset is necessary.
+        [[ -z $screen_name_reset ]] && return
+
+        # Reset the window name to 'zsh'.
+        print -n "\ekzsh\e\\"
+
+        # Just reset the name, so no screen reset necessary for the moment.
+        screen_name_reset=
+    }
+
+    # Add the preexec() and precmd() hooks.
+    add-zsh-hook preexec screen_preexec
+    add-zsh-hook precmd screen_precmd
+fi
+
 
 # COMPLETION SETTINGS
 
-- 
2.44.2