bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2019  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.09';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+|gfortran|mpicc|mpicxx|mpifort)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full_prefix = qr/
  42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
  43     /x;
  44 my $cc_regex_full = qr/
  45     (?:$cc_regex_full_prefix-)?
  46     $cc_regex
  47     /x;
  48 # Regex to check if a line contains a compiler command.
  49 my $cc_regex_normal = qr/
  50     \b$cc_regex(?:\s|\\)
  51     /x;
  52 # Regex to catch (GCC) compiler warnings.
  53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  54 # Regex to catch libtool commands and not lines which show commands executed
  55 # by libtool (e.g. libtool: link: ...).
  56 my $libtool_regex = qr/\blibtool\s.*--mode=/;
  57 my $libtool_link_regex = qr/\blibtool: link: /;
  58
  59 # List of source file extensions which require preprocessing.
  60 my @source_preprocess_compile_cpp = (
  61     # C++
  62     qw( cc cp cxx cpp CPP c++ C ),
  63     # Objective-C++
  64     qw( mm M ),
  65 );
  66 my @source_preprocess_compile_fortran = (
  67     # Fortran
  68     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  69 );
  70 my @source_preprocess_compile = (
  71     # C
  72     qw( c ),
  73     # Objective-C
  74     qw( m ),
  75     # (Objective-)C++
  76     @source_preprocess_compile_cpp,
  77     # Fortran
  78     @source_preprocess_compile_fortran,
  79 );
  80 my @source_preprocess_no_compile = (
  81     # Assembly
  82     qw( S sx ),
  83 );
  84 my @source_preprocess = (
  85     @source_preprocess_compile,
  86     @source_preprocess_no_compile,
  87 );
  88 # List of source file extensions which don't require preprocessing.
  89 my @source_no_preprocess_compile_cpp = (
  90     # C++
  91     qw( ii ),
  92     # Objective-C++
  93     qw( mii ),
  94 );
  95 my @source_no_preprocess_compile_ada = (
  96     # Ada source
  97     qw( ada ),
  98     # Ada body
  99     qw( adb ),
 100 );
 101 my @source_no_preprocess_compile_fortran = (
 102     # Fortran
 103     qw( f for ftn f90 f95 f03 f08 ),
 104 );
 105 my @source_no_preprocess_compile = (
 106     # C
 107     qw( i ),
 108     # (Objective-)C++
 109     @source_no_preprocess_compile_cpp,
 110     # Objective-C
 111     qw( mi ),
 112     # Fortran
 113     @source_no_preprocess_compile_fortran,
 114     # Ada
 115     @source_no_preprocess_compile_ada,
 116 );
 117 my @source_no_preprocess_no_compile_ada = (
 118     # Ada specification
 119     qw( ads ),
 120 );
 121 my @source_no_preprocess_no_compile = (
 122     # Assembly
 123     qw( s ),
 124     # Ada
 125     @source_no_preprocess_no_compile_ada,
 126 );
 127 my @source_no_preprocess = (
 128     @source_no_preprocess_compile,
 129     @source_no_preprocess_no_compile,
 130 );
 131 # List of header file extensions which require preprocessing.
 132 my @header_preprocess = (
 133     # C, C++, Objective-C, Objective-C++
 134     qw( h ),
 135     # C++
 136     qw( hh H hp hxx hpp HPP h++ tcc ),
 137 );
 138 # Object files.
 139 my @object = (
 140     # Normal object files.
 141     qw ( o ),
 142     # Libtool object files.
 143     qw ( lo la ),
 144     # Dynamic libraries. bzip2 uses .sho.
 145     qw ( so sho ),
 146     # Static libraries.
 147     qw ( a ),
 148 );
 149
 150 # Hashes for fast extensions lookup to check if a file falls in one of these
 151 # categories.
 152 my %extensions_no_preprocess = map { $_ => 1 } (
 153     # There's no @header_no_preprocess.
 154     @source_no_preprocess,
 155 );
 156 my %extensions_preprocess = map { $_ => 1 } (
 157     @header_preprocess,
 158     @source_preprocess,
 159 );
 160 my %extensions_compile_link = map { $_ => 1 } (
 161     @source_preprocess,
 162     @source_no_preprocess,
 163 );
 164 my %extensions_compile = map { $_ => 1 } (
 165     @source_preprocess_compile,
 166     @source_no_preprocess_compile,
 167 );
 168 my %extensions_no_compile = map { $_ => 1 } (
 169     @source_preprocess_no_compile,
 170     @source_no_preprocess_no_compile,
 171 );
 172 my %extensions_compile_cpp = map { $_ => 1 } (
 173     @source_preprocess_compile_cpp,
 174     @source_no_preprocess_compile_cpp,
 175 );
 176 my %extensions_ada = map { $_ => 1 } (
 177     @source_no_preprocess_compile_ada,
 178     @source_no_preprocess_no_compile_ada,
 179 );
 180 my %extensions_fortran = map { $_ => 1 } (
 181     @source_no_preprocess_compile_fortran,
 182     @source_preprocess_compile_fortran,
 183 );
 184 my %extensions_object = map { $_ => 1 } (
 185     @object,
 186 );
 187 my %extension = map { $_ => 1 } (
 188     @source_no_preprocess,
 189     @header_preprocess,
 190     @source_preprocess,
 191     @object,
 192 );
 193
 194 # Regexp to match file extensions.
 195 my $file_extension_regex = qr/
 196     \s
 197     \S+             # Filename without extension.
 198     \.
 199     ([^\/\\.,;:\s]+)# File extension.
 200     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 201                     # word characters at the end and because \b matches double
 202                     # extensions (like .cpp.o). Works always as all lines are
 203                     # terminated with "\n".
 204     /x;
 205
 206 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 207 # real regexps below for better execution speed).
 208 my @def_cflags = (
 209     '-g',
 210     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
 211 );
 212 my @def_cflags_debug = (
 213     # These flags indicate a debug build which disables checks for -O2.
 214     '-O0',
 215     '-Og',
 216 );
 217 my @def_cflags_format = (
 218     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 219     '-Werror=format-security', # implies -Wformat-security
 220 );
 221 my @def_cflags_fortify = (
 222     # fortify needs at least -O1, but -O2 is recommended anyway
 223 );
 224 my @def_cflags_stack = (
 225     '-fstack-protector', # keep first, used by cflags_stack_broken()
 226     '--param[= ]ssp-buffer-size=4',
 227 );
 228 my @def_cflags_stack_strong = (
 229     '-fstack-protector-strong', # keep first, used by cflags_stack_broken()
 230 );
 231 my @def_cflags_stack_bad = (
 232     # Blacklist all stack protector options for simplicity.
 233     '-fno-stack-protector',
 234     '-fno-stack-protector-all',
 235     '-fno-stack-protector-strong',
 236 );
 237 my @def_cflags_pie = (
 238     '-fPIE',
 239 );
 240 my @def_cxxflags = (
 241     @def_cflags,
 242 );
 243 # @def_cxxflags_* is the same as @def_cflags_*.
 244 my @def_cppflags = ();
 245 my @def_cppflags_fortify = (
 246     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 247     # If you add another flag fix hack below (search for "Hack to fix") and
 248     # $def_cppflags_fortify[0].
 249 );
 250 my @def_cppflags_fortify_bad = (
 251     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 252     '-U_FORTIFY_SOURCE',
 253     '-D_FORTIFY_SOURCE=0',
 254     '-D_FORTIFY_SOURCE=1',
 255 );
 256 my @def_ldflags = ();
 257 my @def_ldflags_relro = (
 258     '-Wl,(?:-z,)?relro',
 259 );
 260 my @def_ldflags_bindnow = (
 261     '-Wl,(?:-z,)?now',
 262 );
 263 my @def_ldflags_pie = (
 264     '-fPIE',
 265     '-pie',
 266 );
 267 my @def_ldflags_pic = (
 268     '-fPIC',
 269     '-fpic',
 270     '-shared',
 271 );
 272 # References to all flags checked by the flag checker.
 273 my @flag_refs = (
 274     \@def_cflags,
 275     \@def_cflags_format,
 276     \@def_cflags_fortify,
 277     \@def_cflags_stack,
 278     \@def_cflags_stack_strong,
 279     \@def_cflags_stack_bad,
 280     \@def_cflags_pie,
 281     \@def_cxxflags,
 282     \@def_cppflags,
 283     \@def_cppflags_fortify,
 284     \@def_ldflags,
 285     \@def_ldflags_relro,
 286     \@def_ldflags_bindnow,
 287     \@def_ldflags_pie,
 288 );
 289 # References to all used flags.
 290 my @flag_refs_all = (
 291     @flag_refs,
 292     \@def_cflags_debug,
 293     \@def_cppflags_fortify_bad,
 294     \@def_ldflags_pic,
 295 );
 296 # Renaming rules for the output so the regex parts are not visible. Also
 297 # stores string values of flag regexps above, see compile_flag_regexp().
 298 my %flag_renames = (
 299     '-O(?:2|3)'                    => '-O2',
 300     '-Wformat(?:=2)?'              => '-Wformat',
 301     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 302     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 303     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 304 );
 305
 306 my %exit_code = (
 307     no_compiler_commands => 1 << 0,
 308     # used by POD::Usage => 1 << 1,
 309     non_verbose_build    => 1 << 2,
 310     flags_missing        => 1 << 3,
 311     hardening_wrapper    => 1 << 4,
 312     invalid_cmake        => 1 << 5,
 313 );
 314
 315 my %buildd_tag = (
 316     no_compiler_commands => 'I-no-compiler-commands',
 317     non_verbose_build    => 'W-compiler-flags-hidden',
 318     flags_missing        => 'W-dpkg-buildflags-missing',
 319     hardening_wrapper    => 'I-hardening-wrapper-used',
 320     invalid_cmake        => 'I-invalid-cmake-used',
 321 );
 322
 323 # Statistics of missing flags and non-verbose build commands. Used for
 324 # $option_buildd.
 325 my %statistics = (
 326     preprocess          => 0,
 327     preprocess_missing  => 0,
 328     compile             => 0,
 329     compile_missing     => 0,
 330     compile_cpp         => 0,
 331     compile_cpp_missing => 0,
 332     link                => 0,
 333     link_missing        => 0,
 334     commands            => 0,
 335     commands_nonverbose => 0,
 336 );
 337
 338 # Use colored (ANSI) output?
 339 my $option_color;
 340
 341
 342 # FUNCTIONS
 343
 344 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 345 sub array_equal {
 346     my ($first_ref, $second_ref) = @_;
 347
 348     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 349
 350     my $length = scalar @{$first_ref};
 351     for (my $i = 0; $i < $length; $i++) {
 352         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 353     }
 354
 355     return 1;
 356 }
 357
 358 sub error_flags {
 359     my ($message, $missing_flags_ref, $flag_renames_ref, $line, $number) = @_;
 360
 361     # Get string value of qr//-escaped regexps and if requested rename them.
 362     my @missing_flags = map {
 363             $flag_renames_ref->{$_}
 364         } @{$missing_flags_ref};
 365
 366     my $flags = join ' ', @missing_flags;
 367     printf '%d:', $number if defined $number;
 368     printf '%s (%s)%s %s',
 369            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 370            $line;
 371
 372     return;
 373 }
 374 sub error_non_verbose_build {
 375     my ($line, $number) = @_;
 376
 377     printf '%d:', $number if defined $number;
 378     printf '%s%s %s',
 379            error_color('NONVERBOSE BUILD', 'red'),
 380            error_color(':', 'yellow'),
 381            $line;
 382
 383     return;
 384 }
 385 sub error_invalid_cmake {
 386     my ($version) = @_;
 387
 388     printf "%s%s %s\n",
 389             error_color('INVALID CMAKE', 'red'),
 390             error_color(':', 'yellow'),
 391             $version;
 392
 393     return;
 394 }
 395 sub error_hardening_wrapper {
 396     printf "%s%s %s\n",
 397             error_color('HARDENING WRAPPER', 'red'),
 398             error_color(':', 'yellow'),
 399             'no checks possible, aborting';
 400
 401     return;
 402 }
 403 sub error_color {
 404     my ($message, $color) = @_;
 405
 406     if ($option_color) {
 407         return Term::ANSIColor::colored($message, $color);
 408     } else {
 409         return $message;
 410     }
 411 }
 412
 413 sub any_flags_used {
 414     my ($line, @flags) = @_;
 415
 416     foreach my $flag (@flags) {
 417         return 1 if $line =~ /$flag/;
 418     }
 419
 420     return 0;
 421 }
 422 sub all_flags_used {
 423     my ($line, $missing_flags_ref, @flags) = @_;
 424
 425     my @missing_flags = ();
 426     foreach my $flag (@flags) {
 427         if (not $line =~ /$flag/) {
 428             push @missing_flags, $flag;
 429         }
 430     }
 431
 432     return 1 if scalar @missing_flags == 0;
 433
 434     @{$missing_flags_ref} = @missing_flags;
 435     return 0;
 436 }
 437 # Check if any of \@bad_flags occurs after $good_flag. Doesn't check if
 438 # $good_flag is present.
 439 sub flag_overwritten {
 440     my ($line, $good_flag, $bad_flags) = @_;
 441
 442     if (not any_flags_used($line, @{$bad_flags})) {
 443         return 0;
 444     }
 445
 446     my $bad_pos = 0;
 447     foreach my $flag (@{$bad_flags}) {
 448         while ($line =~ /$flag/g) {
 449             if ($bad_pos < $+[0]) {
 450                 $bad_pos = $+[0];
 451             }
 452         }
 453     }
 454     my $good_pos = 0;
 455     while ($line =~ /$good_flag/g) {
 456         $good_pos = $+[0];
 457     }
 458     if ($good_pos > $bad_pos) {
 459         return 0;
 460     }
 461     return 1;
 462 }
 463
 464 sub cppflags_fortify_broken {
 465     my ($line, $missing_flags) = @_;
 466
 467     # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 468     my $fortify_source = $def_cppflags_fortify[0];
 469
 470     # Some build systems enable/disable fortify source multiple times, check
 471     # the final result.
 472     if (not flag_overwritten($line,
 473                              $fortify_source,
 474                              \@def_cppflags_fortify_bad)) {
 475         return 0;
 476     }
 477     push @{$missing_flags}, $fortify_source;
 478     return 1;
 479 }
 480
 481 sub cflags_stack_broken {
 482     my ($line, $missing_flags, $strong) = @_;
 483
 484     my $flag = $strong ? $def_cflags_stack_strong[0]
 485                        : $def_cflags_stack[0];
 486
 487     if (not flag_overwritten($line, $flag, \@def_cflags_stack_bad)) {
 488         return 0;
 489     }
 490     push @{$missing_flags}, $flag;
 491     return 1;
 492 }
 493
 494 # Modifies $missing_flags_ref array.
 495 sub pic_pie_conflict {
 496     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 497
 498     return 0 if not $pie;
 499     return 0 if not any_flags_used($line, @def_ldflags_pic);
 500
 501     my %flags = map { $_ => 1 } @flags_pie;
 502
 503     # Remove all PIE flags from @missing_flags as they are not required with
 504     # -fPIC.
 505     my @result = grep {
 506         not exists $flags{$_}
 507     } @{$missing_flags_ref};
 508     @{$missing_flags_ref} = @result;
 509
 510     # We got a conflict when no flags are left, thus only PIE flags were
 511     # missing. If other flags were missing abort because the conflict is not
 512     # the problem.
 513     return scalar @result == 0;
 514 }
 515
 516 sub is_non_verbose_build {
 517     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
 518
 519     if ($line =~ /$libtool_regex/o) {
 520         # libtool's --silent hides the real compiler flags.
 521         if ($line =~ /\s--silent/) {
 522             return 1;
 523         # If --silent is not present, skip this line as some compiler flags
 524         # might be missing (e.g. -fPIE) which are handled correctly by libtool
 525         # internally. libtool displays the real compiler command on the next
 526         # line, so the flags are checked as usual.
 527         } else {
 528             ${$skip_ref} = 1;
 529             return 0;
 530         }
 531     }
 532
 533     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 534                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 535                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 536                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 537                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 538         return 0;
 539     }
 540
 541     # False positives.
 542     #
 543     # C++ compiler setting.
 544     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 545     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 546     # "Compiling" non binary files.
 547     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|el)['"]?\s*(?:\.\.\.)?$/;
 548     return 0 if $line =~ /^\s*[Cc]ompiling catalog \S+\.po\b/;
 549     # "Compiling" with no file name.
 550     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 551         # $file_extension_regex may need spaces around the filename.
 552         return 0 if not " $1 " =~ /$file_extension_regex/o;
 553     }
 554
 555     my $file = $1;
 556
 557     # On the first pass we only check if this line is verbose or not.
 558     return 1 if not defined $input_ref;
 559
 560     # Second pass, we have access to the next lines.
 561     ${$skip_ref} = 0;
 562
 563     # CMake and other build systems print the non-verbose messages also when
 564     # building verbose. If a compiler and the file name occurs in the next
 565     # lines, treat it as verbose build.
 566     if (defined $file) {
 567         # Get filename, we can't use the complete path as only parts of it are
 568         # used in the real compiler command.
 569         $file =~ m{/([^/\s]+)$};
 570         $file = $1;
 571
 572         for (my $i = 1; $i <= $line_count; $i++) {
 573             my $next_line = $input_ref->[$line_offset + $i];
 574             last unless defined $next_line;
 575
 576             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 577                 # Not a non-verbose line, but we still have to skip the
 578                 # current line as it doesn't contain any compiler commands.
 579                 ${$skip_ref} = 1;
 580                 return 0;
 581             }
 582         }
 583     }
 584
 585     return 1;
 586 }
 587
 588 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
 589 sub remove_flags {
 590     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 591
 592     my %removes = map { $_ => 1 } @flags;
 593     foreach my $flags (@{$flag_refs_ref}) {
 594         @{$flags} = grep {
 595             # Flag found as string.
 596             not exists $removes{$_}
 597             # Flag found as string representation of regexp.
 598                 and (not defined $flag_renames_ref->{$_}
 599                         or not exists $removes{$flag_renames_ref->{$_}})
 600         } @{$flags};
 601     }
 602
 603     return;
 604 }
 605
 606 # Modifies $flag_renames_ref hash.
 607 sub compile_flag_regexp {
 608     my ($flag_renames_ref, @flags) = @_;
 609
 610     my @result = ();
 611     foreach my $flag (@flags) {
 612         # Compile flag regexp for faster execution.
 613         my $regex = qr/\s$flag(?:\s|\\)/;
 614
 615         # Store flag name in replacement string for correct flags in messages
 616         # with qr//ed flag regexps.
 617         $flag_renames_ref->{$regex}
 618             = (exists $flag_renames_ref->{$flag})
 619                 ? $flag_renames_ref->{$flag}
 620                 : $flag;
 621
 622         push @result, $regex;
 623     }
 624     return @result;
 625 }
 626
 627 # Does any extension in @extensions exist in %{$extensions_ref}?
 628 sub extension_found {
 629     my ($extensions_ref, @extensions) = @_;
 630
 631     foreach my $extension (@extensions) {
 632         if (exists $extensions_ref->{$extension}) {
 633             return 1;
 634         }
 635     }
 636     return 0;
 637 }
 638
 639
 640 # MAIN
 641
 642 # Parse command line arguments.
 643 my $option_help             = 0;
 644 my $option_version          = 0;
 645 my $option_pie              = 0;
 646 my $option_bindnow          = 0;
 647 my @option_ignore_arch      = ();
 648 my @option_ignore_flag      = ();
 649 my @option_ignore_arch_flag = ();
 650 my @option_ignore_line      = ();
 651 my @option_ignore_arch_line = ();
 652 my $option_all              = 0;
 653 my $option_arch             = undef;
 654 my $option_buildd           = 0;
 655 my $option_debian           = 0;
 656    $option_color            = 0;
 657 my $option_line_numbers     = 0;
 658 if (not Getopt::Long::GetOptions(
 659             'help|h|?'           => \$option_help,
 660             'version'            => \$option_version,
 661             # Hardening options.
 662             'pie'                => \$option_pie,
 663             'bindnow'            => \$option_bindnow,
 664             'all'                => \$option_all,
 665             # Ignore.
 666             'ignore-arch=s'      => \@option_ignore_arch,
 667             'ignore-flag=s'      => \@option_ignore_flag,
 668             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 669             'ignore-line=s'      => \@option_ignore_line,
 670             'ignore-arch-line=s' => \@option_ignore_arch_line,
 671             # Misc.
 672             'color'              => \$option_color,
 673             'arch=s'             => \$option_arch,
 674             'buildd'             => \$option_buildd,
 675             'debian'             => \$option_debian,
 676             'line-numbers'       => \$option_line_numbers,
 677         )) {
 678     require Pod::Usage;
 679     Pod::Usage::pod2usage(2);
 680 }
 681 if ($option_help) {
 682     require Pod::Usage;
 683     Pod::Usage::pod2usage(1);
 684 }
 685 if ($option_version) {
 686     print <<"EOF";
 687 blhc $VERSION  Copyright (C) 2012-2019  Simon Ruderich
 688
 689 This program is free software: you can redistribute it and/or modify
 690 it under the terms of the GNU General Public License as published by
 691 the Free Software Foundation, either version 3 of the License, or
 692 (at your option) any later version.
 693
 694 This program is distributed in the hope that it will be useful,
 695 but WITHOUT ANY WARRANTY; without even the implied warranty of
 696 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 697 GNU General Public License for more details.
 698
 699 You should have received a copy of the GNU General Public License
 700 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 701 EOF
 702     exit 0;
 703 }
 704
 705 # Arguments missing.
 706 if (scalar @ARGV == 0) {
 707     require Pod::Usage;
 708     Pod::Usage::pod2usage(2);
 709 }
 710
 711 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 712 # installed on Debian's buildds.
 713 if (not $option_buildd) {
 714     require Term::ANSIColor;
 715 }
 716
 717 if ($option_all) {
 718     $option_pie     = 1;
 719     $option_bindnow = 1;
 720 }
 721
 722 # Precompiled ignores for faster lookup.
 723 my %option_ignore_arch_flag = ();
 724 my %option_ignore_arch_line = ();
 725
 726 # Strip flags which should be ignored.
 727 if (scalar @option_ignore_flag > 0) {
 728     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 729 }
 730 # Same for arch specific ignore flags, but only prepare here.
 731 if (scalar @option_ignore_arch_flag > 0) {
 732     foreach my $ignore (@option_ignore_arch_flag) {
 733         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 734
 735         if (not $ignore_arch or not $ignore_flag) {
 736             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 737                         . '("arch:flag" expected)' . "\n", $ignore;
 738             require Pod::Usage;
 739             Pod::Usage::pod2usage(2);
 740         }
 741
 742         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 743     }
 744 }
 745
 746 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 747 # faster with this.
 748 foreach my $flags (@flag_refs_all) {
 749     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 750 }
 751
 752 # Precompile ignore line regexps, also anchor at beginning and end of line.
 753 foreach my $ignore (@option_ignore_line) {
 754     $ignore = qr/^$ignore$/;
 755 }
 756 # Same for arch specific ignore lines.
 757 if (scalar @option_ignore_arch_line > 0) {
 758     foreach my $ignore (@option_ignore_arch_line) {
 759         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 760
 761         if (not $ignore_arch or not $ignore_line) {
 762             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 763                         . '("arch:line" expected)' . "\n", $ignore;
 764             require Pod::Usage;
 765             Pod::Usage::pod2usage(2);
 766         }
 767
 768         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 769     }
 770 }
 771
 772 # Final exit code.
 773 my $exit = 0;
 774
 775 FILE:
 776 foreach my $file (@ARGV) {
 777     print "checking '$file'...\n" if scalar @ARGV > 1;
 778
 779     -f $file or die "No such file: $file";
 780
 781     open my $fh, '<', $file or die $!;
 782
 783     # Architecture of this file.
 784     my $arch = $option_arch;
 785
 786     # Hardening options. Not all architectures support all hardening options.
 787     my $harden_format  = 1;
 788     my $harden_fortify = 1;
 789     my $harden_stack   = 1;
 790     my $harden_stack_strong = 1;
 791     my $harden_relro   = 1;
 792     my $harden_bindnow = $option_bindnow; # defaults to 0
 793     my $harden_pie     = $option_pie;     # defaults to 0
 794
 795     # Does this build log use ada? Ada also uses gcc as compiler but uses
 796     # different CFLAGS. But only perform ada checks if an ada compiler is used
 797     # for performance reasons.
 798     my $ada = 0;
 799     # Fortran also requires different CFLAGS.
 800     my $fortran = 0;
 801
 802     # Number of parallel jobs to prevent false positives when detecting
 803     # non-verbose builds. As not all jobs declare the number of parallel jobs
 804     # use a large enough default.
 805     my $parallel = 10;
 806
 807     # Don't check for PIE flags if automatically applied by the compiler. Only
 808     # used in buildd and Debian mode.
 809     my $disable_harden_pie = 0;
 810     if ($option_debian) {
 811         $disable_harden_pie = 1;
 812     }
 813
 814     my $number = 0;
 815     while (my $line = <$fh>) {
 816         $number++;
 817
 818         # Detect architecture automatically unless overridden. For buildd logs
 819         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 820         # build logs which aren't built (wrong architecture, build error,
 821         # etc.).
 822         if (not $arch) {
 823             if (index($line, 'Build Architecture: ') == 0) {
 824                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 825             # For old logs (sbuild << 0.63.0-1).
 826             } elsif (index($line, 'Architecture: ') == 0) {
 827                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 828             }
 829         }
 830
 831         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 832         # check for hardening flags in buildd mode if an older dpkg-dev is
 833         # used. Default flags (-g -O2) are still checked.
 834         #
 835         # Packages which were built before 1.16.1 but used their own hardening
 836         # flags are not checked.
 837         #
 838         # Strong stack protector is used since dpkg 1.17.11.
 839         #
 840         # Recent GCC versions automatically use PIE (only on supported
 841         # architectures) and dpkg respects this properly since 1.18.15 and
 842         # doesn't pass PIE flags manually.
 843         if ($option_buildd
 844                 and index($line, 'Toolchain package versions: ') == 0) {
 845             require Dpkg::Version;
 846
 847             my $disable = 1;
 848             my $disable_strong = 1;
 849
 850             if ($line =~ /\bdpkg-dev_(\S+)/) {
 851                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
 852                     $disable = 0;
 853                 }
 854                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
 855                     $disable_strong = 0;
 856                 }
 857                 if (Dpkg::Version::version_compare($1, '1.18.15') >= 0) {
 858                     $disable_harden_pie = 1;
 859                 }
 860             }
 861
 862             if ($disable) {
 863                 $harden_format  = 0;
 864                 $harden_fortify = 0;
 865                 $harden_stack   = 0;
 866                 $harden_relro   = 0;
 867                 $harden_bindnow = 0;
 868                 $harden_pie     = 0;
 869             }
 870             if ($disable_strong) {
 871                 $harden_stack_strong = 0;
 872             }
 873         }
 874
 875         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 876         # this was later dropped because upstream rejected the patch. Thus
 877         # build logs with these versions will have fortify hardening flags
 878         # enabled, even though they may be not correctly set and are missing
 879         # when build with later CMake versions. Thanks to Aron Xu for letting
 880         # me know.
 881         if (index($line, 'Package versions: ') == 0
 882                 and $line =~ /\bcmake_(\S+)/
 883                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 884             if (not $option_buildd) {
 885                 error_invalid_cmake($1);
 886                 $exit |= $exit_code{invalid_cmake};
 887             } else {
 888                 print "$buildd_tag{invalid_cmake}|$1|\n";
 889             }
 890         }
 891
 892         # Debian's build daemons use "Filtered Build-Depends:" (or just
 893         # "Build-Depends:" in older versions) for the build dependencies, but
 894         # pbuilder uses "Depends:"; support both.
 895         if (index($line, 'Filtered Build-Depends: ') == 0
 896                 or index($line, 'Build-Depends: ') == 0
 897                 or index($line, 'Depends: ') == 0) {
 898             # If hardening wrapper is used (wraps calls to gcc and adds
 899             # hardening flags automatically) we can't perform any checks,
 900             # abort.
 901             if ($line =~ /\bhardening-wrapper\b/) {
 902                 if (not $option_buildd) {
 903                     error_hardening_wrapper();
 904                     $exit |= $exit_code{hardening_wrapper};
 905                 } else {
 906                     print "$buildd_tag{hardening_wrapper}||\n";
 907                 }
 908                 next FILE;
 909             }
 910
 911             # Ada compiler.
 912             if ($line =~ /\bgnat\b/) {
 913                 $ada = 1;
 914             }
 915             # Fortran compiler.
 916             if ($line =~ /\bgfortran\b/) {
 917                 $fortran = 1;
 918             }
 919         }
 920
 921         # This flags is not always available, but if it is use it.
 922         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
 923             $parallel = $1 * 2;
 924         }
 925
 926         # We skip over unimportant lines at the beginning of the log to
 927         # prevent false positives.
 928         last if index($line, 'dpkg-buildpackage: ') == 0;
 929     }
 930
 931     # Input lines, contain only the lines with compiler commands.
 932     my @input = ();
 933     # Non-verbose lines in the input. Used to reduce calls to
 934     # is_non_verbose_build() (which is quite slow) in the second loop when
 935     # it's already clear if a line is non-verbose or not.
 936     my @input_nonverbose = ();
 937     # Input line number.
 938     my @input_number = ();
 939
 940     my $continuation = 0;
 941     my $complete_line = undef;
 942     my $non_verbose;
 943     while (my $line = <$fh>) {
 944         $number++;
 945
 946         # And stop at the end of the build log. Package details (reported by
 947         # the buildd logs) are not important for us. This also prevents false
 948         # positives.
 949         last if index($line, 'Build finished at ') == 0
 950                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 951
 952         if (not $continuation) {
 953             $non_verbose = 0;
 954         }
 955
 956         # Detect architecture automatically unless overridden.
 957         if (not $arch
 958                 and index($line, 'dpkg-buildpackage: info: host architecture ') == 0) {
 959             $arch = substr $line, 43, -1; # -1 to ignore '\n' at the end
 960         # Older versions of dpkg-buildpackage
 961         } elsif (not $arch
 962                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 963             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 964
 965             # Old buildd logs use e.g. "host architecture is alpha", remove
 966             # the "is", otherwise debarch_to_debtriplet() will not detect the
 967             # architecture.
 968             if (index($arch, 'is ') == 0) {
 969                 $arch = substr $arch, 3;
 970             }
 971         }
 972
 973         next if $line =~ /^\s*#/;
 974         # Ignore compiler warnings for now.
 975         next if $line =~ /$warning_regex/o;
 976
 977         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 978             # Remove all ANSI color sequences which are sometimes used in
 979             # non-verbose builds.
 980             $line = Term::ANSIColor::colorstrip($line);
 981             # Also strip '\0xf' (delete previous character), used by Elinks'
 982             # build system.
 983             $line =~ s/\x0f//g;
 984             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 985             # what it does).
 986             $line =~ s/\033\(B//g;
 987         }
 988
 989         # Check if this line indicates a non verbose build.
 990         my $skip = 0;
 991         $non_verbose |= is_non_verbose_build($line, \$skip);
 992         next if $skip;
 993
 994         # One line may contain multiple commands (";"). Treat each one as
 995         # single line. parse_line() is slow, only use it when necessary.
 996         my @line = (index($line, ';') == -1)
 997                  ? ($line)
 998                  : map {
 999                        # Ensure newline at the line end - necessary for
1000                        # correct parsing later.
1001                        $_ =~ s/\s+$//;
1002                        $_ .= "\n";
1003                    } Text::ParseWords::parse_line(';', 1, $line);
1004         foreach my $line (@line) {
1005             if ($continuation) {
1006                 $continuation = 0;
1007
1008                 # Join lines, but leave the "\" in place so it's clear where
1009                 # the original line break was.
1010                 chomp $complete_line;
1011                 $complete_line .= ' ' . $line;
1012             }
1013             # Line continuation, line ends with "\".
1014             if ($line =~ /\\$/) {
1015                 $continuation = 1;
1016                 # Start line continuation.
1017                 if (not defined $complete_line) {
1018                     $complete_line = $line;
1019                 }
1020                 next;
1021             }
1022
1023             # Use the complete line if a line continuation occurred.
1024             if (defined $complete_line) {
1025                 $line = $complete_line;
1026                 $complete_line = undef;
1027             }
1028
1029             # Ignore lines with no compiler commands.
1030             next if not $non_verbose
1031                     and not $line =~ /$cc_regex_normal/o;
1032             # Ignore lines with no filenames with extensions. May miss some
1033             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
1034             # a problem as the log will most likely contain other non-verbose
1035             # commands which are detected.
1036             next if not $non_verbose
1037                     and not $line =~ /$file_extension_regex/o;
1038
1039             # Ignore false positives.
1040             #
1041             # `./configure` output.
1042             next if not $non_verbose
1043                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
1044             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
1045                                 [Cc]ompiler[\s.]*:?\s+
1046                                 /x;
1047             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
1048                                 \s*=\s*$cc_regex_full
1049                                 # optional compiler options, don't allow
1050                                 # "everything" here to prevent false negatives
1051                                 \s*(?:\s-\S+)*\s*$}xo;
1052             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
1053             # line (or similar for other architectures) which gets recognized
1054             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
1055             # C++ files. No hardening flags are relevant during this step,
1056             # thus ignore `moc-qt*` lines. The resulting files will be
1057             # compiled in a separate step (and therefore checked).
1058             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
1059                                \s.+\s
1060                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
1061                                \s}x;
1062             # Ignore false positives when the line contains only CC=gcc but no
1063             # other gcc command.
1064             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
1065                 my $before = $1;
1066                 my $after  = $2;
1067                 next if     not $before =~ /$cc_regex_normal/o
1068                         and not $after  =~ /$cc_regex_normal/o;
1069             }
1070             # Ignore false positives caused by gcc -v. It outputs a line
1071             # looking like a normal compiler line but which is sometimes
1072             # missing hardening flags, although the normal compiler line
1073             # contains them.
1074             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
1075                                    [0-9.]+/cc1(?:plus)?}xo;
1076             # Ignore false positive with `rm` which may remove files which
1077             # look like a compiler executable thus causing the line to be
1078             # treated as a normal compiler line.
1079             next if $line =~ m{^\s*rm\s+};
1080             # Some build systems emit "gcc > file".
1081             next if $line =~ m{$cc_regex_normal\s*>\s*\S+}o;
1082             # Hex output may contain "cc".
1083             next if $line =~ m#(?:\b[0-9a-fA-F]{2,}\b\s*){5}#;
1084
1085             # Check if additional hardening options were used. Used to ensure
1086             # they are used for the complete build.
1087             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
1088                                                          @def_ldflags_pie);
1089             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
1090
1091             push @input, $line;
1092             push @input_nonverbose, $non_verbose;
1093             push @input_number, $number if $option_line_numbers;
1094         }
1095     }
1096
1097     close $fh or die $!;
1098
1099     # Ignore arch if requested.
1100     if (scalar @option_ignore_arch > 0 and $arch) {
1101         foreach my $ignore (@option_ignore_arch) {
1102             if ($arch eq $ignore) {
1103                 print "ignoring architecture '$arch'\n";
1104                 next FILE;
1105             }
1106         }
1107     }
1108
1109     if (scalar @input == 0) {
1110         if (not $option_buildd) {
1111             print "No compiler commands!\n";
1112             $exit |= $exit_code{no_compiler_commands};
1113         } else {
1114             print "$buildd_tag{no_compiler_commands}||\n";
1115         }
1116         next FILE;
1117     }
1118
1119     if ($option_buildd) {
1120         $statistics{commands} += scalar @input;
1121     }
1122
1123     # Option or auto detected.
1124     if ($arch) {
1125         # The following was partially copied from dpkg-dev 1.19.7
1126         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, _add_build_flags()),
1127         # copyright Raphaël Hertzog <hertzog@debian.org>, Guillem Jover
1128         # <guillem@debian.org>, Kees Cook <kees@debian.org>, Canonical, Ltd.
1129         # licensed under GPL version 2 or later. Keep it in sync.
1130
1131         require Dpkg::Arch;
1132         my ($os, $cpu);
1133         # Recent dpkg versions use a quadruplet for arch. Support both.
1134         eval {
1135             (undef, undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtuple($arch);
1136         };
1137         if ($@) {
1138             (undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1139         }
1140
1141         my %builtin_pie_arch = map { $_ => 1 } qw(
1142             amd64
1143             arm64
1144             armel
1145             armhf
1146             hurd-i386
1147             i386
1148             kfreebsd-amd64
1149             kfreebsd-i386
1150             mips
1151             mipsel
1152             mips64el
1153             powerpc
1154             ppc64
1155             ppc64el
1156             riscv64
1157             s390x
1158             sparc
1159             sparc64
1160         );
1161
1162         # Disable unsupported hardening options.
1163         if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/
1164                 or $cpu =~ /^(?:hppa|avr32)$/) {
1165             $harden_pie = 0;
1166         }
1167         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1168             $harden_stack = 0;
1169             $harden_stack_strong = 0;
1170         }
1171         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1172             $harden_relro   = 0;
1173             $harden_bindnow = 0;
1174         }
1175
1176         if ($disable_harden_pie and exists $builtin_pie_arch{$arch}) {
1177             $harden_pie = 0;
1178         }
1179     }
1180
1181     # Default values.
1182     my @cflags   = @def_cflags;
1183     my @cxxflags = @def_cxxflags;
1184     my @cppflags = @def_cppflags;
1185     my @ldflags  = @def_ldflags;
1186     # Check the specified hardening options, same order as dpkg-buildflags.
1187     if ($harden_pie) {
1188         @cflags   = (@cflags,   @def_cflags_pie);
1189         @cxxflags = (@cxxflags, @def_cflags_pie);
1190         @ldflags  = (@ldflags,  @def_ldflags_pie);
1191     }
1192     if ($harden_stack_strong) {
1193         @cflags   = (@cflags,   @def_cflags_stack_strong);
1194         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1195     } elsif ($harden_stack) {
1196         @cflags   = (@cflags,   @def_cflags_stack);
1197         @cxxflags = (@cxxflags, @def_cflags_stack);
1198     }
1199     if ($harden_fortify) {
1200         @cflags   = (@cflags,   @def_cflags_fortify);
1201         @cxxflags = (@cxxflags, @def_cflags_fortify);
1202         @cppflags = (@cppflags, @def_cppflags_fortify);
1203     }
1204     if ($harden_format) {
1205         @cflags   = (@cflags,   @def_cflags_format);
1206         @cxxflags = (@cxxflags, @def_cflags_format);
1207     }
1208     if ($harden_relro) {
1209         @ldflags = (@ldflags, @def_ldflags_relro);
1210     }
1211     if ($harden_bindnow) {
1212         @ldflags = (@ldflags, @def_ldflags_bindnow);
1213     }
1214
1215     # Ada doesn't support format hardening flags, see #680117 for more
1216     # information. Same for fortran. Filter them out if either language is
1217     # used.
1218     my @cflags_backup;
1219     my @cflags_noformat;
1220     if (($ada or $fortran) and $harden_format) {
1221         @cflags_noformat = grep {
1222             my $ok = 1;
1223             foreach my $flag (@def_cflags_format) {
1224                 $ok = 0 if $_ eq $flag;
1225             }
1226             $ok;
1227         } @cflags;
1228     }
1229
1230     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1231     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1232     # as long as @def_cppflags_fortify contains only one variable.
1233     if (scalar @def_cppflags_fortify == 0) {
1234         $harden_fortify = 0;
1235     }
1236
1237     # Ignore flags for this arch if requested.
1238     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1239         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1240
1241         remove_flags(\@local_flag_refs,
1242                      \%flag_renames,
1243                      @{$option_ignore_arch_flag{$arch}});
1244     }
1245
1246     my @ignore_line = @option_ignore_line;
1247     # Ignore lines for this arch if requested.
1248     if ($arch and exists $option_ignore_arch_line{$arch}) {
1249         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1250     }
1251
1252 LINE:
1253     for (my $i = 0; $i < scalar @input; $i++) {
1254         my $line = $input[$i];
1255
1256         # Ignore line if requested.
1257         foreach my $ignore (@ignore_line) {
1258             next LINE if $line =~ /$ignore/;
1259         }
1260
1261         my $skip = 0;
1262         if ($input_nonverbose[$i]
1263                 and is_non_verbose_build($line, \$skip,
1264                                          \@input, $i, $parallel)) {
1265             if (not $option_buildd) {
1266                 error_non_verbose_build($line, $input_number[$i]);
1267                 $exit |= $exit_code{non_verbose_build};
1268             } else {
1269                 $statistics{commands_nonverbose}++;
1270             }
1271             next;
1272         }
1273         # Even if it's a verbose build, we might have to skip this line (see
1274         # is_non_verbose_build()).
1275         next if $skip;
1276
1277         my $orig_line = $line;
1278
1279         # Remove everything until and including the compiler command. Makes
1280         # checks easier and faster.
1281         $line =~ s/^.*?$cc_regex//o;
1282         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1283         # the brace and similar characters at the line end.
1284         $line =~ s/['")]+$//;
1285
1286         # Skip unnecessary tests when only preprocessing.
1287         my $flag_preprocess = 0;
1288
1289         my $dependency = 0;
1290         my $preprocess = 0;
1291         my $compile    = 0;
1292         my $link       = 0;
1293
1294         # Preprocess, compile, assemble.
1295         if ($line =~ /\s(-E|-S|-c)\b/) {
1296             $preprocess      = 1;
1297             $flag_preprocess = 1 if $1 eq '-E';
1298             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1299         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1300         # -MT -MQ) are always used with -M/-MM.
1301         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1302             $dependency = 1;
1303         # Otherwise assume we are linking.
1304         } else {
1305             $link = 1;
1306         }
1307
1308         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1309         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1310             $dependency      = 0;
1311             $flag_preprocess = 0;
1312         }
1313
1314         # Dependency generation for Makefiles, no preprocessing or other flags
1315         # needed.
1316         next if $dependency;
1317
1318         # Get all file extensions on this line.
1319         my @extensions = $line =~ /$file_extension_regex/go;
1320         # Ignore all unknown extensions to speedup the search below.
1321         @extensions = grep { exists $extension{$_} } @extensions;
1322
1323         # These file types don't require preprocessing.
1324         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1325             $preprocess = 0;
1326         }
1327         # These file types require preprocessing.
1328         if (extension_found(\%extensions_preprocess, @extensions)) {
1329             # Prevent false positives with "libtool: link: g++ -include test.h
1330             # .." compiler lines.
1331             if ($orig_line !~ /$libtool_link_regex/o) {
1332                 $preprocess = 1;
1333             }
1334         }
1335
1336         if (not $flag_preprocess) {
1337             # If there are source files then it's compiling/linking in one
1338             # step and we must check both. We only check for source files
1339             # here, because header files cause too many false positives.
1340             if (extension_found(\%extensions_compile_link, @extensions)) {
1341                 # Assembly files don't need CFLAGS.
1342                 if (not extension_found(\%extensions_compile, @extensions)
1343                         and extension_found(\%extensions_no_compile, @extensions)) {
1344                     $compile = 0;
1345                 # But the rest does.
1346                 } else {
1347                     $compile = 1;
1348                 }
1349             # No compilable extensions found, either linking or compiling
1350             # header flags.
1351             #
1352             # If there are also no object files we are just compiling headers
1353             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1354             # to our liberal checks for compiler lines, this also reduces the
1355             # number of false positives considerably.
1356             } elsif ($link
1357                     and not extension_found(\%extensions_object, @extensions)) {
1358                 $link = 0;
1359             }
1360         }
1361
1362         my $compile_cpp = 0;
1363         my $restore_cflags = 0;
1364         # Assume CXXFLAGS are required when a C++ file is specified in the
1365         # compiler line.
1366         if ($compile
1367                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1368             $compile     = 0;
1369             $compile_cpp = 1;
1370         # Ada needs special CFLAGS, use them if only ada files are compiled.
1371         } elsif ($ada
1372                 and extension_found(\%extensions_ada, @extensions)) {
1373             $restore_cflags = 1;
1374             $preprocess = 0; # Ada uses no CPPFLAGS
1375             @cflags_backup = @cflags;
1376             @cflags        = @cflags_noformat;
1377         # Same for fortran.
1378         } elsif ($fortran
1379                 and extension_found(\%extensions_fortran, @extensions)) {
1380             $restore_cflags = 1;
1381             @cflags_backup = @cflags;
1382             @cflags        = @cflags_noformat;
1383         }
1384
1385         if ($option_buildd) {
1386             $statistics{preprocess}++  if $preprocess;
1387             $statistics{compile}++     if $compile;
1388             $statistics{compile_cpp}++ if $compile_cpp;
1389             $statistics{link}++        if $link;
1390         }
1391
1392         # Check if there are flags indicating a debug build. If that's true,
1393         # skip the check for -O2. This prevents fortification, but that's fine
1394         # for a debug build.
1395         if (any_flags_used($line, @def_cflags_debug)) {
1396             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1397             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1398         }
1399
1400         # Check hardening flags.
1401         my @missing;
1402         if ($compile and (not all_flags_used($line, \@missing, @cflags)
1403                     or (($harden_stack or $harden_stack_strong)
1404                         and cflags_stack_broken($line, \@missing,
1405                                                 $harden_stack_strong)))
1406                 # Libraries linked with -fPIC don't have to (and can't) be
1407                 # linked with -fPIE as well. It's no error if only PIE flags
1408                 # are missing.
1409                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1410                 # Assume dpkg-buildflags returns the correct flags.
1411                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1412             if (not $option_buildd) {
1413                 error_flags('CFLAGS missing', \@missing, \%flag_renames,
1414                             $input[$i], $input_number[$i]);
1415                 $exit |= $exit_code{flags_missing};
1416             } else {
1417                 $statistics{compile_missing}++;
1418             }
1419         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1420                 # Libraries linked with -fPIC don't have to (and can't) be
1421                 # linked with -fPIE as well. It's no error if only PIE flags
1422                 # are missing.
1423                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1424                 # Assume dpkg-buildflags returns the correct flags.
1425                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1426             if (not $option_buildd) {
1427                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames,
1428                             $input[$i], $input_number[$i]);
1429                 $exit |= $exit_code{flags_missing};
1430             } else {
1431                 $statistics{compile_cpp_missing}++;
1432             }
1433         }
1434         if ($preprocess
1435                 and (not all_flags_used($line, \@missing, @cppflags)
1436                     # The fortify flag might be overwritten, detect that.
1437                      or ($harden_fortify
1438                          and cppflags_fortify_broken($line, \@missing)))
1439                 # Assume dpkg-buildflags returns the correct flags.
1440                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1441             if (not $option_buildd) {
1442                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames,
1443                             $input[$i], $input_number[$i]);
1444                 $exit |= $exit_code{flags_missing};
1445             } else {
1446                 $statistics{preprocess_missing}++;
1447             }
1448         }
1449         if ($link and not all_flags_used($line, \@missing, @ldflags)
1450                 # Same here, -fPIC conflicts with -fPIE.
1451                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1452                 # Assume dpkg-buildflags returns the correct flags.
1453                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1454             if (not $option_buildd) {
1455                 error_flags('LDFLAGS missing', \@missing, \%flag_renames,
1456                             $input[$i], $input_number[$i]);
1457                 $exit |= $exit_code{flags_missing};
1458             } else {
1459                 $statistics{link_missing}++;
1460             }
1461         }
1462
1463         # Restore normal CFLAGS.
1464         if ($restore_cflags) {
1465             @cflags = @cflags_backup;
1466         }
1467     }
1468 }
1469
1470 # Print statistics for buildd mode, only output in this mode.
1471 if ($option_buildd) {
1472     my @warning;
1473
1474     if ($statistics{preprocess_missing}) {
1475         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1476                                $statistics{preprocess_missing},
1477                                $statistics{preprocess};
1478     }
1479     if ($statistics{compile_missing}) {
1480         push @warning, sprintf 'CFLAGS %d (of %d)',
1481                                $statistics{compile_missing},
1482                                $statistics{compile};
1483     }
1484     if ($statistics{compile_cpp_missing}) {
1485         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1486                                $statistics{compile_cpp_missing},
1487                                $statistics{compile_cpp};
1488     }
1489     if ($statistics{link_missing}) {
1490         push @warning, sprintf 'LDFLAGS %d (of %d)',
1491                                $statistics{link_missing},
1492                                $statistics{link};
1493     }
1494     if (scalar @warning) {
1495         local $" = ', '; # array join string
1496         print "$buildd_tag{flags_missing}|@warning missing|\n";
1497     }
1498
1499     if ($statistics{commands_nonverbose}) {
1500         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1501                $statistics{commands_nonverbose},
1502                $statistics{commands},
1503     }
1504 }
1505
1506
1507 exit $exit;
1508
1509
1510 __END__
1511
1512 =head1 NAME
1513
1514 blhc - build log hardening check, checks build logs for missing hardening flags
1515
1516 =head1 SYNOPSIS
1517
1518 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1519
1520 =head1 DESCRIPTION
1521
1522 blhc is a small tool which checks build logs for missing hardening flags. It's
1523 licensed under the GPL 3 or later.
1524
1525 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1526 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1527 official buildd build logs)) to help maintainers detect missing hardening
1528 flags in their packages.
1529
1530 Only gcc is detected as compiler at the moment. If other compilers support
1531 hardening flags as well, please report them.
1532
1533 If there's no output, no flags are missing and the build log is fine.
1534
1535 See F<README> for details about performed checks, auto-detection and
1536 limitations.
1537
1538 =head1 OPTIONS
1539
1540 =over 8
1541
1542 =item B<--all>
1543
1544 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1545 auto detected.
1546
1547 =item B<--arch> I<architecture>
1548
1549 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1550 disables hardening flags not available on this architecture. Is detected
1551 automatically if dpkg-buildpackage is used.
1552
1553 =item B<--bindnow>
1554
1555 Force check for all +bindnow hardening flags. By default it's auto detected.
1556
1557 =item B<--buildd>
1558
1559 Special mode for buildds when automatically parsing log files. The following
1560 changes are in effect:
1561
1562 =over 2
1563
1564 =item *
1565
1566 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1567 possible tags.
1568
1569 =item *
1570
1571 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1572 detected).
1573
1574 =item *
1575
1576 Don't require Term::ANSIColor.
1577
1578 =item *
1579
1580 Return exit code 0, unless there was a error (-I, -W messages don't count as
1581 error).
1582
1583 =back
1584
1585 =item B<--debian>
1586
1587 Apply Debian-specific settings. At the moment this only disables checking for
1588 PIE which is automatically applied by Debian's GCC and no longer requires a
1589 compiler command line argument.
1590
1591 =item B<--color>
1592
1593 Use colored (ANSI) output for warning messages.
1594
1595 =item B<--line-numbers>
1596
1597 Display line numbers.
1598
1599 =item B<--ignore-arch> I<arch>
1600
1601 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1602
1603 Used to prevent false positives. This option can be specified multiple times.
1604
1605 =item B<--ignore-arch-flag> I<arch>:I<flag>
1606
1607 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1608
1609 =item B<--ignore-arch-line> I<arch>:I<line>
1610
1611 Like B<--ignore-line>, but only ignore line on I<arch>.
1612
1613 =item B<--ignore-flag> I<flag>
1614
1615 Don't print an error when the specific flag is missing in a compiler line.
1616 I<flag> is a string.
1617
1618 Used to prevent false positives. This option can be specified multiple times.
1619
1620 =item B<--ignore-line> I<regex>
1621
1622 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1623 at the beginning and end of the line to prevent false negatives.
1624
1625 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1626 warnings (which have line continuation resolved).
1627
1628 Used to prevent false positives. This option can be specified multiple times.
1629
1630 =item B<--pie>
1631
1632 Force check for all +pie hardening flags. By default it's auto detected.
1633
1634 =item B<-h -? --help>
1635
1636 Print available options.
1637
1638 =item B<--version>
1639
1640 Print version number and license.
1641
1642 =back
1643
1644 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1645 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1646 all other commands as well.
1647
1648 =head1 EXAMPLES
1649
1650 Normal usage, parse a single log file.
1651
1652     blhc path/to/log/file
1653
1654 If there's no output, no flags are missing and the build log is fine.
1655
1656 Parse multiple log files. The exit code is ORed over all files.
1657
1658     blhc path/to/directory/with/log/files/*
1659
1660 Don't treat missing C<-g> as error:
1661
1662     blhc --ignore-flag -g path/to/log/file
1663
1664 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1665
1666     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1667
1668 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1669 false positive.
1670
1671     blhc --ignore-line '\./script gcc file' path/to/log/file
1672
1673 Ignore lines matching C<./script gcc file> somewhere in the line.
1674
1675     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1676
1677 Use blhc with pbuilder.
1678
1679     pbuilder path/to/package.dsc | tee path/log/file
1680     blhc path/to/file || echo flags missing
1681
1682 Assume this build log was created on a Debian system and thus don't warn about
1683 missing PIE flags if the current architecture injects them automatically (this
1684 is enabled in buildd mode per default). C<--arch> is necessary if the build
1685 log contains no architecture information as written by dpkg-buildpackage.
1686
1687     blhc --debian --all --arch=amd64 path/to/log/file
1688
1689 =head1 BUILDD TAGS
1690
1691 The following tags are used in I<--buildd> mode. In braces the additional data
1692 which is displayed.
1693
1694 =over 2
1695
1696 =item B<I-hardening-wrapper-used>
1697
1698 The package uses hardening-wrapper which intercepts calls to gcc and adds
1699 hardening flags. The build log doesn't contain any hardening flags and thus
1700 can't be checked by blhc.
1701
1702 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1703
1704 Build log contains lines which hide the real compiler flags. For example:
1705
1706     CC test-a.c
1707     CC test-b.c
1708     CC test-c.c
1709     LD test
1710
1711 Most of the time either C<export V=1> or C<export verbose=1> in
1712 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1713 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1714 patched to remove the C<@>s hiding the real compiler commands.
1715
1716 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1717
1718 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1719
1720 =item B<I-invalid-cmake-used> (version)
1721
1722 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1723 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1724 patch was rejected by upstream and later reverted in Debian. Thus those two
1725 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1726 handle them (for example by passing them to CFLAGS). To prevent false
1727 negatives just blacklist those two versions.
1728
1729 =item B<I-no-compiler-commands>
1730
1731 No compiler commands were detected. Either the log contains none or they were
1732 not correctly detected by blhc (please report the bug in this case).
1733
1734 =back
1735
1736 =head1 EXIT STATUS
1737
1738 The exit status is a "bit mask", each listed status is ORed when the error
1739 condition occurs to get the result.
1740
1741 =over 4
1742
1743 =item B<0>
1744
1745 Success.
1746
1747 =item B<1>
1748
1749 No compiler commands were found.
1750
1751 =item B<2>
1752
1753 Invalid arguments/options given to blhc.
1754
1755 =item B<4>
1756
1757 Non verbose build.
1758
1759 =item B<8>
1760
1761 Missing hardening flags.
1762
1763 =item B<16>
1764
1765 Hardening wrapper detected, no tests performed.
1766
1767 =item B<32>
1768
1769 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1770 TAGS"> for a detailed explanation.
1771
1772 =back
1773
1774 =head1 AUTHOR
1775
1776 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1777
1778 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1779 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1780
1781 =head1 LICENSE AND COPYRIGHT
1782
1783 Copyright (C) 2012-2019 by Simon Ruderich
1784
1785 This program is free software: you can redistribute it and/or modify
1786 it under the terms of the GNU General Public License as published by
1787 the Free Software Foundation, either version 3 of the License, or
1788 (at your option) any later version.
1789
1790 This program is distributed in the hope that it will be useful,
1791 but WITHOUT ANY WARRANTY; without even the implied warranty of
1792 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1793 GNU General Public License for more details.
1794
1795 You should have received a copy of the GNU General Public License
1796 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1797
1798 =head1 SEE ALSO
1799
1800 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1801
1802 =cut