bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2016  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.06';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full_prefix = qr/
  42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
  43     /x;
  44 my $cc_regex_full = qr/
  45     (?:$cc_regex_full_prefix-)?
  46     $cc_regex
  47     /x;
  48 # Regex to check if a line contains a compiler command.
  49 my $cc_regex_normal = qr/
  50     \b$cc_regex(?:\s|\\)
  51     /x;
  52 # Regex to catch (GCC) compiler warnings.
  53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  54 # Regex to catch libtool commands and not lines which show commands executed
  55 # by libtool (e.g. libtool: link: ...).
  56 my $libtool_regex = qr/\blibtool\s.*--mode=/;
  57 my $libtool_link_regex = qr/\blibtool: link: /;
  58
  59 # List of source file extensions which require preprocessing.
  60 my @source_preprocess_compile_cpp = (
  61     # C++
  62     qw( cc cp cxx cpp CPP c++ C ),
  63     # Objective-C++
  64     qw( mm M ),
  65 );
  66 my @source_preprocess_compile = (
  67     # C
  68     qw( c ),
  69     # Objective-C
  70     qw( m ),
  71     # (Objective-)C++
  72     @source_preprocess_compile_cpp,
  73     # Fortran
  74     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  75 );
  76 my @source_preprocess_no_compile = (
  77     # Assembly
  78     qw( S sx ),
  79 );
  80 my @source_preprocess = (
  81     @source_preprocess_compile,
  82     @source_preprocess_no_compile,
  83 );
  84 # List of source file extensions which don't require preprocessing.
  85 my @source_no_preprocess_compile_cpp = (
  86     # C++
  87     qw( ii ),
  88     # Objective-C++
  89     qw( mii ),
  90 );
  91 my @source_no_preprocess_compile_ada = (
  92     # Ada source
  93     qw( ada ),
  94     # Ada body
  95     qw( adb ),
  96 );
  97 my @source_no_preprocess_compile = (
  98     # C
  99     qw( i ),
 100     # (Objective-)C++
 101     @source_no_preprocess_compile_cpp,
 102     # Objective-C
 103     qw( mi ),
 104     # Fortran
 105     qw( f for ftn f90 f95 f03 f08 ),
 106     # Ada
 107     @source_no_preprocess_compile_ada,
 108 );
 109 my @source_no_preprocess_no_compile_ada = (
 110     # Ada specification
 111     qw( ads ),
 112 );
 113 my @source_no_preprocess_no_compile = (
 114     # Assembly
 115     qw( s ),
 116     # Ada
 117     @source_no_preprocess_no_compile_ada,
 118 );
 119 my @source_no_preprocess = (
 120     @source_no_preprocess_compile,
 121     @source_no_preprocess_no_compile,
 122 );
 123 # List of header file extensions which require preprocessing.
 124 my @header_preprocess = (
 125     # C, C++, Objective-C, Objective-C++
 126     qw( h ),
 127     # C++
 128     qw( hh H hp hxx hpp HPP h++ tcc ),
 129 );
 130 # Object files.
 131 my @object = (
 132     # Normal object files.
 133     qw ( o ),
 134     # Libtool object files.
 135     qw ( lo la ),
 136     # Dynamic libraries. bzip2 uses .sho.
 137     qw ( so sho ),
 138     # Static libraries.
 139     qw ( a ),
 140 );
 141
 142 # Hashes for fast extensions lookup to check if a file falls in one of these
 143 # categories.
 144 my %extensions_no_preprocess = map { $_ => 1 } (
 145     # There's no @header_no_preprocess.
 146     @source_no_preprocess,
 147 );
 148 my %extensions_preprocess = map { $_ => 1 } (
 149     @header_preprocess,
 150     @source_preprocess,
 151 );
 152 my %extensions_compile_link = map { $_ => 1 } (
 153     @source_preprocess,
 154     @source_no_preprocess,
 155 );
 156 my %extensions_compile = map { $_ => 1 } (
 157     @source_preprocess_compile,
 158     @source_no_preprocess_compile,
 159 );
 160 my %extensions_no_compile = map { $_ => 1 } (
 161     @source_preprocess_no_compile,
 162     @source_no_preprocess_no_compile,
 163 );
 164 my %extensions_compile_cpp = map { $_ => 1 } (
 165     @source_preprocess_compile_cpp,
 166     @source_no_preprocess_compile_cpp,
 167 );
 168 my %extensions_ada = map { $_ => 1 } (
 169     @source_no_preprocess_compile_ada,
 170     @source_no_preprocess_no_compile_ada,
 171 );
 172 my %extensions_object = map { $_ => 1 } (
 173     @object,
 174 );
 175 my %extension = map { $_ => 1 } (
 176     @source_no_preprocess,
 177     @header_preprocess,
 178     @source_preprocess,
 179     @object,
 180 );
 181
 182 # Regexp to match file extensions.
 183 my $file_extension_regex = qr/
 184     \s
 185     \S+             # Filename without extension.
 186     \.
 187     ([^\/\\.,;:\s]+)# File extension.
 188     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 189                     # word characters at the end and because \b matches double
 190                     # extensions (like .cpp.o). Works always as all lines are
 191                     # terminated with "\n".
 192     /x;
 193
 194 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 195 # real regexps below for better execution speed).
 196 my @def_cflags = (
 197     '-g',
 198     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
 199 );
 200 my @def_cflags_debug = (
 201     # These flags indicate a debug build which disables checks for -O2.
 202     '-O0',
 203     '-Og',
 204 );
 205 my @def_cflags_format = (
 206     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 207     '-Werror=format-security', # implies -Wformat-security
 208 );
 209 my @def_cflags_fortify = (
 210     # fortify needs at least -O1, but -O2 is recommended anyway
 211 );
 212 my @def_cflags_stack = (
 213     '-fstack-protector',
 214     '--param[= ]ssp-buffer-size=4',
 215 );
 216 my @def_cflags_stack_strong = (
 217     '-fstack-protector-strong',
 218 );
 219 my @def_cflags_pie = (
 220     '-fPIE',
 221 );
 222 my @def_cxxflags = (
 223     @def_cflags,
 224 );
 225 # @def_cxxflags_* is the same as @def_cflags_*.
 226 my @def_cppflags = ();
 227 my @def_cppflags_fortify = (
 228     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 229     # If you add another flag fix hack below (search for "Hack to fix") and
 230     # $def_cppflags_fortify[0].
 231 );
 232 my @def_cppflags_fortify_bad = (
 233     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 234     '-U_FORTIFY_SOURCE',
 235     '-D_FORTIFY_SOURCE=0',
 236     '-D_FORTIFY_SOURCE=1',
 237 );
 238 my @def_ldflags = ();
 239 my @def_ldflags_relro = (
 240     '-Wl,(?:-z,)?relro',
 241 );
 242 my @def_ldflags_bindnow = (
 243     '-Wl,(?:-z,)?now',
 244 );
 245 my @def_ldflags_pie = (
 246     '-fPIE',
 247     '-pie',
 248 );
 249 my @def_ldflags_pic = (
 250     '-fPIC',
 251     '-fpic',
 252     '-shared',
 253 );
 254 # References to all flags checked by the flag checker.
 255 my @flag_refs = (
 256     \@def_cflags,
 257     \@def_cflags_format,
 258     \@def_cflags_fortify,
 259     \@def_cflags_stack,
 260     \@def_cflags_stack_strong,
 261     \@def_cflags_pie,
 262     \@def_cxxflags,
 263     \@def_cppflags,
 264     \@def_cppflags_fortify,
 265     \@def_ldflags,
 266     \@def_ldflags_relro,
 267     \@def_ldflags_bindnow,
 268     \@def_ldflags_pie,
 269 );
 270 # References to all used flags.
 271 my @flag_refs_all = (
 272     @flag_refs,
 273     \@def_cflags_debug,
 274     \@def_cppflags_fortify_bad,
 275     \@def_ldflags_pic,
 276 );
 277 # Renaming rules for the output so the regex parts are not visible. Also
 278 # stores string values of flag regexps above, see compile_flag_regexp().
 279 my %flag_renames = (
 280     '-O(?:2|3)'                    => '-O2',
 281     '-Wformat(?:=2)?'              => '-Wformat',
 282     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 283     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 284     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 285 );
 286
 287 my %exit_code = (
 288     no_compiler_commands => 1 << 0,
 289     # used by POD::Usage => 1 << 1,
 290     non_verbose_build    => 1 << 2,
 291     flags_missing        => 1 << 3,
 292     hardening_wrapper    => 1 << 4,
 293     invalid_cmake        => 1 << 5,
 294 );
 295
 296 my %buildd_tag = (
 297     no_compiler_commands => 'I-no-compiler-commands',
 298     non_verbose_build    => 'W-compiler-flags-hidden',
 299     flags_missing        => 'W-dpkg-buildflags-missing',
 300     hardening_wrapper    => 'I-hardening-wrapper-used',
 301     invalid_cmake        => 'I-invalid-cmake-used',
 302 );
 303
 304 # Statistics of missing flags and non-verbose build commands. Used for
 305 # $option_buildd.
 306 my %statistics = (
 307     preprocess          => 0,
 308     preprocess_missing  => 0,
 309     compile             => 0,
 310     compile_missing     => 0,
 311     compile_cpp         => 0,
 312     compile_cpp_missing => 0,
 313     link                => 0,
 314     link_missing        => 0,
 315     commands            => 0,
 316     commands_nonverbose => 0,
 317 );
 318
 319 # Use colored (ANSI) output?
 320 my $option_color;
 321
 322
 323 # FUNCTIONS
 324
 325 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 326 sub array_equal {
 327     my ($first_ref, $second_ref) = @_;
 328
 329     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 330
 331     my $length = scalar @{$first_ref};
 332     for (my $i = 0; $i < $length; $i++) {
 333         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 334     }
 335
 336     return 1;
 337 }
 338
 339 sub error_flags {
 340     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 341
 342     # Get string value of qr//-escaped regexps and if requested rename them.
 343     my @missing_flags = map {
 344             $flag_renames_ref->{$_}
 345         } @{$missing_flags_ref};
 346
 347     my $flags = join ' ', @missing_flags;
 348     printf '%s (%s)%s %s',
 349            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 350            $line;
 351
 352     return;
 353 }
 354 sub error_non_verbose_build {
 355     my ($line) = @_;
 356
 357     printf '%s%s %s',
 358            error_color('NONVERBOSE BUILD', 'red'),
 359            error_color(':', 'yellow'),
 360            $line;
 361
 362     return;
 363 }
 364 sub error_invalid_cmake {
 365     my ($version) = @_;
 366
 367     printf "%s%s %s\n",
 368             error_color('INVALID CMAKE', 'red'),
 369             error_color(':', 'yellow'),
 370             $version;
 371
 372     return;
 373 }
 374 sub error_hardening_wrapper {
 375     printf "%s%s %s\n",
 376             error_color('HARDENING WRAPPER', 'red'),
 377             error_color(':', 'yellow'),
 378             'no checks possible, aborting';
 379
 380     return;
 381 }
 382 sub error_color {
 383     my ($message, $color) = @_;
 384
 385     if ($option_color) {
 386         return Term::ANSIColor::colored($message, $color);
 387     } else {
 388         return $message;
 389     }
 390 }
 391
 392 sub any_flags_used {
 393     my ($line, @flags) = @_;
 394
 395     foreach my $flag (@flags) {
 396         return 1 if $line =~ /$flag/;
 397     }
 398
 399     return 0;
 400 }
 401 sub all_flags_used {
 402     my ($line, $missing_flags_ref, @flags) = @_;
 403
 404     my @missing_flags = ();
 405     foreach my $flag (@flags) {
 406         if (not $line =~ /$flag/) {
 407             push @missing_flags, $flag;
 408         }
 409     }
 410
 411     return 1 if scalar @missing_flags == 0;
 412
 413     @{$missing_flags_ref} = @missing_flags;
 414     return 0;
 415 }
 416
 417 sub cppflags_fortify_broken {
 418     my ($line, $missing_flags) = @_;
 419
 420     # This doesn't take the position into account, but is a simple solution.
 421     # And if the build system tries to force -D_FORTIFY_SOURCE=0/1, something
 422     # is wrong anyway.
 423
 424     if (any_flags_used($line, @def_cppflags_fortify_bad)) {
 425         # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 426         push @{$missing_flags}, $def_cppflags_fortify[0];
 427         return 1;
 428     }
 429
 430     return 0;
 431 }
 432
 433 # Modifies $missing_flags_ref array.
 434 sub pic_pie_conflict {
 435     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 436
 437     return 0 if not $pie;
 438     return 0 if not any_flags_used($line, @def_ldflags_pic);
 439
 440     my %flags = map { $_ => 1 } @flags_pie;
 441
 442     # Remove all PIE flags from @missing_flags as they are not required with
 443     # -fPIC.
 444     my @result = grep {
 445         not exists $flags{$_}
 446     } @{$missing_flags_ref};
 447     @{$missing_flags_ref} = @result;
 448
 449     # We got a conflict when no flags are left, thus only PIE flags were
 450     # missing. If other flags were missing abort because the conflict is not
 451     # the problem.
 452     return scalar @result == 0;
 453 }
 454
 455 sub is_non_verbose_build {
 456     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
 457
 458     if ($line =~ /$libtool_regex/o) {
 459         # libtool's --silent hides the real compiler flags.
 460         if ($line =~ /\s--silent/) {
 461             return 1;
 462         # If --silent is not present, skip this line as some compiler flags
 463         # might be missing (e.g. -fPIE) which are handled correctly by libtool
 464         # internally. libtool displays the real compiler command on the next
 465         # line, so the flags are checked as usual.
 466         } else {
 467             ${$skip_ref} = 1;
 468             return 0;
 469         }
 470     }
 471
 472     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 473                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 474                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 475                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 476                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 477         return 0;
 478     }
 479
 480     # False positives.
 481     #
 482     # C++ compiler setting.
 483     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 484     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 485     # "Compiling" non binary files.
 486     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|el)['"]?\s*(?:\.\.\.)?$/;
 487     # "Compiling" with no file name.
 488     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 489         # $file_extension_regex may need spaces around the filename.
 490         return 0 if not " $1 " =~ /$file_extension_regex/o;
 491     }
 492
 493     my $file = $1;
 494
 495     # On the first pass we only check if this line is verbose or not.
 496     return 1 if not defined $input_ref;
 497
 498     # Second pass, we have access to the next lines.
 499     ${$skip_ref} = 0;
 500
 501     # CMake and other build systems print the non-verbose messages also when
 502     # building verbose. If a compiler and the file name occurs in the next
 503     # lines, treat it as verbose build.
 504     if (defined $file) {
 505         # Get filename, we can't use the complete path as only parts of it are
 506         # used in the real compiler command.
 507         $file =~ m{/([^/\s]+)$};
 508         $file = $1;
 509
 510         for (my $i = 1; $i <= $line_count; $i++) {
 511             my $next_line = $input_ref->[$line_offset + $i];
 512             last unless defined $next_line;
 513
 514             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 515                 # Not a non-verbose line, but we still have to skip the
 516                 # current line as it doesn't contain any compiler commands.
 517                 ${$skip_ref} = 1;
 518                 return 0;
 519             }
 520         }
 521     }
 522
 523     return 1;
 524 }
 525
 526 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
 527 sub remove_flags {
 528     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 529
 530     my %removes = map { $_ => 1 } @flags;
 531     foreach my $flags (@{$flag_refs_ref}) {
 532         @{$flags} = grep {
 533             # Flag found as string.
 534             not exists $removes{$_}
 535             # Flag found as string representation of regexp.
 536                 and (not defined $flag_renames_ref->{$_}
 537                         or not exists $removes{$flag_renames_ref->{$_}})
 538         } @{$flags};
 539     }
 540
 541     return;
 542 }
 543
 544 # Modifies $flag_renames_ref hash.
 545 sub compile_flag_regexp {
 546     my ($flag_renames_ref, @flags) = @_;
 547
 548     my @result = ();
 549     foreach my $flag (@flags) {
 550         # Compile flag regexp for faster execution.
 551         my $regex = qr/\s$flag(?:\s|\\)/;
 552
 553         # Store flag name in replacement string for correct flags in messages
 554         # with qr//ed flag regexps.
 555         $flag_renames_ref->{$regex}
 556             = (exists $flag_renames_ref->{$flag})
 557                 ? $flag_renames_ref->{$flag}
 558                 : $flag;
 559
 560         push @result, $regex;
 561     }
 562     return @result;
 563 }
 564
 565 # Does any extension in @extensions exist in %{$extensions_ref}?
 566 sub extension_found {
 567     my ($extensions_ref, @extensions) = @_;
 568
 569     foreach my $extension (@extensions) {
 570         if (exists $extensions_ref->{$extension}) {
 571             return 1;
 572         }
 573     }
 574     return 0;
 575 }
 576
 577
 578 # MAIN
 579
 580 # Parse command line arguments.
 581 my $option_help             = 0;
 582 my $option_version          = 0;
 583 my $option_pie              = 0;
 584 my $option_bindnow          = 0;
 585 my @option_ignore_arch      = ();
 586 my @option_ignore_flag      = ();
 587 my @option_ignore_arch_flag = ();
 588 my @option_ignore_line      = ();
 589 my @option_ignore_arch_line = ();
 590 my $option_all              = 0;
 591 my $option_arch             = undef;
 592 my $option_buildd           = 0;
 593    $option_color            = 0;
 594 if (not Getopt::Long::GetOptions(
 595             'help|h|?'           => \$option_help,
 596             'version'            => \$option_version,
 597             # Hardening options.
 598             'pie'                => \$option_pie,
 599             'bindnow'            => \$option_bindnow,
 600             'all'                => \$option_all,
 601             # Ignore.
 602             'ignore-arch=s'      => \@option_ignore_arch,
 603             'ignore-flag=s'      => \@option_ignore_flag,
 604             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 605             'ignore-line=s'      => \@option_ignore_line,
 606             'ignore-arch-line=s' => \@option_ignore_arch_line,
 607             # Misc.
 608             'color'              => \$option_color,
 609             'arch=s'             => \$option_arch,
 610             'buildd'             => \$option_buildd,
 611         )) {
 612     require Pod::Usage;
 613     Pod::Usage::pod2usage(2);
 614 }
 615 if ($option_help) {
 616     require Pod::Usage;
 617     Pod::Usage::pod2usage(1);
 618 }
 619 if ($option_version) {
 620     print <<"EOF";
 621 blhc $VERSION  Copyright (C) 2012-2016  Simon Ruderich
 622
 623 This program is free software: you can redistribute it and/or modify
 624 it under the terms of the GNU General Public License as published by
 625 the Free Software Foundation, either version 3 of the License, or
 626 (at your option) any later version.
 627
 628 This program is distributed in the hope that it will be useful,
 629 but WITHOUT ANY WARRANTY; without even the implied warranty of
 630 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 631 GNU General Public License for more details.
 632
 633 You should have received a copy of the GNU General Public License
 634 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 635 EOF
 636     exit 0;
 637 }
 638
 639 # Arguments missing.
 640 if (scalar @ARGV == 0) {
 641     require Pod::Usage;
 642     Pod::Usage::pod2usage(2);
 643 }
 644
 645 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 646 # installed on Debian's buildds.
 647 if (not $option_buildd) {
 648     require Term::ANSIColor;
 649 }
 650
 651 if ($option_all) {
 652     $option_pie     = 1;
 653     $option_bindnow = 1;
 654 }
 655
 656 # Precompiled ignores for faster lookup.
 657 my %option_ignore_arch_flag = ();
 658 my %option_ignore_arch_line = ();
 659
 660 # Strip flags which should be ignored.
 661 if (scalar @option_ignore_flag > 0) {
 662     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 663 }
 664 # Same for arch specific ignore flags, but only prepare here.
 665 if (scalar @option_ignore_arch_flag > 0) {
 666     foreach my $ignore (@option_ignore_arch_flag) {
 667         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 668
 669         if (not $ignore_arch or not $ignore_flag) {
 670             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 671                         . '("arch:flag" expected)' . "\n", $ignore;
 672             require Pod::Usage;
 673             Pod::Usage::pod2usage(2);
 674         }
 675
 676         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 677     }
 678 }
 679
 680 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 681 # faster with this.
 682 foreach my $flags (@flag_refs_all) {
 683     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 684 }
 685
 686 # Precompile ignore line regexps, also anchor at beginning and end of line.
 687 foreach my $ignore (@option_ignore_line) {
 688     $ignore = qr/^$ignore$/;
 689 }
 690 # Same for arch specific ignore lines.
 691 if (scalar @option_ignore_arch_line > 0) {
 692     foreach my $ignore (@option_ignore_arch_line) {
 693         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 694
 695         if (not $ignore_arch or not $ignore_line) {
 696             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 697                         . '("arch:line" expected)' . "\n", $ignore;
 698             require Pod::Usage;
 699             Pod::Usage::pod2usage(2);
 700         }
 701
 702         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 703     }
 704 }
 705
 706 # Final exit code.
 707 my $exit = 0;
 708
 709 FILE:
 710 foreach my $file (@ARGV) {
 711     print "checking '$file'...\n" if scalar @ARGV > 1;
 712
 713     -f $file or die "No such file: $file";
 714
 715     open my $fh, '<', $file or die $!;
 716
 717     # Architecture of this file.
 718     my $arch = $option_arch;
 719
 720     # Hardening options. Not all architectures support all hardening options.
 721     my $harden_format  = 1;
 722     my $harden_fortify = 1;
 723     my $harden_stack   = 1;
 724     my $harden_stack_strong = 1;
 725     my $harden_relro   = 1;
 726     my $harden_bindnow = $option_bindnow; # defaults to 0
 727     my $harden_pie     = $option_pie;     # defaults to 0
 728
 729     # Does this build log use ada? Ada also uses gcc as compiler but uses
 730     # different CFLAGS. But only perform ada checks if an ada compiler is used
 731     # for performance reasons.
 732     my $ada = 0;
 733
 734     # Number of parallel jobs to prevent false positives when detecting
 735     # non-verbose builds. As not all jobs declare the number of parallel jobs
 736     # use a large enough default.
 737     my $parallel = 10;
 738
 739     while (my $line = <$fh>) {
 740         # Detect architecture automatically unless overridden. For buildd logs
 741         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 742         # build logs which aren't built (wrong architecture, build error,
 743         # etc.).
 744         if (not $arch) {
 745             if (index($line, 'Build Architecture: ') == 0) {
 746                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 747             # For old logs (sbuild << 0.63.0-1).
 748             } elsif (index($line, 'Architecture: ') == 0) {
 749                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 750             }
 751         }
 752
 753         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 754         # check for hardening flags in buildd mode if an older dpkg-dev is
 755         # used. Default flags (-g -O2) are still checked.
 756         #
 757         # Packages which were built before 1.16.1 but used their own hardening
 758         # flags are not checked.
 759         #
 760         # Strong stack protector is used since dpkg 1.17.11.
 761         if ($option_buildd
 762                 and index($line, 'Toolchain package versions: ') == 0) {
 763             require Dpkg::Version;
 764
 765             my $disable = 1;
 766             my $disable_strong = 1;
 767
 768             if ($line =~ /\bdpkg-dev_(\S+)/) {
 769                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
 770                     $disable = 0;
 771                 }
 772                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
 773                     $disable_strong = 0;
 774                 }
 775             }
 776
 777             if ($disable) {
 778                 $harden_format  = 0;
 779                 $harden_fortify = 0;
 780                 $harden_stack   = 0;
 781                 $harden_relro   = 0;
 782                 $harden_bindnow = 0;
 783                 $harden_pie     = 0;
 784             }
 785             if ($disable_strong) {
 786                 $harden_stack_strong = 0;
 787             }
 788         }
 789
 790         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 791         # this was later dropped because upstream rejected the patch. Thus
 792         # build logs with these versions will have fortify hardening flags
 793         # enabled, even though they may be not correctly set and are missing
 794         # when build with later CMake versions. Thanks to Aron Xu for letting
 795         # me know.
 796         if (index($line, 'Package versions: ') == 0
 797                 and $line =~ /\bcmake_(\S+)/
 798                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 799             if (not $option_buildd) {
 800                 error_invalid_cmake($1);
 801                 $exit |= $exit_code{invalid_cmake};
 802             } else {
 803                 print "$buildd_tag{invalid_cmake}|$1|\n";
 804             }
 805         }
 806
 807         # Debian's build daemons use "Filtered Build-Depends:" (or just
 808         # "Build-Depends:" in older versions) for the build dependencies, but
 809         # pbuilder uses "Depends:"; support both.
 810         if (index($line, 'Filtered Build-Depends: ') == 0
 811                 or index($line, 'Build-Depends: ') == 0
 812                 or index($line, 'Depends: ') == 0) {
 813             # If hardening wrapper is used (wraps calls to gcc and adds
 814             # hardening flags automatically) we can't perform any checks,
 815             # abort.
 816             if ($line =~ /\bhardening-wrapper\b/) {
 817                 if (not $option_buildd) {
 818                     error_hardening_wrapper();
 819                     $exit |= $exit_code{hardening_wrapper};
 820                 } else {
 821                     print "$buildd_tag{hardening_wrapper}||\n";
 822                 }
 823                 next FILE;
 824             }
 825
 826             # Ada compiler.
 827             if ($line =~ /\bgnat\b/) {
 828                 $ada = 1;
 829             }
 830         }
 831
 832         # This flags is not always available, but if it is use it.
 833         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
 834             $parallel = $1;
 835         }
 836
 837         # We skip over unimportant lines at the beginning of the log to
 838         # prevent false positives.
 839         last if index($line, 'dpkg-buildpackage: ') == 0;
 840     }
 841
 842     # Input lines, contain only the lines with compiler commands.
 843     my @input = ();
 844     # Non-verbose lines in the input. Used to reduce calls to
 845     # is_non_verbose_build() (which is quite slow) in the second loop when
 846     # it's already clear if a line is non-verbose or not.
 847     my @input_nonverbose = ();
 848
 849     my $continuation = 0;
 850     my $complete_line = undef;
 851     my $non_verbose;
 852     while (my $line = <$fh>) {
 853         # And stop at the end of the build log. Package details (reported by
 854         # the buildd logs) are not important for us. This also prevents false
 855         # positives.
 856         last if index($line, 'Build finished at ') == 0
 857                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 858
 859         if (not $continuation) {
 860             $non_verbose = 0;
 861         }
 862
 863         # Detect architecture automatically unless overridden.
 864         if (not $arch
 865                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 866             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 867
 868             # Old buildd logs use e.g. "host architecture is alpha", remove
 869             # the "is", otherwise debarch_to_debtriplet() will not detect the
 870             # architecture.
 871             if (index($arch, 'is ') == 0) {
 872                 $arch = substr $arch, 3;
 873             }
 874         }
 875
 876         next if $line =~ /^\s*#/;
 877         # Ignore compiler warnings for now.
 878         next if $line =~ /$warning_regex/o;
 879
 880         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 881             # Remove all ANSI color sequences which are sometimes used in
 882             # non-verbose builds.
 883             $line = Term::ANSIColor::colorstrip($line);
 884             # Also strip '\0xf' (delete previous character), used by Elinks'
 885             # build system.
 886             $line =~ s/\x0f//g;
 887             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 888             # what it does).
 889             $line =~ s/\033\(B//g;
 890         }
 891
 892         # Check if this line indicates a non verbose build.
 893         my $skip = 0;
 894         $non_verbose |= is_non_verbose_build($line, \$skip);
 895         next if $skip;
 896
 897         # One line may contain multiple commands (";"). Treat each one as
 898         # single line. parse_line() is slow, only use it when necessary.
 899         my @line = (index($line, ';') == -1)
 900                  ? ($line)
 901                  : map {
 902                        # Ensure newline at the line end - necessary for
 903                        # correct parsing later.
 904                        $_ =~ s/\s+$//;
 905                        $_ .= "\n";
 906                    } Text::ParseWords::parse_line(';', 1, $line);
 907         foreach my $line (@line) {
 908             if ($continuation) {
 909                 $continuation = 0;
 910
 911                 # Join lines, but leave the "\" in place so it's clear where
 912                 # the original line break was.
 913                 chomp $complete_line;
 914                 $complete_line .= ' ' . $line;
 915             }
 916             # Line continuation, line ends with "\".
 917             if ($line =~ /\\$/) {
 918                 $continuation = 1;
 919                 # Start line continuation.
 920                 if (not defined $complete_line) {
 921                     $complete_line = $line;
 922                 }
 923                 next;
 924             }
 925
 926             # Use the complete line if a line continuation occurred.
 927             if (defined $complete_line) {
 928                 $line = $complete_line;
 929                 $complete_line = undef;
 930             }
 931
 932             # Ignore lines with no compiler commands.
 933             next if not $non_verbose
 934                     and not $line =~ /$cc_regex_normal/o;
 935             # Ignore lines with no filenames with extensions. May miss some
 936             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
 937             # a problem as the log will most likely contain other non-verbose
 938             # commands which are detected.
 939             next if not $non_verbose
 940                     and not $line =~ /$file_extension_regex/o;
 941
 942             # Ignore false positives.
 943             #
 944             # `./configure` output.
 945             next if not $non_verbose
 946                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
 947             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 948                                 [Cc]ompiler[\s.]*:?\s+
 949                                 /x;
 950             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
 951                                 \s*=\s*$cc_regex_full
 952                                 # optional compiler options, don't allow
 953                                 # "everything" here to prevent false negatives
 954                                 \s*(?:\s-\S+)*\s*$}xo;
 955             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
 956             # line (or similar for other architectures) which gets recognized
 957             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
 958             # C++ files. No hardening flags are relevant during this step,
 959             # thus ignore `moc-qt*` lines. The resulting files will be
 960             # compiled in a separate step (and therefore checked).
 961             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
 962                                \s.+\s
 963                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
 964                                \s}x;
 965             # Ignore false positives when the line contains only CC=gcc but no
 966             # other gcc command.
 967             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
 968                 my $before = $1;
 969                 my $after  = $2;
 970                 next if     not $before =~ /$cc_regex_normal/o
 971                         and not $after  =~ /$cc_regex_normal/o;
 972             }
 973             # Ignore false positives caused by gcc -v. It outputs a line
 974             # looking like a normal compiler line but which is sometimes
 975             # missing hardening flags, although the normal compiler line
 976             # contains them.
 977             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
 978                                    [0-9.]+/cc1(?:plus)?}xo;
 979             # Ignore false positive with `rm` which may remove files which
 980             # look like a compiler executable thus causing the line to be
 981             # treated as a normal compiler line.
 982             next if $line =~ m{^\s*rm\s+};
 983             # Some build systems emit "gcc > file".
 984             next if $line =~ m{$cc_regex_normal\s*>\s*\S+};
 985
 986             # Check if additional hardening options were used. Used to ensure
 987             # they are used for the complete build.
 988             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
 989                                                          @def_ldflags_pie);
 990             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 991
 992             push @input, $line;
 993             push @input_nonverbose, $non_verbose;
 994         }
 995     }
 996
 997     close $fh or die $!;
 998
 999     # Ignore arch if requested.
