5fabc39e4bf8f9d090c250eec61a2a07d0a3a721
[blhc/blhc.git] / bin / blhc
1 #!/usr/bin/perl
2
3 # Build log hardening check, checks build logs for missing hardening flags.
4
5 # Copyright (C) 2012-2019  Simon Ruderich
6 #
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
19
20
21 use strict;
22 use warnings;
23
24 use Getopt::Long ();
25 use Text::ParseWords ();
26
27 our $VERSION = '0.10';
28
29
30 # CONSTANTS/VARIABLES
31
32 # Regex to catch compiler commands.
33 my $cc_regex = qr/
34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
35     (?<!\.)                # ignore file names, e.g. "test.gcc"
36     (?:cc|gcc|g\+\+|c\+\+|gfortran|mpicc|mpicxx|mpifort)
37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
38     /x;
39 # Full regex which matches the complete compiler name. Used in a few places to
40 # prevent false negatives.
41 my $cc_regex_full_prefix = qr/
42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
43     /x;
44 my $cc_regex_full = qr/
45     (?:$cc_regex_full_prefix-)?
46     $cc_regex
47     /x;
48 # Regex to check if a line contains a compiler command.
49 my $cc_regex_normal = qr/
50     \b$cc_regex(?:\s|\\)
51     /x;
52 # Regex to catch (GCC) compiler warnings.
53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
54 # Regex to catch libtool commands and not lines which show commands executed
55 # by libtool (e.g. libtool: link: ...).
56 my $libtool_regex = qr/\blibtool["']?\s.*--mode=/;
57 my $libtool_link_regex = qr/\blibtool: link: /;
58
59 # List of source file extensions which require preprocessing.
60 my @source_preprocess_compile_cpp = (
61     # C++
62     qw( cc cp cxx cpp CPP c++ C ),
63     # Objective-C++
64     qw( mm M ),
65 );
66 my @source_preprocess_compile_fortran = (
67     # Fortran
68     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
69 );
70 my @source_preprocess_compile = (
71     # C
72     qw( c ),
73     # Objective-C
74     qw( m ),
75     # (Objective-)C++
76     @source_preprocess_compile_cpp,
77     # Fortran
78     @source_preprocess_compile_fortran,
79 );
80 my @source_preprocess_no_compile = (
81     # Assembly
82     qw( S sx ),
83 );
84 my @source_preprocess = (
85     @source_preprocess_compile,
86     @source_preprocess_no_compile,
87 );
88 # List of source file extensions which don't require preprocessing.
89 my @source_no_preprocess_compile_cpp = (
90     # C++
91     qw( ii ),
92     # Objective-C++
93     qw( mii ),
94 );
95 my @source_no_preprocess_compile_ada = (
96     # Ada source
97     qw( ada ),
98     # Ada body
99     qw( adb ),
100 );
101 my @source_no_preprocess_compile_fortran = (
102     # Fortran
103     qw( f for ftn f90 f95 f03 f08 ),
104 );
105 my @source_no_preprocess_compile = (
106     # C
107     qw( i ),
108     # (Objective-)C++
109     @source_no_preprocess_compile_cpp,
110     # Objective-C
111     qw( mi ),
112     # Fortran
113     @source_no_preprocess_compile_fortran,
114     # Ada
115     @source_no_preprocess_compile_ada,
116 );
117 my @source_no_preprocess_no_compile_ada = (
118     # Ada specification
119     qw( ads ),
120 );
121 my @source_no_preprocess_no_compile = (
122     # Assembly
123     qw( s ),
124     # Ada
125     @source_no_preprocess_no_compile_ada,
126 );
127 my @source_no_preprocess = (
128     @source_no_preprocess_compile,
129     @source_no_preprocess_no_compile,
130 );
131 # List of header file extensions which require preprocessing.
132 my @header_preprocess = (
133     # C, C++, Objective-C, Objective-C++
134     qw( h ),
135     # C++
136     qw( hh H hp hxx hpp HPP h++ tcc ),
137 );
138 # Object files.
139 my @object = (
140     # Normal object files.
141     qw ( o ),
142     # Libtool object files.
143     qw ( lo la ),
144     # Dynamic libraries. bzip2 uses .sho.
145     qw ( so sho ),
146     # Static libraries.
147     qw ( a ),
148 );
149
150 # Hashes for fast extensions lookup to check if a file falls in one of these
151 # categories.
152 my %extensions_no_preprocess = map { $_ => 1 } (
153     # There's no @header_no_preprocess.
154     @source_no_preprocess,
155 );
156 my %extensions_preprocess = map { $_ => 1 } (
157     @header_preprocess,
158     @source_preprocess,
159 );
160 my %extensions_compile_link = map { $_ => 1 } (
161     @source_preprocess,
162     @source_no_preprocess,
163 );
164 my %extensions_compile = map { $_ => 1 } (
165     @source_preprocess_compile,
166     @source_no_preprocess_compile,
167 );
168 my %extensions_no_compile = map { $_ => 1 } (
169     @source_preprocess_no_compile,
170     @source_no_preprocess_no_compile,
171 );
172 my %extensions_compile_cpp = map { $_ => 1 } (
173     @source_preprocess_compile_cpp,
174     @source_no_preprocess_compile_cpp,
175 );
176 my %extensions_ada = map { $_ => 1 } (
177     @source_no_preprocess_compile_ada,
178     @source_no_preprocess_no_compile_ada,
179 );
180 my %extensions_fortran = map { $_ => 1 } (
181     @source_no_preprocess_compile_fortran,
182     @source_preprocess_compile_fortran,
183 );
184 my %extensions_object = map { $_ => 1 } (
185     @object,
186 );
187 my %extension = map { $_ => 1 } (
188     @source_no_preprocess,
189     @header_preprocess,
190     @source_preprocess,
191     @object,
192 );
193
194 # Regexp to match file extensions.
195 my $file_extension_regex = qr/
196     \s
197     \S+             # Filename without extension.
198     \.
199     ([^\/\\.,;:\s]+)# File extension.
200     (?=\s|\\)       # At end of word. Can't use \b because some files have non
201                     # word characters at the end and because \b matches double
202                     # extensions (like .cpp.o). Works always as all lines are
203                     # terminated with "\n".
204     /x;
205
206 # Expected (hardening) flags. All flags are used as regexps (and compiled to
207 # real regexps below for better execution speed).
208 my @def_cflags = (
209     '-g',
210     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
211 );
212 my @def_cflags_debug = (
213     # These flags indicate a debug build which disables checks for -O2.
214     '-O0',
215     '-Og',
216 );
217 my @def_cflags_format = (
218     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
219     '-Werror=format-security', # implies -Wformat-security
220 );
221 my @def_cflags_fortify = (
222     # fortify needs at least -O1, but -O2 is recommended anyway
223 );
224 my @def_cflags_stack = (
225     '-fstack-protector', # keep first, used by cflags_stack_broken()
226     '--param[= ]ssp-buffer-size=4',
227 );
228 my @def_cflags_stack_strong = (
229     '-fstack-protector-strong', # keep first, used by cflags_stack_broken()
230 );
231 my @def_cflags_stack_bad = (
232     # Blacklist all stack protector options for simplicity.
233     '-fno-stack-protector',
234     '-fno-stack-protector-all',
235     '-fno-stack-protector-strong',
236 );
237 my @def_cflags_pie = (
238     '-fPIE',
239 );
240 my @def_cxxflags = (
241     @def_cflags,
242 );
243 # @def_cxxflags_* is the same as @def_cflags_*.
244 my @def_cppflags = ();
245 my @def_cppflags_fortify = (
246     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
247     # If you add another flag fix hack below (search for "Hack to fix") and
248     # $def_cppflags_fortify[0].
249 );
250 my @def_cppflags_fortify_bad = (
251     # These flags may overwrite -D_FORTIFY_SOURCE=2.
252     '-U_FORTIFY_SOURCE',
253     '-D_FORTIFY_SOURCE=0',
254     '-D_FORTIFY_SOURCE=1',
255 );
256 my @def_ldflags = ();
257 my @def_ldflags_relro = (
258     '-Wl,(?:-z,)?relro',
259 );
260 my @def_ldflags_bindnow = (
261     '-Wl,(?:-z,)?now',
262 );
263 my @def_ldflags_pie = (
264     '-fPIE',
265     '-pie',
266 );
267 my @def_ldflags_pic = (
268     '-fPIC',
269     '-fpic',
270     '-shared',
271 );
272 # References to all flags checked by the flag checker.
273 my @flag_refs = (
274     \@def_cflags,
275     \@def_cflags_format,
276     \@def_cflags_fortify,
277     \@def_cflags_stack,
278     \@def_cflags_stack_strong,
279     \@def_cflags_stack_bad,
280     \@def_cflags_pie,
281     \@def_cxxflags,
282     \@def_cppflags,
283     \@def_cppflags_fortify,
284     \@def_ldflags,
285     \@def_ldflags_relro,
286     \@def_ldflags_bindnow,
287     \@def_ldflags_pie,
288 );
289 # References to all used flags.
290 my @flag_refs_all = (
291     @flag_refs,
292     \@def_cflags_debug,
293     \@def_cppflags_fortify_bad,
294     \@def_ldflags_pic,
295 );
296 # Renaming rules for the output so the regex parts are not visible. Also
297 # stores string values of flag regexps above, see compile_flag_regexp().
298 my %flag_renames = (
299     '-O(?:2|3)'                    => '-O2',
300     '-Wformat(?:=2)?'              => '-Wformat',
301     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
302     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
303     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
304 );
305
306 my %exit_code = (
307     no_compiler_commands => 1 << 0,
308     # used by POD::Usage => 1 << 1,
309     non_verbose_build    => 1 << 2,
310     flags_missing        => 1 << 3,
311     hardening_wrapper    => 1 << 4,
312     invalid_cmake        => 1 << 5,
313 );
314
315 my %buildd_tag = (
316     no_compiler_commands => 'I-no-compiler-commands',
317     non_verbose_build    => 'W-compiler-flags-hidden',
318     flags_missing        => 'W-dpkg-buildflags-missing',
319     hardening_wrapper    => 'I-hardening-wrapper-used',
320     invalid_cmake        => 'I-invalid-cmake-used',
321 );
322
323 # Statistics of missing flags and non-verbose build commands. Used for
324 # $option_buildd.
325 my %statistics = (
326     preprocess          => 0,
327     preprocess_missing  => 0,
328     compile             => 0,
329     compile_missing     => 0,
330     compile_cpp         => 0,
331     compile_cpp_missing => 0,
332     link                => 0,
333     link_missing        => 0,
334     commands            => 0,
335     commands_nonverbose => 0,
336 );
337
338 # Use colored (ANSI) output?
339 my $option_color;
340
341
342 # FUNCTIONS
343
344 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
345 sub array_equal {
346     my ($first_ref, $second_ref) = @_;
347
348     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
349
350     my $length = scalar @{$first_ref};
351     for (my $i = 0; $i < $length; $i++) {
352         return 0 if $first_ref->[$i] ne $second_ref->[$i];
353     }
354
355     return 1;
356 }
357
358 sub error_flags {
359     my ($message, $missing_flags_ref, $flag_renames_ref, $line, $number) = @_;
360
361     # Get string value of qr//-escaped regexps and if requested rename them.
362     my @missing_flags = map {
363             $flag_renames_ref->{$_}
364         } @{$missing_flags_ref};
365
366     my $flags = join ' ', @missing_flags;
367     printf '%d:', $number if defined $number;
368     printf '%s (%s)%s %s',
369            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
370            $line;
371
372     return;
373 }
374 sub error_non_verbose_build {
375     my ($line, $number) = @_;
376
377     printf '%d:', $number if defined $number;
378     printf '%s%s %s',
379            error_color('NONVERBOSE BUILD', 'red'),
380            error_color(':', 'yellow'),
381            $line;
382
383     return;
384 }
385 sub error_invalid_cmake {
386     my ($version) = @_;
387
388     printf "%s%s %s\n",
389             error_color('INVALID CMAKE', 'red'),
390             error_color(':', 'yellow'),
391             $version;
392
393     return;
394 }
395 sub error_hardening_wrapper {
396     printf "%s%s %s\n",
397             error_color('HARDENING WRAPPER', 'red'),
398             error_color(':', 'yellow'),
399             'no checks possible, aborting';
400
401     return;
402 }
403 sub error_color {
404     my ($message, $color) = @_;
405
406     if ($option_color) {
407         return Term::ANSIColor::colored($message, $color);
408     } else {
409         return $message;
410     }
411 }
412
413 sub any_flags_used {
414     my ($line, @flags) = @_;
415
416     foreach my $flag (@flags) {
417         return 1 if $line =~ /$flag/;
418     }
419
420     return 0;
421 }
422 sub all_flags_used {
423     my ($line, $missing_flags_ref, @flags) = @_;
424
425     my @missing_flags = ();
426     foreach my $flag (@flags) {
427         if (not $line =~ /$flag/) {
428             push @missing_flags, $flag;
429         }
430     }
431
432     return 1 if scalar @missing_flags == 0;
433
434     @{$missing_flags_ref} = @missing_flags;
435     return 0;
436 }
437 # Check if any of \@bad_flags occurs after $good_flag. Doesn't check if
438 # $good_flag is present.
439 sub flag_overwritten {
440     my ($line, $good_flag, $bad_flags) = @_;
441
442     if (not any_flags_used($line, @{$bad_flags})) {
443         return 0;
444     }
445
446     my $bad_pos = 0;
447     foreach my $flag (@{$bad_flags}) {
448         while ($line =~ /$flag/g) {
449             if ($bad_pos < $+[0]) {
450                 $bad_pos = $+[0];
451             }
452         }
453     }
454     my $good_pos = 0;
455     while ($line =~ /$good_flag/g) {
456         $good_pos = $+[0];
457     }
458     if ($good_pos > $bad_pos) {
459         return 0;
460     }
461     return 1;
462 }
463
464 sub cppflags_fortify_broken {
465     my ($line, $missing_flags) = @_;
466
467     # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
468     my $fortify_source = $def_cppflags_fortify[0];
469
470     # Some build systems enable/disable fortify source multiple times, check
471     # the final result.
472     if (not flag_overwritten($line,
473                              $fortify_source,
474                              \@def_cppflags_fortify_bad)) {
475         return 0;
476     }
477     push @{$missing_flags}, $fortify_source;
478     return 1;
479 }
480
481 sub cflags_stack_broken {
482     my ($line, $missing_flags, $strong) = @_;
483
484     my $flag = $strong ? $def_cflags_stack_strong[0]
485                        : $def_cflags_stack[0];
486
487     if (not flag_overwritten($line, $flag, \@def_cflags_stack_bad)) {
488         return 0;
489     }
490     push @{$missing_flags}, $flag;
491     return 1;
492 }
493
494 # Modifies $missing_flags_ref array.
495 sub pic_pie_conflict {
496     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
497
498     return 0 if not $pie;
499     return 0 if not any_flags_used($line, @def_ldflags_pic);
500
501     my %flags = map { $_ => 1 } @flags_pie;
502
503     # Remove all PIE flags from @missing_flags as they are not required with
504     # -fPIC.
505     my @result = grep {
506         not exists $flags{$_}
507     } @{$missing_flags_ref};
508     @{$missing_flags_ref} = @result;
509
510     # We got a conflict when no flags are left, thus only PIE flags were
511     # missing. If other flags were missing abort because the conflict is not
512     # the problem.
513     return scalar @result == 0;
514 }
515
516 sub is_non_verbose_build {
517     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
518
519     if ($line =~ /$libtool_regex/o) {
520         # libtool's --silent hides the real compiler flags.
521         if ($line =~ /\s--silent/) {
522             return 1;
523         # If --silent is not present, skip this line as some compiler flags
524         # might be missing (e.g. -fPIE) which are handled correctly by libtool
525         # internally. libtool displays the real compiler command on the next
526         # line, so the flags are checked as usual.
527         } else {
528             ${$skip_ref} = 1;
529             return 0;
530         }
531     }
532
533     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
534                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
535                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
536                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
537                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
538         return 0;
539     }
540
541     # False positives.
542     #
543     # C++ compiler setting.
544     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
545     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
546     # "Compiling" non binary files.
547     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|pyx|el)['"]?\s*(?:\.\.\.|because it changed\.)?$/;
548     return 0 if $line =~ /^\s*[Cc]ompiling catalog \S+\.po\b/;
549     # "Compiling" with no file name.
550     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
551         # $file_extension_regex may need spaces around the filename.
552         return 0 if not " $1 " =~ /$file_extension_regex/o;
553     }
554
555     my $file = $1;
556
557     # On the first pass we only check if this line is verbose or not.
558     return 1 if not defined $input_ref;
559
560     # Second pass, we have access to the next lines.
561     ${$skip_ref} = 0;
562
563     # CMake and other build systems print the non-verbose messages also when
564     # building verbose. If a compiler and the file name occurs in the next
565     # lines, treat it as verbose build.
566     if (defined $file) {
567         # Get filename, we can't use the complete path as only parts of it are
568         # used in the real compiler command.
569         $file =~ m{/([^/\s]+)$};
570         $file = $1;
571
572         for (my $i = 1; $i <= $line_count; $i++) {
573             my $next_line = $input_ref->[$line_offset + $i];
574             last unless defined $next_line;
575
576             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
577                 # Not a non-verbose line, but we still have to skip the
578                 # current line as it doesn't contain any compiler commands.
579                 ${$skip_ref} = 1;
580                 return 0;
581             }
582         }
583     }
584
585     return 1;
586 }
587
588 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
589 sub remove_flags {
590     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
591
592     my %removes = map { $_ => 1 } @flags;
593     foreach my $flags (@{$flag_refs_ref}) {
594         @{$flags} = grep {
595             # Flag found as string.
596             not exists $removes{$_}
597             # Flag found as string representation of regexp.
598                 and (not defined $flag_renames_ref->{$_}
599                         or not exists $removes{$flag_renames_ref->{$_}})
600         } @{$flags};
601     }
602
603     return;
604 }
605
606 # Modifies $flag_renames_ref hash.
607 sub compile_flag_regexp {
608     my ($flag_renames_ref, @flags) = @_;
609
610     my @result = ();
611     foreach my $flag (@flags) {
612         # Compile flag regexp for faster execution.
613         my $regex = qr/\s$flag(?:\s|\\)/;
614
615         # Store flag name in replacement string for correct flags in messages
616         # with qr//ed flag regexps.
617         $flag_renames_ref->{$regex}
618             = (exists $flag_renames_ref->{$flag})
619                 ? $flag_renames_ref->{$flag}
620                 : $flag;
621
622         push @result, $regex;
623     }
624     return @result;
625 }
626
627 # Does any extension in @extensions exist in %{$extensions_ref}?
628 sub extension_found {
629     my ($extensions_ref, @extensions) = @_;
630
631     foreach my $extension (@extensions) {
632         if (exists $extensions_ref->{$extension}) {
633             return 1;
634         }
635     }
636     return 0;
637 }
638
639
640 # MAIN
641
642 # Parse command line arguments.
643 my $option_help             = 0;
644 my $option_version          = 0;
645 my $option_pie              = 0;
646 my $option_bindnow          = 0;
647 my @option_ignore_arch      = ();
648 my @option_ignore_flag      = ();
649 my @option_ignore_arch_flag = ();
650 my @option_ignore_line      = ();
651 my @option_ignore_arch_line = ();
652 my $option_all              = 0;
653 my $option_arch             = undef;
654 my $option_buildd           = 0;
655 my $option_debian           = 0;
656    $option_color            = 0;
657 my $option_line_numbers     = 0;
658 if (not Getopt::Long::GetOptions(
659             'help|h|?'           => \$option_help,
660             'version'            => \$option_version,
661             # Hardening options.
662             'pie'                => \$option_pie,
663             'bindnow'            => \$option_bindnow,
664             'all'                => \$option_all,
665             # Ignore.
666             'ignore-arch=s'      => \@option_ignore_arch,
667             'ignore-flag=s'      => \@option_ignore_flag,
668             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
669             'ignore-line=s'      => \@option_ignore_line,
670             'ignore-arch-line=s' => \@option_ignore_arch_line,
671             # Misc.
672             'color'              => \$option_color,
673             'arch=s'             => \$option_arch,
674             'buildd'             => \$option_buildd,
675             'debian'             => \$option_debian,
676             'line-numbers'       => \$option_line_numbers,
677         )) {
678     require Pod::Usage;
679     Pod::Usage::pod2usage(2);
680 }
681 if ($option_help) {
682     require Pod::Usage;
683     Pod::Usage::pod2usage(1);
684 }
685 if ($option_version) {
686     print <<"EOF";
687 blhc $VERSION  Copyright (C) 2012-2019  Simon Ruderich
688
689 This program is free software: you can redistribute it and/or modify
690 it under the terms of the GNU General Public License as published by
691 the Free Software Foundation, either version 3 of the License, or
692 (at your option) any later version.
693
694 This program is distributed in the hope that it will be useful,
695 but WITHOUT ANY WARRANTY; without even the implied warranty of
696 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
697 GNU General Public License for more details.
698
699 You should have received a copy of the GNU General Public License
700 along with this program.  If not, see <http://www.gnu.org/licenses/>.
701 EOF
702     exit 0;
703 }
704
705 # Arguments missing.
706 if (scalar @ARGV == 0) {
707     require Pod::Usage;
708     Pod::Usage::pod2usage(2);
709 }
710
711 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
712 # installed on Debian's buildds.
713 if (not $option_buildd) {
714     require Term::ANSIColor;
715 }
716
717 if ($option_all) {
718     $option_pie     = 1;
719     $option_bindnow = 1;
720 }
721
722 # Precompiled ignores for faster lookup.
723 my %option_ignore_arch_flag = ();
724 my %option_ignore_arch_line = ();
725
726 # Strip flags which should be ignored.
727 if (scalar @option_ignore_flag > 0) {
728     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
729 }
730 # Same for arch specific ignore flags, but only prepare here.
731 if (scalar @option_ignore_arch_flag > 0) {
732     foreach my $ignore (@option_ignore_arch_flag) {
733         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
734
735         if (not $ignore_arch or not $ignore_flag) {
736             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
737                         . '("arch:flag" expected)' . "\n", $ignore;
738             require Pod::Usage;
739             Pod::Usage::pod2usage(2);
740         }
741
742         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
743     }
744 }
745
746 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
747 # faster with this.
748 foreach my $flags (@flag_refs_all) {
749     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
750 }
751
752 # Precompile ignore line regexps, also anchor at beginning and end of line.
753 foreach my $ignore (@option_ignore_line) {
754     $ignore = qr/^$ignore$/;
755 }
756 # Same for arch specific ignore lines.
757 if (scalar @option_ignore_arch_line > 0) {
758     foreach my $ignore (@option_ignore_arch_line) {
759         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
760
761         if (not $ignore_arch or not $ignore_line) {
762             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
763                         . '("arch:line" expected)' . "\n", $ignore;
764             require Pod::Usage;
765             Pod::Usage::pod2usage(2);
766         }
767
768         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
769     }
770 }
771
772 # Final exit code.
773 my $exit = 0;
774
775 FILE:
776 foreach my $file (@ARGV) {
777     print "checking '$file'...\n" if scalar @ARGV > 1;
778
779     -f $file or die "No such file: $file";
780
781     open my $fh, '<', $file or die $!;
782
783     # Architecture of this file.
784     my $arch = $option_arch;
785
786     # Hardening options. Not all architectures support all hardening options.
787     my $harden_format  = 1;
788     my $harden_fortify = 1;
789     my $harden_stack   = 1;
790     my $harden_stack_strong = 1;
791     my $harden_relro   = 1;
792     my $harden_bindnow = $option_bindnow; # defaults to 0
793     my $harden_pie     = $option_pie;     # defaults to 0
794
795     # Number of parallel jobs to prevent false positives when detecting
796     # non-verbose builds. As not all jobs declare the number of parallel jobs
797     # use a large enough default.
798     my $parallel = 10;
799
800     # Don't check for PIE flags if automatically applied by the compiler. Only
801     # used in buildd and Debian mode.
802     my $disable_harden_pie = 0;
803     if ($option_debian) {
804         $disable_harden_pie = 1;
805     }
806
807     my $number = 0;
808     while (my $line = <$fh>) {
809         $number++;
810
811         # Detect architecture automatically unless overridden. For buildd logs
812         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
813         # build logs which aren't built (wrong architecture, build error,
814         # etc.).
815         if (not $arch) {
816             if (index($line, 'Build Architecture: ') == 0) {
817                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
818             # For old logs (sbuild << 0.63.0-1).
819             } elsif (index($line, 'Architecture: ') == 0) {
820                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
821             }
822         }
823
824         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
825         # check for hardening flags in buildd mode if an older dpkg-dev is
826         # used. Default flags (-g -O2) are still checked.
827         #
828         # Packages which were built before 1.16.1 but used their own hardening
829         # flags are not checked.
830         #
831         # Strong stack protector is used since dpkg 1.17.11.
832         #
833         # Recent GCC versions automatically use PIE (only on supported
834         # architectures) and dpkg respects this properly since 1.18.15 and
835         # doesn't pass PIE flags manually.
836         if ($option_buildd
837                 and index($line, 'Toolchain package versions: ') == 0) {
838             require Dpkg::Version;
839
840             my $disable = 1;
841             my $disable_strong = 1;
842
843             if ($line =~ /\bdpkg-dev_(\S+)/) {
844                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
845                     $disable = 0;
846                 }
847                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
848                     $disable_strong = 0;
849                 }
850                 if (Dpkg::Version::version_compare($1, '1.18.15') >= 0) {
851                     $disable_harden_pie = 1;
852                 }
853             }
854
855             if ($disable) {
856                 $harden_format  = 0;
857                 $harden_fortify = 0;
858                 $harden_stack   = 0;
859                 $harden_relro   = 0;
860                 $harden_bindnow = 0;
861                 $harden_pie     = 0;
862             }
863             if ($disable_strong) {
864                 $harden_stack_strong = 0;
865             }
866         }
867
868         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
869         # this was later dropped because upstream rejected the patch. Thus
870         # build logs with these versions will have fortify hardening flags
871         # enabled, even though they may be not correctly set and are missing
872         # when build with later CMake versions. Thanks to Aron Xu for letting
873         # me know.
874         if (index($line, 'Package versions: ') == 0
875                 and $line =~ /\bcmake_(\S+)/
876                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
877             if (not $option_buildd) {
878                 error_invalid_cmake($1);
879                 $exit |= $exit_code{invalid_cmake};
880             } else {
881                 print "$buildd_tag{invalid_cmake}|$1|\n";
882             }
883         }
884
885         # Debian's build daemons use "Filtered Build-Depends:" (or just
886         # "Build-Depends:" in older versions) for the build dependencies, but
887         # pbuilder uses "Depends:"; support both.
888         if (index($line, 'Filtered Build-Depends: ') == 0
889                 or index($line, 'Build-Depends: ') == 0
890                 or index($line, 'Depends: ') == 0) {
891             # If hardening wrapper is used (wraps calls to gcc and adds
892             # hardening flags automatically) we can't perform any checks,
893             # abort.
894             if ($line =~ /\bhardening-wrapper\b/) {
895                 if (not $option_buildd) {
896                     error_hardening_wrapper();
897                     $exit |= $exit_code{hardening_wrapper};
898                 } else {
899                     print "$buildd_tag{hardening_wrapper}||\n";
900                 }
901                 next FILE;
902             }
903         }
904
905         # This flags is not always available, but if it is use it.
906         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
907             $parallel = $1 * 2;
908         }
909
910         # We skip over unimportant lines at the beginning of the log to
911         # prevent false positives.
912         last if index($line, 'dpkg-buildpackage: ') == 0;
913     }
914
915     # Input lines, contain only the lines with compiler commands.
916     my @input = ();
917     # Non-verbose lines in the input. Used to reduce calls to
918     # is_non_verbose_build() (which is quite slow) in the second loop when
919     # it's already clear if a line is non-verbose or not.
920     my @input_nonverbose = ();
921     # Input line number.
922     my @input_number = ();
923
924     my $continuation = 0;
925     my $complete_line = undef;
926     my $non_verbose;
927     while (my $line = <$fh>) {
928         $number++;
929
930         # And stop at the end of the build log. Package details (reported by
931         # the buildd logs) are not important for us. This also prevents false
932         # positives.
933         last if index($line, 'Build finished at ') == 0
934                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
935
936         if (not $continuation) {
937             $non_verbose = 0;
938         }
939
940         # Detect architecture automatically unless overridden.
941         if (not $arch
942                 and index($line, 'dpkg-buildpackage: info: host architecture ') == 0) {
943             $arch = substr $line, 43, -1; # -1 to ignore '\n' at the end
944         # Older versions of dpkg-buildpackage
945         } elsif (not $arch
946                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
947             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
948
949             # Old buildd logs use e.g. "host architecture is alpha", remove
950             # the "is", otherwise debarch_to_debtriplet() will not detect the
951             # architecture.
952             if (index($arch, 'is ') == 0) {
953                 $arch = substr $arch, 3;
954             }
955         }
956
957         next if $line =~ /^\s*#/;
958         # Ignore compiler warnings for now.
959         next if $line =~ /$warning_regex/o;
960
961         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
962             # Remove all ANSI color sequences which are sometimes used in
963             # non-verbose builds.
964             $line = Term::ANSIColor::colorstrip($line);
965             # Also strip '\0xf' (delete previous character), used by Elinks'
966             # build system.
967             $line =~ s/\x0f//g;
968             # And "ESC(B" which seems to be used on armhf and hurd (not sure
969             # what it does).
970             $line =~ s/\033\(B//g;
971         }
972
973         # Check if this line indicates a non verbose build.
974         my $skip = 0;
975         $non_verbose |= is_non_verbose_build($line, \$skip);
976         next if $skip;
977
978         # One line may contain multiple commands (";"). Treat each one as
979         # single line. parse_line() is slow, only use it when necessary.
980         my @line = (index($line, ';') == -1)
981                  ? ($line)
982                  : map {
983                        # Ensure newline at the line end - necessary for
984                        # correct parsing later.
985                        $_ =~ s/\s+$//;
986                        $_ .= "\n";
987                    } Text::ParseWords::parse_line(';', 1, $line);
988         foreach my $line (@line) {
989             if ($continuation) {
990                 $continuation = 0;
991
992                 # Join lines, but leave the "\" in place so it's clear where
993                 # the original line break was.
994                 chomp $complete_line;
995                 $complete_line .= ' ' . $line;
996             }
997             # Line continuation, line ends with "\".
998             if ($line =~ /\\$/) {
999                 $continuation = 1;
1000                 # Start line continuation.
1001                 if (not defined $complete_line) {
1002                     $complete_line = $line;
1003                 }
1004                 next;
1005             }
1006
1007             # Use the complete line if a line continuation occurred.
1008             if (defined $complete_line) {
1009                 $line = $complete_line;
1010                 $complete_line = undef;
1011             }
1012
1013             # Ignore lines with no compiler commands.
1014             next if not $non_verbose
1015                     and not $line =~ /$cc_regex_normal/o;
1016             # Ignore lines with no filenames with extensions. May miss some
1017             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
1018             # a problem as the log will most likely contain other non-verbose
1019             # commands which are detected.
1020             next if not $non_verbose
1021                     and not $line =~ /$file_extension_regex/o;
1022
1023             # Ignore false positives.
1024             #
1025             # `./configure` output.
1026             next if not $non_verbose
1027                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
1028             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
1029                                 [Cc]ompiler[\s.]*:?\s+
1030                                 /x;
1031             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
1032                                 \s*=\s*$cc_regex_full
1033                                 # optional compiler options, don't allow
1034                                 # "everything" here to prevent false negatives
1035                                 \s*(?:\s-\S+)*\s*$}xo;
1036             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
1037             # line (or similar for other architectures) which gets recognized
1038             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
1039             # C++ files. No hardening flags are relevant during this step,
1040             # thus ignore `moc-qt*` lines. The resulting files will be
1041             # compiled in a separate step (and therefore checked).
1042             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
1043                                \s.+\s
1044                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
1045                                \s}x;
1046             # Ignore false positives when the line contains only CC=gcc but no
1047             # other gcc command.
1048             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
1049                 my $before = $1;
1050                 my $after  = $2;
1051                 next if     not $before =~ /$cc_regex_normal/o
1052                         and not $after  =~ /$cc_regex_normal/o;
1053             }
1054             # Ignore false positives caused by gcc -v. It outputs a line
1055             # looking like a normal compiler line but which is sometimes
1056             # missing hardening flags, although the normal compiler line
1057             # contains them.
1058             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
1059                                    [0-9.]+/cc1(?:plus)?}xo;
1060             # Ignore false positive with `rm` which may remove files which
1061             # look like a compiler executable thus causing the line to be
1062             # treated as a normal compiler line.
1063             next if $line =~ m{^\s*rm\s+};
1064             # Some build systems emit "gcc > file".
1065             next if $line =~ m{$cc_regex_normal\s*>\s*\S+}o;
1066             # Hex output may contain "cc".
1067             next if $line =~ m#(?:\b[0-9a-fA-F]{2,}\b\s*){5}#;
1068
1069             # Check if additional hardening options were used. Used to ensure
1070             # they are used for the complete build.
1071             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
1072                                                          @def_ldflags_pie);
1073             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
1074
1075             push @input, $line;
1076             push @input_nonverbose, $non_verbose;
1077             push @input_number, $number if $option_line_numbers;
1078         }
1079     }
1080
1081     close $fh or die $!;
1082
1083     # Ignore arch if requested.
1084     if (scalar @option_ignore_arch > 0 and $arch) {
1085         foreach my $ignore (@option_ignore_arch) {
1086             if ($arch eq $ignore) {
1087                 print "ignoring architecture '$arch'\n";
1088                 next FILE;
1089             }
1090         }
1091     }
1092
1093     if (scalar @input == 0) {
1094         if (not $option_buildd) {
1095             print "No compiler commands!\n";
1096             $exit |= $exit_code{no_compiler_commands};
1097         } else {
1098             print "$buildd_tag{no_compiler_commands}||\n";
1099         }
1100         next FILE;
1101     }
1102
1103     if ($option_buildd) {
1104         $statistics{commands} += scalar @input;
1105     }
1106
1107     # Option or auto detected.
1108     if ($arch) {
1109         # The following was partially copied from dpkg-dev 1.19.7
1110         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, _add_build_flags()),
1111         # copyright RaphaĆ«l Hertzog <hertzog@debian.org>, Guillem Jover
1112         # <guillem@debian.org>, Kees Cook <kees@debian.org>, Canonical, Ltd.
1113         # licensed under GPL version 2 or later. Keep it in sync.
1114
1115         require Dpkg::Arch;
1116         my ($os, $cpu);
1117         # Recent dpkg versions use a quadruplet for arch. Support both.
1118         eval {
1119             (undef, undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtuple($arch);
1120         };
1121         if ($@) {
1122             (undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1123         }
1124
1125         my %builtin_pie_arch = map { $_ => 1 } qw(
1126             amd64
1127             arm64
1128             armel
1129             armhf
1130             hurd-i386
1131             i386
1132             kfreebsd-amd64
1133             kfreebsd-i386
1134             mips
1135             mipsel
1136             mips64el
1137             powerpc
1138             ppc64
1139             ppc64el
1140             riscv64
1141             s390x
1142             sparc
1143             sparc64
1144         );
1145
1146         # Disable unsupported hardening options.
1147         if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/
1148                 or $cpu =~ /^(?:hppa|avr32)$/) {
1149             $harden_pie = 0;
1150         }
1151         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1152             $harden_stack = 0;
1153             $harden_stack_strong = 0;
1154         }
1155         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1156             $harden_relro   = 0;
1157             $harden_bindnow = 0;
1158         }
1159
1160         if ($disable_harden_pie and exists $builtin_pie_arch{$arch}) {
1161             $harden_pie = 0;
1162         }
1163     }
1164
1165     # Default values.
1166     my @cflags   = @def_cflags;
1167     my @cxxflags = @def_cxxflags;
1168     my @cppflags = @def_cppflags;
1169     my @ldflags  = @def_ldflags;
1170     # Check the specified hardening options, same order as dpkg-buildflags.
1171     if ($harden_pie) {
1172         @cflags   = (@cflags,   @def_cflags_pie);
1173         @cxxflags = (@cxxflags, @def_cflags_pie);
1174         @ldflags  = (@ldflags,  @def_ldflags_pie);
1175     }
1176     if ($harden_stack_strong) {
1177         @cflags   = (@cflags,   @def_cflags_stack_strong);
1178         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1179     } elsif ($harden_stack) {
1180         @cflags   = (@cflags,   @def_cflags_stack);
1181         @cxxflags = (@cxxflags, @def_cflags_stack);
1182     }
1183     if ($harden_fortify) {
1184         @cflags   = (@cflags,   @def_cflags_fortify);
1185         @cxxflags = (@cxxflags, @def_cflags_fortify);
1186         @cppflags = (@cppflags, @def_cppflags_fortify);
1187     }
1188     if ($harden_format) {
1189         @cflags   = (@cflags,   @def_cflags_format);
1190         @cxxflags = (@cxxflags, @def_cflags_format);
1191     }
1192     if ($harden_relro) {
1193         @ldflags = (@ldflags, @def_ldflags_relro);
1194     }
1195     if ($harden_bindnow) {
1196         @ldflags = (@ldflags, @def_ldflags_bindnow);
1197     }
1198
1199     # Ada doesn't support format hardening flags, see #680117 for more
1200     # information. Same for fortran.
1201     my @cflags_backup;
1202     my @cflags_noformat = grep {
1203         my $ok = 1;
1204         foreach my $flag (@def_cflags_format) {
1205             $ok = 0 if $_ eq $flag;
1206         }
1207         $ok;
1208     } @cflags;
1209
1210     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1211     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1212     # as long as @def_cppflags_fortify contains only one variable.
1213     if (scalar @def_cppflags_fortify == 0) {
1214         $harden_fortify = 0;
1215     }
1216
1217     # Ignore flags for this arch if requested.
1218     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1219         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1220
1221         remove_flags(\@local_flag_refs,
1222                      \%flag_renames,
1223                      @{$option_ignore_arch_flag{$arch}});
1224     }
1225
1226     my @ignore_line = @option_ignore_line;
1227     # Ignore lines for this arch if requested.
1228     if ($arch and exists $option_ignore_arch_line{$arch}) {
1229         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1230     }
1231
1232 LINE:
1233     for (my $i = 0; $i < scalar @input; $i++) {
1234         my $line = $input[$i];
1235
1236         # Ignore line if requested.
1237         foreach my $ignore (@ignore_line) {
1238             next LINE if $line =~ /$ignore/;
1239         }
1240
1241         my $skip = 0;
1242         if ($input_nonverbose[$i]
1243                 and is_non_verbose_build($line, \$skip,
1244                                          \@input, $i, $parallel)) {
1245             if (not $option_buildd) {
1246                 error_non_verbose_build($line, $input_number[$i]);
1247                 $exit |= $exit_code{non_verbose_build};
1248             } else {
1249                 $statistics{commands_nonverbose}++;
1250             }
1251             next;
1252         }
1253         # Even if it's a verbose build, we might have to skip this line (see
1254         # is_non_verbose_build()).
1255         next if $skip;
1256
1257         my $orig_line = $line;
1258
1259         # Remove everything until and including the compiler command. Makes
1260         # checks easier and faster.
1261         $line =~ s/^.*?$cc_regex//o;
1262         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1263         # the brace and similar characters at the line end.
1264         $line =~ s/['")]+$//;
1265
1266         # Skip unnecessary tests when only preprocessing.
1267         my $flag_preprocess = 0;
1268
1269         my $dependency = 0;
1270         my $preprocess = 0;
1271         my $compile    = 0;
1272         my $link       = 0;
1273
1274         # Preprocess, compile, assemble.
1275         if ($line =~ /\s(-E|-S|-c)\b/) {
1276             $preprocess      = 1;
1277             $flag_preprocess = 1 if $1 eq '-E';
1278             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1279         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1280         # -MT -MQ) are always used with -M/-MM.
1281         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1282             $dependency = 1;
1283         # Otherwise assume we are linking.
1284         } else {
1285             $link = 1;
1286         }
1287
1288         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1289         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1290             $dependency      = 0;
1291             $flag_preprocess = 0;
1292         }
1293
1294         # Dependency generation for Makefiles, no preprocessing or other flags
1295         # needed.
1296         next if $dependency;
1297
1298         # Get all file extensions on this line.
1299         my @extensions = $line =~ /$file_extension_regex/go;
1300         # Ignore all unknown extensions to speedup the search below.
1301         @extensions = grep { exists $extension{$_} } @extensions;
1302
1303         # These file types don't require preprocessing.
1304         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1305             $preprocess = 0;
1306         }
1307         # These file types require preprocessing.
1308         if (extension_found(\%extensions_preprocess, @extensions)) {
1309             # Prevent false positives with "libtool: link: g++ -include test.h
1310             # .." compiler lines.
1311             if ($orig_line !~ /$libtool_link_regex/o) {
1312                 $preprocess = 1;
1313             }
1314         }
1315
1316         if (not $flag_preprocess) {
1317             # If there are source files then it's compiling/linking in one
1318             # step and we must check both. We only check for source files
1319             # here, because header files cause too many false positives.
1320             if (extension_found(\%extensions_compile_link, @extensions)) {
1321                 # Assembly files don't need CFLAGS.
1322                 if (not extension_found(\%extensions_compile, @extensions)
1323                         and extension_found(\%extensions_no_compile, @extensions)) {
1324                     $compile = 0;
1325                 # But the rest does.
1326                 } else {
1327                     $compile = 1;
1328                 }
1329             # No compilable extensions found, either linking or compiling
1330             # header flags.
1331             #
1332             # If there are also no object files we are just compiling headers
1333             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1334             # to our liberal checks for compiler lines, this also reduces the
1335             # number of false positives considerably.
1336             } elsif ($link
1337                     and not extension_found(\%extensions_object, @extensions)) {
1338                 $link = 0;
1339             }
1340         }
1341
1342         my $compile_cpp = 0;
1343         my $restore_cflags = 0;
1344         # Assume CXXFLAGS are required when a C++ file is specified in the
1345         # compiler line.
1346         if ($compile
1347                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1348             $compile     = 0;
1349             $compile_cpp = 1;
1350         # Ada needs special CFLAGS
1351         } elsif (extension_found(\%extensions_ada, @extensions)) {
1352             $restore_cflags = 1;
1353             $preprocess = 0; # Ada uses no CPPFLAGS
1354             @cflags_backup = @cflags;
1355             @cflags        = @cflags_noformat;
1356         # Same for fortran
1357         } elsif (extension_found(\%extensions_fortran, @extensions)) {
1358             $restore_cflags = 1;
1359             @cflags_backup = @cflags;
1360             @cflags        = @cflags_noformat;
1361         }
1362
1363         if ($option_buildd) {
1364             $statistics{preprocess}++  if $preprocess;
1365             $statistics{compile}++     if $compile;
1366             $statistics{compile_cpp}++ if $compile_cpp;
1367             $statistics{link}++        if $link;
1368         }
1369
1370         # Check if there are flags indicating a debug build. If that's true,
1371         # skip the check for -O2. This prevents fortification, but that's fine
1372         # for a debug build.
1373         if (any_flags_used($line, @def_cflags_debug)) {
1374             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1375             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1376         }
1377
1378         # Check hardening flags.
1379         my @missing;
1380         if ($compile and (not all_flags_used($line, \@missing, @cflags)
1381                     or (($harden_stack or $harden_stack_strong)
1382                         and cflags_stack_broken($line, \@missing,
1383                                                 $harden_stack_strong)))
1384                 # Libraries linked with -fPIC don't have to (and can't) be
1385                 # linked with -fPIE as well. It's no error if only PIE flags
1386                 # are missing.
1387                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1388                 # Assume dpkg-buildflags returns the correct flags.
1389                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1390             if (not $option_buildd) {
1391                 error_flags('CFLAGS missing', \@missing, \%flag_renames,
1392                             $input[$i], $input_number[$i]);
1393                 $exit |= $exit_code{flags_missing};
1394             } else {
1395                 $statistics{compile_missing}++;
1396             }
1397         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1398                 # Libraries linked with -fPIC don't have to (and can't) be
1399                 # linked with -fPIE as well. It's no error if only PIE flags
1400                 # are missing.
1401                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1402                 # Assume dpkg-buildflags returns the correct flags.
1403                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1404             if (not $option_buildd) {
1405                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames,
1406                             $input[$i], $input_number[$i]);
1407                 $exit |= $exit_code{flags_missing};
1408             } else {
1409                 $statistics{compile_cpp_missing}++;
1410             }
1411         }
1412         if ($preprocess
1413                 and (not all_flags_used($line, \@missing, @cppflags)
1414                     # The fortify flag might be overwritten, detect that.
1415                      or ($harden_fortify
1416                          and cppflags_fortify_broken($line, \@missing)))
1417                 # Assume dpkg-buildflags returns the correct flags.
1418                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1419             if (not $option_buildd) {
1420                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames,
1421                             $input[$i], $input_number[$i]);
1422                 $exit |= $exit_code{flags_missing};
1423             } else {
1424                 $statistics{preprocess_missing}++;
1425             }
1426         }
1427         if ($link and not all_flags_used($line, \@missing, @ldflags)
1428                 # Same here, -fPIC conflicts with -fPIE.
1429                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1430                 # Assume dpkg-buildflags returns the correct flags.
1431                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1432             if (not $option_buildd) {
1433                 error_flags('LDFLAGS missing', \@missing, \%flag_renames,
1434                             $input[$i], $input_number[$i]);
1435                 $exit |= $exit_code{flags_missing};
1436             } else {
1437                 $statistics{link_missing}++;
1438             }
1439         }
1440
1441         # Restore normal CFLAGS.
1442         if ($restore_cflags) {
1443             @cflags = @cflags_backup;
1444         }
1445     }
1446 }
1447
1448 # Print statistics for buildd mode, only output in this mode.
1449 if ($option_buildd) {
1450     my @warning;
1451
1452     if ($statistics{preprocess_missing}) {
1453         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1454                                $statistics{preprocess_missing},
1455                                $statistics{preprocess};
1456     }
1457     if ($statistics{compile_missing}) {
1458         push @warning, sprintf 'CFLAGS %d (of %d)',
1459                                $statistics{compile_missing},
1460                                $statistics{compile};
1461     }
1462     if ($statistics{compile_cpp_missing}) {
1463         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1464                                $statistics{compile_cpp_missing},
1465                                $statistics{compile_cpp};
1466     }
1467     if ($statistics{link_missing}) {
1468         push @warning, sprintf 'LDFLAGS %d (of %d)',
1469                                $statistics{link_missing},
1470                                $statistics{link};
1471     }
1472     if (scalar @warning) {
1473         local $" = ', '; # array join string
1474         print "$buildd_tag{flags_missing}|@warning missing|\n";
1475     }
1476
1477     if ($statistics{commands_nonverbose}) {
1478         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1479                $statistics{commands_nonverbose},
1480                $statistics{commands},
1481     }
1482 }
1483
1484
1485 exit $exit;
1486
1487
1488 __END__
1489
1490 =head1 NAME
1491
1492 blhc - build log hardening check, checks build logs for missing hardening flags
1493
1494 =head1 SYNOPSIS
1495
1496 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1497
1498 =head1 DESCRIPTION
1499
1500 blhc is a small tool which checks build logs for missing hardening flags. It's
1501 licensed under the GPL 3 or later.
1502
1503 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1504 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1505 official buildd build logs)) to help maintainers detect missing hardening
1506 flags in their packages.
1507
1508 Only gcc is detected as compiler at the moment. If other compilers support
1509 hardening flags as well, please report them.
1510
1511 If there's no output, no flags are missing and the build log is fine.
1512
1513 See F<README> for details about performed checks, auto-detection and
1514 limitations.
1515
1516 =head1 OPTIONS
1517
1518 =over 8
1519
1520 =item B<--all>
1521
1522 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1523 auto detected.
1524
1525 =item B<--arch> I<architecture>
1526
1527 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1528 disables hardening flags not available on this architecture. Is detected
1529 automatically if dpkg-buildpackage is used.
1530
1531 =item B<--bindnow>
1532
1533 Force check for all +bindnow hardening flags. By default it's auto detected.
1534
1535 =item B<--buildd>
1536
1537 Special mode for buildds when automatically parsing log files. The following
1538 changes are in effect:
1539
1540 =over 2
1541
1542 =item *
1543
1544 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1545 possible tags.
1546
1547 =item *
1548
1549 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1550 detected).
1551
1552 =item *
1553
1554 Don't require Term::ANSIColor.
1555
1556 =item *
1557
1558 Return exit code 0, unless there was a error (-I, -W messages don't count as
1559 error).
1560
1561 =back
1562
1563 =item B<--debian>
1564
1565 Apply Debian-specific settings. At the moment this only disables checking for
1566 PIE which is automatically applied by Debian's GCC and no longer requires a
1567 compiler command line argument.
1568
1569 =item B<--color>
1570
1571 Use colored (ANSI) output for warning messages.
1572
1573 =item B<--line-numbers>
1574
1575 Display line numbers.
1576
1577 =item B<--ignore-arch> I<arch>
1578
1579 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1580
1581 Used to prevent false positives. This option can be specified multiple times.
1582
1583 =item B<--ignore-arch-flag> I<arch>:I<flag>
1584
1585 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1586
1587 =item B<--ignore-arch-line> I<arch>:I<line>
1588
1589 Like B<--ignore-line>, but only ignore line on I<arch>.
1590
1591 =item B<--ignore-flag> I<flag>
1592
1593 Don't print an error when the specific flag is missing in a compiler line.
1594 I<flag> is a string.
1595
1596 Used to prevent false positives. This option can be specified multiple times.
1597
1598 =item B<--ignore-line> I<regex>
1599
1600 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1601 at the beginning and end of the line to prevent false negatives.
1602
1603 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1604 warnings (which have line continuation resolved).
1605
1606 Used to prevent false positives. This option can be specified multiple times.
1607
1608 =item B<--pie>
1609
1610 Force check for all +pie hardening flags. By default it's auto detected.
1611
1612 =item B<-h -? --help>
1613
1614 Print available options.
1615
1616 =item B<--version>
1617
1618 Print version number and license.
1619
1620 =back
1621
1622 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1623 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1624 all other commands as well.
1625
1626 =head1 EXAMPLES
1627
1628 Normal usage, parse a single log file.
1629
1630     blhc path/to/log/file
1631
1632 If there's no output, no flags are missing and the build log is fine.
1633
1634 Parse multiple log files. The exit code is ORed over all files.
1635
1636     blhc path/to/directory/with/log/files/*
1637
1638 Don't treat missing C<-g> as error:
1639
1640     blhc --ignore-flag -g path/to/log/file
1641
1642 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1643
1644     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1645
1646 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1647 false positive.
1648
1649     blhc --ignore-line '\./script gcc file' path/to/log/file
1650
1651 Ignore lines matching C<./script gcc file> somewhere in the line.
1652
1653     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1654
1655 Use blhc with pbuilder.
1656
1657     pbuilder path/to/package.dsc | tee path/log/file
1658     blhc path/to/file || echo flags missing
1659
1660 Assume this build log was created on a Debian system and thus don't warn about
1661 missing PIE flags if the current architecture injects them automatically (this
1662 is enabled in buildd mode per default). C<--arch> is necessary if the build
1663 log contains no architecture information as written by dpkg-buildpackage.
1664
1665     blhc --debian --all --arch=amd64 path/to/log/file
1666
1667 =head1 BUILDD TAGS
1668
1669 The following tags are used in I<--buildd> mode. In braces the additional data
1670 which is displayed.
1671
1672 =over 2
1673
1674 =item B<I-hardening-wrapper-used>
1675
1676 The package uses hardening-wrapper which intercepts calls to gcc and adds
1677 hardening flags. The build log doesn't contain any hardening flags and thus
1678 can't be checked by blhc.
1679
1680 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1681
1682 Build log contains lines which hide the real compiler flags. For example:
1683
1684     CC test-a.c
1685     CC test-b.c
1686     CC test-c.c
1687     LD test
1688
1689 Most of the time either C<export V=1> or C<export verbose=1> in
1690 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1691 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1692 patched to remove the C<@>s hiding the real compiler commands.
1693
1694 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1695
1696 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1697
1698 =item B<I-invalid-cmake-used> (version)
1699
1700 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1701 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1702 patch was rejected by upstream and later reverted in Debian. Thus those two
1703 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1704 handle them (for example by passing them to CFLAGS). To prevent false
1705 negatives just blacklist those two versions.
1706
1707 =item B<I-no-compiler-commands>
1708
1709 No compiler commands were detected. Either the log contains none or they were
1710 not correctly detected by blhc (please report the bug in this case).
1711
1712 =back
1713
1714 =head1 EXIT STATUS
1715
1716 The exit status is a "bit mask", each listed status is ORed when the error
1717 condition occurs to get the result.
1718
1719 =over 4
1720
1721 =item B<0>
1722
1723 Success.
1724
1725 =item B<1>
1726
1727 No compiler commands were found.
1728
1729 =item B<2>
1730
1731 Invalid arguments/options given to blhc.
1732
1733 =item B<4>
1734
1735 Non verbose build.
1736
1737 =item B<8>
1738
1739 Missing hardening flags.
1740
1741 =item B<16>
1742
1743 Hardening wrapper detected, no tests performed.
1744
1745 =item B<32>
1746
1747 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1748 TAGS"> for a detailed explanation.
1749
1750 =back
1751
1752 =head1 AUTHOR
1753
1754 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1755
1756 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1757 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1758
1759 =head1 LICENSE AND COPYRIGHT
1760
1761 Copyright (C) 2012-2019 by Simon Ruderich
1762
1763 This program is free software: you can redistribute it and/or modify
1764 it under the terms of the GNU General Public License as published by
1765 the Free Software Foundation, either version 3 of the License, or
1766 (at your option) any later version.
1767
1768 This program is distributed in the hope that it will be useful,
1769 but WITHOUT ANY WARRANTY; without even the implied warranty of
1770 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1771 GNU General Public License for more details.
1772
1773 You should have received a copy of the GNU General Public License
1774 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1775
1776 =head1 SEE ALSO
1777
1778 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1779
1780 =cut