bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.03';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full = qr/
  42     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  43     $cc_regex
  44     /x;
  45 # Regex to check if a line contains a compiler command.
  46 my $cc_regex_normal = qr/
  47     \b$cc_regex(?:\s|\\)
  48     /x;
  49 # Regex to catch (GCC) compiler warnings.
  50 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  51
  52 # List of source file extensions which require preprocessing.
  53 my @source_preprocess_compile_cpp = (
  54     # C++
  55     qw( cc cp cxx cpp CPP c++ C ),
  56     # Objective-C++
  57     qw( mm M ),
  58 );
  59 my @source_preprocess_compile = (
  60     # C
  61     qw( c ),
  62     # Objective-C
  63     qw( m ),
  64     # (Objective-)C++
  65     @source_preprocess_compile_cpp,
  66     # Fortran
  67     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  68 );
  69 my @source_preprocess_no_compile = (
  70     # Assembly
  71     qw( S sx ),
  72 );
  73 my @source_preprocess = (
  74     @source_preprocess_compile,
  75     @source_preprocess_no_compile,
  76 );
  77 # List of source file extensions which don't require preprocessing.
  78 my @source_no_preprocess_compile_cpp = (
  79     # C++
  80     qw( ii ),
  81     # Objective-C++
  82     qw( mii ),
  83 );
  84 my @source_no_preprocess_compile_ada = (
  85     # Ada body
  86     qw( adb ),
  87     # If you add another file, fix use of @source_no_preprocess_compile_ada
  88     # below (search for $compile_ada).
  89 );
  90 my @source_no_preprocess_compile = (
  91     # C
  92     qw( i ),
  93     # (Objective-)C++
  94     @source_no_preprocess_compile_cpp,
  95     # Objective-C
  96     qw( mi ),
  97     # Fortran
  98     qw( f for ftn f90 f95 f03 f08 ),
  99     # Ada
 100     @source_no_preprocess_compile_ada,
 101 );
 102 my @source_no_preprocess_no_compile = (
 103     # Assembly
 104     qw( s ),
 105     # Ada specification
 106     qw( ads ),
 107 );
 108 my @source_no_preprocess = (
 109     @source_no_preprocess_compile,
 110     @source_no_preprocess_no_compile,
 111 );
 112 # List of header file extensions which require preprocessing.
 113 my @header_preprocess = (
 114     # C, C++, Objective-C, Objective-C++
 115     qw( h ),
 116     # C++
 117     qw( hh H hp hxx hpp HPP h++ tcc ),
 118 );
 119 # Object files.
 120 my @object = (
 121     # Normal object files.
 122     qw ( o ),
 123     # Libtool object files.
 124     qw ( lo la ),
 125     # Dynamic libraries. bzip2 uses .sho.
 126     qw ( so sho ),
 127     # Static libraries.
 128     qw ( a ),
 129 );
 130
 131 # Hashes for fast extensions lookup to check if a file falls in one of these
 132 # categories.
 133 my %extensions_no_preprocess = map { $_ => 1 } (
 134     # There's no @header_no_preprocess.
 135     @source_no_preprocess,
 136 );
 137 my %extensions_preprocess = map { $_ => 1 } (
 138     @header_preprocess,
 139     @source_preprocess,
 140 );
 141 my %extensions_compile_link = map { $_ => 1 } (
 142     @source_preprocess,
 143     @source_no_preprocess,
 144 );
 145 my %extensions_compile = map { $_ => 1 } (
 146     @source_preprocess_compile,
 147     @source_no_preprocess_compile,
 148 );
 149 my %extensions_no_compile = map { $_ => 1 } (
 150     @source_preprocess_no_compile,
 151     @source_no_preprocess_no_compile,
 152 );
 153 my %extensions_compile_cpp = map { $_ => 1 } (
 154     @source_preprocess_compile_cpp,
 155     @source_no_preprocess_compile_cpp,
 156 );
 157 my %extensions_object = map { $_ => 1 } (
 158     @object,
 159 );
 160 my %extension = map { $_ => 1 } (
 161     @source_no_preprocess,
 162     @header_preprocess,
 163     @source_preprocess,
 164     @object,
 165 );
 166
 167 # Regexp to match file extensions.
 168 my $file_extension_regex = qr/
 169     \s
 170     \S+             # Filename without extension.
 171     \.
 172     ([^\/\\.,;:\s]+)# File extension.
 173     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 174                     # word characters at the end and because \b matches double
 175                     # extensions (like .cpp.o). Works always as all lines are
 176                     # terminated with "\n".
 177     /x;
 178
 179 # Expected (hardening) flags. All flags are used as regexps.
 180 my @def_cflags = (
 181     '-g',
 182     '-O(?:2|3)',
 183 );
 184 my @def_cflags_format = (
 185     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 186     '-Werror=format-security', # implies -Wformat-security
 187 );
 188 my @def_cflags_fortify = (
 189     # fortify needs at least -O1, but -O2 is recommended anyway
 190 );
 191 my @def_cflags_stack = (
 192     '-fstack-protector',
 193     '--param[= ]ssp-buffer-size=4',
 194 );
 195 my @def_cflags_pie = (
 196     '-fPIE',
 197 );
 198 my @def_cxxflags = (
 199     @def_cflags,
 200 );
 201 # @def_cxxflags_* is the same as @def_cflags_*.
 202 my @def_cppflags = ();
 203 my @def_cppflags_fortify = (
 204     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 205     # If you add another flag fix hack below (search for "Hack to fix").
 206 );
 207 my @def_cppflags_fortify_bad = (
 208     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 209     '-U_FORTIFY_SOURCE',
 210     '-D_FORTIFY_SOURCE=0',
 211     '-D_FORTIFY_SOURCE=1',
 212 );
 213 my @def_ldflags = ();
 214 my @def_ldflags_relro = (
 215     '-Wl,(?:-z,)?relro',
 216 );
 217 my @def_ldflags_bindnow = (
 218     '-Wl,(?:-z,)?now',
 219 );
 220 my @def_ldflags_pie = (
 221     '-fPIE',
 222     '-pie',
 223 );
 224 my @def_ldflags_pic = (
 225     '-fPIC',
 226     '-fpic',
 227     '-shared',
 228 );
 229 # References to all flags checked by the flag checker.
 230 my @flag_refs = (
 231     \@def_cflags,
 232     \@def_cflags_format,
 233     \@def_cflags_fortify,
 234     \@def_cflags_stack,
 235     \@def_cflags_pie,
 236     \@def_cxxflags,
 237     \@def_cppflags,
 238     \@def_cppflags_fortify,
 239     \@def_ldflags,
 240     \@def_ldflags_relro,
 241     \@def_ldflags_bindnow,
 242     \@def_ldflags_pie,
 243 );
 244 # References to all used flags.
 245 my @flag_refs_all = (
 246     @flag_refs,
 247     \@def_cppflags_fortify_bad,
 248     \@def_ldflags_pic,
 249 );
 250 # Renaming rules for the output so the regex parts are not visible. Also
 251 # stores string values of flag regexps above, see compile_flag_regexp().
 252 my %flag_renames = (
 253     '-O(?:2|3)'                    => '-O2',
 254     '-Wformat(?:=2)?'              => '-Wformat',
 255     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 256     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 257     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 258 );
 259
 260 my %exit_code = (
 261     no_compiler_commands => 1 << 0,
 262     # used by POD::Usage => 1 << 1,
 263     non_verbose_build    => 1 << 2,
 264     flags_missing        => 1 << 3,
 265     hardening_wrapper    => 1 << 4,
 266     invalid_cmake        => 1 << 5,
 267 );
 268
 269 my %buildd_tag = (
 270     no_compiler_commands => 'I-no-compiler-commands',
 271     non_verbose_build    => 'W-compiler-flags-hidden',
 272     flags_missing        => 'W-dpkg-buildflags-missing',
 273     hardening_wrapper    => 'I-hardening-wrapper-used',
 274     invalid_cmake        => 'I-invalid-cmake-used',
 275 );
 276
 277 # Statistics of missing flags and non-verbose build commands. Used for
 278 # $option_buildd.
 279 my %statistics = (
 280     preprocess          => 0,
 281     preprocess_missing  => 0,
 282     compile             => 0,
 283     compile_missing     => 0,
 284     compile_cpp         => 0,
 285     compile_cpp_missing => 0,
 286     link                => 0,
 287     link_missing        => 0,
 288     commands            => 0,
 289     commands_nonverbose => 0,
 290 );
 291
 292 # Use colored (ANSI) output?
 293 my $option_color;
 294
 295
 296 # FUNCTIONS
 297
 298 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 299 sub array_equal {
 300     my ($first_ref, $second_ref) = @_;
 301
 302     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 303
 304     my $length = scalar @{$first_ref};
 305     for (my $i = 0; $i < $length; $i++) {
 306         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 307     }
 308
 309     return 1;
 310 }
 311
 312 sub error_flags {
 313     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 314
 315     # Get string value of qr//-escaped regexps and if requested rename them.
 316     my @missing_flags = map {
 317             $flag_renames_ref->{$_}
 318         } @{$missing_flags_ref};
 319
 320     my $flags = join ' ', @missing_flags;
 321     printf '%s (%s)%s %s',
 322            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 323            $line;
 324
 325     return;
 326 }
 327 sub error_non_verbose_build {
 328     my ($line) = @_;
 329
 330     printf '%s%s %s',
 331            error_color('NONVERBOSE BUILD', 'red'),
 332            error_color(':', 'yellow'),
 333            $line;
 334
 335     return;
 336 }
 337 sub error_invalid_cmake {
 338     my ($version) = @_;
 339
 340     printf "%s%s %s\n",
 341             error_color('INVALID CMAKE', 'red'),
 342             error_color(':', 'yellow'),
 343             $version;
 344
 345     return;
 346 }
 347 sub error_hardening_wrapper {
 348     printf "%s%s %s\n",
 349             error_color('HARDENING WRAPPER', 'red'),
 350             error_color(':', 'yellow'),
 351             'no checks possible, aborting';
 352
 353     return;
 354 }
 355 sub error_color {
 356     my ($message, $color) = @_;
 357
 358     if ($option_color) {
 359         return Term::ANSIColor::colored($message, $color);
 360     } else {
 361         return $message;
 362     }
 363 }
 364
 365 sub any_flags_used {
 366     my ($line, @flags) = @_;
 367
 368     foreach my $flag (@flags) {
 369         return 1 if $line =~ /$flag/;
 370     }
 371
 372     return 0;
 373 }
 374 sub all_flags_used {
 375     my ($line, $missing_flags_ref, @flags) = @_;
 376
 377     my @missing_flags = ();
 378     foreach my $flag (@flags) {
 379         if (not $line =~ /$flag/) {
 380             push @missing_flags, $flag;
 381         }
 382     }
 383
 384     return 1 if scalar @missing_flags == 0;
 385
 386     @{$missing_flags_ref} = @missing_flags;
 387     return 0;
 388 }
 389
 390 sub cppflags_fortify_broken {
 391     my ($line, $missing_flags) = @_;
 392
 393     # This doesn't take the position into account, but is a simple solution.
 394     # And if the build system tries to force -D_FORTIFY_SOURCE=0/1, something
 395     # is wrong anyway.
 396
 397     if (any_flags_used($line, @def_cppflags_fortify_bad)) {
 398         # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 399         push @{$missing_flags}, $def_cppflags_fortify[0];
 400         return 1;
 401     }
 402
 403     return 0;
 404 }
 405
 406 # Modifies $missing_flags_ref array.
 407 sub pic_pie_conflict {
 408     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 409
 410     return 0 if not $pie;
 411     return 0 if not any_flags_used($line, @def_ldflags_pic);
 412
 413     my %flags = map { $_ => 1 } @flags_pie;
 414
 415     # Remove all PIE flags from @missing_flags as they are not required with
 416     # -fPIC.
 417     my @result = grep {
 418         not exists $flags{$_}
 419     } @{$missing_flags_ref};
 420     @{$missing_flags_ref} = @result;
 421
 422     # We got a conflict when no flags are left, thus only PIE flags were
 423     # missing. If other flags were missing abort because the conflict is not
 424     # the problem.
 425     return scalar @result == 0;
 426 }
 427
 428 sub is_non_verbose_build {
 429     my ($line, $next_line, $skip_ref) = @_;
 430
 431     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 432                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 433                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 434                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 435                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 436         return 0;
 437     }
 438
 439     # False positives.
 440     #
 441     # C++ compiler setting.
 442     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 443     # "Compiling" with no file name.
 444     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 445         # $file_extension_regex may need spaces around the filename.
 446         return 0 if not " $1 " =~ /$file_extension_regex/o;
 447     }
 448
 449     my $file = $1;
 450
 451     # On the first pass we only check if this line is verbose or not.
 452     return 1 if not defined $next_line;
 453
 454     # Second pass, we have access to the next line.
 455     ${$skip_ref} = 0;
 456
 457     # CMake and other build systems print the non-verbose messages also when
 458     # building verbose. If a compiler and the file name occurs in the next
 459     # line, treat it as verbose build.
 460     if (defined $file) {
 461         # Get filename, we can't use the complete path as only parts of it are
 462         # used in the real compiler command.
 463         $file =~ m{/([^/\s]+)$};
 464         $file = $1;
 465
 466         if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 467             # Not a non-verbose line, but we still have to skip the current line
 468             # as it doesn't contain any compiler commands.
 469             ${$skip_ref} = 1;
 470             return 0;
 471         }
 472     }
 473
 474     return 1;
 475 }
 476
 477 sub remove_flags {
 478     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 479
 480     my %removes = map { $_ => 1 } @flags;
 481     foreach my $flags (@{$flag_refs_ref}) {
 482         @{$flags} = grep {
 483             # Flag found as string.
 484             not exists $removes{$_}
 485             # Flag found as string representation of regexp.
 486                 and (not defined $flag_renames_ref->{$_}
 487                         or not exists $removes{$flag_renames_ref->{$_}})
 488         } @{$flags};
 489     }
 490
 491     return;
 492 }
 493
 494 sub compile_flag_regexp {
 495     my ($flag_renames_ref, @flags) = @_;
 496
 497     my @result = ();
 498     foreach my $flag (@flags) {
 499         # Store flag name in replacement string for correct flags in messages
 500         # with qr//ed flag regexps.
 501         $flag_renames_ref->{qr/\s$flag(?:\s|\\)/}
 502             = (exists $flag_renames_ref->{$flag})
 503                 ? $flag_renames_ref->{$flag}
 504                 : $flag;
 505
 506         # Compile flag regexp for faster execution.
 507         push @result, qr/\s$flag(?:\s|\\)/;
 508     }
 509     return @result;
 510 }
 511
 512 sub extension_found {
 513     my ($extensions_ref, @extensions) = @_;
 514
 515     my $found = 0;
 516     foreach my $extension (@extensions) {
 517         if (exists $extensions_ref->{$extension}) {
 518             $found = 1;
 519             last;
 520         }
 521     }
 522     return $found;
 523 }
 524
 525
 526 # MAIN
 527
 528 # Parse command line arguments.
 529 my $option_help             = 0;
 530 my $option_version          = 0;
 531 my $option_pie              = 0;
 532 my $option_bindnow          = 0;
 533 my @option_ignore_arch      = ();
 534 my @option_ignore_flag      = ();
 535 my @option_ignore_arch_flag = ();
 536 my @option_ignore_line      = ();
 537 my @option_ignore_arch_line = ();
 538 my $option_all              = 0;
 539 my $option_arch             = undef;
 540 my $option_buildd           = 0;
 541    $option_color            = 0;
 542 if (not Getopt::Long::GetOptions(
 543             'help|h|?'           => \$option_help,
 544             'version'            => \$option_version,
 545             # Hardening options.
 546             'pie'                => \$option_pie,
 547             'bindnow'            => \$option_bindnow,
 548             'all'                => \$option_all,
 549             # Ignore.
 550             'ignore-arch=s'      => \@option_ignore_arch,
 551             'ignore-flag=s'      => \@option_ignore_flag,
 552             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 553             'ignore-line=s'      => \@option_ignore_line,
 554             'ignore-arch-line=s' => \@option_ignore_arch_line,
 555             # Misc.
 556             'color'              => \$option_color,
 557             'arch=s'             => \$option_arch,
 558             'buildd'             => \$option_buildd,
 559         )) {
 560     require Pod::Usage;
 561     Pod::Usage::pod2usage(2);
 562 }
 563 if ($option_help) {
 564     require Pod::Usage;
 565     Pod::Usage::pod2usage(1);
 566 }
 567 if ($option_version) {
 568     print "blhc $VERSION  Copyright (C) 2012  Simon Ruderich
 569
 570 This program is free software: you can redistribute it and/or modify
 571 it under the terms of the GNU General Public License as published by
 572 the Free Software Foundation, either version 3 of the License, or
 573 (at your option) any later version.
 574
 575 This program is distributed in the hope that it will be useful,
 576 but WITHOUT ANY WARRANTY; without even the implied warranty of
 577 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 578 GNU General Public License for more details.
 579
 580 You should have received a copy of the GNU General Public License
 581 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 582 ";
 583     exit 0;
 584 }
 585
 586 # Arguments missing.
 587 if (scalar @ARGV == 0) {
 588     require Pod::Usage;
 589     Pod::Usage::pod2usage(2);
 590 }
 591
 592 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 593 # installed on Debian's buildds.
 594 if (not $option_buildd) {
 595     require Term::ANSIColor;
 596 }
 597
 598 if ($option_all) {
 599     $option_pie     = 1;
 600     $option_bindnow = 1;
 601 }
 602
 603 # Precompiled ignores for faster lookup.
 604 my %option_ignore_arch_flag = ();
 605 my %option_ignore_arch_line = ();
 606
 607 # Strip flags which should be ignored.
 608 if (scalar @option_ignore_flag > 0) {
 609     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 610 }
 611 # Same for arch specific ignore flags, but only prepare here.
 612 if (scalar @option_ignore_arch_flag > 0) {
 613     foreach my $ignore (@option_ignore_arch_flag) {
 614         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 615
 616         if (not $ignore_arch or not $ignore_flag) {
 617             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 618                         . '("arch:flag" expected)' . "\n", $ignore;
 619             require Pod::Usage;
 620             Pod::Usage::pod2usage(2);
 621         }
 622
 623         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 624     }
 625 }
 626
 627 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 628 # faster with this.
 629 foreach my $flags (@flag_refs_all) {
 630     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 631 }
 632
 633 # Precompile ignore line regexps, also anchor at beginning and end of line.
 634 foreach my $ignore (@option_ignore_line) {
 635     $ignore = qr/^$ignore$/;
 636 }
 637 # Same for arch specific ignore lines.
 638 if (scalar @option_ignore_arch_line > 0) {
 639     foreach my $ignore (@option_ignore_arch_line) {
 640         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 641
 642         if (not $ignore_arch or not $ignore_line) {
 643             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 644                         . '("arch:line" expected)' . "\n", $ignore;
 645             require Pod::Usage;
 646             Pod::Usage::pod2usage(2);
 647         }
 648
 649         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 650     }
 651 }
 652
 653 # Final exit code.
 654 my $exit = 0;
 655
 656 FILE:
 657 foreach my $file (@ARGV) {
 658     print "checking '$file'...\n" if scalar @ARGV > 1;
 659
 660     -f $file or die "No such file: $file";
 661
 662     open my $fh, '<', $file or die $!;
 663
 664     # Architecture of this file.
 665     my $arch = $option_arch;
 666
 667     # Hardening options. Not all architectures support all hardening options.
 668     my $harden_format  = 1;
 669     my $harden_fortify = 1;
 670     my $harden_stack   = 1;
 671     my $harden_relro   = 1;
 672     my $harden_bindnow = $option_bindnow; # defaults to 0
 673     my $harden_pie     = $option_pie;     # defaults to 0
 674
 675     # Does this build log use ada? Ada also uses gcc as compiler but uses
 676     # different CFLAGS. But only perform ada checks if an ada compiler used
 677     # for performance reasons.
 678     my $ada = 0;
 679
 680     while (my $line = <$fh>) {
 681         # Detect architecture automatically unless overridden. For buildd logs
 682         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 683         # build logs which aren't built (wrong architecture, build error,
 684         # etc.).
 685         if (not $arch and index($line, 'Architecture: ') == 0) {
 686             $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 687         }
 688
 689         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 690         # check for hardening flags in buildd mode if an older dpkg-dev is
 691         # used. Default flags (-g -O2) are still checked.
 692         #
 693         # Packages which were built before 1.16.1 but used their own hardening
 694         # flags are not checked.
 695         if ($option_buildd
 696                 and index($line, 'Toolchain package versions: ') == 0) {
 697             require Dpkg::Version;
 698             if (not $line =~ /\bdpkg-dev_(\S+)/
 699                     or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
 700                 $harden_format  = 0;
 701                 $harden_fortify = 0;
 702                 $harden_stack   = 0;
 703                 $harden_relro   = 0;
 704                 $harden_bindnow = 0;
 705                 $harden_pie     = 0;
 706             }
 707         }
 708
 709         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 710         # this was later dropped because upstream rejected the patch. Thus
 711         # build logs with these versions will have fortify hardening flags
 712         # enabled, even though they may be not correctly set and are missing
 713         # when build with later CMake versions. Thanks to Aron Xu for letting
 714         # me know.
 715         if (index($line, 'Package versions: ') == 0
 716                 and $line =~ /\bcmake_(\S+)/
 717                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 718             if (not $option_buildd) {
 719                 error_invalid_cmake($1);
 720                 $exit |= $exit_code{invalid_cmake};
 721             } else {
 722                 print "$buildd_tag{invalid_cmake}|$1|\n";
 723             }
 724         }
 725
 726         if (index($line, 'Build-Depends: ') == 0) {
 727             # If hardening wrapper is used (wraps calls to gcc and adds
 728             # hardening flags automatically) we can't perform any checks,
 729             # abort.
 730             if ($line =~ /\bhardening-wrapper\b/) {
 731                 if (not $option_buildd) {
 732                     error_hardening_wrapper();
 733                     $exit |= $exit_code{hardening_wrapper};
 734                 } else {
 735                     print "$buildd_tag{hardening_wrapper}||\n";
 736                 }
 737                 next FILE;
 738             }
 739
 740             # Ada compiler.
 741             if ($line =~ /\bgnat\b/) {
 742                 $ada = 1;
 743             }
 744         }
 745
 746         # We skip over unimportant lines at the beginning of the log to
 747         # prevent false positives.
 748         last if index($line, 'dpkg-buildpackage: ') == 0;
 749     }
 750
 751     # Input lines, contain only the lines with compiler commands.
 752     my @input = ();
 753     # Non-verbose lines in the input. Used to reduce calls to
 754     # is_non_verbose_build() (which is quite slow) in the second loop when
 755     # it's already clear if a line is non-verbose or not.
 756     my @input_nonverbose = ();
 757
 758     my $continuation = 0;
 759     my $complete_line = undef;
 760     while (my $line = <$fh>) {
 761         # And stop at the end of the build log. Package details (reported by
 762         # the buildd logs) are not important for us. This also prevents false
 763         # positives.
 764         last if index($line, 'Build finished at ') == 0
 765                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 766
 767         # Detect architecture automatically unless overridden.
 768         if (not $arch
 769                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 770             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 771         }
 772
 773         # Ignore compiler warnings for now.
 774         next if $line =~ /$warning_regex/o;
 775
 776         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 777             # Remove all ANSI color sequences which are sometimes used in
 778             # non-verbose builds.
 779             $line = Term::ANSIColor::colorstrip($line);
 780             # Also strip '\0xf' (delete previous character), used by Elinks'
 781             # build system.
 782             $line =~ s/\x0f//g;
 783             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 784             # what it does).
 785             $line =~ s/\033\(B//g;
 786         }
 787
 788         # Check if this line indicates a non verbose build.
 789         my $non_verbose = is_non_verbose_build($line);
 790
 791         # One line may contain multiple commands (";"). Treat each one as
 792         # single line. parse_line() is slow, only use it when necessary.
 793         my @line = (index($line, ';') == -1)
 794                  ? ($line)
 795                  : map {
 796                        # Ensure newline at the line end - necessary for
 797                        # correct parsing later.
 798                        $_ =~ s/\s+$//;
 799                        $_ .= "\n";
 800                    } Text::ParseWords::parse_line(';', 1, $line);
 801         foreach my $line (@line) {
 802             if ($continuation) {
 803                 $continuation = 0;
 804
 805                 # Join lines, but leave the "\" in place so it's clear where
 806                 # the original line break was.
 807                 chomp $complete_line;
 808                 $complete_line .= ' ' . $line;
 809             }
 810             # Line continuation, line ends with "\".
 811             if ($line =~ /\\$/) {
 812                 $continuation = 1;
 813                 # Start line continuation.
 814                 if (not defined $complete_line) {
 815                     $complete_line = $line;
 816                 }
 817                 next;
 818             }
 819
 820             # Use the complete line if a line continuation occurred.
 821             if (defined $complete_line) {
 822                 $line = $complete_line;
 823                 $complete_line = undef;
 824             }
 825
 826             # Ignore lines with no compiler commands.
 827             next if not $non_verbose
 828                     and not $line =~ /$cc_regex_normal/o;
 829             # Ignore lines with no filenames with extensions. May miss some
 830             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
 831             # a problem as the log will most likely contain other non-verbose
 832             # commands which are detected.
 833             next if not $non_verbose
 834                     and not $line =~ /$file_extension_regex/o;
 835
 836             # Ignore false positives.
 837             #
 838             # `./configure` output.
 839             next if not $non_verbose
 840                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
 841             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 842                                 [Cc]ompiler[\s.]*:?\s+
 843                                 /x;
 844             next if $line =~ /^\s*(?:- )?(?:HOST_)?(?:CC|CXX)\s*=\s*$cc_regex_full\s*$/o;
 845             # `moc-qt4`, contains '-I/usr/share/qt4/mkspecs/linux-g++' (or
 846             # similar for other architectures) which gets recognized as a
 847             # compiler line. Ignore it.
 848             next if $line =~ m{^/usr/bin/moc-qt4
 849                                \s.+\s
 850                                -I/usr/share/qt4/mkspecs/[a-z]+-g\++(?:-64)?
 851                                \s}x;
 852             # Ignore false positives when the line contains only CC=gcc but no
 853             # other gcc command.
 854             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
 855                 my $before = $1;
 856                 my $after  = $2;
 857                 next if     not $before =~ /$cc_regex_normal/o
 858                         and not $after  =~ /$cc_regex_normal/o;
 859             }
 860
 861             # Check if additional hardening options were used. Used to ensure
 862             # they are used for the complete build.
 863             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
 864                                                          @def_ldflags_pie);
 865             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 866
 867             push @input, $line;
 868             push @input_nonverbose, $non_verbose;
 869         }
 870     }
 871
 872     close $fh or die $!;
 873
 874     # Ignore arch if requested.
 875     if (scalar @option_ignore_arch > 0 and $arch) {
 876         foreach my $ignore (@option_ignore_arch) {
 877             if ($arch eq $ignore) {
 878                 print "ignoring architecture '$arch'\n";
 879                 next FILE;
 880             }
 881         }
 882     }
 883
 884     if (scalar @input == 0) {
 885         if (not $option_buildd) {
 886             print "No compiler commands!\n";
 887             $exit |= $exit_code{no_compiler_commands};
 888         } else {
 889             print "$buildd_tag{no_compiler_commands}||\n";
 890         }
 891         next FILE;
 892     }
 893
 894     if ($option_buildd) {
 895         $statistics{commands} += scalar @input;
 896     }
 897
 898     # Option or auto detected.
 899     if ($arch) {
 900         # The following was partially copied from dpkg-dev 1.16.4.3
 901         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 902         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 903         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 904         # later. Keep it in sync.
 905
 906         require Dpkg::Arch;
 907         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
 908
 909         # Disable unsupported hardening options.
 910         if ($cpu =~ /^(?:ia64|alpha|mips|mipsel|hppa)$/ or $arch eq 'arm') {
 911             $harden_stack = 0;
 912         }
 913         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
 914             $harden_relro   = 0;
 915             $harden_bindnow = 0;
 916         }
 917     }
 918
 919     # Default values.
 920     my @cflags   = @def_cflags;
 921     my @cxxflags = @def_cxxflags;
 922     my @cppflags = @def_cppflags;
 923     my @ldflags  = @def_ldflags;
 924     # Check the specified hardening options, same order as dpkg-buildflags.
 925     if ($harden_pie) {
 926         @cflags   = (@cflags,   @def_cflags_pie);
 927         @cxxflags = (@cxxflags, @def_cflags_pie);
 928         @ldflags  = (@ldflags,  @def_ldflags_pie);
 929     }
 930     if ($harden_stack) {
 931         @cflags   = (@cflags,   @def_cflags_stack);
 932         @cxxflags = (@cxxflags, @def_cflags_stack);
 933     }
 934     if ($harden_fortify) {
 935         @cflags   = (@cflags,   @def_cflags_fortify);
 936         @cxxflags = (@cxxflags, @def_cflags_fortify);
 937         @cppflags = (@cppflags, @def_cppflags_fortify);
 938     }
 939     if ($harden_format) {
 940         @cflags   = (@cflags,   @def_cflags_format);
 941         @cxxflags = (@cxxflags, @def_cflags_format);
 942     }
 943     if ($harden_relro) {
 944         @ldflags = (@ldflags, @def_ldflags_relro);
 945     }
 946     if ($harden_bindnow) {
 947         @ldflags = (@ldflags, @def_ldflags_bindnow);
 948     }
 949
 950     # Stores normal CFLAGS when @cflags_ada are temporarily used.
 951     my @cflags_backup;
 952     # Ada CFLAGS.
 953     my @cflags_ada = @cflags;
 954     # Ada doesn't support format hardening flags, see #680117 for more
 955     # information. Filter them out if ada is used.
 956     if ($ada and $harden_format) {
 957         @cflags_ada = grep {
 958             my $ok = 1;
 959             foreach my $flag (@def_cflags_format) {
 960                 $ok = 0 if $_ eq $flag;
 961             }
 962             $ok;
 963         } @cflags;
 964     }
 965
 966     # Hack to fix cppflags_fortify_broken() if --ignore-flag
 967     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
 968     # as long as @def_cppflags_fortify contains only one variable.
 969     if (scalar @def_cppflags_fortify == 0) {
 970         $harden_fortify = 0;
 971     }
 972
 973     # Ignore flags for this arch if requested.
 974     if ($arch and exists $option_ignore_arch_flag{$arch}) {
 975         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
 976
 977         remove_flags(\@local_flag_refs,
 978                      \%flag_renames,
 979                      @{$option_ignore_arch_flag{$arch}});
 980     }
 981
 982     my @ignore_line = @option_ignore_line;
 983     # Ignore lines for this arch if requested.
 984     if ($arch and exists $option_ignore_arch_line{$arch}) {
 985         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
 986     }
 987
 988 LINE:
 989     for (my $i = 0; $i < scalar @input; $i++) {
 990         my $line = $input[$i];
 991
 992         # Ignore line if requested.
 993         foreach my $ignore (@ignore_line) {
 994             next LINE if $line =~ /$ignore/;
 995         }
 996
 997         my $skip = 0;
 998         if ($input_nonverbose[$i]
 999                 and is_non_verbose_build($line, $input[$i + 1], \$skip)) {
1000             if (not $option_buildd) {
1001                 error_non_verbose_build($line);
1002                 $exit |= $exit_code{non_verbose_build};
1003             } else {
1004                 $statistics{commands_nonverbose}++;
1005             }
1006             next;
1007         }
1008         # Even if it's a verbose build, we might have to skip this line.
1009         next if $skip;
1010
1011         # Remove everything until and including the compiler command. Makes
1012         # checks easier and faster.
1013         $line =~ s/^.*?$cc_regex//o;
1014         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1015         # the brace and similar characters at the line end.
1016         $line =~ s/['")]+$//;
1017
1018         # Skip unnecessary tests when only preprocessing.
1019         my $flag_preprocess = 0;
1020
1021         my $dependency = 0;
1022         my $preprocess = 0;
1023         my $compile    = 0;
1024         my $link       = 0;
1025
1026         # Preprocess, compile, assemble.
1027         if ($line =~ /\s(-E|-S|-c)\b/) {
1028             $preprocess      = 1;
1029             $flag_preprocess = 1 if $1 eq '-E';
1030             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1031         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1032         # -MT -MQ) are always used with -M/-MM.
1033         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1034             $dependency = 1;
1035         # Otherwise assume we are linking.
1036         } else {
1037             $link = 1;
1038         }
1039
1040         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1041         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1042             $dependency      = 0;
1043             $flag_preprocess = 0;
1044         }
1045
1046         # Dependency generation for Makefiles, no preprocessing or other flags
1047         # needed.
1048         next if $dependency;
1049
1050         # Get all file extensions on this line.
1051         my @extensions = $line =~ /$file_extension_regex/go;
1052         # Ignore all unknown extensions to speedup the search below.
1053         @extensions = grep { exists $extension{$_} } @extensions;
1054
1055         # These file types don't require preprocessing.
1056         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1057             $preprocess = 0;
1058         }
1059         # These file types require preprocessing.
1060         if (extension_found(\%extensions_preprocess, @extensions)) {
1061             $preprocess = 1;
1062         }
1063
1064         if (not $flag_preprocess) {
1065             # If there are source files then it's compiling/linking in one
1066             # step and we must check both. We only check for source files
1067             # here, because header files cause too many false positives.
1068             if (extension_found(\%extensions_compile_link, @extensions)) {
1069                 # Assembly files don't need CFLAGS.
1070                 if (not extension_found(\%extensions_compile, @extensions)
1071                         and extension_found(\%extensions_no_compile, @extensions)) {
1072                     $compile = 0;
1073                 # But the rest does.
1074                 } else {
1075                     $compile = 1;
1076                 }
1077             # No compilable extensions found, either linking or compiling
1078             # header flags.
1079             #
1080             # If there are also no object files we are just compiling headers
1081             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1082             # to our liberal checks for compiler lines, this also reduces the
1083             # number of false positives considerably.
1084             } elsif ($link
1085                     and not extension_found(\%extensions_object, @extensions)) {
1086                 $link = 0;
1087             }
1088         }
1089
1090         my $compile_cpp = 0;
1091         my $compile_ada = 0;
1092         # Assume CXXFLAGS are required when a C++ file is specified in the
1093         # compiler line.
1094         if ($compile
1095                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1096             $compile     = 0;
1097             $compile_cpp = 1;
1098         # Ada needs special CFLAGS, use them if only ada files are compiled.
1099         } elsif ($ada
1100                     and $compile
1101                     and array_equal(\@extensions,
1102                                     \@source_no_preprocess_compile_ada)) {
1103             $compile_ada = 1;
1104             @cflags_backup = @cflags;
1105             @cflags        = @cflags_ada;
1106         }
1107
1108         if ($option_buildd) {
1109             $statistics{preprocess}++  if $preprocess;
1110             $statistics{compile}++     if $compile;
1111             $statistics{compile_cpp}++ if $compile_cpp;
1112             $statistics{link}++        if $link;
1113         }
1114
1115         # Check hardening flags.
1116         my @missing;
1117         if ($compile and not all_flags_used($line, \@missing, @cflags)
1118                 # Libraries linked with -fPIC don't have to (and can't) be
1119                 # linked with -fPIE as well. It's no error if only PIE flags
1120                 # are missing.
1121                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1122                 # Assume dpkg-buildflags returns the correct flags.
1123                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1124             if (not $option_buildd) {
1125                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1126                 $exit |= $exit_code{flags_missing};
1127             } else {
1128                 $statistics{compile_missing}++;
1129             }
1130         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1131                 # Libraries linked with -fPIC don't have to (and can't) be
1132                 # linked with -fPIE as well. It's no error if only PIE flags
1133                 # are missing.
1134                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1135                 # Assume dpkg-buildflags returns the correct flags.
1136                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1137             if (not $option_buildd) {
1138                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1139                 $exit |= $exit_code{flags_missing};
1140             } else {
1141                 $statistics{compile_cpp_missing}++;
1142             }
1143         }
1144         if ($preprocess
1145                 and (not all_flags_used($line, \@missing, @cppflags)
1146                     # The fortify flag might be overwritten, detect that.
1147                      or ($harden_fortify
1148                          and cppflags_fortify_broken($line, \@missing)))
1149                 # Assume dpkg-buildflags returns the correct flags.
1150                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1151             if (not $option_buildd) {
1152                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1153                 $exit |= $exit_code{flags_missing};
1154             } else {
1155                 $statistics{preprocess_missing}++;
1156             }
1157         }
1158         if ($link and not all_flags_used($line, \@missing, @ldflags)
1159                 # Same here, -fPIC conflicts with -fPIE.
1160                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1161                 # Assume dpkg-buildflags returns the correct flags.
1162                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1163             if (not $option_buildd) {
1164                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1165                 $exit |= $exit_code{flags_missing};
1166             } else {
1167                 $statistics{link_missing}++;
1168             }
1169         }
1170
1171         # Restore normal CFLAGS.
1172         if ($compile_ada) {
1173             @cflags = @cflags_backup;
1174         }
1175     }
1176 }
1177
1178 # Print statistics for buildd mode, only output in this mode.
1179 if ($option_buildd) {
1180     my @warning;
1181
1182     if ($statistics{preprocess_missing}) {
1183         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1184                                $statistics{preprocess_missing},
1185                                $statistics{preprocess};
1186     }
1187     if ($statistics{compile_missing}) {
1188         push @warning, sprintf 'CFLAGS %d (of %d)',
1189                                $statistics{compile_missing},
1190                                $statistics{compile};
1191     }
1192     if ($statistics{compile_cpp_missing}) {
1193         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1194                                $statistics{compile_cpp_missing},
1195                                $statistics{compile_cpp};
1196     }
1197     if ($statistics{link_missing}) {
1198         push @warning, sprintf 'LDFLAGS %d (of %d)',
1199                                $statistics{link_missing},
1200                                $statistics{link};
1201     }
1202     if (scalar @warning) {
1203         local $" = ', '; # array join string
1204         print "$buildd_tag{flags_missing}|@warning missing|\n";
1205     }
1206
1207     if ($statistics{commands_nonverbose}) {
1208         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1209                $statistics{commands_nonverbose},
1210                $statistics{commands},
1211     }
1212 }
1213
1214
1215 exit $exit;
1216
1217
1218 __END__
1219
1220 =head1 NAME
1221
1222 blhc - build log hardening check, checks build logs for missing hardening flags
1223
1224 =head1 SYNOPSIS
1225
1226 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1227
1228 =head1 DESCRIPTION
1229
1230 blhc is a small tool which checks build logs for missing hardening flags. It's
1231 licensed under the GPL 3 or later.
1232
1233 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1234 tools using dpkg-buildpackage like pbuilder or the official buildd build logs)
1235 to help maintainers detect missing hardening flags in their packages.
1236
1237 Only gcc is detected as compiler at the moment. If other compilers support
1238 hardening flags as well, please report them.
1239
1240 If there's no output, no flags are missing and the build log is fine.
1241
1242 =head1 OPTIONS
1243
1244 =over 8
1245
1246 =item B<--all>
1247
1248 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1249 auto detected.
1250
1251 =item B<--arch> I<architecture>
1252
1253 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1254 disables hardening flags not available on this architecture. Is detected
1255 automatically if dpkg-buildpackage is used.
1256
1257 =item B<--bindnow>
1258
1259 Force check for all +bindnow hardening flags. By default it's auto detected.
1260
1261 =item B<--buildd>
1262
1263 Special mode for buildds when automatically parsing log files. The following
1264 changes are in effect:
1265
1266 =over 2
1267
1268 =item *
1269
1270 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1271 possible tags.
1272
1273 =item *
1274
1275 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1276 detected).
1277
1278 =item *
1279
1280 Don't require Term::ANSIColor.
1281
1282 =item *
1283
1284 Return exit code 0, unless there was a error (-I, -W messages don't count as
1285 error).
1286
1287 =back
1288
1289 =item B<--color>
1290
1291 Use colored (ANSI) output for warning messages.
1292
1293 =item B<--ignore-arch> I<arch>
1294
1295 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1296
1297 Used to prevent false positives. This option can be specified multiple times.
1298
1299 =item B<--ignore-arch-flag> I<arch>:I<flag>
1300
1301 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1302
1303 =item B<--ignore-arch-line> I<arch>:I<line>
1304
1305 Like B<--ignore-line>, but only ignore line on I<arch>.
1306
1307 =item B<--ignore-flag> I<flag>
1308
1309 Don't print an error when the specific flag is missing in a compiler line.
1310 I<flag> is a string.
1311
1312 Used to prevent false positives. This option can be specified multiple times.
1313
1314 =item B<--ignore-line> I<regex>
1315
1316 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1317 at the beginning and end of the line to prevent false negatives.
1318
1319 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1320 warnings (which have line continuation resolved).
1321
1322 Used to prevent false positives. This option can be specified multiple times.
1323
1324 =item B<--pie>
1325
1326 Force check for all +pie hardening flags. By default it's auto detected.
1327
1328 =item B<-h -? --help>
1329
1330 Print available options.
1331
1332 =item B<--version>
1333
1334 Print version number and license.
1335
1336 =back
1337
1338 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1339 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1340 all other commands as well.
1341
1342 =head1 EXAMPLES
1343
1344 Normal usage, parse a single log file.
1345
1346     blhc path/to/log/file
1347
1348 If there's no output, no flags are missing and the build log is fine.
1349
1350 Parse multiple log files. The exit code is ORed over all files.
1351
1352     blhc path/to/directory/with/log/files/*
1353
1354 Don't treat missing C<-g> as error:
1355
1356     blhc --ignore-flag -g path/to/log/file
1357
1358 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1359
1360     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1361
1362 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1363 false positive.
1364
1365     blhc --ignore-line '\./script gcc file' path/to/log/file
1366
1367 Ignore lines matching C<./script gcc file> somewhere in the line.
1368
1369     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1370
1371 Use blhc with pbuilder.
1372
1373     pbuilder path/to/package.dsc | tee path/log/file
1374     blhc path/to/file || echo flags missing
1375
1376 =head1 BUILDD TAGS
1377
1378 The following tags are used in I<--buildd> mode. In braces the additional data
1379 which is displayed.
1380
1381 =over 2
1382
1383 =item B<I-hardening-wrapper-used>
1384
1385 The package uses hardening-wrapper which intercepts calls to gcc and adds
1386 hardening flags. The build log doesn't contain any hardening flags and thus
1387 can't be checked by blhc.
1388
1389 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1390
1391 Build log contains lines which hide the real compiler flags. For example:
1392
1393     CC test-a.c
1394     CC test-b.c
1395     CC test-c.c
1396     LD test
1397
1398 Most of the time either C<export V=1> or C<export verbose=1> in
1399 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1400 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1401 patched to remove the C<@>s hiding the real compiler commands.
1402
1403 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1404
1405 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1406
1407 =item B<I-invalid-cmake-used> (version)
1408
1409 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1410 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1411 patch was rejected by upstream and later reverted in Debian. Thus those two
1412 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1413 handle them (for example by passing them to CFLAGS). To prevent false
1414 negatives just blacklist those two versions.
1415
1416 =item B<I-no-compiler-commands>
1417
1418 No compiler commands were detected. Either the log contains none or they were
1419 not correctly detected by blhc (please report the bug in this case).
1420
1421 =back
1422
1423 =head1 EXIT STATUS
1424
1425 The exit status is a "bit mask", each listed status is ORed when the error
1426 condition occurs to get the result.
1427
1428 =over 4
1429
1430 =item B<0>
1431
1432 Success.
1433
1434 =item B<1>
1435
1436 No compiler commands were found.
1437
1438 =item B<2>
1439
1440 Invalid arguments/options given to blhc.
1441
1442 =item B<4>
1443
1444 Non verbose build.
1445
1446 =item B<8>
1447
1448 Missing hardening flags.
1449
1450 =item B<16>
1451
1452 Hardening wrapper detected, no tests performed.
1453
1454 =item B<32>
1455
1456 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1457 TAGS"> for a detailed explanation.
1458
1459 =back
1460
1461 =head1 AUTHOR
1462
1463 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1464
1465 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1466 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1467
1468 =head1 LICENSE AND COPYRIGHT
1469
1470 Copyright (C) 2012 by Simon Ruderich
1471
1472 This program is free software: you can redistribute it and/or modify
1473 it under the terms of the GNU General Public License as published by
1474 the Free Software Foundation, either version 3 of the License, or
1475 (at your option) any later version.
1476
1477 This program is distributed in the hope that it will be useful,
1478 but WITHOUT ANY WARRANTY; without even the implied warranty of
1479 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1480 GNU General Public License for more details.
1481
1482 You should have received a copy of the GNU General Public License
1483 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1484
1485 =head1 SEE ALSO
1486
1487 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1488
1489 =cut