bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2020  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.11';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+|gfortran|mpicc|mpicxx|mpifort)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full_prefix = qr/
  42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
  43     /x;
  44 my $cc_regex_full = qr/
  45     (?:$cc_regex_full_prefix-)?
  46     $cc_regex
  47     /x;
  48 # Regex to check if a line contains a compiler command.
  49 my $cc_regex_normal = qr/
  50     \b$cc_regex(?:\s|\\)
  51     /x;
  52 # Regex to catch (GCC) compiler warnings.
  53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  54 # Regex to catch libtool commands and not lines which show commands executed
  55 # by libtool (e.g. libtool: link: ...).
  56 my $libtool_regex = qr/\blibtool["']?\s.*--mode=/;
  57 my $libtool_link_regex = qr/\blibtool: link: /;
  58
  59 # List of source file extensions which require preprocessing.
  60 my @source_preprocess_compile_cpp = (
  61     # C++
  62     qw( cc cp cxx cpp CPP c++ C ),
  63     # Objective-C++
  64     qw( mm M ),
  65 );
  66 my @source_preprocess_compile_fortran = (
  67     # Fortran
  68     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  69 );
  70 my @source_preprocess_compile = (
  71     # C
  72     qw( c ),
  73     # Objective-C
  74     qw( m ),
  75     # (Objective-)C++
  76     @source_preprocess_compile_cpp,
  77     # Fortran
  78     @source_preprocess_compile_fortran,
  79 );
  80 my @source_preprocess_no_compile = (
  81     # Assembly
  82     qw( S sx ),
  83 );
  84 my @source_preprocess = (
  85     @source_preprocess_compile,
  86     @source_preprocess_no_compile,
  87 );
  88 # List of source file extensions which don't require preprocessing.
  89 my @source_no_preprocess_compile_cpp = (
  90     # C++
  91     qw( ii ),
  92     # Objective-C++
  93     qw( mii ),
  94 );
  95 my @source_no_preprocess_compile_ada = (
  96     # Ada source
  97     qw( ada ),
  98     # Ada body
  99     qw( adb ),
 100 );
 101 my @source_no_preprocess_compile_fortran = (
 102     # Fortran
 103     qw( f for ftn f90 f95 f03 f08 ),
 104 );
 105 my @source_no_preprocess_compile = (
 106     # C
 107     qw( i ),
 108     # (Objective-)C++
 109     @source_no_preprocess_compile_cpp,
 110     # Objective-C
 111     qw( mi ),
 112     # Fortran
 113     @source_no_preprocess_compile_fortran,
 114     # Ada
 115     @source_no_preprocess_compile_ada,
 116 );
 117 my @source_no_preprocess_no_compile_ada = (
 118     # Ada specification
 119     qw( ads ),
 120 );
 121 my @source_no_preprocess_no_compile = (
 122     # Assembly
 123     qw( s ),
 124     # Ada
 125     @source_no_preprocess_no_compile_ada,
 126 );
 127 my @source_no_preprocess = (
 128     @source_no_preprocess_compile,
 129     @source_no_preprocess_no_compile,
 130 );
 131 # List of header file extensions which require preprocessing.
 132 my @header_preprocess = (
 133     # C, C++, Objective-C, Objective-C++
 134     qw( h ),
 135     # C++
 136     qw( hh H hp hxx hpp HPP h++ tcc ),
 137 );
 138 # Object files.
 139 my @object = (
 140     # Normal object files.
 141     qw ( o ),
 142     # Libtool object files.
 143     qw ( lo la ),
 144     # Dynamic libraries. bzip2 uses .sho.
 145     qw ( so sho ),
 146     # Static libraries.
 147     qw ( a ),
 148 );
 149
 150 # Hashes for fast extensions lookup to check if a file falls in one of these
 151 # categories.
 152 my %extensions_no_preprocess = map { $_ => 1 } (
 153     # There's no @header_no_preprocess.
 154     @source_no_preprocess,
 155 );
 156 my %extensions_preprocess = map { $_ => 1 } (
 157     @header_preprocess,
 158     @source_preprocess,
 159 );
 160 my %extensions_compile_link = map { $_ => 1 } (
 161     @source_preprocess,
 162     @source_no_preprocess,
 163 );
 164 my %extensions_compile = map { $_ => 1 } (
 165     @source_preprocess_compile,
 166     @source_no_preprocess_compile,
 167 );
 168 my %extensions_no_compile = map { $_ => 1 } (
 169     @source_preprocess_no_compile,
 170     @source_no_preprocess_no_compile,
 171 );
 172 my %extensions_compile_cpp = map { $_ => 1 } (
 173     @source_preprocess_compile_cpp,
 174     @source_no_preprocess_compile_cpp,
 175 );
 176 my %extensions_ada = map { $_ => 1 } (
 177     @source_no_preprocess_compile_ada,
 178     @source_no_preprocess_no_compile_ada,
 179 );
 180 my %extensions_fortran = map { $_ => 1 } (
 181     @source_no_preprocess_compile_fortran,
 182     @source_preprocess_compile_fortran,
 183 );
 184 my %extensions_object = map { $_ => 1 } (
 185     @object,
 186 );
 187 my %extension = map { $_ => 1 } (
 188     @source_no_preprocess,
 189     @header_preprocess,
 190     @source_preprocess,
 191     @object,
 192 );
 193
 194 # Regexp to match file extensions.
 195 my $file_extension_regex = qr/
 196     \s
 197     \S+             # Filename without extension.
 198     \.
 199     ([^\/\\.,;:\s]+)# File extension.
 200     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 201                     # word characters at the end and because \b matches double
 202                     # extensions (like .cpp.o). Works always as all lines are
 203                     # terminated with "\n".
 204     /x;
 205
 206 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 207 # real regexps below for better execution speed).
 208 my @def_cflags = (
 209     '-g',
 210     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
 211 );
 212 my @def_cflags_debug = (
 213     # These flags indicate a debug build which disables checks for -O2.
 214     '-O0',
 215     '-Og',
 216 );
 217 my @def_cflags_format = (
 218     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 219     '-Werror=format-security', # implies -Wformat-security
 220 );
 221 my @def_cflags_fortify = (
 222     # fortify needs at least -O1, but -O2 is recommended anyway
 223 );
 224 my @def_cflags_stack = (
 225     '-fstack-protector', # keep first, used by cflags_stack_broken()
 226     '--param[= ]ssp-buffer-size=4',
 227 );
 228 my @def_cflags_stack_strong = (
 229     '-fstack-protector-strong', # keep first, used by cflags_stack_broken()
 230 );
 231 my @def_cflags_stack_bad = (
 232     # Blacklist all stack protector options for simplicity.
 233     '-fno-stack-protector',
 234     '-fno-stack-protector-all',
 235     '-fno-stack-protector-strong',
 236 );
 237 my @def_cflags_pie = (
 238     '-fPIE',
 239 );
 240 my @def_cxxflags = (
 241     @def_cflags,
 242 );
 243 # @def_cxxflags_* is the same as @def_cflags_*.
 244 my @def_cppflags = ();
 245 my @def_cppflags_fortify = (
 246     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 247     # If you add another flag fix hack below (search for "Hack to fix") and
 248     # $def_cppflags_fortify[0].
 249 );
 250 my @def_cppflags_fortify_bad = (
 251     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 252     '-U_FORTIFY_SOURCE',
 253     '-D_FORTIFY_SOURCE=0',
 254     '-D_FORTIFY_SOURCE=1',
 255 );
 256 my @def_ldflags = ();
 257 my @def_ldflags_relro = (
 258     '-Wl,(?:-z,)?relro',
 259 );
 260 my @def_ldflags_bindnow = (
 261     '-Wl,(?:-z,)?now',
 262 );
 263 my @def_ldflags_pie = (
 264     '-fPIE',
 265     '-pie',
 266 );
 267 my @def_ldflags_pic = (
 268     '-fPIC',
 269     '-fpic',
 270     '-shared',
 271 );
 272 # References to all flags checked by the flag checker.
 273 my @flag_refs = (
 274     \@def_cflags,
 275     \@def_cflags_format,
 276     \@def_cflags_fortify,
 277     \@def_cflags_stack,
 278     \@def_cflags_stack_strong,
 279     \@def_cflags_stack_bad,
 280     \@def_cflags_pie,
 281     \@def_cxxflags,
 282     \@def_cppflags,
 283     \@def_cppflags_fortify,
 284     \@def_ldflags,
 285     \@def_ldflags_relro,
 286     \@def_ldflags_bindnow,
 287     \@def_ldflags_pie,
 288 );
 289 # References to all used flags.
 290 my @flag_refs_all = (
 291     @flag_refs,
 292     \@def_cflags_debug,
 293     \@def_cppflags_fortify_bad,
 294     \@def_ldflags_pic,
 295 );
 296 # Renaming rules for the output so the regex parts are not visible. Also
 297 # stores string values of flag regexps above, see compile_flag_regexp().
 298 my %flag_renames = (
 299     '-O(?:2|3)'                    => '-O2',
 300     '-Wformat(?:=2)?'              => '-Wformat',
 301     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 302     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 303     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 304 );
 305
 306 my %exit_code = (
 307     no_compiler_commands => 1 << 0,
 308     # used by POD::Usage => 1 << 1,
 309     non_verbose_build    => 1 << 2,
 310     flags_missing        => 1 << 3,
 311     hardening_wrapper    => 1 << 4,
 312     invalid_cmake        => 1 << 5,
 313 );
 314
 315 my %buildd_tag = (
 316     no_compiler_commands => 'I-no-compiler-commands',
 317     non_verbose_build    => 'W-compiler-flags-hidden',
 318     flags_missing        => 'W-dpkg-buildflags-missing',
 319     hardening_wrapper    => 'I-hardening-wrapper-used',
 320     invalid_cmake        => 'I-invalid-cmake-used',
 321 );
 322
 323 # Statistics of missing flags and non-verbose build commands. Used for
 324 # $option_buildd.
 325 my %statistics = (
 326     preprocess          => 0,
 327     preprocess_missing  => 0,
 328     compile             => 0,
 329     compile_missing     => 0,
 330     compile_cpp         => 0,
 331     compile_cpp_missing => 0,
 332     link                => 0,
 333     link_missing        => 0,
 334     commands            => 0,
 335     commands_nonverbose => 0,
 336 );
 337
 338 # Use colored (ANSI) output?
 339 my $option_color;
 340
 341
 342 # FUNCTIONS
 343
 344 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 345 sub array_equal {
 346     my ($first_ref, $second_ref) = @_;
 347
 348     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 349
 350     my $length = scalar @{$first_ref};
 351     for (my $i = 0; $i < $length; $i++) {
 352         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 353     }
 354
 355     return 1;
 356 }
 357
 358 sub error_flags {
 359     my ($message, $missing_flags_ref, $flag_renames_ref, $line, $number) = @_;
 360
 361     # Get string value of qr//-escaped regexps and if requested rename them.
 362     my @missing_flags = map {
 363             $flag_renames_ref->{$_}
 364         } @{$missing_flags_ref};
 365
 366     my $flags = join ' ', @missing_flags;
 367     printf '%d:', $number if defined $number;
 368     printf '%s (%s)%s %s',
 369            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 370            $line;
 371
 372     return;
 373 }
 374 sub error_non_verbose_build {
 375     my ($line, $number) = @_;
 376
 377     printf '%d:', $number if defined $number;
 378     printf '%s%s %s',
 379            error_color('NONVERBOSE BUILD', 'red'),
 380            error_color(':', 'yellow'),
 381            $line;
 382
 383     return;
 384 }
 385 sub error_invalid_cmake {
 386     my ($version) = @_;
 387
 388     printf "%s%s %s\n",
 389             error_color('INVALID CMAKE', 'red'),
 390             error_color(':', 'yellow'),
 391             $version;
 392
 393     return;
 394 }
 395 sub error_hardening_wrapper {
 396     printf "%s%s %s\n",
 397             error_color('HARDENING WRAPPER', 'red'),
 398             error_color(':', 'yellow'),
 399             'no checks possible, aborting';
 400
 401     return;
 402 }
 403 sub error_color {
 404     my ($message, $color) = @_;
 405
 406     if ($option_color) {
 407         return Term::ANSIColor::colored($message, $color);
 408     } else {
 409         return $message;
 410     }
 411 }
 412
 413 sub any_flags_used {
 414     my ($line, @flags) = @_;
 415
 416     foreach my $flag (@flags) {
 417         return 1 if $line =~ /$flag/;
 418     }
 419
 420     return 0;
 421 }
 422 sub all_flags_used {
 423     my ($line, $missing_flags_ref, @flags) = @_;
 424
 425     my @missing_flags = ();
 426     foreach my $flag (@flags) {
 427         if (not $line =~ /$flag/) {
 428             push @missing_flags, $flag;
 429         }
 430     }
 431
 432     return 1 if scalar @missing_flags == 0;
 433
 434     @{$missing_flags_ref} = @missing_flags;
 435     return 0;
 436 }
 437 # Check if any of \@bad_flags occurs after $good_flag. Doesn't check if
 438 # $good_flag is present.
 439 sub flag_overwritten {
 440     my ($line, $good_flag, $bad_flags) = @_;
 441
 442     if (not any_flags_used($line, @{$bad_flags})) {
 443         return 0;
 444     }
 445
 446     my $bad_pos = 0;
 447     foreach my $flag (@{$bad_flags}) {
 448         while ($line =~ /$flag/g) {
 449             if ($bad_pos < $+[0]) {
 450                 $bad_pos = $+[0];
 451             }
 452         }
 453     }
 454     my $good_pos = 0;
 455     while ($line =~ /$good_flag/g) {
 456         $good_pos = $+[0];
 457     }
 458     if ($good_pos > $bad_pos) {
 459         return 0;
 460     }
 461     return 1;
 462 }
 463
 464 sub cppflags_fortify_broken {
 465     my ($line, $missing_flags) = @_;
 466
 467     # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 468     my $fortify_source = $def_cppflags_fortify[0];
 469
 470     # Some build systems enable/disable fortify source multiple times, check
 471     # the final result.
 472     if (not flag_overwritten($line,
 473                              $fortify_source,
 474                              \@def_cppflags_fortify_bad)) {
 475         return 0;
 476     }
 477     push @{$missing_flags}, $fortify_source;
 478     return 1;
 479 }
 480
 481 sub cflags_stack_broken {
 482     my ($line, $missing_flags, $strong) = @_;
 483
 484     my $flag = $strong ? $def_cflags_stack_strong[0]
 485                        : $def_cflags_stack[0];
 486
 487     if (not flag_overwritten($line, $flag, \@def_cflags_stack_bad)) {
 488         return 0;
 489     }
 490     push @{$missing_flags}, $flag;
 491     return 1;
 492 }
 493
 494 # Modifies $missing_flags_ref array.
 495 sub pic_pie_conflict {
 496     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 497
 498     return 0 if not $pie;
 499     return 0 if not any_flags_used($line, @def_ldflags_pic);
 500
 501     my %flags = map { $_ => 1 } @flags_pie;
 502
 503     # Remove all PIE flags from @missing_flags as they are not required with
 504     # -fPIC.
 505     my @result = grep {
 506         not exists $flags{$_}
 507     } @{$missing_flags_ref};
 508     @{$missing_flags_ref} = @result;
 509
 510     # We got a conflict when no flags are left, thus only PIE flags were
 511     # missing. If other flags were missing abort because the conflict is not
 512     # the problem.
 513     return scalar @result == 0;
 514 }
 515
 516 sub is_non_verbose_build {
 517     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
 518
 519     if ($line =~ /$libtool_regex/o) {
 520         # libtool's --silent hides the real compiler flags.
 521         if ($line =~ /\s--silent/) {
 522             return 1;
 523         # If --silent is not present, skip this line as some compiler flags
 524         # might be missing (e.g. -fPIE) which are handled correctly by libtool
 525         # internally. libtool displays the real compiler command on the next
 526         # line, so the flags are checked as usual.
 527         } else {
 528             ${$skip_ref} = 1;
 529             return 0;
 530         }
 531     }
 532
 533     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 534                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 535                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 536                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 537                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 538         return 0;
 539     }
 540
 541     # False positives.
 542     #
 543     # C++ compiler setting.
 544     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 545     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 546     # "Compiling" non binary files.
 547     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|pyx|el)['"]?\s*(?:\.\.\.|because it changed\.)?$/;
 548     return 0 if $line =~ /^\s*[Cc]ompiling catalog \S+\.po\b/;
 549     # "Compiling" with no file name.
 550     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 551         # $file_extension_regex may need spaces around the filename.
 552         return 0 if not " $1 " =~ /$file_extension_regex/o;
 553     }
 554
 555     my $file = $1;
 556
 557     # On the first pass we only check if this line is verbose or not.
 558     return 1 if not defined $input_ref;
 559
 560     # Second pass, we have access to the next lines.
 561     ${$skip_ref} = 0;
 562
 563     # CMake and other build systems print the non-verbose messages also when
 564     # building verbose. If a compiler and the file name occurs in the next
 565     # lines, treat it as verbose build.
 566     if (defined $file) {
 567         # Get filename, we can't use the complete path as only parts of it are
 568         # used in the real compiler command.
 569         $file =~ m{/([^/\s]+)$};
 570         $file = $1;
 571
 572         for (my $i = 1; $i <= $line_count; $i++) {
 573             my $next_line = $input_ref->[$line_offset + $i];
 574             last unless defined $next_line;
 575
 576             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 577                 # Not a non-verbose line, but we still have to skip the
 578                 # current line as it doesn't contain any compiler commands.
 579                 ${$skip_ref} = 1;
 580                 return 0;
 581             }
 582         }
 583     }
 584
 585     return 1;
 586 }
 587
 588 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
 589 sub remove_flags {
 590     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 591
 592     my %removes = map { $_ => 1 } @flags;
 593     foreach my $flags (@{$flag_refs_ref}) {
 594         @{$flags} = grep {
 595             # Flag found as string.
 596             not exists $removes{$_}
 597             # Flag found as string representation of regexp.
 598                 and (not defined $flag_renames_ref->{$_}
 599                         or not exists $removes{$flag_renames_ref->{$_}})
 600         } @{$flags};
 601     }
 602
 603     return;
 604 }
 605
 606 # Modifies $flag_renames_ref hash.
 607 sub compile_flag_regexp {
 608     my ($flag_renames_ref, @flags) = @_;
 609
 610     my @result = ();
 611     foreach my $flag (@flags) {
 612         # Compile flag regexp for faster execution.
 613         my $regex = qr/\s$flag(?:\s|\\)/;
 614
 615         # Store flag name in replacement string for correct flags in messages
 616         # with qr//ed flag regexps.
 617         $flag_renames_ref->{$regex}
 618             = (exists $flag_renames_ref->{$flag})
 619                 ? $flag_renames_ref->{$flag}
 620                 : $flag;
 621
 622         push @result, $regex;
 623     }
 624     return @result;
 625 }
 626
 627 # Does any extension in @extensions exist in %{$extensions_ref}?
 628 sub extension_found {
 629     my ($extensions_ref, @extensions) = @_;
 630
 631     foreach my $extension (@extensions) {
 632         if (exists $extensions_ref->{$extension}) {
 633             return 1;
 634         }
 635     }
 636     return 0;
 637 }
 638
 639
 640 # MAIN
 641
 642 # Parse command line arguments.
 643 my $option_help             = 0;
 644 my $option_version          = 0;
 645 my $option_pie              = 0;
 646 my $option_bindnow          = 0;
 647 my @option_ignore_arch      = ();
 648 my @option_ignore_flag      = ();
 649 my @option_ignore_arch_flag = ();
 650 my @option_ignore_line      = ();
 651 my @option_ignore_arch_line = ();
 652 my $option_all              = 0;
 653 my $option_arch             = undef;
 654 my $option_buildd           = 0;
 655 my $option_debian           = 0;
 656    $option_color            = 0;
 657 my $option_line_numbers     = 0;
 658 if (not Getopt::Long::GetOptions(
 659             'help|h|?'           => \$option_help,
 660             'version'            => \$option_version,
 661             # Hardening options.
 662             'pie'                => \$option_pie,
 663             'bindnow'            => \$option_bindnow,
 664             'all'                => \$option_all,
 665             # Ignore.
 666             'ignore-arch=s'      => \@option_ignore_arch,
 667             'ignore-flag=s'      => \@option_ignore_flag,
 668             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 669             'ignore-line=s'      => \@option_ignore_line,
 670             'ignore-arch-line=s' => \@option_ignore_arch_line,
 671             # Misc.
 672             'color'              => \$option_color,
 673             'arch=s'             => \$option_arch,
 674             'buildd'             => \$option_buildd,
 675             'debian'             => \$option_debian,
 676             'line-numbers'       => \$option_line_numbers,
 677         )) {
 678     require Pod::Usage;
 679     Pod::Usage::pod2usage(2);
 680 }
 681 if ($option_help) {
 682     require Pod::Usage;
 683     Pod::Usage::pod2usage(1);
 684 }
 685 if ($option_version) {
 686     print <<"EOF";
 687 blhc $VERSION  Copyright (C) 2012-2020  Simon Ruderich
 688
 689 This program is free software: you can redistribute it and/or modify
 690 it under the terms of the GNU General Public License as published by
 691 the Free Software Foundation, either version 3 of the License, or
 692 (at your option) any later version.
 693
 694 This program is distributed in the hope that it will be useful,
 695 but WITHOUT ANY WARRANTY; without even the implied warranty of
 696 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 697 GNU General Public License for more details.
 698
 699 You should have received a copy of the GNU General Public License
 700 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 701 EOF
 702     exit 0;
 703 }
 704
 705 # Arguments missing.
 706 if (scalar @ARGV == 0) {
 707     require Pod::Usage;
 708     Pod::Usage::pod2usage(2);
 709 }
 710
 711 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 712 # installed on Debian's buildds.
 713 if (not $option_buildd) {
 714     require Term::ANSIColor;
 715 }
 716
 717 if ($option_all) {
 718     $option_pie     = 1;
 719     $option_bindnow = 1;
 720 }
 721
 722 # Precompiled ignores for faster lookup.
 723 my %option_ignore_arch_flag = ();
 724 my %option_ignore_arch_line = ();
 725
 726 # Strip flags which should be ignored.
 727 if (scalar @option_ignore_flag > 0) {
 728     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 729 }
 730 # Same for arch specific ignore flags, but only prepare here.
 731 if (scalar @option_ignore_arch_flag > 0) {
 732     foreach my $ignore (@option_ignore_arch_flag) {
 733         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 734
 735         if (not $ignore_arch or not $ignore_flag) {
 736             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 737                         . '("arch:flag" expected)' . "\n", $ignore;
 738             require Pod::Usage;
 739             Pod::Usage::pod2usage(2);
 740         }
 741
 742         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 743     }
 744 }
 745
 746 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 747 # faster with this.
 748 foreach my $flags (@flag_refs_all) {
 749     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 750 }
 751
 752 # Precompile ignore line regexps, also anchor at beginning and end of line.
 753 # Additional entries are also extracted from the build log, see below.
 754 foreach my $ignore (@option_ignore_line) {
 755     $ignore = qr/^$ignore$/;
 756 }
 757 # Same for arch specific ignore lines.
 758 if (scalar @option_ignore_arch_line > 0) {
 759     foreach my $ignore (@option_ignore_arch_line) {
 760         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 761
 762         if (not $ignore_arch or not $ignore_line) {
 763             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 764                         . '("arch:line" expected)' . "\n", $ignore;
 765             require Pod::Usage;
 766             Pod::Usage::pod2usage(2);
 767         }
 768
 769         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 770     }
 771 }
 772
 773 # Final exit code.
 774 my $exit = 0;
 775
 776 FILE:
 777 foreach my $file (@ARGV) {
 778     print "checking '$file'...\n" if scalar @ARGV > 1;
 779
 780     -f $file or die "No such file: $file";
 781
 782     open my $fh, '<', $file or die $!;
 783
 784     # Architecture of this file.
 785     my $arch = $option_arch;
 786
 787     # Hardening options. Not all architectures support all hardening options.
 788     my $harden_format  = 1;
 789     my $harden_fortify = 1;
 790     my $harden_stack   = 1;
 791     my $harden_stack_strong = 1;
 792     my $harden_relro   = 1;
 793     my $harden_bindnow = $option_bindnow; # defaults to 0
 794     my $harden_pie     = $option_pie;     # defaults to 0
 795
 796     # Number of parallel jobs to prevent false positives when detecting
 797     # non-verbose builds. As not all jobs declare the number of parallel jobs
 798     # use a large enough default.
 799     my $parallel = 10;
 800
 801     # Don't check for PIE flags if automatically applied by the compiler. Only
 802     # used in buildd and Debian mode.
 803     my $disable_harden_pie = 0;
 804     if ($option_debian) {
 805         $disable_harden_pie = 1;
 806     }
 807
 808     my $number = 0;
 809     while (my $line = <$fh>) {
 810         $number++;
 811
 812         # Detect architecture automatically unless overridden. For buildd logs
 813         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 814         # build logs which aren't built (wrong architecture, build error,
 815         # etc.).
 816         if (not $arch) {
 817             if (index($line, 'Build Architecture: ') == 0) {
 818                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 819             # For old logs (sbuild << 0.63.0-1).
 820             } elsif (index($line, 'Architecture: ') == 0) {
 821                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 822             }
 823         }
 824
 825         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 826         # check for hardening flags in buildd mode if an older dpkg-dev is
 827         # used. Default flags (-g -O2) are still checked.
 828         #
 829         # Packages which were built before 1.16.1 but used their own hardening
 830         # flags are not checked.
 831         #
 832         # Strong stack protector is used since dpkg 1.17.11.
 833         #
 834         # Recent GCC versions automatically use PIE (only on supported
 835         # architectures) and dpkg respects this properly since 1.18.15 and
 836         # doesn't pass PIE flags manually.
 837         if ($option_buildd
 838                 and index($line, 'Toolchain package versions: ') == 0) {
 839             require Dpkg::Version;
 840
 841             my $disable = 1;
 842             my $disable_strong = 1;
 843
 844             if ($line =~ /\bdpkg-dev_(\S+)/) {
 845                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
 846                     $disable = 0;
 847                 }
 848                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
 849                     $disable_strong = 0;
 850                 }
 851                 if (Dpkg::Version::version_compare($1, '1.18.15') >= 0) {
 852                     $disable_harden_pie = 1;
 853                 }
 854             }
 855
 856             if ($disable) {
 857                 $harden_format  = 0;
 858                 $harden_fortify = 0;
 859                 $harden_stack   = 0;
 860                 $harden_relro   = 0;
 861                 $harden_bindnow = 0;
 862                 $harden_pie     = 0;
 863             }
 864             if ($disable_strong) {
 865                 $harden_stack_strong = 0;
 866             }
 867         }
 868
 869         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 870         # this was later dropped because upstream rejected the patch. Thus
 871         # build logs with these versions will have fortify hardening flags
 872         # enabled, even though they may be not correctly set and are missing
 873         # when build with later CMake versions. Thanks to Aron Xu for letting
 874         # me know.
 875         if (index($line, 'Package versions: ') == 0
 876                 and $line =~ /\bcmake_(\S+)/
 877                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 878             if (not $option_buildd) {
 879                 error_invalid_cmake($1);
 880                 $exit |= $exit_code{invalid_cmake};
 881             } else {
 882                 print "$buildd_tag{invalid_cmake}|$1|\n";
 883             }
 884         }
 885
 886         # Debian's build daemons use "Filtered Build-Depends:" (or just
 887         # "Build-Depends:" in older versions) for the build dependencies, but
 888         # pbuilder uses "Depends:"; support both.
 889         if (index($line, 'Filtered Build-Depends: ') == 0
 890                 or index($line, 'Build-Depends: ') == 0
 891                 or index($line, 'Depends: ') == 0) {
 892             # If hardening wrapper is used (wraps calls to gcc and adds
 893             # hardening flags automatically) we can't perform any checks,
 894             # abort.
 895             if ($line =~ /\bhardening-wrapper\b/) {
 896                 if (not $option_buildd) {
 897                     error_hardening_wrapper();
 898                     $exit |= $exit_code{hardening_wrapper};
 899                 } else {
 900                     print "$buildd_tag{hardening_wrapper}||\n";
 901                 }
 902                 next FILE;
 903             }
 904         }
 905
 906         # This flags is not always available, but if it is use it.
 907         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
 908             $parallel = $1 * 2;
 909         }
 910
 911         # We skip over unimportant lines at the beginning of the log to
 912         # prevent false positives.
 913         last if index($line, 'dpkg-buildpackage: ') == 0;
 914     }
 915
 916     # Input lines, contain only the lines with compiler commands.
 917     my @input = ();
 918     # Non-verbose lines in the input. Used to reduce calls to
 919     # is_non_verbose_build() (which is quite slow) in the second loop when
 920     # it's already clear if a line is non-verbose or not.
 921     my @input_nonverbose = ();
 922     # Input line number.
 923     my @input_number = ();
 924
 925     my $continuation = 0;
 926     my $complete_line = undef;
 927     my $non_verbose;
 928     while (my $line = <$fh>) {
 929         $number++;
 930
 931         # And stop at the end of the build log. Package details (reported by
 932         # the buildd logs) are not important for us. This also prevents false
 933         # positives.
 934         last if index($line, 'Build finished at ') == 0
 935                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 936
 937         if (not $continuation) {
 938             $non_verbose = 0;
 939         }
 940
 941         # Detect architecture automatically unless overridden.
 942         if (not $arch
 943                 and index($line, 'dpkg-buildpackage: info: host architecture ') == 0) {
 944             $arch = substr $line, 43, -1; # -1 to ignore '\n' at the end
 945         # Older versions of dpkg-buildpackage
 946         } elsif (not $arch
 947                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 948             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 949
 950             # Old buildd logs use e.g. "host architecture is alpha", remove
 951             # the "is", otherwise debarch_to_debtriplet() will not detect the
 952             # architecture.
 953             if (index($arch, 'is ') == 0) {
 954                 $arch = substr $arch, 3;
 955             }
 956         }
 957
 958         # Permit dynamic excludes from within the build log to ignore false
 959         # positives. Cannot use a separate config file as we often only have
 960         # the build log itself.
 961         if (index($line, 'blhc: ignore-line-regexp: ') == 0) {
 962             my $ignore = substr $line, 26, -1; # -1 to ignore '\n' at the end
 963             push @option_ignore_line, qr/^$ignore$/;
 964             next;
 965         }
 966
 967         next if $line =~ /^\s*#/;
 968         # Ignore compiler warnings for now.
 969         next if $line =~ /$warning_regex/o;
 970
 971         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 972             # Remove all ANSI color sequences which are sometimes used in
 973             # non-verbose builds.
 974             $line = Term::ANSIColor::colorstrip($line);
 975             # Also strip '\0xf' (delete previous character), used by Elinks'
 976             # build system.
 977             $line =~ s/\x0f//g;
 978             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 979             # what it does).
 980             $line =~ s/\033\(B//g;
 981         }
 982
 983         # Check if this line indicates a non verbose build.
 984         my $skip = 0;
 985         $non_verbose |= is_non_verbose_build($line, \$skip);
 986         next if $skip;
 987
 988         # One line may contain multiple commands (";"). Treat each one as
 989         # single line. parse_line() is slow, only use it when necessary.
 990         my @line = (index($line, ';') == -1)
 991                  ? ($line)
 992                  : map {
 993                        # Ensure newline at the line end - necessary for
 994                        # correct parsing later.
 995                        $_ =~ s/\s+$//;
 996                        $_ .= "\n";
 997                    } Text::ParseWords::parse_line(';', 1, $line);
 998         foreach my $line (@line) {
 999             if ($continuation) {
1000                 $continuation = 0;
1001
1002                 # Join lines, but leave the "\" in place so it's clear where
1003                 # the original line break was.
1004                 chomp $complete_line;
1005                 $complete_line .= ' ' . $line;
1006             }
1007             # Line continuation, line ends with "\".
1008             if ($line =~ /\\$/) {
1009                 $continuation = 1;
1010                 # Start line continuation.
1011                 if (not defined $complete_line) {
1012                     $complete_line = $line;
1013                 }
1014                 next;
1015             }
1016
1017             # Use the complete line if a line continuation occurred.
1018             if (defined $complete_line) {
1019                 $line = $complete_line;
1020                 $complete_line = undef;
1021             }
1022
1023             # Ignore lines with no compiler commands.
1024             next if not $non_verbose
1025                     and not $line =~ /$cc_regex_normal/o;
1026             # Ignore lines with no filenames with extensions. May miss some
1027             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
1028             # a problem as the log will most likely contain other non-verbose
1029             # commands which are detected.
1030             next if not $non_verbose
1031                     and not $line =~ /$file_extension_regex/o;
1032
1033             # Ignore false positives.
1034             #
1035             # `./configure` output.
1036             next if not $non_verbose
1037                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
1038             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
1039                                 [Cc]ompiler[\s.]*:?\s+
1040                                 /x;
1041             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
1042                                 \s*=\s*$cc_regex_full
1043                                 # optional compiler options, don't allow
1044                                 # "everything" here to prevent false negatives
1045                                 \s*(?:\s-\S+)*\s*$}xo;
1046             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
1047             # line (or similar for other architectures) which gets recognized
1048             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
1049             # C++ files. No hardening flags are relevant during this step,
1050             # thus ignore `moc-qt*` lines. The resulting files will be
1051             # compiled in a separate step (and therefore checked).
1052             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
1053                                \s.+\s
1054                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
1055                                \s}x;
1056             # Ignore false positives when the line contains only CC=gcc but no
1057             # other gcc command.
1058             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
1059                 my $before = $1;
1060                 my $after  = $2;
1061                 next if     not $before =~ /$cc_regex_normal/o
1062                         and not $after  =~ /$cc_regex_normal/o;
1063             }
1064             # Ignore false positives caused by gcc -v. It outputs a line
1065             # looking like a normal compiler line but which is sometimes
1066             # missing hardening flags, although the normal compiler line
1067             # contains them.
1068             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
1069                                    [0-9.]+/cc1(?:plus)?}xo;
1070             # Ignore false positive with `rm` which may remove files which
1071             # look like a compiler executable thus causing the line to be
1072             # treated as a normal compiler line.
1073             next if $line =~ m{^\s*rm\s+};
1074             next if $line =~ m{^\s*dwz\s+};
1075             # Some build systems emit "gcc > file".
1076             next if $line =~ m{$cc_regex_normal\s*>\s*\S+}o;
1077             # Hex output may contain "cc".
1078             next if $line =~ m#(?:\b[0-9a-fA-F]{2,}\b\s*){5}#;
1079             # Meson build output
1080             next if $line =~ /^C\+\+ linker for the host machine: /;
1081
1082             # Check if additional hardening options were used. Used to ensure
1083             # they are used for the complete build.
1084             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
1085                                                          @def_ldflags_pie);
1086             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
1087
1088             push @input, $line;
1089             push @input_nonverbose, $non_verbose;
1090             push @input_number, $number if $option_line_numbers;
1091         }
1092     }
1093
1094     close $fh or die $!;
1095
1096     # Ignore arch if requested.
1097     if (scalar @option_ignore_arch > 0 and $arch) {
1098         foreach my $ignore (@option_ignore_arch) {
1099             if ($arch eq $ignore) {
1100                 print "ignoring architecture '$arch'\n";
1101                 next FILE;
1102             }
1103         }
1104     }
1105
1106     if (scalar @input == 0) {
1107         if (not $option_buildd) {
1108             print "No compiler commands!\n";
1109             $exit |= $exit_code{no_compiler_commands};
1110         } else {
1111             print "$buildd_tag{no_compiler_commands}||\n";
1112         }
1113         next FILE;
1114     }
1115
1116     if ($option_buildd) {
1117         $statistics{commands} += scalar @input;
1118     }
1119
1120     # Option or auto detected.
1121     if ($arch) {
1122         # The following was partially copied from dpkg-dev 1.20.5
1123         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, _add_build_flags()),
1124         # copyright Raphaël Hertzog <hertzog@debian.org>, Guillem Jover
1125         # <guillem@debian.org>, Kees Cook <kees@debian.org>, Canonical, Ltd.
1126         # licensed under GPL version 2 or later. Keep it in sync.
1127
1128         require Dpkg::Arch;
1129         my ($os, $cpu);
1130         # Recent dpkg versions use a quadruplet for arch. Support both.
1131         eval {
1132             (undef, undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtuple($arch);
1133         };
1134         if ($@) {
1135             (undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1136         }
1137
1138         my %builtin_pie_arch = map { $_ => 1 } qw(
1139             amd64
1140             arm64
1141             armel
1142             armhf
1143             hurd-i386
1144             i386
1145             kfreebsd-amd64
1146             kfreebsd-i386
1147             mips
1148             mipsel
1149             mips64el
1150             powerpc
1151             ppc64
1152             ppc64el
1153             riscv64
1154             s390x
1155             sparc
1156             sparc64
1157         );
1158
1159         # Disable unsupported hardening options.
1160         if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/
1161                 or $cpu =~ /^(?:hppa|avr32)$/) {
1162             $harden_pie = 0;
1163         }
1164         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1165             $harden_stack = 0;
1166             $harden_stack_strong = 0;
1167         }
1168         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1169             $harden_relro   = 0;
1170             $harden_bindnow = 0;
1171         }
1172
1173         if ($disable_harden_pie and exists $builtin_pie_arch{$arch}) {
1174             $harden_pie = 0;
1175         }
1176     }
1177
1178     # Default values.
1179     my @cflags   = @def_cflags;
1180     my @cxxflags = @def_cxxflags;
1181     my @cppflags = @def_cppflags;
1182     my @ldflags  = @def_ldflags;
1183     # Check the specified hardening options, same order as dpkg-buildflags.
1184     if ($harden_pie) {
1185         @cflags   = (@cflags,   @def_cflags_pie);
1186         @cxxflags = (@cxxflags, @def_cflags_pie);
1187         @ldflags  = (@ldflags,  @def_ldflags_pie);
1188     }
1189     if ($harden_stack_strong) {
1190         @cflags   = (@cflags,   @def_cflags_stack_strong);
1191         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1192     } elsif ($harden_stack) {
1193         @cflags   = (@cflags,   @def_cflags_stack);
1194         @cxxflags = (@cxxflags, @def_cflags_stack);
1195     }
1196     if ($harden_fortify) {
1197         @cflags   = (@cflags,   @def_cflags_fortify);
1198         @cxxflags = (@cxxflags, @def_cflags_fortify);
1199         @cppflags = (@cppflags, @def_cppflags_fortify);
1200     }
1201     if ($harden_format) {
1202         @cflags   = (@cflags,   @def_cflags_format);
1203         @cxxflags = (@cxxflags, @def_cflags_format);
1204     }
1205     if ($harden_relro) {
1206         @ldflags = (@ldflags, @def_ldflags_relro);
1207     }
1208     if ($harden_bindnow) {
1209         @ldflags = (@ldflags, @def_ldflags_bindnow);
1210     }
1211
1212     # Ada doesn't support format hardening flags, see #680117 for more
1213     # information. Same for fortran.
1214     my @cflags_backup;
1215     my @cflags_noformat = grep {
1216         my $ok = 1;
1217         foreach my $flag (@def_cflags_format) {
1218             $ok = 0 if $_ eq $flag;
1219         }
1220         $ok;
1221     } @cflags;
1222
1223     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1224     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1225     # as long as @def_cppflags_fortify contains only one variable.
1226     if (scalar @def_cppflags_fortify == 0) {
1227         $harden_fortify = 0;
1228     }
1229
1230     # Ignore flags for this arch if requested.
1231     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1232         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1233
1234         remove_flags(\@local_flag_refs,
1235                      \%flag_renames,
1236                      @{$option_ignore_arch_flag{$arch}});
1237     }
1238
1239     my @ignore_line = @option_ignore_line;
1240     # Ignore lines for this arch if requested.
1241     if ($arch and exists $option_ignore_arch_line{$arch}) {
1242         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1243     }
1244
1245 LINE:
1246     for (my $i = 0; $i < scalar @input; $i++) {
1247         my $line = $input[$i];
1248
1249         # Ignore line if requested.
1250         foreach my $ignore (@ignore_line) {
1251             next LINE if $line =~ /$ignore/;
1252         }
1253
1254         my $skip = 0;
1255         if ($input_nonverbose[$i]
1256                 and is_non_verbose_build($line, \$skip,
1257                                          \@input, $i, $parallel)) {
1258             if (not $option_buildd) {
1259                 error_non_verbose_build($line, $input_number[$i]);
1260                 $exit |= $exit_code{non_verbose_build};
1261             } else {
1262                 $statistics{commands_nonverbose}++;
1263             }
1264             next;
1265         }
1266         # Even if it's a verbose build, we might have to skip this line (see
1267         # is_non_verbose_build()).
1268         next if $skip;
1269
1270         my $orig_line = $line;
1271
1272         # Remove everything until and including the compiler command. Makes
1273         # checks easier and faster.
1274         $line =~ s/^.*?$cc_regex//o;
1275         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1276         # the brace and similar characters at the line end.
1277         $line =~ s/['")]+$//;
1278
1279         # Skip unnecessary tests when only preprocessing.
1280         my $flag_preprocess = 0;
1281
1282         my $dependency = 0;
1283         my $preprocess = 0;
1284         my $compile    = 0;
1285         my $link       = 0;
1286
1287         # Preprocess, compile, assemble.
1288         if ($line =~ /\s(-E|-S|-c)\b/) {
1289             $preprocess      = 1;
1290             $flag_preprocess = 1 if $1 eq '-E';
1291             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1292         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1293         # -MT -MQ) are always used with -M/-MM.
1294         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1295             $dependency = 1;
1296         # Otherwise assume we are linking.
1297         } else {
1298             $link = 1;
1299         }
1300
1301         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1302         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1303             $dependency      = 0;
1304             $flag_preprocess = 0;
1305         }
1306
1307         # Dependency generation for Makefiles, no preprocessing or other flags
1308         # needed.
1309         next if $dependency;
1310
1311         # Get all file extensions on this line.
1312         my @extensions = $line =~ /$file_extension_regex/go;
1313         # Ignore all unknown extensions to speedup the search below.
1314         @extensions = grep { exists $extension{$_} } @extensions;
1315
1316         # These file types don't require preprocessing.
1317         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1318             $preprocess = 0;
1319         }
1320         # These file types require preprocessing.
1321         if (extension_found(\%extensions_preprocess, @extensions)) {
1322             # Prevent false positives with "libtool: link: g++ -include test.h
1323             # .." compiler lines.
1324             if ($orig_line !~ /$libtool_link_regex/o) {
1325                 $preprocess = 1;
1326             }
1327         }
1328
1329         if (not $flag_preprocess) {
1330             # If there are source files then it's compiling/linking in one
1331             # step and we must check both. We only check for source files
1332             # here, because header files cause too many false positives.
1333             if (extension_found(\%extensions_compile_link, @extensions)) {
1334                 # Assembly files don't need CFLAGS.
1335                 if (not extension_found(\%extensions_compile, @extensions)
1336                         and extension_found(\%extensions_no_compile, @extensions)) {
1337                     $compile = 0;
1338                 # But the rest does.
1339                 } else {
1340                     $compile = 1;
1341                 }
1342             # No compilable extensions found, either linking or compiling
1343             # header flags.
1344             #
1345             # If there are also no object files we are just compiling headers
1346             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1347             # to our liberal checks for compiler lines, this also reduces the
1348             # number of false positives considerably.
1349             } elsif ($link
1350                     and not extension_found(\%extensions_object, @extensions)) {
1351                 $link = 0;
1352             }
1353         }
1354
1355         my $compile_cpp = 0;
1356         my $restore_cflags = 0;
1357         # Assume CXXFLAGS are required when a C++ file is specified in the
1358         # compiler line.
1359         if ($compile
1360                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1361             $compile     = 0;
1362             $compile_cpp = 1;
1363         # Ada needs special CFLAGS
1364         } elsif (extension_found(\%extensions_ada, @extensions)) {
1365             $restore_cflags = 1;
1366             $preprocess = 0; # Ada uses no CPPFLAGS
1367             @cflags_backup = @cflags;
1368             @cflags        = @cflags_noformat;
1369         # Same for fortran
1370         } elsif (extension_found(\%extensions_fortran, @extensions)) {
1371             $restore_cflags = 1;
1372             @cflags_backup = @cflags;
1373             @cflags        = @cflags_noformat;
1374         }
1375
1376         if ($option_buildd) {
1377             $statistics{preprocess}++  if $preprocess;
1378             $statistics{compile}++     if $compile;
1379             $statistics{compile_cpp}++ if $compile_cpp;
1380             $statistics{link}++        if $link;
1381         }
1382
1383         # Check if there are flags indicating a debug build. If that's true,
1384         # skip the check for -O2. This prevents fortification, but that's fine
1385         # for a debug build.
1386         if (any_flags_used($line, @def_cflags_debug)) {
1387             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1388             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1389         }
1390
1391         # Check hardening flags.
1392         my @missing;
1393         if ($compile and (not all_flags_used($line, \@missing, @cflags)
1394                     or (($harden_stack or $harden_stack_strong)
1395                         and cflags_stack_broken($line, \@missing,
1396                                                 $harden_stack_strong)))
1397                 # Libraries linked with -fPIC don't have to (and can't) be
1398                 # linked with -fPIE as well. It's no error if only PIE flags
1399                 # are missing.
1400                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1401                 # Assume dpkg-buildflags returns the correct flags.
1402                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1403             if (not $option_buildd) {
1404                 error_flags('CFLAGS missing', \@missing, \%flag_renames,
1405                             $input[$i], $input_number[$i]);
1406                 $exit |= $exit_code{flags_missing};
1407             } else {
1408                 $statistics{compile_missing}++;
1409             }
1410         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1411                 # Libraries linked with -fPIC don't have to (and can't) be
1412                 # linked with -fPIE as well. It's no error if only PIE flags
1413                 # are missing.
1414                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1415                 # Assume dpkg-buildflags returns the correct flags.
1416                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1417             if (not $option_buildd) {
1418                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames,
1419                             $input[$i], $input_number[$i]);
1420                 $exit |= $exit_code{flags_missing};
1421             } else {
1422                 $statistics{compile_cpp_missing}++;
1423             }
1424         }
1425         if ($preprocess
1426                 and (not all_flags_used($line, \@missing, @cppflags)
1427                     # The fortify flag might be overwritten, detect that.
1428                      or ($harden_fortify
1429                          and cppflags_fortify_broken($line, \@missing)))
1430                 # Assume dpkg-buildflags returns the correct flags.
1431                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1432             if (not $option_buildd) {
1433                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames,
1434                             $input[$i], $input_number[$i]);
1435                 $exit |= $exit_code{flags_missing};
1436             } else {
1437                 $statistics{preprocess_missing}++;
1438             }
1439         }
1440         if ($link and not all_flags_used($line, \@missing, @ldflags)
1441                 # Same here, -fPIC conflicts with -fPIE.
1442                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1443                 # Assume dpkg-buildflags returns the correct flags.
1444                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1445             if (not $option_buildd) {
1446                 error_flags('LDFLAGS missing', \@missing, \%flag_renames,
1447                             $input[$i], $input_number[$i]);
1448                 $exit |= $exit_code{flags_missing};
1449             } else {
1450                 $statistics{link_missing}++;
1451             }
1452         }
1453
1454         # Restore normal CFLAGS.
1455         if ($restore_cflags) {
1456             @cflags = @cflags_backup;
1457         }
1458     }
1459 }
1460
1461 # Print statistics for buildd mode, only output in this mode.
1462 if ($option_buildd) {
1463     my @warning;
1464
1465     if ($statistics{preprocess_missing}) {
1466         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1467                                $statistics{preprocess_missing},
1468                                $statistics{preprocess};
1469     }
1470     if ($statistics{compile_missing}) {
1471         push @warning, sprintf 'CFLAGS %d (of %d)',
1472                                $statistics{compile_missing},
1473                                $statistics{compile};
1474     }
1475     if ($statistics{compile_cpp_missing}) {
1476         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1477                                $statistics{compile_cpp_missing},
1478                                $statistics{compile_cpp};
1479     }
1480     if ($statistics{link_missing}) {
1481         push @warning, sprintf 'LDFLAGS %d (of %d)',
1482                                $statistics{link_missing},
1483                                $statistics{link};
1484     }
1485     if (scalar @warning) {
1486         local $" = ', '; # array join string
1487         print "$buildd_tag{flags_missing}|@warning missing|\n";
1488     }
1489
1490     if ($statistics{commands_nonverbose}) {
1491         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1492                $statistics{commands_nonverbose},
1493                $statistics{commands},
1494     }
1495 }
1496
1497
1498 exit $exit;
1499
1500
1501 __END__
1502
1503 =head1 NAME
1504
1505 blhc - build log hardening check, checks build logs for missing hardening flags
1506
1507 =head1 SYNOPSIS
1508
1509 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1510
1511 =head1 DESCRIPTION
1512
1513 blhc is a small tool which checks build logs for missing hardening flags. It's
1514 licensed under the GPL 3 or later.
1515
1516 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1517 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1518 official buildd build logs)) to help maintainers detect missing hardening
1519 flags in their packages.
1520
1521 Only gcc is detected as compiler at the moment. If other compilers support
1522 hardening flags as well, please report them.
1523
1524 If there's no output, no flags are missing and the build log is fine.
1525
1526 See F<README> for details about performed checks, auto-detection and
1527 limitations.
1528
1529 =head1 FALSE POSITIVES
1530
1531 To suppress false positives you can embed the following string in the build
1532 log:
1533
1534     blhc: ignore-line-regexp: REGEXP
1535
1536 All lines fully matching REGEXP (see B<--ignore-line> for details) will be
1537 ignored.
1538
1539 Please use this feature sparingly so that missing flags are not overlooked. If
1540 you find false positives which affect more packages please report a bug.
1541
1542 To generate this string simply use echo in C<debian/rules>; make sure to use @
1543 to suppress the echo command itself as it could also trigger a false positive.
1544
1545 =head1 OPTIONS
1546
1547 =over 8
1548
1549 =item B<--all>
1550
1551 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1552 auto detected.
1553
1554 =item B<--arch> I<architecture>
1555
1556 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1557 disables hardening flags not available on this architecture. Is detected
1558 automatically if dpkg-buildpackage is used.
1559
1560 =item B<--bindnow>
1561
1562 Force check for all +bindnow hardening flags. By default it's auto detected.
1563
1564 =item B<--buildd>
1565
1566 Special mode for buildds when automatically parsing log files. The following
1567 changes are in effect:
1568
1569 =over 2
1570
1571 =item *
1572
1573 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1574 possible tags.
1575
1576 =item *
1577
1578 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1579 detected).
1580
1581 =item *
1582
1583 Don't require Term::ANSIColor.
1584
1585 =item *
1586
1587 Return exit code 0, unless there was a error (-I, -W messages don't count as
1588 error).
1589
1590 =back
1591
1592 =item B<--debian>
1593
1594 Apply Debian-specific settings. At the moment this only disables checking for
1595 PIE which is automatically applied by Debian's GCC and no longer requires a
1596 compiler command line argument.
1597
1598 =item B<--color>
1599
1600 Use colored (ANSI) output for warning messages.
1601
1602 =item B<--line-numbers>
1603
1604 Display line numbers.
1605
1606 =item B<--ignore-arch> I<arch>
1607
1608 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1609
1610 Used to prevent false positives. This option can be specified multiple times.
1611
1612 =item B<--ignore-arch-flag> I<arch>:I<flag>
1613
1614 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1615
1616 =item B<--ignore-arch-line> I<arch>:I<line>
1617
1618 Like B<--ignore-line>, but only ignore line on I<arch>.
1619
1620 =item B<--ignore-flag> I<flag>
1621
1622 Don't print an error when the specific flag is missing in a compiler line.
1623 I<flag> is a string.
1624
1625 Used to prevent false positives. This option can be specified multiple times.
1626
1627 =item B<--ignore-line> I<regex>
1628
1629 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1630 at the beginning and end of the line to prevent false negatives.
1631
1632 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1633 warnings (which have line continuation resolved).
1634
1635 Used to prevent false positives. This option can be specified multiple times.
1636
1637 =item B<--pie>
1638
1639 Force check for all +pie hardening flags. By default it's auto detected.
1640
1641 =item B<-h -? --help>
1642
1643 Print available options.
1644
1645 =item B<--version>
1646
1647 Print version number and license.
1648
1649 =back
1650
1651 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1652 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1653 all other commands as well.
1654
1655 =head1 EXAMPLES
1656
1657 Normal usage, parse a single log file.
1658
1659     blhc path/to/log/file
1660
1661 If there's no output, no flags are missing and the build log is fine.
1662
1663 Parse multiple log files. The exit code is ORed over all files.
1664
1665     blhc path/to/directory/with/log/files/*
1666
1667 Don't treat missing C<-g> as error:
1668
1669     blhc --ignore-flag -g path/to/log/file
1670
1671 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1672
1673     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1674
1675 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1676 false positive.
1677
1678     blhc --ignore-line '\./script gcc file' path/to/log/file
1679
1680 Ignore lines matching C<./script gcc file> somewhere in the line.
1681
1682     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1683
1684 Use blhc with pbuilder.
1685
1686     pbuilder path/to/package.dsc | tee path/log/file
1687     blhc path/to/file || echo flags missing
1688
1689 Assume this build log was created on a Debian system and thus don't warn about
1690 missing PIE flags if the current architecture injects them automatically (this
1691 is enabled in buildd mode per default). C<--arch> is necessary if the build
1692 log contains no architecture information as written by dpkg-buildpackage.
1693
1694     blhc --debian --all --arch=amd64 path/to/log/file
1695
1696 =head1 BUILDD TAGS
1697
1698 The following tags are used in I<--buildd> mode. In braces the additional data
1699 which is displayed.
1700
1701 =over 2
1702
1703 =item B<I-hardening-wrapper-used>
1704
1705 The package uses hardening-wrapper which intercepts calls to gcc and adds
1706 hardening flags. The build log doesn't contain any hardening flags and thus
1707 can't be checked by blhc.
1708
1709 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1710
1711 Build log contains lines which hide the real compiler flags. For example:
1712
1713     CC test-a.c
1714     CC test-b.c
1715     CC test-c.c
1716     LD test
1717
1718 Most of the time either C<export V=1> or C<export verbose=1> in
1719 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1720 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1721 patched to remove the C<@>s hiding the real compiler commands.
1722
1723 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1724
1725 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1726
1727 =item B<I-invalid-cmake-used> (version)
1728
1729 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1730 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1731 patch was rejected by upstream and later reverted in Debian. Thus those two
1732 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1733 handle them (for example by passing them to CFLAGS). To prevent false
1734 negatives just blacklist those two versions.
1735
1736 =item B<I-no-compiler-commands>
1737
1738 No compiler commands were detected. Either the log contains none or they were
1739 not correctly detected by blhc (please report the bug in this case).
1740
1741 =back
1742
1743 =head1 EXIT STATUS
1744
1745 The exit status is a "bit mask", each listed status is ORed when the error
1746 condition occurs to get the result.
1747
1748 =over 4
1749
1750 =item B<0>
1751
1752 Success.
1753
1754 =item B<1>
1755
1756 No compiler commands were found.
1757
1758 =item B<2>
1759
1760 Invalid arguments/options given to blhc.
1761
1762 =item B<4>
1763
1764 Non verbose build.
1765
1766 =item B<8>
1767
1768 Missing hardening flags.
1769
1770 =item B<16>
1771
1772 Hardening wrapper detected, no tests performed.
1773
1774 =item B<32>
1775
1776 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1777 TAGS"> for a detailed explanation.
1778
1779 =back
1780
1781 =head1 AUTHOR
1782
1783 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1784
1785 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1786 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1787
1788 =head1 LICENSE AND COPYRIGHT
1789
1790 Copyright (C) 2012-2020 by Simon Ruderich
1791
1792 This program is free software: you can redistribute it and/or modify
1793 it under the terms of the GNU General Public License as published by
1794 the Free Software Foundation, either version 3 of the License, or
1795 (at your option) any later version.
1796
1797 This program is distributed in the hope that it will be useful,
1798 but WITHOUT ANY WARRANTY; without even the implied warranty of
1799 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1800 GNU General Public License for more details.
1801
1802 You should have received a copy of the GNU General Public License
1803 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1804
1805 =head1 SEE ALSO
1806
1807 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1808
1809 =cut