bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2016  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.06';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full_prefix = qr/
  42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
  43     /x;
  44 my $cc_regex_full = qr/
  45     (?:$cc_regex_full_prefix-)?
  46     $cc_regex
  47     /x;
  48 # Regex to check if a line contains a compiler command.
  49 my $cc_regex_normal = qr/
  50     \b$cc_regex(?:\s|\\)
  51     /x;
  52 # Regex to catch (GCC) compiler warnings.
  53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  54 # Regex to catch libtool commands and not lines which show commands executed
  55 # by libtool (e.g. libtool: link: ...).
  56 my $libtool_regex = qr/\blibtool\s.*--mode=/;
  57 my $libtool_link_regex = qr/\blibtool: link: /;
  58
  59 # List of source file extensions which require preprocessing.
  60 my @source_preprocess_compile_cpp = (
  61     # C++
  62     qw( cc cp cxx cpp CPP c++ C ),
  63     # Objective-C++
  64     qw( mm M ),
  65 );
  66 my @source_preprocess_compile = (
  67     # C
  68     qw( c ),
  69     # Objective-C
  70     qw( m ),
  71     # (Objective-)C++
  72     @source_preprocess_compile_cpp,
  73     # Fortran
  74     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  75 );
  76 my @source_preprocess_no_compile = (
  77     # Assembly
  78     qw( S sx ),
  79 );
  80 my @source_preprocess = (
  81     @source_preprocess_compile,
  82     @source_preprocess_no_compile,
  83 );
  84 # List of source file extensions which don't require preprocessing.
  85 my @source_no_preprocess_compile_cpp = (
  86     # C++
  87     qw( ii ),
  88     # Objective-C++
  89     qw( mii ),
  90 );
  91 my @source_no_preprocess_compile_ada = (
  92     # Ada body
  93     qw( adb ),
  94     # If you add another file, fix use of @source_no_preprocess_compile_ada
  95     # below (search for $compile_ada).
  96 );
  97 my @source_no_preprocess_compile = (
  98     # C
  99     qw( i ),
 100     # (Objective-)C++
 101     @source_no_preprocess_compile_cpp,
 102     # Objective-C
 103     qw( mi ),
 104     # Fortran
 105     qw( f for ftn f90 f95 f03 f08 ),
 106     # Ada
 107     @source_no_preprocess_compile_ada,
 108 );
 109 my @source_no_preprocess_no_compile = (
 110     # Assembly
 111     qw( s ),
 112     # Ada specification
 113     qw( ads ),
 114 );
 115 my @source_no_preprocess = (
 116     @source_no_preprocess_compile,
 117     @source_no_preprocess_no_compile,
 118 );
 119 # List of header file extensions which require preprocessing.
 120 my @header_preprocess = (
 121     # C, C++, Objective-C, Objective-C++
 122     qw( h ),
 123     # C++
 124     qw( hh H hp hxx hpp HPP h++ tcc ),
 125 );
 126 # Object files.
 127 my @object = (
 128     # Normal object files.
 129     qw ( o ),
 130     # Libtool object files.
 131     qw ( lo la ),
 132     # Dynamic libraries. bzip2 uses .sho.
 133     qw ( so sho ),
 134     # Static libraries.
 135     qw ( a ),
 136 );
 137
 138 # Hashes for fast extensions lookup to check if a file falls in one of these
 139 # categories.
 140 my %extensions_no_preprocess = map { $_ => 1 } (
 141     # There's no @header_no_preprocess.
 142     @source_no_preprocess,
 143 );
 144 my %extensions_preprocess = map { $_ => 1 } (
 145     @header_preprocess,
 146     @source_preprocess,
 147 );
 148 my %extensions_compile_link = map { $_ => 1 } (
 149     @source_preprocess,
 150     @source_no_preprocess,
 151 );
 152 my %extensions_compile = map { $_ => 1 } (
 153     @source_preprocess_compile,
 154     @source_no_preprocess_compile,
 155 );
 156 my %extensions_no_compile = map { $_ => 1 } (
 157     @source_preprocess_no_compile,
 158     @source_no_preprocess_no_compile,
 159 );
 160 my %extensions_compile_cpp = map { $_ => 1 } (
 161     @source_preprocess_compile_cpp,
 162     @source_no_preprocess_compile_cpp,
 163 );
 164 my %extensions_object = map { $_ => 1 } (
 165     @object,
 166 );
 167 my %extension = map { $_ => 1 } (
 168     @source_no_preprocess,
 169     @header_preprocess,
 170     @source_preprocess,
 171     @object,
 172 );
 173
 174 # Regexp to match file extensions.
 175 my $file_extension_regex = qr/
 176     \s
 177     \S+             # Filename without extension.
 178     \.
 179     ([^\/\\.,;:\s]+)# File extension.
 180     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 181                     # word characters at the end and because \b matches double
 182                     # extensions (like .cpp.o). Works always as all lines are
 183                     # terminated with "\n".
 184     /x;
 185
 186 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 187 # real regexps below for better execution speed).
 188 my @def_cflags = (
 189     '-g',
 190     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
 191 );
 192 my @def_cflags_debug = (
 193     # These flags indicate a debug build which disables checks for -O2.
 194     '-O0',
 195     '-Og',
 196 );
 197 my @def_cflags_format = (
 198     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 199     '-Werror=format-security', # implies -Wformat-security
 200 );
 201 my @def_cflags_fortify = (
 202     # fortify needs at least -O1, but -O2 is recommended anyway
 203 );
 204 my @def_cflags_stack = (
 205     '-fstack-protector',
 206     '--param[= ]ssp-buffer-size=4',
 207 );
 208 my @def_cflags_stack_strong = (
 209     '-fstack-protector-strong',
 210 );
 211 my @def_cflags_pie = (
 212     '-fPIE',
 213 );
 214 my @def_cxxflags = (
 215     @def_cflags,
 216 );
 217 # @def_cxxflags_* is the same as @def_cflags_*.
 218 my @def_cppflags = ();
 219 my @def_cppflags_fortify = (
 220     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 221     # If you add another flag fix hack below (search for "Hack to fix") and
 222     # $def_cppflags_fortify[0].
 223 );
 224 my @def_cppflags_fortify_bad = (
 225     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 226     '-U_FORTIFY_SOURCE',
 227     '-D_FORTIFY_SOURCE=0',
 228     '-D_FORTIFY_SOURCE=1',
 229 );
 230 my @def_ldflags = ();
 231 my @def_ldflags_relro = (
 232     '-Wl,(?:-z,)?relro',
 233 );
 234 my @def_ldflags_bindnow = (
 235     '-Wl,(?:-z,)?now',
 236 );
 237 my @def_ldflags_pie = (
 238     '-fPIE',
 239     '-pie',
 240 );
 241 my @def_ldflags_pic = (
 242     '-fPIC',
 243     '-fpic',
 244     '-shared',
 245 );
 246 # References to all flags checked by the flag checker.
 247 my @flag_refs = (
 248     \@def_cflags,
 249     \@def_cflags_format,
 250     \@def_cflags_fortify,
 251     \@def_cflags_stack,
 252     \@def_cflags_stack_strong,
 253     \@def_cflags_pie,
 254     \@def_cxxflags,
 255     \@def_cppflags,
 256     \@def_cppflags_fortify,
 257     \@def_ldflags,
 258     \@def_ldflags_relro,
 259     \@def_ldflags_bindnow,
 260     \@def_ldflags_pie,
 261 );
 262 # References to all used flags.
 263 my @flag_refs_all = (
 264     @flag_refs,
 265     \@def_cflags_debug,
 266     \@def_cppflags_fortify_bad,
 267     \@def_ldflags_pic,
 268 );
 269 # Renaming rules for the output so the regex parts are not visible. Also
 270 # stores string values of flag regexps above, see compile_flag_regexp().
 271 my %flag_renames = (
 272     '-O(?:2|3)'                    => '-O2',
 273     '-Wformat(?:=2)?'              => '-Wformat',
 274     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 275     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 276     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 277 );
 278
 279 my %exit_code = (
 280     no_compiler_commands => 1 << 0,
 281     # used by POD::Usage => 1 << 1,
 282     non_verbose_build    => 1 << 2,
 283     flags_missing        => 1 << 3,
 284     hardening_wrapper    => 1 << 4,
 285     invalid_cmake        => 1 << 5,
 286 );
 287
 288 my %buildd_tag = (
 289     no_compiler_commands => 'I-no-compiler-commands',
 290     non_verbose_build    => 'W-compiler-flags-hidden',
 291     flags_missing        => 'W-dpkg-buildflags-missing',
 292     hardening_wrapper    => 'I-hardening-wrapper-used',
 293     invalid_cmake        => 'I-invalid-cmake-used',
 294 );
 295
 296 # Statistics of missing flags and non-verbose build commands. Used for
 297 # $option_buildd.
 298 my %statistics = (
 299     preprocess          => 0,
 300     preprocess_missing  => 0,
 301     compile             => 0,
 302     compile_missing     => 0,
 303     compile_cpp         => 0,
 304     compile_cpp_missing => 0,
 305     link                => 0,
 306     link_missing        => 0,
 307     commands            => 0,
 308     commands_nonverbose => 0,
 309 );
 310
 311 # Use colored (ANSI) output?
 312 my $option_color;
 313
 314
 315 # FUNCTIONS
 316
 317 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 318 sub array_equal {
 319     my ($first_ref, $second_ref) = @_;
 320
 321     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 322
 323     my $length = scalar @{$first_ref};
 324     for (my $i = 0; $i < $length; $i++) {
 325         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 326     }
 327
 328     return 1;
 329 }
 330
 331 sub error_flags {
 332     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 333
 334     # Get string value of qr//-escaped regexps and if requested rename them.
 335     my @missing_flags = map {
 336             $flag_renames_ref->{$_}
 337         } @{$missing_flags_ref};
 338
 339     my $flags = join ' ', @missing_flags;
 340     printf '%s (%s)%s %s',
 341            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 342            $line;
 343
 344     return;
 345 }
 346 sub error_non_verbose_build {
 347     my ($line) = @_;
 348
 349     printf '%s%s %s',
 350            error_color('NONVERBOSE BUILD', 'red'),
 351            error_color(':', 'yellow'),
 352            $line;
 353
 354     return;
 355 }
 356 sub error_invalid_cmake {
 357     my ($version) = @_;
 358
 359     printf "%s%s %s\n",
 360             error_color('INVALID CMAKE', 'red'),
 361             error_color(':', 'yellow'),
 362             $version;
 363
 364     return;
 365 }
 366 sub error_hardening_wrapper {
 367     printf "%s%s %s\n",
 368             error_color('HARDENING WRAPPER', 'red'),
 369             error_color(':', 'yellow'),
 370             'no checks possible, aborting';
 371
 372     return;
 373 }
 374 sub error_color {
 375     my ($message, $color) = @_;
 376
 377     if ($option_color) {
 378         return Term::ANSIColor::colored($message, $color);
 379     } else {
 380         return $message;
 381     }
 382 }
 383
 384 sub any_flags_used {
 385     my ($line, @flags) = @_;
 386
 387     foreach my $flag (@flags) {
 388         return 1 if $line =~ /$flag/;
 389     }
 390
 391     return 0;
 392 }
 393 sub all_flags_used {
 394     my ($line, $missing_flags_ref, @flags) = @_;
 395
 396     my @missing_flags = ();
 397     foreach my $flag (@flags) {
 398         if (not $line =~ /$flag/) {
 399             push @missing_flags, $flag;
 400         }
 401     }
 402
 403     return 1 if scalar @missing_flags == 0;
 404
 405     @{$missing_flags_ref} = @missing_flags;
 406     return 0;
 407 }
 408
 409 sub cppflags_fortify_broken {
 410     my ($line, $missing_flags) = @_;
 411
 412     # This doesn't take the position into account, but is a simple solution.
 413     # And if the build system tries to force -D_FORTIFY_SOURCE=0/1, something
 414     # is wrong anyway.
 415
 416     if (any_flags_used($line, @def_cppflags_fortify_bad)) {
 417         # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 418         push @{$missing_flags}, $def_cppflags_fortify[0];
 419         return 1;
 420     }
 421
 422     return 0;
 423 }
 424
 425 # Modifies $missing_flags_ref array.
 426 sub pic_pie_conflict {
 427     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 428
 429     return 0 if not $pie;
 430     return 0 if not any_flags_used($line, @def_ldflags_pic);
 431
 432     my %flags = map { $_ => 1 } @flags_pie;
 433
 434     # Remove all PIE flags from @missing_flags as they are not required with
 435     # -fPIC.
 436     my @result = grep {
 437         not exists $flags{$_}
 438     } @{$missing_flags_ref};
 439     @{$missing_flags_ref} = @result;
 440
 441     # We got a conflict when no flags are left, thus only PIE flags were
 442     # missing. If other flags were missing abort because the conflict is not
 443     # the problem.
 444     return scalar @result == 0;
 445 }
 446
 447 sub is_non_verbose_build {
 448     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
 449
 450     if ($line =~ /$libtool_regex/o) {
 451         # libtool's --silent hides the real compiler flags.
 452         if ($line =~ /\s--silent/) {
 453             return 1;
 454         # If --silent is not present, skip this line as some compiler flags
 455         # might be missing (e.g. -fPIE) which are handled correctly by libtool
 456         # internally. libtool displays the real compiler command on the next
 457         # line, so the flags are checked as usual.
 458         } else {
 459             ${$skip_ref} = 1;
 460             return 0;
 461         }
 462     }
 463
 464     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 465                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 466                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 467                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 468                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 469         return 0;
 470     }
 471
 472     # False positives.
 473     #
 474     # C++ compiler setting.
 475     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 476     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 477     # "Compiling" non binary files.
 478     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|el)['"]?\s*(?:\.\.\.)?$/;
 479     # "Compiling" with no file name.
 480     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 481         # $file_extension_regex may need spaces around the filename.
 482         return 0 if not " $1 " =~ /$file_extension_regex/o;
 483     }
 484
 485     my $file = $1;
 486
 487     # On the first pass we only check if this line is verbose or not.
 488     return 1 if not defined $input_ref;
 489
 490     # Second pass, we have access to the next lines.
 491     ${$skip_ref} = 0;
 492
 493     # CMake and other build systems print the non-verbose messages also when
 494     # building verbose. If a compiler and the file name occurs in the next
 495     # lines, treat it as verbose build.
 496     if (defined $file) {
 497         # Get filename, we can't use the complete path as only parts of it are
 498         # used in the real compiler command.
 499         $file =~ m{/([^/\s]+)$};
 500         $file = $1;
 501
 502         for (my $i = 1; $i <= $line_count; $i++) {
 503             my $next_line = $input_ref->[$line_offset + $i];
 504             last unless defined $next_line;
 505
 506             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 507                 # Not a non-verbose line, but we still have to skip the
 508                 # current line as it doesn't contain any compiler commands.
 509                 ${$skip_ref} = 1;
 510                 return 0;
 511             }
 512         }
 513     }
 514
 515     return 1;
 516 }
 517
 518 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
 519 sub remove_flags {
 520     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 521
 522     my %removes = map { $_ => 1 } @flags;
 523     foreach my $flags (@{$flag_refs_ref}) {
 524         @{$flags} = grep {
 525             # Flag found as string.
 526             not exists $removes{$_}
 527             # Flag found as string representation of regexp.
 528                 and (not defined $flag_renames_ref->{$_}
 529                         or not exists $removes{$flag_renames_ref->{$_}})
 530         } @{$flags};
 531     }
 532
 533     return;
 534 }
 535
 536 # Modifies $flag_renames_ref hash.
 537 sub compile_flag_regexp {
 538     my ($flag_renames_ref, @flags) = @_;
 539
 540     my @result = ();
 541     foreach my $flag (@flags) {
 542         # Compile flag regexp for faster execution.
 543         my $regex = qr/\s$flag(?:\s|\\)/;
 544
 545         # Store flag name in replacement string for correct flags in messages
 546         # with qr//ed flag regexps.
 547         $flag_renames_ref->{$regex}
 548             = (exists $flag_renames_ref->{$flag})
 549                 ? $flag_renames_ref->{$flag}
 550                 : $flag;
 551
 552         push @result, $regex;
 553     }
 554     return @result;
 555 }
 556
 557 # Does any extension in @extensions exist in %{$extensions_ref}?
 558 sub extension_found {
 559     my ($extensions_ref, @extensions) = @_;
 560
 561     foreach my $extension (@extensions) {
 562         if (exists $extensions_ref->{$extension}) {
 563             return 1;
 564         }
 565     }
 566     return 0;
 567 }
 568
 569
 570 # MAIN
 571
 572 # Parse command line arguments.
 573 my $option_help             = 0;
 574 my $option_version          = 0;
 575 my $option_pie              = 0;
 576 my $option_bindnow          = 0;
 577 my @option_ignore_arch      = ();
 578 my @option_ignore_flag      = ();
 579 my @option_ignore_arch_flag = ();
 580 my @option_ignore_line      = ();
 581 my @option_ignore_arch_line = ();
 582 my $option_all              = 0;
 583 my $option_arch             = undef;
 584 my $option_buildd           = 0;
 585    $option_color            = 0;
 586 if (not Getopt::Long::GetOptions(
 587             'help|h|?'           => \$option_help,
 588             'version'            => \$option_version,
 589             # Hardening options.
 590             'pie'                => \$option_pie,
 591             'bindnow'            => \$option_bindnow,
 592             'all'                => \$option_all,
 593             # Ignore.
 594             'ignore-arch=s'      => \@option_ignore_arch,
 595             'ignore-flag=s'      => \@option_ignore_flag,
 596             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 597             'ignore-line=s'      => \@option_ignore_line,
 598             'ignore-arch-line=s' => \@option_ignore_arch_line,
 599             # Misc.
 600             'color'              => \$option_color,
 601             'arch=s'             => \$option_arch,
 602             'buildd'             => \$option_buildd,
 603         )) {
 604     require Pod::Usage;
 605     Pod::Usage::pod2usage(2);
 606 }
 607 if ($option_help) {
 608     require Pod::Usage;
 609     Pod::Usage::pod2usage(1);
 610 }
 611 if ($option_version) {
 612     print <<"EOF";
 613 blhc $VERSION  Copyright (C) 2012-2016  Simon Ruderich
 614
 615 This program is free software: you can redistribute it and/or modify
 616 it under the terms of the GNU General Public License as published by
 617 the Free Software Foundation, either version 3 of the License, or
 618 (at your option) any later version.
 619
 620 This program is distributed in the hope that it will be useful,
 621 but WITHOUT ANY WARRANTY; without even the implied warranty of
 622 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 623 GNU General Public License for more details.
 624
 625 You should have received a copy of the GNU General Public License
 626 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 627 EOF
 628     exit 0;
 629 }
 630
 631 # Arguments missing.
 632 if (scalar @ARGV == 0) {
 633     require Pod::Usage;
 634     Pod::Usage::pod2usage(2);
 635 }
 636
 637 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 638 # installed on Debian's buildds.
 639 if (not $option_buildd) {
 640     require Term::ANSIColor;
 641 }
 642
 643 if ($option_all) {
 644     $option_pie     = 1;
 645     $option_bindnow = 1;
 646 }
 647
 648 # Precompiled ignores for faster lookup.
 649 my %option_ignore_arch_flag = ();
 650 my %option_ignore_arch_line = ();
 651
 652 # Strip flags which should be ignored.
 653 if (scalar @option_ignore_flag > 0) {
 654     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 655 }
 656 # Same for arch specific ignore flags, but only prepare here.
 657 if (scalar @option_ignore_arch_flag > 0) {
 658     foreach my $ignore (@option_ignore_arch_flag) {
 659         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 660
 661         if (not $ignore_arch or not $ignore_flag) {
 662             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 663                         . '("arch:flag" expected)' . "\n", $ignore;
 664             require Pod::Usage;
 665             Pod::Usage::pod2usage(2);
 666         }
 667
 668         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 669     }
 670 }
 671
 672 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 673 # faster with this.
 674 foreach my $flags (@flag_refs_all) {
 675     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 676 }
 677
 678 # Precompile ignore line regexps, also anchor at beginning and end of line.
 679 foreach my $ignore (@option_ignore_line) {
 680     $ignore = qr/^$ignore$/;
 681 }
 682 # Same for arch specific ignore lines.
 683 if (scalar @option_ignore_arch_line > 0) {
 684     foreach my $ignore (@option_ignore_arch_line) {
 685         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 686
 687         if (not $ignore_arch or not $ignore_line) {
 688             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 689                         . '("arch:line" expected)' . "\n", $ignore;
 690             require Pod::Usage;
 691             Pod::Usage::pod2usage(2);
 692         }
 693
 694         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 695     }
 696 }
 697
 698 # Final exit code.
 699 my $exit = 0;
 700
 701 FILE:
 702 foreach my $file (@ARGV) {
 703     print "checking '$file'...\n" if scalar @ARGV > 1;
 704
 705     -f $file or die "No such file: $file";
 706
 707     open my $fh, '<', $file or die $!;
 708
 709     # Architecture of this file.
 710     my $arch = $option_arch;
 711
 712     # Hardening options. Not all architectures support all hardening options.
 713     my $harden_format  = 1;
 714     my $harden_fortify = 1;
 715     my $harden_stack   = 1;
 716     my $harden_stack_strong = 1;
 717     my $harden_relro   = 1;
 718     my $harden_bindnow = $option_bindnow; # defaults to 0
 719     my $harden_pie     = $option_pie;     # defaults to 0
 720
 721     # Does this build log use ada? Ada also uses gcc as compiler but uses
 722     # different CFLAGS. But only perform ada checks if an ada compiler is used
 723     # for performance reasons.
 724     my $ada = 0;
 725
 726     # Number of parallel jobs to prevent false positives when detecting
 727     # non-verbose builds. As not all jobs declare the number of parallel jobs
 728     # use a large enough default.
 729     my $parallel = 10;
 730
 731     while (my $line = <$fh>) {
 732         # Detect architecture automatically unless overridden. For buildd logs
 733         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 734         # build logs which aren't built (wrong architecture, build error,
 735         # etc.).
 736         if (not $arch) {
 737             if (index($line, 'Build Architecture: ') == 0) {
 738                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 739             # For old logs (sbuild << 0.63.0-1).
 740             } elsif (index($line, 'Architecture: ') == 0) {
 741                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 742             }
 743         }
 744
 745         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 746         # check for hardening flags in buildd mode if an older dpkg-dev is
 747         # used. Default flags (-g -O2) are still checked.
 748         #
 749         # Packages which were built before 1.16.1 but used their own hardening
 750         # flags are not checked.
 751         #
 752         # Strong stack protector is used since dpkg 1.17.11.
 753         if ($option_buildd
 754                 and index($line, 'Toolchain package versions: ') == 0) {
 755             require Dpkg::Version;
 756
 757             my $disable = 1;
 758             my $disable_strong = 1;
 759
 760             if ($line =~ /\bdpkg-dev_(\S+)/) {
 761                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
 762                     $disable = 0;
 763                 }
 764                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
 765                     $disable_strong = 0;
 766                 }
 767             }
 768
 769             if ($disable) {
 770                 $harden_format  = 0;
 771                 $harden_fortify = 0;
 772                 $harden_stack   = 0;
 773                 $harden_relro   = 0;
 774                 $harden_bindnow = 0;
 775                 $harden_pie     = 0;
 776             }
 777             if ($disable_strong) {
 778                 $harden_stack_strong = 0;
 779             }
 780         }
 781
 782         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 783         # this was later dropped because upstream rejected the patch. Thus
 784         # build logs with these versions will have fortify hardening flags
 785         # enabled, even though they may be not correctly set and are missing
 786         # when build with later CMake versions. Thanks to Aron Xu for letting
 787         # me know.
 788         if (index($line, 'Package versions: ') == 0
 789                 and $line =~ /\bcmake_(\S+)/
 790                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 791             if (not $option_buildd) {
 792                 error_invalid_cmake($1);
 793                 $exit |= $exit_code{invalid_cmake};
 794             } else {
 795                 print "$buildd_tag{invalid_cmake}|$1|\n";
 796             }
 797         }
 798
 799         # Debian's build daemons use "Filtered Build-Depends:" (or just
 800         # "Build-Depends:" in older versions) for the build dependencies, but
 801         # pbuilder uses "Depends:"; support both.
 802         if (index($line, 'Filtered Build-Depends: ') == 0
 803                 or index($line, 'Build-Depends: ') == 0
 804                 or index($line, 'Depends: ') == 0) {
 805             # If hardening wrapper is used (wraps calls to gcc and adds
 806             # hardening flags automatically) we can't perform any checks,
 807             # abort.
 808             if ($line =~ /\bhardening-wrapper\b/) {
 809                 if (not $option_buildd) {
 810                     error_hardening_wrapper();
 811                     $exit |= $exit_code{hardening_wrapper};
 812                 } else {
 813                     print "$buildd_tag{hardening_wrapper}||\n";
 814                 }
 815                 next FILE;
 816             }
 817
 818             # Ada compiler.
 819             if ($line =~ /\bgnat\b/) {
 820                 $ada = 1;
 821             }
 822         }
 823
 824         # This flags is not always available, but if it is use it.
 825         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
 826             $parallel = $1;
 827         }
 828
 829         # We skip over unimportant lines at the beginning of the log to
 830         # prevent false positives.
 831         last if index($line, 'dpkg-buildpackage: ') == 0;
 832     }
 833
 834     # Input lines, contain only the lines with compiler commands.
 835     my @input = ();
 836     # Non-verbose lines in the input. Used to reduce calls to
 837     # is_non_verbose_build() (which is quite slow) in the second loop when
 838     # it's already clear if a line is non-verbose or not.
 839     my @input_nonverbose = ();
 840
 841     my $continuation = 0;
 842     my $complete_line = undef;
 843     my $non_verbose;
 844     while (my $line = <$fh>) {
 845         # And stop at the end of the build log. Package details (reported by
 846         # the buildd logs) are not important for us. This also prevents false
 847         # positives.
 848         last if index($line, 'Build finished at ') == 0
 849                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 850
 851         if (not $continuation) {
 852             $non_verbose = 0;
 853         }
 854
 855         # Detect architecture automatically unless overridden.
 856         if (not $arch
 857                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 858             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 859
 860             # Old buildd logs use e.g. "host architecture is alpha", remove
 861             # the "is", otherwise debarch_to_debtriplet() will not detect the
 862             # architecture.
 863             if (index($arch, 'is ') == 0) {
 864                 $arch = substr $arch, 3;
 865             }
 866         }
 867
 868         next if $line =~ /^\s*#/;
 869         # Ignore compiler warnings for now.
 870         next if $line =~ /$warning_regex/o;
 871
 872         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 873             # Remove all ANSI color sequences which are sometimes used in
 874             # non-verbose builds.
 875             $line = Term::ANSIColor::colorstrip($line);
 876             # Also strip '\0xf' (delete previous character), used by Elinks'
 877             # build system.
 878             $line =~ s/\x0f//g;
 879             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 880             # what it does).
 881             $line =~ s/\033\(B//g;
 882         }
 883
 884         # Check if this line indicates a non verbose build.
 885         my $skip = 0;
 886         $non_verbose |= is_non_verbose_build($line, \$skip);
 887         next if $skip;
 888
 889         # One line may contain multiple commands (";"). Treat each one as
 890         # single line. parse_line() is slow, only use it when necessary.
 891         my @line = (index($line, ';') == -1)
 892                  ? ($line)
 893                  : map {
 894                        # Ensure newline at the line end - necessary for
 895                        # correct parsing later.
 896                        $_ =~ s/\s+$//;
 897                        $_ .= "\n";
 898                    } Text::ParseWords::parse_line(';', 1, $line);
 899         foreach my $line (@line) {
 900             if ($continuation) {
 901                 $continuation = 0;
 902
 903                 # Join lines, but leave the "\" in place so it's clear where
 904                 # the original line break was.
 905                 chomp $complete_line;
 906                 $complete_line .= ' ' . $line;
 907             }
 908             # Line continuation, line ends with "\".
 909             if ($line =~ /\\$/) {
 910                 $continuation = 1;
 911                 # Start line continuation.
 912                 if (not defined $complete_line) {
 913                     $complete_line = $line;
 914                 }
 915                 next;
 916             }
 917
 918             # Use the complete line if a line continuation occurred.
 919             if (defined $complete_line) {
 920                 $line = $complete_line;
 921                 $complete_line = undef;
 922             }
 923
 924             # Ignore lines with no compiler commands.
 925             next if not $non_verbose
 926                     and not $line =~ /$cc_regex_normal/o;
 927             # Ignore lines with no filenames with extensions. May miss some
 928             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
 929             # a problem as the log will most likely contain other non-verbose
 930             # commands which are detected.
 931             next if not $non_verbose
 932                     and not $line =~ /$file_extension_regex/o;
 933
 934             # Ignore false positives.
 935             #
 936             # `./configure` output.
 937             next if not $non_verbose
 938                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
 939             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 940                                 [Cc]ompiler[\s.]*:?\s+
 941                                 /x;
 942             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
 943                                 \s*=\s*$cc_regex_full
 944                                 # optional compiler options, don't allow
 945                                 # "everything" here to prevent false negatives
 946                                 \s*(?:\s-\S+)*\s*$}xo;
 947             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
 948             # line (or similar for other architectures) which gets recognized
 949             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
 950             # C++ files. No hardening flags are relevant during this step,
 951             # thus ignore `moc-qt*` lines. The resulting files will be
 952             # compiled in a separate step (and therefore checked).
 953             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
 954                                \s.+\s
 955                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
 956                                \s}x;
 957             # Ignore false positives when the line contains only CC=gcc but no
 958             # other gcc command.
 959             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
 960                 my $before = $1;
 961                 my $after  = $2;
 962                 next if     not $before =~ /$cc_regex_normal/o
 963                         and not $after  =~ /$cc_regex_normal/o;
 964             }
 965             # Ignore false positives caused by gcc -v. It outputs a line
 966             # looking like a normal compiler line but which is sometimes
 967             # missing hardening flags, although the normal compiler line
 968             # contains them.
 969             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
 970                                    [0-9.]+/cc1(?:plus)?}xo;
 971             # Ignore false positive with `rm` which may remove files which
 972             # look like a compiler executable thus causing the line to be
 973             # treated as a normal compiler line.
 974             next if $line =~ m{^\s*rm\s+};
 975
 976             # Check if additional hardening options were used. Used to ensure
 977             # they are used for the complete build.
 978             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
 979                                                          @def_ldflags_pie);
 980             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 981
 982             push @input, $line;
 983             push @input_nonverbose, $non_verbose;
 984         }
 985     }
 986
 987     close $fh or die $!;
 988
 989     # Ignore arch if requested.
 990     if (scalar @option_ignore_arch > 0 and $arch) {
 991         foreach my $ignore (@option_ignore_arch) {
 992             if ($arch eq $ignore) {
 993                 print "ignoring architecture '$arch'\n";
 994                 next FILE;
 995             }
 996         }
 997     }
 998
 999     if (scalar @input == 0) {
1000         if (not $option_buildd) {
1001             print "No compiler commands!\n";
1002             $exit |= $exit_code{no_compiler_commands};
1003         } else {
1004             print "$buildd_tag{no_compiler_commands}||\n";
1005         }
1006         next FILE;
1007     }
1008
1009     if ($option_buildd) {
1010         $statistics{commands} += scalar @input;
1011     }
1012
1013     # Option or auto detected.
1014     if ($arch) {
1015         # The following was partially copied from dpkg-dev 1.18.7
1016         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
1017         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
1018         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
1019         # later. Keep it in sync.
1020
1021         require Dpkg::Arch;
1022         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1023
1024         # Disable unsupported hardening options.
1025         if ($os !~ /^(?:linux|knetbsd|hurd)$/ or $cpu =~ /^(?:hppa|avr32)$/) {
1026             $harden_pie = 0;
1027         }
1028         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1029             $harden_stack = 0;
1030             $harden_stack_strong = 0;
1031         }
1032         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1033             $harden_relro   = 0;
1034             $harden_bindnow = 0;
1035         }
1036     }
1037
1038     # Default values.
1039     my @cflags   = @def_cflags;
1040     my @cxxflags = @def_cxxflags;
1041     my @cppflags = @def_cppflags;
1042     my @ldflags  = @def_ldflags;
1043     # Check the specified hardening options, same order as dpkg-buildflags.
1044     if ($harden_pie) {
1045         @cflags   = (@cflags,   @def_cflags_pie);
1046         @cxxflags = (@cxxflags, @def_cflags_pie);
1047         @ldflags  = (@ldflags,  @def_ldflags_pie);
1048     }
1049     if ($harden_stack_strong) {
1050         @cflags   = (@cflags,   @def_cflags_stack_strong);
1051         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1052     } elsif ($harden_stack) {
1053         @cflags   = (@cflags,   @def_cflags_stack);
1054         @cxxflags = (@cxxflags, @def_cflags_stack);
1055     }
1056     if ($harden_fortify) {
1057         @cflags   = (@cflags,   @def_cflags_fortify);
1058         @cxxflags = (@cxxflags, @def_cflags_fortify);
1059         @cppflags = (@cppflags, @def_cppflags_fortify);
1060     }
1061     if ($harden_format) {
1062         @cflags   = (@cflags,   @def_cflags_format);
1063         @cxxflags = (@cxxflags, @def_cflags_format);
1064     }
1065     if ($harden_relro) {
1066         @ldflags = (@ldflags, @def_ldflags_relro);
1067     }
1068     if ($harden_bindnow) {
1069         @ldflags = (@ldflags, @def_ldflags_bindnow);
1070     }
1071
1072     # Stores normal CFLAGS when @cflags_ada are temporarily used.
1073     my @cflags_backup;
1074     # Ada CFLAGS, only set if ada is used.
1075     my @cflags_ada;
1076     # Ada doesn't support format hardening flags, see #680117 for more
1077     # information. Filter them out if ada is used.
1078     if ($ada and $harden_format) {
1079         @cflags_ada = grep {
1080             my $ok = 1;
1081             foreach my $flag (@def_cflags_format) {
1082                 $ok = 0 if $_ eq $flag;
1083             }
1084             $ok;
1085         } @cflags;
1086     }
1087
1088     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1089     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1090     # as long as @def_cppflags_fortify contains only one variable.
1091     if (scalar @def_cppflags_fortify == 0) {
1092         $harden_fortify = 0;
1093     }
1094
1095     # Ignore flags for this arch if requested.
1096     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1097         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1098
1099         remove_flags(\@local_flag_refs,
1100                      \%flag_renames,
1101                      @{$option_ignore_arch_flag{$arch}});
1102     }
1103
1104     my @ignore_line = @option_ignore_line;
1105     # Ignore lines for this arch if requested.
1106     if ($arch and exists $option_ignore_arch_line{$arch}) {
1107         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1108     }
1109
1110 LINE:
1111     for (my $i = 0; $i < scalar @input; $i++) {
1112         my $line = $input[$i];
1113
1114         # Ignore line if requested.
1115         foreach my $ignore (@ignore_line) {
1116             next LINE if $line =~ /$ignore/;
1117         }
1118
1119         my $skip = 0;
1120         if ($input_nonverbose[$i]
1121                 and is_non_verbose_build($line, \$skip,
1122                                          \@input, $i, $parallel)) {
1123             if (not $option_buildd) {
1124                 error_non_verbose_build($line);
1125                 $exit |= $exit_code{non_verbose_build};
1126             } else {
1127                 $statistics{commands_nonverbose}++;
1128             }
1129             next;
1130         }
1131         # Even if it's a verbose build, we might have to skip this line (see
1132         # is_non_verbose_build()).
1133         next if $skip;
1134
1135         my $orig_line = $line;
1136
1137         # Remove everything until and including the compiler command. Makes
1138         # checks easier and faster.
1139         $line =~ s/^.*?$cc_regex//o;
1140         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1141         # the brace and similar characters at the line end.
1142         $line =~ s/['")]+$//;
1143
1144         # Skip unnecessary tests when only preprocessing.
1145         my $flag_preprocess = 0;
1146
1147         my $dependency = 0;
1148         my $preprocess = 0;
1149         my $compile    = 0;
1150         my $link       = 0;
1151
1152         # Preprocess, compile, assemble.
1153         if ($line =~ /\s(-E|-S|-c)\b/) {
1154             $preprocess      = 1;
1155             $flag_preprocess = 1 if $1 eq '-E';
1156             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1157         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1158         # -MT -MQ) are always used with -M/-MM.
1159         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1160             $dependency = 1;
1161         # Otherwise assume we are linking.
1162         } else {
1163             $link = 1;
1164         }
1165
1166         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1167         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1168             $dependency      = 0;
1169             $flag_preprocess = 0;
1170         }
1171
1172         # Dependency generation for Makefiles, no preprocessing or other flags
1173         # needed.
1174         next if $dependency;
1175
1176         # Get all file extensions on this line.
1177         my @extensions = $line =~ /$file_extension_regex/go;
1178         # Ignore all unknown extensions to speedup the search below.
1179         @extensions = grep { exists $extension{$_} } @extensions;
1180
1181         # These file types don't require preprocessing.
1182         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1183             $preprocess = 0;
1184         }
1185         # These file types require preprocessing.
1186         if (extension_found(\%extensions_preprocess, @extensions)) {
1187             # Prevent false positives with "libtool: link: g++ -include test.h
1188             # .." compiler lines.
1189             if ($orig_line !~ /$libtool_link_regex/o) {
1190                 $preprocess = 1;
1191             }
1192         }
1193
1194         if (not $flag_preprocess) {
1195             # If there are source files then it's compiling/linking in one
1196             # step and we must check both. We only check for source files
1197             # here, because header files cause too many false positives.
1198             if (extension_found(\%extensions_compile_link, @extensions)) {
1199                 # Assembly files don't need CFLAGS.
1200                 if (not extension_found(\%extensions_compile, @extensions)
1201                         and extension_found(\%extensions_no_compile, @extensions)) {
1202                     $compile = 0;
1203                 # But the rest does.
1204                 } else {
1205                     $compile = 1;
1206                 }
1207             # No compilable extensions found, either linking or compiling
1208             # header flags.
1209             #
1210             # If there are also no object files we are just compiling headers
1211             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1212             # to our liberal checks for compiler lines, this also reduces the
1213             # number of false positives considerably.
1214             } elsif ($link
1215                     and not extension_found(\%extensions_object, @extensions)) {
1216                 $link = 0;
1217             }
1218         }
1219
1220         my $compile_cpp = 0;
1221         my $compile_ada = 0;
1222         # Assume CXXFLAGS are required when a C++ file is specified in the
1223         # compiler line.
1224         if ($compile
1225                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1226             $compile     = 0;
1227             $compile_cpp = 1;
1228         # Ada needs special CFLAGS, use them if only ada files are compiled.
1229         } elsif ($ada
1230                     and $compile
1231                     and array_equal(\@extensions,
1232                                     \@source_no_preprocess_compile_ada)) {
1233             $compile_ada = 1;
1234             @cflags_backup = @cflags;
1235             @cflags        = @cflags_ada;
1236         }
1237
1238         if ($option_buildd) {
1239             $statistics{preprocess}++  if $preprocess;
1240             $statistics{compile}++     if $compile;
1241             $statistics{compile_cpp}++ if $compile_cpp;
1242             $statistics{link}++        if $link;
1243         }
1244
1245         # Check if there are flags indicating a debug build. If that's true,
1246         # skip the check for -O2. This prevents fortification, but that's fine
1247         # for a debug build.
1248         if (any_flags_used($line, @def_cflags_debug)) {
1249             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1250             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1251         }
1252
1253         # Check hardening flags.
1254         my @missing;
1255         if ($compile and not all_flags_used($line, \@missing, @cflags)
1256                 # Libraries linked with -fPIC don't have to (and can't) be
1257                 # linked with -fPIE as well. It's no error if only PIE flags
1258                 # are missing.
1259                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1260                 # Assume dpkg-buildflags returns the correct flags.
1261                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1262             if (not $option_buildd) {
1263                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1264                 $exit |= $exit_code{flags_missing};
1265             } else {
1266                 $statistics{compile_missing}++;
1267             }
1268         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1269                 # Libraries linked with -fPIC don't have to (and can't) be
1270                 # linked with -fPIE as well. It's no error if only PIE flags
1271                 # are missing.
1272                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1273                 # Assume dpkg-buildflags returns the correct flags.
1274                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1275             if (not $option_buildd) {
1276                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1277                 $exit |= $exit_code{flags_missing};
1278             } else {
1279                 $statistics{compile_cpp_missing}++;
1280             }
1281         }
1282         if ($preprocess
1283                 and (not all_flags_used($line, \@missing, @cppflags)
1284                     # The fortify flag might be overwritten, detect that.
1285                      or ($harden_fortify
1286                          and cppflags_fortify_broken($line, \@missing)))
1287                 # Assume dpkg-buildflags returns the correct flags.
1288                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1289             if (not $option_buildd) {
1290                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1291                 $exit |= $exit_code{flags_missing};
1292             } else {
1293                 $statistics{preprocess_missing}++;
1294             }
1295         }
1296         if ($link and not all_flags_used($line, \@missing, @ldflags)
1297                 # Same here, -fPIC conflicts with -fPIE.
1298                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1299                 # Assume dpkg-buildflags returns the correct flags.
1300                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1301             if (not $option_buildd) {
1302                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1303                 $exit |= $exit_code{flags_missing};
1304             } else {
1305                 $statistics{link_missing}++;
1306             }
1307         }
1308
1309         # Restore normal CFLAGS.
1310         if ($compile_ada) {
1311             @cflags = @cflags_backup;
1312         }
1313     }
1314 }
1315
1316 # Print statistics for buildd mode, only output in this mode.
1317 if ($option_buildd) {
1318     my @warning;
1319
1320     if ($statistics{preprocess_missing}) {
1321         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1322                                $statistics{preprocess_missing},
1323                                $statistics{preprocess};
1324     }
1325     if ($statistics{compile_missing}) {
1326         push @warning, sprintf 'CFLAGS %d (of %d)',
1327                                $statistics{compile_missing},
1328                                $statistics{compile};
1329     }
1330     if ($statistics{compile_cpp_missing}) {
1331         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1332                                $statistics{compile_cpp_missing},
1333                                $statistics{compile_cpp};
1334     }
1335     if ($statistics{link_missing}) {
1336         push @warning, sprintf 'LDFLAGS %d (of %d)',
1337                                $statistics{link_missing},
1338                                $statistics{link};
1339     }
1340     if (scalar @warning) {
1341         local $" = ', '; # array join string
1342         print "$buildd_tag{flags_missing}|@warning missing|\n";
1343     }
1344
1345     if ($statistics{commands_nonverbose}) {
1346         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1347                $statistics{commands_nonverbose},
1348                $statistics{commands},
1349     }
1350 }
1351
1352
1353 exit $exit;
1354
1355
1356 __END__
1357
1358 =head1 NAME
1359
1360 blhc - build log hardening check, checks build logs for missing hardening flags
1361
1362 =head1 SYNOPSIS
1363
1364 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1365
1366 =head1 DESCRIPTION
1367
1368 blhc is a small tool which checks build logs for missing hardening flags. It's
1369 licensed under the GPL 3 or later.
1370
1371 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1372 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1373 official buildd build logs)) to help maintainers detect missing hardening
1374 flags in their packages.
1375
1376 Only gcc is detected as compiler at the moment. If other compilers support
1377 hardening flags as well, please report them.
1378
1379 If there's no output, no flags are missing and the build log is fine.
1380
1381 See F<README> for details about performed checks, auto-detection and
1382 limitations.
1383
1384 =head1 OPTIONS
1385
1386 =over 8
1387
1388 =item B<--all>
1389
1390 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1391 auto detected.
1392
1393 =item B<--arch> I<architecture>
1394
1395 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1396 disables hardening flags not available on this architecture. Is detected
1397 automatically if dpkg-buildpackage is used.
1398
1399 =item B<--bindnow>
1400
1401 Force check for all +bindnow hardening flags. By default it's auto detected.
1402
1403 =item B<--buildd>
1404
1405 Special mode for buildds when automatically parsing log files. The following
1406 changes are in effect:
1407
1408 =over 2
1409
1410 =item *
1411
1412 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1413 possible tags.
1414
1415 =item *
1416
1417 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1418 detected).
1419
1420 =item *
1421
1422 Don't require Term::ANSIColor.
1423
1424 =item *
1425
1426 Return exit code 0, unless there was a error (-I, -W messages don't count as
1427 error).
1428
1429 =back
1430
1431 =item B<--color>
1432
1433 Use colored (ANSI) output for warning messages.
1434
1435 =item B<--ignore-arch> I<arch>
1436
1437 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1438
1439 Used to prevent false positives. This option can be specified multiple times.
1440
1441 =item B<--ignore-arch-flag> I<arch>:I<flag>
1442
1443 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1444
1445 =item B<--ignore-arch-line> I<arch>:I<line>
1446
1447 Like B<--ignore-line>, but only ignore line on I<arch>.
1448
1449 =item B<--ignore-flag> I<flag>
1450
1451 Don't print an error when the specific flag is missing in a compiler line.
1452 I<flag> is a string.
1453
1454 Used to prevent false positives. This option can be specified multiple times.
1455
1456 =item B<--ignore-line> I<regex>
1457
1458 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1459 at the beginning and end of the line to prevent false negatives.
1460
1461 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1462 warnings (which have line continuation resolved).
1463
1464 Used to prevent false positives. This option can be specified multiple times.
1465
1466 =item B<--pie>
1467
1468 Force check for all +pie hardening flags. By default it's auto detected.
1469
1470 =item B<-h -? --help>
1471
1472 Print available options.
1473
1474 =item B<--version>
1475
1476 Print version number and license.
1477
1478 =back
1479
1480 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1481 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1482 all other commands as well.
1483
1484 =head1 EXAMPLES
1485
1486 Normal usage, parse a single log file.
1487
1488     blhc path/to/log/file
1489
1490 If there's no output, no flags are missing and the build log is fine.
1491
1492 Parse multiple log files. The exit code is ORed over all files.
1493
1494     blhc path/to/directory/with/log/files/*
1495
1496 Don't treat missing C<-g> as error:
1497
1498     blhc --ignore-flag -g path/to/log/file
1499
1500 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1501
1502     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1503
1504 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1505 false positive.
1506
1507     blhc --ignore-line '\./script gcc file' path/to/log/file
1508
1509 Ignore lines matching C<./script gcc file> somewhere in the line.
1510
1511     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1512
1513 Use blhc with pbuilder.
1514
1515     pbuilder path/to/package.dsc | tee path/log/file
1516     blhc path/to/file || echo flags missing
1517
1518 =head1 BUILDD TAGS
1519
1520 The following tags are used in I<--buildd> mode. In braces the additional data
1521 which is displayed.
1522
1523 =over 2
1524
1525 =item B<I-hardening-wrapper-used>
1526
1527 The package uses hardening-wrapper which intercepts calls to gcc and adds
1528 hardening flags. The build log doesn't contain any hardening flags and thus
1529 can't be checked by blhc.
1530
1531 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1532
1533 Build log contains lines which hide the real compiler flags. For example:
1534
1535     CC test-a.c
1536     CC test-b.c
1537     CC test-c.c
1538     LD test
1539
1540 Most of the time either C<export V=1> or C<export verbose=1> in
1541 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1542 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1543 patched to remove the C<@>s hiding the real compiler commands.
1544
1545 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1546
1547 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1548
1549 =item B<I-invalid-cmake-used> (version)
1550
1551 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1552 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1553 patch was rejected by upstream and later reverted in Debian. Thus those two
1554 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1555 handle them (for example by passing them to CFLAGS). To prevent false
1556 negatives just blacklist those two versions.
1557
1558 =item B<I-no-compiler-commands>
1559
1560 No compiler commands were detected. Either the log contains none or they were
1561 not correctly detected by blhc (please report the bug in this case).
1562
1563 =back
1564
1565 =head1 EXIT STATUS
1566
1567 The exit status is a "bit mask", each listed status is ORed when the error
1568 condition occurs to get the result.
1569
1570 =over 4
1571
1572 =item B<0>
1573
1574 Success.
1575
1576 =item B<1>
1577
1578 No compiler commands were found.
1579
1580 =item B<2>
1581
1582 Invalid arguments/options given to blhc.
1583
1584 =item B<4>
1585
1586 Non verbose build.
1587
1588 =item B<8>
1589
1590 Missing hardening flags.
1591
1592 =item B<16>
1593
1594 Hardening wrapper detected, no tests performed.
1595
1596 =item B<32>
1597
1598 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1599 TAGS"> for a detailed explanation.
1600
1601 =back
1602
1603 =head1 AUTHOR
1604
1605 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1606
1607 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1608 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1609
1610 =head1 LICENSE AND COPYRIGHT
1611
1612 Copyright (C) 2012-2016 by Simon Ruderich
1613
1614 This program is free software: you can redistribute it and/or modify
1615 it under the terms of the GNU General Public License as published by
1616 the Free Software Foundation, either version 3 of the License, or
1617 (at your option) any later version.
1618
1619 This program is distributed in the hope that it will be useful,
1620 but WITHOUT ANY WARRANTY; without even the implied warranty of
1621 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1622 GNU General Public License for more details.
1623
1624 You should have received a copy of the GNU General Public License
1625 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1626
1627 =head1 SEE ALSO
1628
1629 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1630
1631 =cut