bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Term::ANSIColor ();
  26 use Text::ParseWords ();
  27
  28 our $VERSION = '0.01';
  29
  30
  31 # CONSTANTS/VARIABLES
  32
  33 # Regex to catch compiler commands.
  34 my $cc_regex = qr/(?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  35                   (?<!\.)(?:cc|gcc|g\+\+|c\+\+)
  36                   (?:-[\d.]+)?/x;
  37 # Regex to catch (GCC) compiler warnings.
  38 my $warning_regex = qr/^(.+?):([0-9]+):[0-9]+: warning: (.+?) \[(.+?)\]$/;
  39
  40 # List of source file extensions which require preprocessing.
  41 my @source_preprocess_compile_cpp = (
  42     # C++
  43     qw( cc cp cxx cpp CPP c++ C ),
  44     # Objective-C++
  45     qw( mm Mr),
  46 );
  47 my @source_preprocess_compile = (
  48     # C
  49     qw( c ),
  50     # Objective-C
  51     qw( m ),
  52     # (Objective-)C++
  53     @source_preprocess_compile_cpp,
  54     # Fortran
  55     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  56 );
  57 my @source_preprocess_no_compile = (
  58     # Assembly
  59     qw( s ),
  60 );
  61 my @source_preprocess = (
  62     @source_preprocess_compile,
  63     @source_preprocess_no_compile,
  64 );
  65 # List of source file extensions which don't require preprocessing.
  66 my @source_no_preprocess_compile_cpp = (
  67     # C++
  68     qw( ii ),
  69     # Objective-C++
  70     qw( mii ),
  71 );
  72 my @source_no_preprocess_compile = (
  73     # C
  74     qw( i ),
  75     # (Objective-)C++
  76     @source_no_preprocess_compile_cpp,
  77     # Objective-C
  78     qw( mi ),
  79     # Fortran
  80     qw( f for ftn f90 f95 f03 f08 ),
  81 );
  82 my @source_no_preprocess_no_compile = (
  83     # Assembly
  84     qw( S sx ),
  85 );
  86 my @source_no_preprocess = (
  87     @source_no_preprocess_compile,
  88     @source_no_preprocess_no_compile,
  89 );
  90 # List of header file extensions which require preprocessing.
  91 my @header_preprocess = (
  92     # C, C++, Objective-C, Objective-C++
  93     qw( h ),
  94     # C++
  95     qw( hh H hp hxx hpp HPP h++ tcc ),
  96 );
  97
  98 # Hashes for fast extensions lookup to check if a file falls in one of these
  99 # categories.
 100 my %extensions_no_preprocess = map { $_ => 1 } (
 101     @source_no_preprocess,
 102 );
 103 my %extensions_preprocess = map { $_ => 1 } (
 104     @header_preprocess,
 105     @source_preprocess,
 106 );
 107 my %extensions_compile_link = map { $_ => 1 } (
 108     @source_preprocess,
 109     @source_no_preprocess,
 110 );
 111 my %extensions_compile = map { $_ => 1 } (
 112     @source_preprocess_compile,
 113     @source_no_preprocess_compile,
 114 );
 115 my %extensions_no_compile = map { $_ => 1 } (
 116     @source_preprocess_no_compile,
 117     @source_no_preprocess_no_compile,
 118 );
 119 my %extensions_compile_cpp = map { $_ => 1 } (
 120     @source_preprocess_compile_cpp,
 121     @source_no_preprocess_compile_cpp,
 122 );
 123 my %extension = map { $_ => 1 } (
 124     @source_no_preprocess,
 125     @source_no_preprocess_compile,
 126     @source_no_preprocess_compile_cpp,
 127     @source_no_preprocess_no_compile,
 128     @header_preprocess,
 129     @source_preprocess,
 130     @source_preprocess_compile,
 131     @source_preprocess_compile_cpp,
 132     @source_preprocess_no_compile,
 133 );
 134
 135 # Regexp to match file extensions.
 136 my $file_extension_regex = qr/
 137     \s
 138     \S+         # Filename without extension.
 139     \.
 140     ([^\\.\s]+) # File extension.
 141     (?=\s|\\)   # At end of word. Can't use \b because some files have non
 142                 # word characters at the end and because \b matches double
 143                 # extensions (like .cpp.o). Works always as all lines are
 144                 # terminated with "\n".
 145     /x;
 146
 147 # Expected (hardening) flags. All flags are used as regexps.
 148 my @cflags = (
 149     '-g',
 150     '-O(?:2|3)',
 151 );
 152 my @cflags_format = (
 153     '-Wformat',
 154     '-Wformat-security',
 155     '-Werror=format-security',
 156 );
 157 my @cflags_fortify = (
 158     # fortify needs at least -O1, but -O2 is recommended anyway
 159 );
 160 my @cflags_stack = (
 161     '-fstack-protector',
 162     '--param=ssp-buffer-size=4',
 163 );
 164 my @cflags_pie = (
 165     '-fPIE',
 166 );
 167 my @cxxflags = (
 168     '-g',
 169     '-O(?:2|3)',
 170 );
 171 # @cxxflags_* is the same as @cflags_*.
 172 my @cppflags = ();
 173 my @cppflags_fortify = (
 174     '-D_FORTIFY_SOURCE=2',
 175 );
 176 my @ldflags = ();
 177 my @ldflags_relro = (
 178     '-Wl,(-z,)?relro',
 179 );
 180 my @ldflags_bindnow = (
 181     '-Wl,(-z,)?now',
 182 );
 183 my @ldflags_pie = (
 184     '-fPIE',
 185     '-pie',
 186 );
 187 # Renaming rules for the output so the regex parts are not visible.
 188 my %flag_renames = (
 189     '-O(?:2|3)'       => '-O2',
 190     '-Wl,(-z,)?relro' => '-Wl,-z,relro',
 191     '-Wl,(-z,)?now'   => '-Wl,-z,now',
 192 );
 193
 194 # Use colored (ANSI) output?
 195 my $option_color;
 196
 197
 198 # FUNCTIONS
 199
 200 sub error_flags {
 201     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 202
 203     # Rename flags if requested.
 204     my @missing_flags = map {
 205         (exists $flag_renames_ref->{$_})
 206             ? $flag_renames_ref->{$_}
 207             : $_
 208     } @{$missing_flags_ref};
 209
 210     my $flags = join ' ', @missing_flags;
 211     printf "%s (%s)%s %s",
 212            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 213            $line;
 214 }
 215 sub error_non_verbose_build {
 216     my ($line) = @_;
 217
 218     printf "%s%s %s",
 219            error_color('NONVERBOSE BUILD', 'red'),
 220            error_color(':', 'yellow'),
 221            $line;
 222 }
 223 sub error_hardening_wrapper {
 224     printf "%s%s %s\n",
 225             error_color('HARDENING WRAPPER', 'red'),
 226             error_color(':', 'yellow'),
 227             'no checks possible, aborting';
 228 }
 229 sub error_color {
 230     my ($message, $color) = @_;
 231
 232     if ($option_color) {
 233         return Term::ANSIColor::colored($message, $color);
 234     } else {
 235         return $message;
 236     }
 237 }
 238
 239 sub any_flags_used {
 240     my ($line, @flags) = @_;
 241
 242     foreach my $flag (@flags) {
 243         return 1 if $line =~ /\s$flag(?:\s|\\)/;
 244     }
 245
 246     return 0;
 247 }
 248 sub all_flags_used {
 249     my ($line, $missing_flags_ref, @flags) = @_;
 250
 251     my @missing_flags = ();
 252     foreach my $flag (@flags) {
 253         if ($line !~ /\s$flag(?:\s|\\)/) {
 254             push @missing_flags, $flag;
 255         }
 256     }
 257
 258     return 1 if scalar @missing_flags == 0;
 259
 260     @{$missing_flags_ref} = @missing_flags;
 261     return 0;
 262 }
 263
 264 # Modifies $missing_flags_ref array.
 265 sub pic_pie_conflict {
 266     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 267
 268     return 0 if not $pie;
 269     return 0 if not any_flags_used($line, ('-fPIC', '-fpic'));
 270
 271     my %flags = map { $_ => 1 } @flags_pie;
 272
 273     # Remove all PIE flags from @missing_flags as they are not required with
 274     # -fPIC.
 275     my @result = grep {
 276         not exists $flags{$_}
 277     } @{$missing_flags_ref};
 278     @{$missing_flags_ref} = @result;
 279
 280     # We got a conflict when no flags are left, thus only PIE flags were
 281     # missing. If other flags were missing abort because the conflict is not
 282     # the problem.
 283     return scalar @result == 0;
 284 }
 285
 286 sub is_non_verbose_build {
 287     my ($line, $next_line, $skip_ref) = @_;
 288
 289     if (not ($line =~ /^checking if you want to see long compiling messages\.\.\. no/
 290                 or $line =~ /^\s*\[?(?:CC|CCLD|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 291                 or $line =~ /^\s*(?:C|c)ompiling\s+(.+?)(?:\.\.\.)?$/
 292                 or $line =~ /^\s*(?:B|b)uilding (?:program|shared library)\s+(.+?)$/
 293                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 294         return 0;
 295     }
 296
 297     my $file = $1;
 298
 299     # On the first pass we only check if this line is verbose or not.
 300     return 1 if not defined $next_line;
 301
 302     # Second pass, we have access to the next line.
 303     ${$skip_ref} = 0;
 304
 305     # CMake and other build systems print the non-verbose messages also when
 306     # building verbose. If a compiler and the file name occurs in the next
 307     # line, treat it as verbose build.
 308     if (defined $file) {
 309         # Get filename, we can't use the complete path as only parts of it are
 310         # used in the real compiler command.
 311         $file =~ m{/([a-zA-Z0-9._-]+)$};
 312         $file = $1;
 313
 314         if ($next_line =~ /\Q$file\E/ and $next_line =~ /$cc_regex/) {
 315             # We still have to skip the current line as it doesn't contain any
 316             # compiler commands.
 317             ${$skip_ref} = 1;
 318             return 0;
 319         }
 320     }
 321
 322     return 1;
 323 }
 324
 325 sub extension_found {
 326     my ($extensions_ref, @extensions) = @_;
 327
 328     my $found = 0;
 329     foreach my $extension (@extensions) {
 330         if (exists $extensions_ref->{$extension}) {
 331             $found = 1;
 332             last;
 333         }
 334     }
 335     return $found;
 336 }
 337
 338
 339 # MAIN
 340
 341 # Hardening options. Not all architectures support all hardening options.
 342 my $harden_format  = 1;
 343 my $harden_fortify = 1;
 344 my $harden_stack   = 1;
 345 my $harden_relro   = 1;
 346 my $harden_bindnow = 0;
 347 my $harden_pie     = 0;
 348
 349 # Parse command line arguments.
 350 my $option_help    = 0;
 351 my $option_version = 0;
 352 my $option_all     = 0;
 353 my $option_arch    = undef;
 354 my $option_buildd  = 0;
 355    $option_color   = 0;
 356 if (not Getopt::Long::GetOptions(
 357             'help|h|?' => \$option_help,
 358             'version'  => \$option_version,
 359             # Hardening options.
 360             'pie'      => \$harden_pie,
 361             'bindnow'  => \$harden_bindnow,
 362             'all'      => \$option_all,
 363             # Misc.
 364             'color'    => \$option_color,
 365             'arch=s'   => \$option_arch,
 366             'buildd'   => \$option_buildd,
 367         )) {
 368     require Pod::Usage;
 369     Pod::Usage::pod2usage(2);
 370 }
 371 if ($option_help) {
 372     require Pod::Usage;
 373     Pod::Usage::pod2usage(1);
 374 }
 375 if ($option_version) {
 376     print "blhc $VERSION  Copyright (C) 2012  Simon Ruderich
 377
 378 This program is free software: you can redistribute it and/or modify
 379 it under the terms of the GNU General Public License as published by
 380 the Free Software Foundation, either version 3 of the License, or
 381 (at your option) any later version.
 382
 383 This program is distributed in the hope that it will be useful,
 384 but WITHOUT ANY WARRANTY; without even the implied warranty of
 385 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 386 GNU General Public License for more details.
 387
 388 You should have received a copy of the GNU General Public License
 389 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 390 ";
 391     exit 0;
 392 }
 393
 394 if ($option_all) {
 395     $harden_pie     = 1;
 396     $harden_bindnow = 1;
 397 }
 398
 399 # Final exit code.
 400 my $exit = 0;
 401
 402 # Input lines, contain only the lines with compiler commands.
 403 my @input = ();
 404
 405 my $start = 0;
 406 my $continuation = 0;
 407 my $complete_line = undef;
 408 while (my $line = <>) {
 409     # dpkg-buildflags only provides hardening flags since 1.16.1, don't check
 410     # for hardening flags in buildd mode if an older dpkg-dev is used. Default
 411     # flags (-g -O2) are still checked.
 412     #
 413     # Packages which were built before 1.16.1 but used their own hardening
 414     # flags are not checked.
 415     if ($option_buildd and not $start
 416             and $line =~ /^Toolchain package versions: /) {
 417         require Dpkg::Version;
 418         if ($line !~ /dpkg-dev_(\S+)/
 419                 or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
 420             $harden_format  = 0;
 421             $harden_fortify = 0;
 422             $harden_stack   = 0;
 423             $harden_relro   = 0;
 424             $harden_bindnow = 0;
 425             $harden_pie     = 0;
 426         }
 427     }
 428
 429     # If hardening wrapper is used (wraps calls to gcc and adds hardening
 430     # flags automatically) we can't perform any checks, abort.
 431     if (not $start and $line =~ /^Build-Depends: .*\bhardening-wrapper\b/) {
 432         error_hardening_wrapper();
 433         $exit |= 1 << 4;
 434         exit $exit;
 435     }
 436
 437     # We skip over unimportant lines at the beginning of the log to prevent
 438     # false positives.
 439     $start = 1 if $line =~ /^dpkg-buildpackage:/;
 440     next if not $start;
 441     # And stop at the end of the build log. Package details (reported by the
 442     # buildd logs) are not important for us. This also prevents false
 443     # positives.
 444     last if $line =~ /^Build finished at \d{8}-\d{4}$/;
 445
 446     # Detect architecture automatically unless overridden.
 447     if (not $option_arch
 448             and $line =~ /^dpkg-buildpackage: host architecture (.+)$/) {
 449         $option_arch = $1;
 450     }
 451
 452     # Ignore compiler warnings for now.
 453     next if $line =~ /$warning_regex/;
 454
 455     # Remove all ANSI color sequences which are sometimes used in non-verbose
 456     # builds.
 457     $line = Term::ANSIColor::colorstrip($line);
 458     # Also strip '\0xf' (delete previous character), used by Elinks' build
 459     # system.
 460     $line =~ s/\x0f//g;
 461     # And "ESC(B" which seems to be used on armhf and hurd (not sure what it
 462     # does).
 463     $line =~ s/\033\(B//g;
 464
 465     # Check if this line indicates a non verbose build.
 466     my $non_verbose = is_non_verbose_build($line);
 467
 468     # One line may contain multiple commands (";"). Treat each one as single
 469     # line. parse_line() is slow, only use it when necessary.
 470     my @line = (not $line =~ /;/)
 471              ? ($line)
 472              : Text::ParseWords::parse_line(';', 1, $line);
 473     foreach $line (@line) {
 474         # Add newline, drop all other whitespace at the end of a line.
 475         $line =~ s/\s+$//;
 476         $line .= "\n";
 477
 478         if ($continuation) {
 479             $continuation = 0;
 480
 481             # Join lines, but leave the "\" in place so it's clear where the
 482             # original line break was.
 483             chomp $complete_line;
 484             $complete_line .= ' ' . $line;
 485         }
 486         # Line continuation, line ends with "\".
 487         if ($line =~ /\\\s*$/) {
 488             $continuation = 1;
 489             # Start line continuation.
 490             if (not defined $complete_line) {
 491                 $complete_line = $line;
 492             }
 493             next;
 494         }
 495
 496         if (not $continuation) {
 497             # Use the complete line if a line continuation occurred.
 498             if (defined $complete_line) {
 499                 $line = $complete_line;
 500                 $complete_line = undef;
 501             }
 502
 503             # Ignore lines with no compiler commands.
 504             next if $line !~ /\b$cc_regex(?:\s|\\)/ and not $non_verbose;
 505
 506             # Ignore false positives.
 507             #
 508             # `./configure` output.
 509             next if not $non_verbose
 510                     and $line =~ /^(?:checking|(?:C|c)onfigure:) /;
 511             next if $line =~ /^\s*(?:Host\s+)?(?:C\s+)?
 512                                (?:C|c)ompiler[\s.]*:?\s+
 513                                $cc_regex
 514                                (?:\s-std=[a-z0-9:+]+)?\s*$
 515                              /x
 516                     or $line =~ /^\s*(?:- )?(?:HOST_)?(?:CC|CXX)\s*=\s*$cc_regex\s*$/
 517                     or $line =~ /^\s*-- Check for working (?:C|CXX) compiler: /
 518                     or $line =~ /^\s*(?:echo )?Using [A-Z_]+\s*=\s*/;
 519             # `make` output.
 520             next if $line =~ /^Making [a-z]+ in \S+/; # e.g. "[...] in c++"
 521
 522             # Check if additional hardening options were used. Used to ensure
 523             # they are used for the complete build.
 524             $harden_pie     = 1 if any_flags_used($line, @cflags_pie, @ldflags_pie);
 525             $harden_bindnow = 1 if any_flags_used($line, @ldflags_bindnow);
 526
 527             push @input, $line;
 528         }
 529     }
 530 }
 531
 532 if (scalar @input == 0) {
 533     print "No compiler commands!\n";
 534     $exit |= 1;
 535     exit $exit;
 536 }
 537
 538 # Option or auto detected.
 539 if ($option_arch) {
 540     # The following was partially copied from dpkg-dev 1.16.1.2
 541     # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 542     # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 543     # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 544     # later. Keep it in sync.
 545
 546     require Dpkg::Arch;
 547     my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($option_arch);
 548
 549     # Disable unsupported hardening options.
 550     if ($cpu =~ /^(ia64|alpha|mips|mipsel|hppa)$/ or $option_arch eq 'arm') {
 551         $harden_stack = 0;
 552     }
 553     if ($cpu =~ /^(ia64|hppa|avr32)$/) {
 554         $harden_relro   = 0;
 555         $harden_bindnow = 0;
 556     }
 557 }
 558
 559 # Check the specified hardening options, same order as dpkg-buildflags.
 560 if ($harden_pie) {
 561     @cflags  = (@cflags,  @cflags_pie);
 562     @cxxflags = (@cxxflags, @cflags_pie);
 563     @ldflags = (@ldflags, @ldflags_pie);
 564 }
 565 if ($harden_stack) {
 566     @cflags = (@cflags, @cflags_stack);
 567     @cxxflags = (@cxxflags, @cflags_stack);
 568 }
 569 if ($harden_fortify) {
 570     @cflags   = (@cflags,   @cflags_fortify);
 571     @cxxflags = (@cxxflags, @cflags_fortify);
 572     @cppflags = (@cppflags, @cppflags_fortify);
 573 }
 574 if ($harden_format) {
 575     @cflags = (@cflags, @cflags_format);
 576     @cxxflags = (@cxxflags, @cflags_format);
 577 }
 578 if ($harden_relro) {
 579     @ldflags = (@ldflags, @ldflags_relro);
 580 }
 581 if ($harden_bindnow) {
 582     @ldflags = (@ldflags, @ldflags_bindnow);
 583 }
 584
 585 for (my $i = 0; $i < scalar @input; $i++) {
 586     my $line = $input[$i];
 587
 588     my $skip = 0;
 589     if (is_non_verbose_build($line, $input[$i + 1], \$skip)) {
 590         error_non_verbose_build($line);
 591         $exit |= 1 << 2;
 592         next;
 593     }
 594     # Even if it's a verbose build, we might have to skip this line.
 595     next if $skip;
 596
 597     # Remove everything until and including the compiler command. Makes checks
 598     # easier and faster.
 599     $line =~ s/^.*?$cc_regex//;
 600
 601     # Skip unnecessary tests when only preprocessing.
 602     my $flag_preprocess = 0;
 603
 604     my $preprocess = 0;
 605     my $compile    = 0;
 606     my $link       = 0;
 607
 608     # Preprocess, compile, assemble.
 609     if ($line =~ /\s(-E|-S|-c)\b/) {
 610         $preprocess      = 1;
 611         $flag_preprocess = 1 if $1 eq '-E';
 612         $compile         = 1 if $1 eq '-S' or $1 eq '-c';
 613     # Otherwise assume we are linking.
 614     } else {
 615         $link = 1;
 616     }
 617
 618     # Get all file extensions on this line.
 619     my @extensions = $line =~ /$file_extension_regex/g;
 620     # Ignore all unknown extensions to speedup the search below.
 621     @extensions = grep { exists $extension{$_} } @extensions;
 622
 623     # These file types don't require preprocessing.
 624     if (extension_found(\%extensions_no_preprocess, @extensions)) {
 625         $preprocess = 0;
 626     }
 627     # These file types require preprocessing.
 628     if (extension_found(\%extensions_preprocess, @extensions)) {
 629         $preprocess = 1;
 630     }
 631
 632     # If there are source files then it's compiling/linking in one step and we
 633     # must check both. We only check for source files here, because header
 634     # files cause too many false positives.
 635     if (not $flag_preprocess
 636             and extension_found(\%extensions_compile_link, @extensions)) {
 637         # Assembly files don't need CFLAGS.
 638         if (not extension_found(\%extensions_compile, @extensions)
 639                 and extension_found(\%extensions_no_compile, @extensions)) {
 640             $compile = 0;
 641         # But the rest does.
 642         } else {
 643             $compile = 1;
 644         }
 645     }
 646
 647     # Assume CXXFLAGS are required when a C++ file is specified in the
 648     # compiler line.
 649     my $compile_cpp = 0;
 650     if ($compile
 651             and extension_found(\%extensions_compile_cpp, @extensions)) {
 652         $compile     = 0;
 653         $compile_cpp = 1;
 654     }
 655
 656     # Check hardening flags.
 657     my @missing;
 658     if ($compile and not all_flags_used($line, \@missing, @cflags)
 659             # Libraries linked with -fPIC don't have to (and can't) be linked
 660             # with -fPIE as well. It's no error if only PIE flags are missing.
 661             and not pic_pie_conflict($line, $harden_pie, \@missing, @cflags_pie)
 662             # Assume dpkg-buildflags returns the correct flags.
 663             and not $line =~ /`dpkg-buildflags --get CFLAGS`/) {
 664         error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 665         $exit |= 1 << 3;
 666     } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
 667             # Libraries linked with -fPIC don't have to (and can't) be linked
 668             # with -fPIE as well. It's no error if only PIE flags are missing.
 669             and not pic_pie_conflict($line, $harden_pie, \@missing, @cflags_pie)
 670             # Assume dpkg-buildflags returns the correct flags.
 671             and not $line =~ /`dpkg-buildflags --get CXXFLAGS`/) {
 672         error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 673         $exit |= 1 << 3;
 674     }
 675     if ($preprocess and not all_flags_used($line, \@missing, @cppflags)
 676             # Assume dpkg-buildflags returns the correct flags.
 677             and not $line =~ /`dpkg-buildflags --get CPPFLAGS`/) {
 678         error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 679         $exit |= 1 << 3;
 680     }
 681     if ($link and not all_flags_used($line, \@missing, @ldflags)
 682             # Same here, -fPIC conflicts with -fPIE.
 683             and not pic_pie_conflict($line, $harden_pie, \@missing, @ldflags_pie)
 684             # Assume dpkg-buildflags returns the correct flags.
 685             and not $line =~ /`dpkg-buildflags --get LDFLAGS`/) {
 686         error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 687         $exit |= 1 << 3;
 688     }
 689 }
 690
 691 exit $exit;
 692
 693
 694 __END__
 695
 696 =head1 NAME
 697
 698 blhc - build log hardening check, checks build logs for missing hardening flags
 699
 700 =head1 SYNOPSIS
 701
 702 B<blhc> [options] <dpkg-buildpackage build log file>
 703
 704     --all                   force +all (+pie, +bindnow) check
 705     --arch                  set architecture (autodetected)
 706     --bindnow               force +bindbow check
 707     --buildd                parser mode for buildds
 708     --color                 use colored output
 709     --pie                   force +pie check
 710     --help                  available options
 711     --version               version number and license
 712
 713 =head1 DESCRIPTION
 714
 715 blhc is a small tool which checks build logs for missing hardening flags and
 716 other important warnings. It's licensed under the GPL 3 or later.
 717
 718 =head1 OPTIONS
 719
 720 =over 8
 721
 722 =item B<--all>
 723
 724 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
 725 auto detected.
 726
 727 =item B<--arch>
 728
 729 Set the specific architecture (e.g. amd64, armel, etc.), automatically
 730 disables hardening flags not available on this architecture. Is detected
 731 automatically if dpkg-buildpackage is used.
 732
 733 =item B<--bindnow>
 734
 735 Force check for all +bindnow hardening flags. By default it's auto detected.
 736
 737 =item B<--buildd>
 738
 739 Special mode for buildds when automatically parsing log files. The following
 740 changes are in effect:
 741
 742 =over 2
 743
 744 =item
 745
 746 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
 747 detected).
 748
 749 =back
 750
 751 =item B<--color>
 752
 753 Use colored (ANSI) output for warning messages.
 754
 755 =item B<--pie>
 756
 757 Force check for all +pie hardening flags. By default it's auto detected.
 758
 759 =item B<-h -? --help>
 760
 761 Print available options.
 762
 763 =item B<--version>
 764
 765 Print version number and license.
 766
 767 =back
 768
 769 Auto detection for B<--pie> and B<--bindnow> only works if at least one
 770 command uses the required hardening flag (e.g. -fPIE). Then it's required for
 771 all other commands as well.
 772
 773 =head1 EXIT STATUS
 774
 775 The exit status is a "bit mask", each listed status is ORed when the error
 776 condition occurs to get the result.
 777
 778 =over 4
 779
 780 =item B<0>
 781
 782 Success.
 783
 784 =item B<1>
 785
 786 No compiler commands were found.
 787
 788 =item B<2>
 789
 790 Invalid arguments/options given to blhc.
 791
 792 =item B<4>
 793
 794 Non verbose build.
 795
 796 =item B<8>
 797
 798 Missing hardening flags.
 799
 800 =item B<16>
 801
 802 Hardening wrapper detected, no tests performed.
 803
 804 =back
 805
 806 =head1 AUTHOR
 807
 808 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
 809
 810 =head1 COPYRIGHT AND LICENSE
 811
 812 Copyright (C) 2012 by Simon Ruderich
 813
 814 This program is free software: you can redistribute it and/or modify
 815 it under the terms of the GNU General Public License as published by
 816 the Free Software Foundation, either version 3 of the License, or
 817 (at your option) any later version.
 818
 819 This program is distributed in the hope that it will be useful,
 820 but WITHOUT ANY WARRANTY; without even the implied warranty of
 821 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 822 GNU General Public License for more details.
 823
 824 You should have received a copy of the GNU General Public License
 825 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 826
 827 =cut