bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Term::ANSIColor ();
  26 use Text::ParseWords ();
  27
  28 our $VERSION = '0.01';
  29
  30
  31 # CONSTANTS/VARIABLES
  32
  33 # Regex to catch compiler commands.
  34 my $cc_regex = qr/
  35     (?<!\.)(?:cc|gcc|g\+\+|c\+\+)
  36     (?:-[\d.]+)?
  37     /x;
  38 # Full regex which matches the complete compiler name. Used in a few places to
  39 # prevent false negatives.
  40 my $cc_regex_full = qr/
  41     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  42     $cc_regex
  43     /x;
  44 # Regex to catch (GCC) compiler warnings.
  45 my $warning_regex = qr/^(.+?):([0-9]+):[0-9]+: warning: (.+?) \[(.+?)\]$/;
  46
  47 # List of source file extensions which require preprocessing.
  48 my @source_preprocess_compile_cpp = (
  49     # C++
  50     qw( cc cp cxx cpp CPP c++ C ),
  51     # Objective-C++
  52     qw( mm Mr),
  53 );
  54 my @source_preprocess_compile = (
  55     # C
  56     qw( c ),
  57     # Objective-C
  58     qw( m ),
  59     # (Objective-)C++
  60     @source_preprocess_compile_cpp,
  61     # Fortran
  62     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  63 );
  64 my @source_preprocess_no_compile = (
  65     # Assembly
  66     qw( s ),
  67 );
  68 my @source_preprocess = (
  69     @source_preprocess_compile,
  70     @source_preprocess_no_compile,
  71 );
  72 # List of source file extensions which don't require preprocessing.
  73 my @source_no_preprocess_compile_cpp = (
  74     # C++
  75     qw( ii ),
  76     # Objective-C++
  77     qw( mii ),
  78 );
  79 my @source_no_preprocess_compile = (
  80     # C
  81     qw( i ),
  82     # (Objective-)C++
  83     @source_no_preprocess_compile_cpp,
  84     # Objective-C
  85     qw( mi ),
  86     # Fortran
  87     qw( f for ftn f90 f95 f03 f08 ),
  88 );
  89 my @source_no_preprocess_no_compile = (
  90     # Assembly
  91     qw( S sx ),
  92 );
  93 my @source_no_preprocess = (
  94     @source_no_preprocess_compile,
  95     @source_no_preprocess_no_compile,
  96 );
  97 # List of header file extensions which require preprocessing.
  98 my @header_preprocess = (
  99     # C, C++, Objective-C, Objective-C++
 100     qw( h ),
 101     # C++
 102     qw( hh H hp hxx hpp HPP h++ tcc ),
 103 );
 104
 105 # Hashes for fast extensions lookup to check if a file falls in one of these
 106 # categories.
 107 my %extensions_no_preprocess = map { $_ => 1 } (
 108     @source_no_preprocess,
 109 );
 110 my %extensions_preprocess = map { $_ => 1 } (
 111     @header_preprocess,
 112     @source_preprocess,
 113 );
 114 my %extensions_compile_link = map { $_ => 1 } (
 115     @source_preprocess,
 116     @source_no_preprocess,
 117 );
 118 my %extensions_compile = map { $_ => 1 } (
 119     @source_preprocess_compile,
 120     @source_no_preprocess_compile,
 121 );
 122 my %extensions_no_compile = map { $_ => 1 } (
 123     @source_preprocess_no_compile,
 124     @source_no_preprocess_no_compile,
 125 );
 126 my %extensions_compile_cpp = map { $_ => 1 } (
 127     @source_preprocess_compile_cpp,
 128     @source_no_preprocess_compile_cpp,
 129 );
 130 my %extension = map { $_ => 1 } (
 131     @source_no_preprocess,
 132     @source_no_preprocess_compile,
 133     @source_no_preprocess_compile_cpp,
 134     @source_no_preprocess_no_compile,
 135     @header_preprocess,
 136     @source_preprocess,
 137     @source_preprocess_compile,
 138     @source_preprocess_compile_cpp,
 139     @source_preprocess_no_compile,
 140 );
 141
 142 # Regexp to match file extensions.
 143 my $file_extension_regex = qr/
 144     \s
 145     \S+             # Filename without extension.
 146     \.
 147     ([^\\.,;:\s]+)  # File extension.
 148     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 149                     # word characters at the end and because \b matches double
 150                     # extensions (like .cpp.o). Works always as all lines are
 151                     # terminated with "\n".
 152     /x;
 153
 154 # Expected (hardening) flags. All flags are used as regexps.
 155 my @def_cflags = (
 156     '-g',
 157     '-O(?:2|3)',
 158 );
 159 my @def_cflags_format = (
 160     '-Wformat',
 161     '-Wformat-security',
 162     '-Werror=format-security',
 163 );
 164 my @def_cflags_fortify = (
 165     # fortify needs at least -O1, but -O2 is recommended anyway
 166 );
 167 my @def_cflags_stack = (
 168     '-fstack-protector',
 169     '--param=ssp-buffer-size=4',
 170 );
 171 my @def_cflags_pie = (
 172     '-fPIE',
 173 );
 174 my @def_cxxflags = (
 175     @def_cflags,
 176 );
 177 # @def_cxxflags_* is the same as @def_cflags_*.
 178 my @def_cppflags = ();
 179 my @def_cppflags_fortify = (
 180     '-D_FORTIFY_SOURCE=2',
 181 );
 182 my @def_ldflags = ();
 183 my @def_ldflags_relro = (
 184     '-Wl,(?:-z,)?relro',
 185 );
 186 my @def_ldflags_bindnow = (
 187     '-Wl,(?:-z,)?now',
 188 );
 189 my @def_ldflags_pie = (
 190     '-fPIE',
 191     '-pie',
 192 );
 193 my @def_ldflags_pic = (
 194     '-fPIC',
 195     '-fpic',
 196     '-shared',
 197 );
 198 # Renaming rules for the output so the regex parts are not visible. Also
 199 # stores string values of flag regexps above, see compile_flag_regexp().
 200 my %flag_renames = (
 201     '-O(?:2|3)'         => '-O2',
 202     '-Wl,(?:-z,)?relro' => '-Wl,-z,relro',
 203     '-Wl,(?:-z,)?now'   => '-Wl,-z,now',
 204 );
 205
 206 my %exit_code = (
 207     no_compiler_commands => 1 << 0,
 208     # used by POD::Usage => 1 << 1,
 209     non_verbose_build    => 1 << 2,
 210     flags_missing        => 1 << 3,
 211     hardening_wrapper    => 1 << 4,
 212     invalid_cmake        => 1 << 5,
 213 );
 214
 215 # Statistics of missing flags and non-verbose build commands. Used for
 216 # $option_buildd.
 217 my %statistics = (
 218     preprocess          => 0,
 219     preprocess_missing  => 0,
 220     compile             => 0,
 221     compile_missing     => 0,
 222     compile_cpp         => 0,
 223     compile_cpp_missing => 0,
 224     link                => 0,
 225     link_missing        => 0,
 226     commands            => 0,
 227     commands_nonverbose => 0,
 228 );
 229
 230 # Use colored (ANSI) output?
 231 my $option_color;
 232
 233
 234 # FUNCTIONS
 235
 236 sub error_flags {
 237     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 238
 239     # Get string value of qr//-escaped regexps and if requested rename them.
 240     my @missing_flags = map {
 241             $flag_renames_ref->{$_}
 242         } @{$missing_flags_ref};
 243
 244     my $flags = join ' ', @missing_flags;
 245     printf "%s (%s)%s %s",
 246            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 247            $line;
 248 }
 249 sub error_non_verbose_build {
 250     my ($line) = @_;
 251
 252     printf "%s%s %s",
 253            error_color('NONVERBOSE BUILD', 'red'),
 254            error_color(':', 'yellow'),
 255            $line;
 256 }
 257 sub error_invalid_cmake {
 258     my ($version) = @_;
 259
 260     printf "%s%s %s\n",
 261             error_color('INVALID CMAKE', 'red'),
 262             error_color(':', 'yellow'),
 263             $version;
 264 }
 265 sub error_hardening_wrapper {
 266     printf "%s%s %s\n",
 267             error_color('HARDENING WRAPPER', 'red'),
 268             error_color(':', 'yellow'),
 269             'no checks possible, aborting';
 270 }
 271 sub error_color {
 272     my ($message, $color) = @_;
 273
 274     if ($option_color) {
 275         return Term::ANSIColor::colored($message, $color);
 276     } else {
 277         return $message;
 278     }
 279 }
 280
 281 sub any_flags_used {
 282     my ($line, @flags) = @_;
 283
 284     foreach my $flag (@flags) {
 285         return 1 if $line =~ /$flag/;
 286     }
 287
 288     return 0;
 289 }
 290 sub all_flags_used {
 291     my ($line, $missing_flags_ref, @flags) = @_;
 292
 293     my @missing_flags = ();
 294     foreach my $flag (@flags) {
 295         if (not $line =~ /$flag/) {
 296             push @missing_flags, $flag;
 297         }
 298     }
 299
 300     return 1 if scalar @missing_flags == 0;
 301
 302     @{$missing_flags_ref} = @missing_flags;
 303     return 0;
 304 }
 305
 306 # Modifies $missing_flags_ref array.
 307 sub pic_pie_conflict {
 308     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 309
 310     return 0 if not $pie;
 311     return 0 if not any_flags_used($line, @def_ldflags_pic);
 312
 313     my %flags = map { $_ => 1 } @flags_pie;
 314
 315     # Remove all PIE flags from @missing_flags as they are not required with
 316     # -fPIC.
 317     my @result = grep {
 318         not exists $flags{$_}
 319     } @{$missing_flags_ref};
 320     @{$missing_flags_ref} = @result;
 321
 322     # We got a conflict when no flags are left, thus only PIE flags were
 323     # missing. If other flags were missing abort because the conflict is not
 324     # the problem.
 325     return scalar @result == 0;
 326 }
 327
 328 sub is_non_verbose_build {
 329     my ($line, $next_line, $skip_ref) = @_;
 330
 331     if (not ($line =~ /^checking if you want to see long compiling messages\.\.\. no/
 332                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 333                 or $line =~ /^\s*(?:C|c)ompiling\s+(.+?)(?:\.\.\.)?$/
 334                 or $line =~ /^\s*(?:B|b)uilding (?:program|shared library)\s+(.+?)$/
 335                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 336         return 0;
 337     }
 338
 339     # False positives.
 340     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 341
 342     my $file = $1;
 343
 344     # On the first pass we only check if this line is verbose or not.
 345     return 1 if not defined $next_line;
 346
 347     # Second pass, we have access to the next line.
 348     ${$skip_ref} = 0;
 349
 350     # CMake and other build systems print the non-verbose messages also when
 351     # building verbose. If a compiler and the file name occurs in the next
 352     # line, treat it as verbose build.
 353     if (defined $file) {
 354         # Get filename, we can't use the complete path as only parts of it are
 355         # used in the real compiler command.
 356         $file =~ m{/([^/\s]+)$};
 357         $file = $1;
 358
 359         if ($next_line =~ /\Q$file\E/ and $next_line =~ /$cc_regex/o) {
 360             # We still have to skip the current line as it doesn't contain any
 361             # compiler commands.
 362             ${$skip_ref} = 1;
 363             return 0;
 364         }
 365     }
 366
 367     return 1;
 368 }
 369
 370 sub compile_flag_regexp {
 371     my ($flag_renames_ref, @flags) = @_;
 372
 373     my @result = ();
 374     foreach my $flag (@flags) {
 375         # Store flag name in replacement string for correct flags in messages
 376         # with qr//ed flag regexps.
 377         $flag_renames_ref->{qr/\s$flag(?:\s|\\)/}
 378             = (exists $flag_renames_ref->{$flag})
 379                 ? $flag_renames_ref->{$flag}
 380                 : $flag;
 381
 382         # Compile flag regexp for faster execution.
 383         push @result, qr/\s$flag(?:\s|\\)/;
 384     }
 385     return @result;
 386 }
 387
 388 sub extension_found {
 389     my ($extensions_ref, @extensions) = @_;
 390
 391     my $found = 0;
 392     foreach my $extension (@extensions) {
 393         if (exists $extensions_ref->{$extension}) {
 394             $found = 1;
 395             last;
 396         }
 397     }
 398     return $found;
 399 }
 400
 401
 402 # MAIN
 403
 404 # Parse command line arguments.
 405 my $option_help    = 0;
 406 my $option_version = 0;
 407 my $option_pie     = 0;
 408 my $option_bindnow = 0;
 409 my $option_all     = 0;
 410 my $option_arch    = undef;
 411 my $option_buildd  = 0;
 412    $option_color   = 0;
 413 if (not Getopt::Long::GetOptions(
 414             'help|h|?' => \$option_help,
 415             'version'  => \$option_version,
 416             # Hardening options.
 417             'pie'      => \$option_pie,
 418             'bindnow'  => \$option_bindnow,
 419             'all'      => \$option_all,
 420             # Misc.
 421             'color'    => \$option_color,
 422             'arch=s'   => \$option_arch,
 423             'buildd'   => \$option_buildd,
 424         )) {
 425     require Pod::Usage;
 426     Pod::Usage::pod2usage(2);
 427 }
 428 if ($option_help) {
 429     require Pod::Usage;
 430     Pod::Usage::pod2usage(1);
 431 }
 432 if ($option_version) {
 433     print "blhc $VERSION  Copyright (C) 2012  Simon Ruderich
 434
 435 This program is free software: you can redistribute it and/or modify
 436 it under the terms of the GNU General Public License as published by
 437 the Free Software Foundation, either version 3 of the License, or
 438 (at your option) any later version.
 439
 440 This program is distributed in the hope that it will be useful,
 441 but WITHOUT ANY WARRANTY; without even the implied warranty of
 442 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 443 GNU General Public License for more details.
 444
 445 You should have received a copy of the GNU General Public License
 446 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 447 ";
 448     exit 0;
 449 }
 450
 451 if ($option_all) {
 452     $option_pie     = 1;
 453     $option_bindnow = 1;
 454 }
 455
 456 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 457 # faster with this.
 458 @def_cflags           = compile_flag_regexp(\%flag_renames, @def_cflags);
 459 @def_cflags_format    = compile_flag_regexp(\%flag_renames, @def_cflags_format);
 460 @def_cflags_fortify   = compile_flag_regexp(\%flag_renames, @def_cflags_fortify);
 461 @def_cflags_stack     = compile_flag_regexp(\%flag_renames, @def_cflags_stack);
 462 @def_cflags_pie       = compile_flag_regexp(\%flag_renames, @def_cflags_pie);
 463 @def_cxxflags         = compile_flag_regexp(\%flag_renames, @def_cxxflags);
 464 @def_cppflags         = compile_flag_regexp(\%flag_renames, @def_cppflags);
 465 @def_cppflags_fortify = compile_flag_regexp(\%flag_renames, @def_cppflags_fortify);
 466 @def_ldflags          = compile_flag_regexp(\%flag_renames, @def_ldflags);
 467 @def_ldflags_relro    = compile_flag_regexp(\%flag_renames, @def_ldflags_relro);
 468 @def_ldflags_bindnow  = compile_flag_regexp(\%flag_renames, @def_ldflags_bindnow);
 469 @def_ldflags_pie      = compile_flag_regexp(\%flag_renames, @def_ldflags_pie);
 470 @def_ldflags_pic      = compile_flag_regexp(\%flag_renames, @def_ldflags_pic);
 471
 472 # Final exit code.
 473 my $exit = 0;
 474
 475 FILE: foreach my $file (@ARGV) {
 476     print "checking '$file'...\n" if scalar @ARGV > 1;
 477
 478     open my $fh, '<', $file or die "$!: $file";
 479
 480     # Architecture of this file.
 481     my $arch = $option_arch;
 482
 483     # Hardening options. Not all architectures support all hardening options.
 484     my $harden_format  = 1;
 485     my $harden_fortify = 1;
 486     my $harden_stack   = 1;
 487     my $harden_relro   = 1;
 488     my $harden_bindnow = $option_bindnow; # defaults to 0
 489     my $harden_pie     = $option_pie;     # defaults to 0
 490
 491     while (my $line = <$fh>) {
 492         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 493         # check for hardening flags in buildd mode if an older dpkg-dev is
 494         # used. Default flags (-g -O2) are still checked.
 495         #
 496         # Packages which were built before 1.16.1 but used their own hardening
 497         # flags are not checked.
 498         if ($option_buildd and $line =~ /^Toolchain package versions: /) {
 499             require Dpkg::Version;
 500             if ($line !~ /\bdpkg-dev_(\S+)/
 501                     or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
 502                 $harden_format  = 0;
 503                 $harden_fortify = 0;
 504                 $harden_stack   = 0;
 505                 $harden_relro   = 0;
 506                 $harden_bindnow = 0;
 507                 $harden_pie     = 0;
 508             }
 509         }
 510
 511         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 512         # this was later dropped because upstream rejected the patch. Thus
 513         # build logs with these versions will have fortify hardening flags
 514         # enabled, even though they may be not correctly set and are missing
 515         # when build with later CMake versions. Thanks to Aron Xu for letting
 516         # me know.
 517         if ($line =~ /^Package versions: /
 518                 and $line =~ /\bcmake_(\S+)/
 519                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 520             if (not $option_buildd) {
 521                 error_invalid_cmake($1);
 522             } else {
 523                 print "W-invalid-cmake-used $1\n";
 524             }
 525             $exit |= $exit_code{invalid_cmake};
 526         }
 527
 528         # If hardening wrapper is used (wraps calls to gcc and adds hardening
 529         # flags automatically) we can't perform any checks, abort.
 530         if ($line =~ /^Build-Depends: .*\bhardening-wrapper\b/) {
 531             if (not $option_buildd) {
 532                 error_hardening_wrapper();
 533             } else {
 534                 print "I-hardening-wrapper-used\n";
 535             }
 536             $exit |= $exit_code{hardening_wrapper};
 537             next FILE;
 538         }
 539
 540         # We skip over unimportant lines at the beginning of the log to
 541         # prevent false positives.
 542         last if $line =~ /^dpkg-buildpackage:/;
 543     }
 544
 545     # Input lines, contain only the lines with compiler commands.
 546     my @input = ();
 547
 548     my $continuation = 0;
 549     my $complete_line = undef;
 550     while (my $line = <$fh>) {
 551         # And stop at the end of the build log. Package details (reported by
 552         # the buildd logs) are not important for us. This also prevents false
 553         # positives.
 554         last if $line =~ /^Build finished at \d{8}-\d{4}$/;
 555
 556         # Detect architecture automatically unless overridden.
 557         if (not $arch
 558                 and $line =~ /^dpkg-buildpackage: host architecture (.+)$/) {
 559             $arch = $1;
 560         }
 561
 562         # Ignore compiler warnings for now.
 563         next if $line =~ /$warning_regex/o;
 564
 565         if ($line =~ /\033/) { # esc
 566             # Remove all ANSI color sequences which are sometimes used in
 567             # non-verbose builds.
 568             $line = Term::ANSIColor::colorstrip($line);
 569             # Also strip '\0xf' (delete previous character), used by Elinks'
 570             # build system.
 571             $line =~ s/\x0f//g;
 572             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 573             # what it does).
 574             $line =~ s/\033\(B//g;
 575         }
 576
 577         # Check if this line indicates a non verbose build.
 578         my $non_verbose = is_non_verbose_build($line);
 579
 580         # One line may contain multiple commands (";"). Treat each one as
 581         # single line. parse_line() is slow, only use it when necessary.
 582         my @line = (not $line =~ /;/)
 583                  ? ($line)
 584                  : map {
 585                        # Ensure newline at the line end - necessary for
 586                        # correct parsing later.
 587                        $_ =~ s/\s+$//;
 588                        $_ .= "\n";
 589                    } Text::ParseWords::parse_line(';', 1, $line);
 590         foreach $line (@line) {
 591             if ($continuation) {
 592                 $continuation = 0;
 593
 594                 # Join lines, but leave the "\" in place so it's clear where
 595                 # the original line break was.
 596                 chomp $complete_line;
 597                 $complete_line .= ' ' . $line;
 598             }
 599             # Line continuation, line ends with "\".
 600             if ($line =~ /\\\s*$/) {
 601                 $continuation = 1;
 602                 # Start line continuation.
 603                 if (not defined $complete_line) {
 604                     $complete_line = $line;
 605                 }
 606                 next;
 607             }
 608
 609             if (not $continuation) {
 610                 # Use the complete line if a line continuation occurred.
 611                 if (defined $complete_line) {
 612                     $line = $complete_line;
 613                     $complete_line = undef;
 614                 }
 615
 616                 # Ignore lines with no compiler commands.
 617                 next if not $non_verbose
 618                         and not $line =~ /\b$cc_regex(?:\s|\\)/o;
 619                 # Ignore lines with no filenames with extensions. May miss
 620                 # some non-verbose builds (e.g. "gcc -o test" [sic!]), but
 621                 # shouldn't be a problem as the log will most likely contain
 622                 # other non-verbose commands which are detected.
 623                 next if not $non_verbose
 624                         and not $line =~ /$file_extension_regex/o;
 625
 626                 # Ignore false positives.
 627                 #
 628                 # `./configure` output.
 629                 next if not $non_verbose
 630                         and $line =~ /^(?:checking|(?:C|c)onfigure:) /;
 631                 next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 632                                    (?:C|c)ompiler[\s.]*:?\s+
 633                                  /xo;
 634                 next if $line =~ /^\s*(?:- )?(?:HOST_)?(?:CC|CXX)\s*=\s*$cc_regex_full\s*$/o;
 635
 636                 # Check if additional hardening options were used. Used to
 637                 # ensure they are used for the complete build.
 638                 $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie, @def_ldflags_pie);
 639                 $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 640
 641                 push @input, $line;
 642             }
 643         }
 644     }
 645
 646     close $fh;
 647
 648     if (scalar @input == 0) {
 649         if (not $option_buildd) {
 650             print "No compiler commands!\n";
 651         } else {
 652             print "W-no-compiler-commands\n";
 653         }
 654         $exit |= $exit_code{no_compiler_commands};
 655         next FILE;
 656     }
 657
 658     if ($option_buildd) {
 659         $statistics{commands} += scalar @input;
 660     }
 661
 662     # Option or auto detected.
 663     if ($arch) {
 664         # The following was partially copied from dpkg-dev 1.16.1.2
 665         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 666         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 667         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 668         # later. Keep it in sync.
 669
 670         require Dpkg::Arch;
 671         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
 672
 673         # Disable unsupported hardening options.
 674         if ($cpu =~ /^(ia64|alpha|mips|mipsel|hppa)$/ or $arch eq 'arm') {
 675             $harden_stack = 0;
 676         }
 677         if ($cpu =~ /^(ia64|hppa|avr32)$/) {
 678             $harden_relro   = 0;
 679             $harden_bindnow = 0;
 680         }
 681     }
 682
 683     # Default values.
 684     my @cflags   = @def_cflags;
 685     my @cxxflags = @def_cxxflags;
 686     my @cppflags = @def_cppflags;
 687     my @ldflags  = @def_ldflags;
 688     # Check the specified hardening options, same order as dpkg-buildflags.
 689     if ($harden_pie) {
 690         @cflags   = (@cflags,   @def_cflags_pie);
 691         @cxxflags = (@cxxflags, @def_cflags_pie);
 692         @ldflags  = (@ldflags,  @def_ldflags_pie);
 693     }
 694     if ($harden_stack) {
 695         @cflags   = (@cflags,   @def_cflags_stack);
 696         @cxxflags = (@cxxflags, @def_cflags_stack);
 697     }
 698     if ($harden_fortify) {
 699         @cflags   = (@cflags,   @def_cflags_fortify);
 700         @cxxflags = (@cxxflags, @def_cflags_fortify);
 701         @cppflags = (@cppflags, @def_cppflags_fortify);
 702     }
 703     if ($harden_format) {
 704         @cflags   = (@cflags,   @def_cflags_format);
 705         @cxxflags = (@cxxflags, @def_cflags_format);
 706     }
 707     if ($harden_relro) {
 708         @ldflags = (@ldflags, @def_ldflags_relro);
 709     }
 710     if ($harden_bindnow) {
 711         @ldflags = (@ldflags, @def_ldflags_bindnow);
 712     }
 713
 714     for (my $i = 0; $i < scalar @input; $i++) {
 715         my $line = $input[$i];
 716
 717         my $skip = 0;
 718         if (is_non_verbose_build($line, $input[$i + 1], \$skip)) {
 719             if (not $option_buildd) {
 720                 error_non_verbose_build($line);
 721             } else {
 722                 $statistics{commands_nonverbose}++;
 723             }
 724             $exit |= $exit_code{non_verbose_build};
 725             next;
 726         }
 727         # Even if it's a verbose build, we might have to skip this line.
 728         next if $skip;
 729
 730         # Remove everything until and including the compiler command. Makes
 731         # checks easier and faster.
 732         $line =~ s/^.*?$cc_regex//o;
 733         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
 734         # the brace and similar characters.
 735         $line =~ s/['")]+$//;
 736
 737         # Skip unnecessary tests when only preprocessing.
 738         my $flag_preprocess = 0;
 739
 740         my $preprocess = 0;
 741         my $compile    = 0;
 742         my $link       = 0;
 743
 744         # Preprocess, compile, assemble.
 745         if ($line =~ /\s(-E|-S|-c)\b/) {
 746             $preprocess      = 1;
 747             $flag_preprocess = 1 if $1 eq '-E';
 748             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
 749         # Otherwise assume we are linking.
 750         } else {
 751             $link = 1;
 752         }
 753
 754         # Get all file extensions on this line.
 755         my @extensions = $line =~ /$file_extension_regex/go;
 756         # Ignore all unknown extensions to speedup the search below.
 757         @extensions = grep { exists $extension{$_} } @extensions;
 758
 759         # These file types don't require preprocessing.
 760         if (extension_found(\%extensions_no_preprocess, @extensions)) {
 761             $preprocess = 0;
 762         }
 763         # These file types require preprocessing.
 764         if (extension_found(\%extensions_preprocess, @extensions)) {
 765             $preprocess = 1;
 766         }
 767
 768         # If there are source files then it's compiling/linking in one step
 769         # and we must check both. We only check for source files here, because
 770         # header files cause too many false positives.
 771         if (not $flag_preprocess
 772                 and extension_found(\%extensions_compile_link, @extensions)) {
 773             # Assembly files don't need CFLAGS.
 774             if (not extension_found(\%extensions_compile, @extensions)
 775                     and extension_found(\%extensions_no_compile, @extensions)) {
 776                 $compile = 0;
 777             # But the rest does.
 778             } else {
 779                 $compile = 1;
 780             }
 781         }
 782
 783         # Assume CXXFLAGS are required when a C++ file is specified in the
 784         # compiler line.
 785         my $compile_cpp = 0;
 786         if ($compile
 787                 and extension_found(\%extensions_compile_cpp, @extensions)) {
 788             $compile     = 0;
 789             $compile_cpp = 1;
 790         }
 791
 792         if ($option_buildd) {
 793             $statistics{preprocess}++  if $preprocess;
 794             $statistics{compile}++     if $compile;
 795             $statistics{compile_cpp}++ if $compile_cpp;
 796             $statistics{link}++        if $link;
 797         }
 798
 799         # Check hardening flags.
 800         my @missing;
 801         if ($compile and not all_flags_used($line, \@missing, @cflags)
 802                 # Libraries linked with -fPIC don't have to (and can't) be
 803                 # linked with -fPIE as well. It's no error if only PIE flags
 804                 # are missing.
 805                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
 806                 # Assume dpkg-buildflags returns the correct flags.
 807                 and not $line =~ /`dpkg-buildflags --get CFLAGS`/) {
 808             if (not $option_buildd) {
 809                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 810             } else {
 811                 $statistics{compile_missing}++;
 812             }
 813             $exit |= $exit_code{flags_missing};
 814         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
 815                 # Libraries linked with -fPIC don't have to (and can't) be
 816                 # linked with -fPIE as well. It's no error if only PIE flags
 817                 # are missing.
 818                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
 819                 # Assume dpkg-buildflags returns the correct flags.
 820                 and not $line =~ /`dpkg-buildflags --get CXXFLAGS`/) {
 821             if (not $option_buildd) {
 822                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 823             } else {
 824                 $statistics{compile_cpp_missing}++;
 825             }
 826             $exit |= $exit_code{flags_missing};
 827         }
 828         if ($preprocess and not all_flags_used($line, \@missing, @cppflags)
 829                 # Assume dpkg-buildflags returns the correct flags.
 830                 and not $line =~ /`dpkg-buildflags --get CPPFLAGS`/) {
 831             if (not $option_buildd) {
 832                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 833             } else {
 834                 $statistics{preprocess_missing}++;
 835             }
 836             $exit |= $exit_code{flags_missing};
 837         }
 838         if ($link and not all_flags_used($line, \@missing, @ldflags)
 839                 # Same here, -fPIC conflicts with -fPIE.
 840                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
 841                 # Assume dpkg-buildflags returns the correct flags.
 842                 and not $line =~ /`dpkg-buildflags --get LDFLAGS`/) {
 843             if (not $option_buildd) {
 844                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 845             } else {
 846                 $statistics{link_missing}++;
 847             }
 848             $exit |= $exit_code{flags_missing};
 849         }
 850     }
 851 }
 852
 853 # Print statistics for buildd mode, only output in this mode.
 854 if ($option_buildd) {
 855     my @warning;
 856
 857     if ($statistics{preprocess_missing}) {
 858         push @warning, sprintf "CPPFLAGS %d (of %d)",
 859                                $statistics{preprocess_missing},
 860                                $statistics{preprocess};
 861     }
 862     if ($statistics{compile_missing}) {
 863         push @warning, sprintf "CFLAGS %d (of %d)",
 864                                $statistics{compile_missing},
 865                                $statistics{compile};
 866     }
 867     if ($statistics{compile_cpp_missing}) {
 868         push @warning, sprintf "CXXFLAGS %d (of %d)",
 869                                $statistics{compile_cpp_missing},
 870                                $statistics{compile_cpp};
 871     }
 872     if ($statistics{link_missing}) {
 873         push @warning, sprintf "LDFLAGS %d (of %d)",
 874                                $statistics{link_missing},
 875                                $statistics{link};
 876     }
 877     if (scalar @warning) {
 878         local $" = ', '; # array join string
 879         print "W-dpkg-buildflags-missing @warning missing\n";
 880     }
 881
 882     if ($statistics{commands_nonverbose}) {
 883         printf "W-compiler-flags-hidden %d (of %d) hidden\n",
 884                $statistics{commands_nonverbose},
 885                $statistics{commands},
 886     }
 887 }
 888
 889
 890 exit $exit;
 891
 892
 893 __END__
 894
 895 =head1 NAME
 896
 897 blhc - build log hardening check, checks build logs for missing hardening flags
 898
 899 =head1 SYNOPSIS
 900
 901 B<blhc> [I<options>] I<E<lt>dpkg-buildpackage build log fileE<gt>..>
 902
 903 =head1 DESCRIPTION
 904
 905 blhc is a small tool which checks build logs for missing hardening flags and
 906 other important warnings. It's licensed under the GPL 3 or later.
 907
 908 =head1 OPTIONS
 909
 910 =over 8
 911
 912 =item B<--all>
 913
 914 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
 915 auto detected.
 916
 917 =item B<--arch> I<architecture>
 918
 919 Set the specific architecture (e.g. amd64, armel, etc.), automatically
 920 disables hardening flags not available on this architecture. Is detected
 921 automatically if dpkg-buildpackage is used.
 922
 923 =item B<--bindnow>
 924
 925 Force check for all +bindnow hardening flags. By default it's auto detected.
 926
 927 =item B<--buildd>
 928
 929 Special mode for buildds when automatically parsing log files. The following
 930 changes are in effect:
 931
 932 =over 2
 933
 934 =item
 935
 936 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
 937 detected).
 938
 939 =back
 940
 941 =item B<--color>
 942
 943 Use colored (ANSI) output for warning messages.
 944
 945 =item B<--pie>
 946
 947 Force check for all +pie hardening flags. By default it's auto detected.
 948
 949 =item B<-h -? --help>
 950
 951 Print available options.
 952
 953 =item B<--version>
 954
 955 Print version number and license.
 956
 957 =back
 958
 959 Auto detection for B<--pie> and B<--bindnow> only works if at least one
 960 command uses the required hardening flag (e.g. -fPIE). Then it's required for
 961 all other commands as well.
 962
 963 =head1 EXIT STATUS
 964
 965 The exit status is a "bit mask", each listed status is ORed when the error
 966 condition occurs to get the result.
 967
 968 =over 4
 969
 970 =item B<0>
 971
 972 Success.
 973
 974 =item B<1>
 975
 976 No compiler commands were found.
 977
 978 =item B<2>
 979
 980 Invalid arguments/options given to blhc.
 981
 982 =item B<4>
 983
 984 Non verbose build.
 985
 986 =item B<8>
 987
 988 Missing hardening flags.
 989
 990 =item B<16>
 991
 992 Hardening wrapper detected, no tests performed.
 993
 994 =back
 995
 996 =head1 AUTHOR
 997
 998 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
 999
1000 =head1 COPYRIGHT AND LICENSE
1001
1002 Copyright (C) 2012 by Simon Ruderich
1003
1004 This program is free software: you can redistribute it and/or modify
1005 it under the terms of the GNU General Public License as published by
1006 the Free Software Foundation, either version 3 of the License, or
1007 (at your option) any later version.
1008
1009 This program is distributed in the hope that it will be useful,
1010 but WITHOUT ANY WARRANTY; without even the implied warranty of
1011 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1012 GNU General Public License for more details.
1013
1014 You should have received a copy of the GNU General Public License
1015 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1016
1017 =cut