1000     if (scalar @option_ignore_arch > 0 and $arch) {
1001         foreach my $ignore (@option_ignore_arch) {
1002             if ($arch eq $ignore) {
1003                 print "ignoring architecture '$arch'\n";
1004                 next FILE;
1005             }
1006         }
1007     }
1008
1009     if (scalar @input == 0) {
1010         if (not $option_buildd) {
1011             print "No compiler commands!\n";
1012             $exit |= $exit_code{no_compiler_commands};
1013         } else {
1014             print "$buildd_tag{no_compiler_commands}||\n";
1015         }
1016         next FILE;
1017     }
1018
1019     if ($option_buildd) {
1020         $statistics{commands} += scalar @input;
1021     }
1022
1023     # Option or auto detected.
1024     if ($arch) {
1025         # The following was partially copied from dpkg-dev 1.18.10
1026         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, _add_hardening_flags()),
1027         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
1028         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
1029         # later. Keep it in sync.
1030
1031         require Dpkg::Arch;
1032         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1033
1034         # Disable unsupported hardening options.
1035         if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/
1036                 or $cpu =~ /^(?:hppa|avr32)$/) {
1037             $harden_pie = 0;
1038         }
1039         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1040             $harden_stack = 0;
1041             $harden_stack_strong = 0;
1042         }
1043         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1044             $harden_relro   = 0;
1045             $harden_bindnow = 0;
1046         }
1047     }
1048
1049     # Default values.
1050     my @cflags   = @def_cflags;
1051     my @cxxflags = @def_cxxflags;
1052     my @cppflags = @def_cppflags;
1053     my @ldflags  = @def_ldflags;
1054     # Check the specified hardening options, same order as dpkg-buildflags.
1055     if ($harden_pie) {
1056         @cflags   = (@cflags,   @def_cflags_pie);
1057         @cxxflags = (@cxxflags, @def_cflags_pie);
1058         @ldflags  = (@ldflags,  @def_ldflags_pie);
1059     }
1060     if ($harden_stack_strong) {
1061         @cflags   = (@cflags,   @def_cflags_stack_strong);
1062         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1063     } elsif ($harden_stack) {
1064         @cflags   = (@cflags,   @def_cflags_stack);
1065         @cxxflags = (@cxxflags, @def_cflags_stack);
1066     }
1067     if ($harden_fortify) {
1068         @cflags   = (@cflags,   @def_cflags_fortify);
1069         @cxxflags = (@cxxflags, @def_cflags_fortify);
1070         @cppflags = (@cppflags, @def_cppflags_fortify);
1071     }
1072     if ($harden_format) {
1073         @cflags   = (@cflags,   @def_cflags_format);
1074         @cxxflags = (@cxxflags, @def_cflags_format);
1075     }
1076     if ($harden_relro) {
1077         @ldflags = (@ldflags, @def_ldflags_relro);
1078     }
1079     if ($harden_bindnow) {
1080         @ldflags = (@ldflags, @def_ldflags_bindnow);
1081     }
1082
1083     # Stores normal CFLAGS when @cflags_ada are temporarily used.
1084     my @cflags_backup;
1085     # Ada CFLAGS, only set if ada is used.
1086     my @cflags_ada;
1087     # Ada doesn't support format hardening flags, see #680117 for more
1088     # information. Filter them out if ada is used.
1089     if ($ada and $harden_format) {
1090         @cflags_ada = grep {
1091             my $ok = 1;
1092             foreach my $flag (@def_cflags_format) {
1093                 $ok = 0 if $_ eq $flag;
1094             }
1095             $ok;
1096         } @cflags;
1097     }
1098
1099     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1100     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1101     # as long as @def_cppflags_fortify contains only one variable.
1102     if (scalar @def_cppflags_fortify == 0) {
1103         $harden_fortify = 0;
1104     }
1105
1106     # Ignore flags for this arch if requested.
1107     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1108         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1109
1110         remove_flags(\@local_flag_refs,
1111                      \%flag_renames,
1112                      @{$option_ignore_arch_flag{$arch}});
1113     }
1114
1115     my @ignore_line = @option_ignore_line;
1116     # Ignore lines for this arch if requested.
1117     if ($arch and exists $option_ignore_arch_line{$arch}) {
1118         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1119     }
1120
1121 LINE:
1122     for (my $i = 0; $i < scalar @input; $i++) {
1123         my $line = $input[$i];
1124
1125         # Ignore line if requested.
1126         foreach my $ignore (@ignore_line) {
1127             next LINE if $line =~ /$ignore/;
1128         }
1129
1130         my $skip = 0;
1131         if ($input_nonverbose[$i]
1132                 and is_non_verbose_build($line, \$skip,
1133                                          \@input, $i, $parallel)) {
1134             if (not $option_buildd) {
1135                 error_non_verbose_build($line);
1136                 $exit |= $exit_code{non_verbose_build};
1137             } else {
1138                 $statistics{commands_nonverbose}++;
1139             }
1140             next;
1141         }
1142         # Even if it's a verbose build, we might have to skip this line (see
1143         # is_non_verbose_build()).
1144         next if $skip;
1145
1146         my $orig_line = $line;
1147
1148         # Remove everything until and including the compiler command. Makes
1149         # checks easier and faster.
1150         $line =~ s/^.*?$cc_regex//o;
1151         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1152         # the brace and similar characters at the line end.
1153         $line =~ s/['")]+$//;
1154
1155         # Skip unnecessary tests when only preprocessing.
1156         my $flag_preprocess = 0;
1157
1158         my $dependency = 0;
1159         my $preprocess = 0;
1160         my $compile    = 0;
1161         my $link       = 0;
1162
1163         # Preprocess, compile, assemble.
1164         if ($line =~ /\s(-E|-S|-c)\b/) {
1165             $preprocess      = 1;
1166             $flag_preprocess = 1 if $1 eq '-E';
1167             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1168         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1169         # -MT -MQ) are always used with -M/-MM.
1170         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1171             $dependency = 1;
1172         # Otherwise assume we are linking.
1173         } else {
1174             $link = 1;
1175         }
1176
1177         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1178         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1179             $dependency      = 0;
1180             $flag_preprocess = 0;
1181         }
1182
1183         # Dependency generation for Makefiles, no preprocessing or other flags
1184         # needed.
1185         next if $dependency;
1186
1187         # Get all file extensions on this line.
1188         my @extensions = $line =~ /$file_extension_regex/go;
1189         # Ignore all unknown extensions to speedup the search below.
1190         @extensions = grep { exists $extension{$_} } @extensions;
1191
1192         # These file types don't require preprocessing.
1193         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1194             $preprocess = 0;
1195         }
1196         # These file types require preprocessing.
1197         if (extension_found(\%extensions_preprocess, @extensions)) {
1198             # Prevent false positives with "libtool: link: g++ -include test.h
1199             # .." compiler lines.
1200             if ($orig_line !~ /$libtool_link_regex/o) {
1201                 $preprocess = 1;
1202             }
1203         }
1204
1205         if (not $flag_preprocess) {
1206             # If there are source files then it's compiling/linking in one
1207             # step and we must check both. We only check for source files
1208             # here, because header files cause too many false positives.
1209             if (extension_found(\%extensions_compile_link, @extensions)) {
1210                 # Assembly files don't need CFLAGS.
1211                 if (not extension_found(\%extensions_compile, @extensions)
1212                         and extension_found(\%extensions_no_compile, @extensions)) {
1213                     $compile = 0;
1214                 # But the rest does.
1215                 } else {
1216                     $compile = 1;
1217                 }
1218             # No compilable extensions found, either linking or compiling
1219             # header flags.
1220             #
1221             # If there are also no object files we are just compiling headers
1222             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1223             # to our liberal checks for compiler lines, this also reduces the
1224             # number of false positives considerably.
1225             } elsif ($link
1226                     and not extension_found(\%extensions_object, @extensions)) {
1227                 $link = 0;
1228             }
1229         }
1230
1231         my $compile_cpp = 0;
1232         my $compile_ada = 0;
1233         # Assume CXXFLAGS are required when a C++ file is specified in the
1234         # compiler line.
1235         if ($compile
1236                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1237             $compile     = 0;
1238             $compile_cpp = 1;
1239         # Ada needs special CFLAGS, use them if only ada files are compiled.
1240         } elsif ($ada
1241                 and extension_found(\%extensions_ada, @extensions)) {
1242             $compile_ada = 1;
1243             $preprocess = 0; # Ada uses no CPPFLAGS
1244             @cflags_backup = @cflags;
1245             @cflags        = @cflags_ada;
1246         }
1247
1248         if ($option_buildd) {
1249             $statistics{preprocess}++  if $preprocess;
1250             $statistics{compile}++     if $compile;
1251             $statistics{compile_cpp}++ if $compile_cpp;
1252             $statistics{link}++        if $link;
1253         }
1254
1255         # Check if there are flags indicating a debug build. If that's true,
1256         # skip the check for -O2. This prevents fortification, but that's fine
1257         # for a debug build.
1258         if (any_flags_used($line, @def_cflags_debug)) {
1259             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1260             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1261         }
1262
1263         # Check hardening flags.
1264         my @missing;
1265         if ($compile and not all_flags_used($line, \@missing, @cflags)
1266                 # Libraries linked with -fPIC don't have to (and can't) be
1267                 # linked with -fPIE as well. It's no error if only PIE flags
1268                 # are missing.
1269                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1270                 # Assume dpkg-buildflags returns the correct flags.
1271                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1272             if (not $option_buildd) {
1273                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1274                 $exit |= $exit_code{flags_missing};
1275             } else {
1276                 $statistics{compile_missing}++;
1277             }
1278         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1279                 # Libraries linked with -fPIC don't have to (and can't) be
1280                 # linked with -fPIE as well. It's no error if only PIE flags
1281                 # are missing.
1282                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1283                 # Assume dpkg-buildflags returns the correct flags.
1284                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1285             if (not $option_buildd) {
1286                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1287                 $exit |= $exit_code{flags_missing};
1288             } else {
1289                 $statistics{compile_cpp_missing}++;
1290             }
1291         }
1292         if ($preprocess
1293                 and (not all_flags_used($line, \@missing, @cppflags)
1294                     # The fortify flag might be overwritten, detect that.
1295                      or ($harden_fortify
1296                          and cppflags_fortify_broken($line, \@missing)))
1297                 # Assume dpkg-buildflags returns the correct flags.
1298                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1299             if (not $option_buildd) {
1300                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1301                 $exit |= $exit_code{flags_missing};
1302             } else {
1303                 $statistics{preprocess_missing}++;
1304             }
1305         }
1306         if ($link and not all_flags_used($line, \@missing, @ldflags)
1307                 # Same here, -fPIC conflicts with -fPIE.
1308                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1309                 # Assume dpkg-buildflags returns the correct flags.
1310                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1311             if (not $option_buildd) {
1312                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1313                 $exit |= $exit_code{flags_missing};
1314             } else {
1315                 $statistics{link_missing}++;
1316             }
1317         }
1318
1319         # Restore normal CFLAGS.
1320         if ($compile_ada) {
1321             @cflags = @cflags_backup;
1322         }
1323     }
1324 }
1325
1326 # Print statistics for buildd mode, only output in this mode.
1327 if ($option_buildd) {
1328     my @warning;
1329
1330     if ($statistics{preprocess_missing}) {
1331         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1332                                $statistics{preprocess_missing},
1333                                $statistics{preprocess};
1334     }
1335     if ($statistics{compile_missing}) {
1336         push @warning, sprintf 'CFLAGS %d (of %d)',
1337                                $statistics{compile_missing},
1338                                $statistics{compile};
1339     }
1340     if ($statistics{compile_cpp_missing}) {
1341         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1342                                $statistics{compile_cpp_missing},
1343                                $statistics{compile_cpp};
1344     }
1345     if ($statistics{link_missing}) {
1346         push @warning, sprintf 'LDFLAGS %d (of %d)',
1347                                $statistics{link_missing},
1348                                $statistics{link};
1349     }
1350     if (scalar @warning) {
1351         local $" = ', '; # array join string
1352         print "$buildd_tag{flags_missing}|@warning missing|\n";
1353     }
1354
1355     if ($statistics{commands_nonverbose}) {
1356         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1357                $statistics{commands_nonverbose},
1358                $statistics{commands},
1359     }
1360 }
1361
1362
1363 exit $exit;
1364
1365
1366 __END__
1367
1368 =head1 NAME
1369
1370 blhc - build log hardening check, checks build logs for missing hardening flags
1371
1372 =head1 SYNOPSIS
1373
1374 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1375
1376 =head1 DESCRIPTION
1377
1378 blhc is a small tool which checks build logs for missing hardening flags. It's
1379 licensed under the GPL 3 or later.
1380
1381 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1382 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1383 official buildd build logs)) to help maintainers detect missing hardening
1384 flags in their packages.
1385
1386 Only gcc is detected as compiler at the moment. If other compilers support
1387 hardening flags as well, please report them.
1388
1389 If there's no output, no flags are missing and the build log is fine.
1390
1391 See F<README> for details about performed checks, auto-detection and
1392 limitations.
1393
1394 =head1 OPTIONS
1395
1396 =over 8
1397
1398 =item B<--all>
1399
1400 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1401 auto detected.
1402
1403 =item B<--arch> I<architecture>
1404
1405 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1406 disables hardening flags not available on this architecture. Is detected
1407 automatically if dpkg-buildpackage is used.
1408
1409 =item B<--bindnow>
1410
1411 Force check for all +bindnow hardening flags. By default it's auto detected.
1412
1413 =item B<--buildd>
1414
1415 Special mode for buildds when automatically parsing log files. The following
1416 changes are in effect:
1417
1418 =over 2
1419
1420 =item *
1421
1422 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1423 possible tags.
1424
1425 =item *
1426
1427 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1428 detected).
1429
1430 =item *
1431
1432 Don't require Term::ANSIColor.
1433
1434 =item *
1435
1436 Return exit code 0, unless there was a error (-I, -W messages don't count as
1437 error).
1438
1439 =back
1440
1441 =item B<--color>
1442
1443 Use colored (ANSI) output for warning messages.
1444
1445 =item B<--ignore-arch> I<arch>
1446
1447 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1448
1449 Used to prevent false positives. This option can be specified multiple times.
1450
1451 =item B<--ignore-arch-flag> I<arch>:I<flag>
1452
1453 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1454
1455 =item B<--ignore-arch-line> I<arch>:I<line>
1456
1457 Like B<--ignore-line>, but only ignore line on I<arch>.
1458
1459 =item B<--ignore-flag> I<flag>
1460
1461 Don't print an error when the specific flag is missing in a compiler line.
1462 I<flag> is a string.
1463
1464 Used to prevent false positives. This option can be specified multiple times.
1465
1466 =item B<--ignore-line> I<regex>
1467
1468 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1469 at the beginning and end of the line to prevent false negatives.
1470
1471 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1472 warnings (which have line continuation resolved).
1473
1474 Used to prevent false positives. This option can be specified multiple times.
1475
1476 =item B<--pie>
1477
1478 Force check for all +pie hardening flags. By default it's auto detected.
1479
1480 =item B<-h -? --help>
1481
1482 Print available options.
1483
1484 =item B<--version>
1485
1486 Print version number and license.
1487
1488 =back
1489
1490 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1491 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1492 all other commands as well.
1493
1494 =head1 EXAMPLES
1495
1496 Normal usage, parse a single log file.
1497
1498     blhc path/to/log/file
1499
1500 If there's no output, no flags are missing and the build log is fine.
1501
1502 Parse multiple log files. The exit code is ORed over all files.
1503
1504     blhc path/to/directory/with/log/files/*
1505
1506 Don't treat missing C<-g> as error:
1507
1508     blhc --ignore-flag -g path/to/log/file
1509
1510 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1511
1512     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1513
1514 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1515 false positive.
1516
1517     blhc --ignore-line '\./script gcc file' path/to/log/file
1518
1519 Ignore lines matching C<./script gcc file> somewhere in the line.
1520
1521     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1522
1523 Use blhc with pbuilder.
1524
1525     pbuilder path/to/package.dsc | tee path/log/file
1526     blhc path/to/file || echo flags missing
1527
1528 =head1 BUILDD TAGS
1529
1530 The following tags are used in I<--buildd> mode. In braces the additional data
1531 which is displayed.
1532
1533 =over 2
1534
1535 =item B<I-hardening-wrapper-used>
1536
1537 The package uses hardening-wrapper which intercepts calls to gcc and adds
1538 hardening flags. The build log doesn't contain any hardening flags and thus
1539 can't be checked by blhc.
1540
1541 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1542
1543 Build log contains lines which hide the real compiler flags. For example:
1544
1545     CC test-a.c
1546     CC test-b.c
1547     CC test-c.c
1548     LD test
1549
1550 Most of the time either C<export V=1> or C<export verbose=1> in
1551 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1552 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1553 patched to remove the C<@>s hiding the real compiler commands.
1554
1555 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1556
1557 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1558
1559 =item B<I-invalid-cmake-used> (version)
1560
1561 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1562 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1563 patch was rejected by upstream and later reverted in Debian. Thus those two
1564 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1565 handle them (for example by passing them to CFLAGS). To prevent false
1566 negatives just blacklist those two versions.
1567
1568 =item B<I-no-compiler-commands>
1569
1570 No compiler commands were detected. Either the log contains none or they were
1571 not correctly detected by blhc (please report the bug in this case).
1572
1573 =back
1574
1575 =head1 EXIT STATUS
1576
1577 The exit status is a "bit mask", each listed status is ORed when the error
1578 condition occurs to get the result.
1579
1580 =over 4
1581
1582 =item B<0>
1583
1584 Success.
1585
1586 =item B<1>
1587
1588 No compiler commands were found.
1589
1590 =item B<2>
1591
1592 Invalid arguments/options given to blhc.
1593
1594 =item B<4>
1595
1596 Non verbose build.
1597
1598 =item B<8>
1599
1600 Missing hardening flags.
1601
1602 =item B<16>
1603
1604 Hardening wrapper detected, no tests performed.
1605
1606 =item B<32>
1607
1608 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1609 TAGS"> for a detailed explanation.
1610
1611 =back
1612
1613 =head1 AUTHOR
1614
1615 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1616
1617 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1618 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1619
1620 =head1 LICENSE AND COPYRIGHT
1621
1622 Copyright (C) 2012-2016 by Simon Ruderich
1623
1624 This program is free software: you can redistribute it and/or modify
1625 it under the terms of the GNU General Public License as published by
1626 the Free Software Foundation, either version 3 of the License, or
1627 (at your option) any later version.
1628
1629 This program is distributed in the hope that it will be useful,
1630 but WITHOUT ANY WARRANTY; without even the implied warranty of
1631 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1632 GNU General Public License for more details.
1633
1634 You should have received a copy of the GNU General Public License
1635 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1636
1637 =head1 SEE ALSO
1638
1639 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1640
1641 =cut