bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.01';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\.)(?:cc|gcc|g\+\+|c\+\+)
  35     (?:-[\d.]+)?
  36     /x;
  37 # Full regex which matches the complete compiler name. Used in a few places to
  38 # prevent false negatives.
  39 my $cc_regex_full = qr/
  40     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  41     $cc_regex
  42     /x;
  43 # Regex to catch (GCC) compiler warnings.
  44 my $warning_regex = qr/^(.+?):([0-9]+):[0-9]+: warning: (.+?) \[(.+?)\]$/;
  45
  46 # List of source file extensions which require preprocessing.
  47 my @source_preprocess_compile_cpp = (
  48     # C++
  49     qw( cc cp cxx cpp CPP c++ C ),
  50     # Objective-C++
  51     qw( mm M ),
  52 );
  53 my @source_preprocess_compile = (
  54     # C
  55     qw( c ),
  56     # Objective-C
  57     qw( m ),
  58     # (Objective-)C++
  59     @source_preprocess_compile_cpp,
  60     # Fortran
  61     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  62 );
  63 my @source_preprocess_no_compile = (
  64     # Assembly
  65     qw( S sx ),
  66 );
  67 my @source_preprocess = (
  68     @source_preprocess_compile,
  69     @source_preprocess_no_compile,
  70 );
  71 # List of source file extensions which don't require preprocessing.
  72 my @source_no_preprocess_compile_cpp = (
  73     # C++
  74     qw( ii ),
  75     # Objective-C++
  76     qw( mii ),
  77 );
  78 my @source_no_preprocess_compile = (
  79     # C
  80     qw( i ),
  81     # (Objective-)C++
  82     @source_no_preprocess_compile_cpp,
  83     # Objective-C
  84     qw( mi ),
  85     # Fortran
  86     qw( f for ftn f90 f95 f03 f08 ),
  87 );
  88 my @source_no_preprocess_no_compile = (
  89     # Assembly
  90     qw( s ),
  91 );
  92 my @source_no_preprocess = (
  93     @source_no_preprocess_compile,
  94     @source_no_preprocess_no_compile,
  95 );
  96 # List of header file extensions which require preprocessing.
  97 my @header_preprocess = (
  98     # C, C++, Objective-C, Objective-C++
  99     qw( h ),
 100     # C++
 101     qw( hh H hp hxx hpp HPP h++ tcc ),
 102 );
 103
 104 # Hashes for fast extensions lookup to check if a file falls in one of these
 105 # categories.
 106 my %extensions_no_preprocess = map { $_ => 1 } (
 107     @source_no_preprocess,
 108 );
 109 my %extensions_preprocess = map { $_ => 1 } (
 110     @header_preprocess,
 111     @source_preprocess,
 112 );
 113 my %extensions_compile_link = map { $_ => 1 } (
 114     @source_preprocess,
 115     @source_no_preprocess,
 116 );
 117 my %extensions_compile = map { $_ => 1 } (
 118     @source_preprocess_compile,
 119     @source_no_preprocess_compile,
 120 );
 121 my %extensions_no_compile = map { $_ => 1 } (
 122     @source_preprocess_no_compile,
 123     @source_no_preprocess_no_compile,
 124 );
 125 my %extensions_compile_cpp = map { $_ => 1 } (
 126     @source_preprocess_compile_cpp,
 127     @source_no_preprocess_compile_cpp,
 128 );
 129 my %extension = map { $_ => 1 } (
 130     @source_no_preprocess,
 131     @header_preprocess,
 132     @source_preprocess,
 133 );
 134
 135 # Regexp to match file extensions.
 136 my $file_extension_regex = qr/
 137     \s
 138     \S+             # Filename without extension.
 139     \.
 140     ([^\/\\.,;:\s]+)# File extension.
 141     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 142                     # word characters at the end and because \b matches double
 143                     # extensions (like .cpp.o). Works always as all lines are
 144                     # terminated with "\n".
 145     /x;
 146
 147 # Expected (hardening) flags. All flags are used as regexps.
 148 my @def_cflags = (
 149     '-g',
 150     '-O(?:2|3)',
 151 );
 152 my @def_cflags_format = (
 153     '-Wformat',
 154     '-Wformat-security',
 155     '-Werror=format-security',
 156 );
 157 my @def_cflags_fortify = (
 158     # fortify needs at least -O1, but -O2 is recommended anyway
 159 );
 160 my @def_cflags_stack = (
 161     '-fstack-protector',
 162     '--param=ssp-buffer-size=4',
 163 );
 164 my @def_cflags_pie = (
 165     '-fPIE',
 166 );
 167 my @def_cxxflags = (
 168     @def_cflags,
 169 );
 170 # @def_cxxflags_* is the same as @def_cflags_*.
 171 my @def_cppflags = ();
 172 my @def_cppflags_fortify = (
 173     '-D_FORTIFY_SOURCE=2',
 174 );
 175 my @def_ldflags = ();
 176 my @def_ldflags_relro = (
 177     '-Wl,(?:-z,)?relro',
 178 );
 179 my @def_ldflags_bindnow = (
 180     '-Wl,(?:-z,)?now',
 181 );
 182 my @def_ldflags_pie = (
 183     '-fPIE',
 184     '-pie',
 185 );
 186 my @def_ldflags_pic = (
 187     '-fPIC',
 188     '-fpic',
 189     '-shared',
 190 );
 191 # References to all flags checked by the parser.
 192 my @flag_refs = (
 193     \@def_cflags,
 194     \@def_cflags_format,
 195     \@def_cflags_fortify,
 196     \@def_cflags_stack,
 197     \@def_cflags_pie,
 198     \@def_cxxflags,
 199     \@def_cppflags,
 200     \@def_cppflags_fortify,
 201     \@def_ldflags,
 202     \@def_ldflags_relro,
 203     \@def_ldflags_bindnow,
 204 );
 205 # References to all used flags.
 206 my @flag_refs_all = (
 207     @flag_refs,
 208     \@def_ldflags_pie,
 209     \@def_ldflags_pic,
 210 );
 211 # Renaming rules for the output so the regex parts are not visible. Also
 212 # stores string values of flag regexps above, see compile_flag_regexp().
 213 my %flag_renames = (
 214     '-O(?:2|3)'         => '-O2',
 215     '-Wl,(?:-z,)?relro' => '-Wl,-z,relro',
 216     '-Wl,(?:-z,)?now'   => '-Wl,-z,now',
 217 );
 218
 219 my %exit_code = (
 220     no_compiler_commands => 1 << 0,
 221     # used by POD::Usage => 1 << 1,
 222     non_verbose_build    => 1 << 2,
 223     flags_missing        => 1 << 3,
 224     hardening_wrapper    => 1 << 4,
 225     invalid_cmake        => 1 << 5,
 226 );
 227
 228 # Statistics of missing flags and non-verbose build commands. Used for
 229 # $option_buildd.
 230 my %statistics = (
 231     preprocess          => 0,
 232     preprocess_missing  => 0,
 233     compile             => 0,
 234     compile_missing     => 0,
 235     compile_cpp         => 0,
 236     compile_cpp_missing => 0,
 237     link                => 0,
 238     link_missing        => 0,
 239     commands            => 0,
 240     commands_nonverbose => 0,
 241 );
 242
 243 # Use colored (ANSI) output?
 244 my $option_color;
 245
 246
 247 # FUNCTIONS
 248
 249 sub error_flags {
 250     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 251
 252     # Get string value of qr//-escaped regexps and if requested rename them.
 253     my @missing_flags = map {
 254             $flag_renames_ref->{$_}
 255         } @{$missing_flags_ref};
 256
 257     my $flags = join ' ', @missing_flags;
 258     printf "%s (%s)%s %s",
 259            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 260            $line;
 261 }
 262 sub error_non_verbose_build {
 263     my ($line) = @_;
 264
 265     printf "%s%s %s",
 266            error_color('NONVERBOSE BUILD', 'red'),
 267            error_color(':', 'yellow'),
 268            $line;
 269 }
 270 sub error_invalid_cmake {
 271     my ($version) = @_;
 272
 273     printf "%s%s %s\n",
 274             error_color('INVALID CMAKE', 'red'),
 275             error_color(':', 'yellow'),
 276             $version;
 277 }
 278 sub error_hardening_wrapper {
 279     printf "%s%s %s\n",
 280             error_color('HARDENING WRAPPER', 'red'),
 281             error_color(':', 'yellow'),
 282             'no checks possible, aborting';
 283 }
 284 sub error_color {
 285     my ($message, $color) = @_;
 286
 287     if ($option_color) {
 288         return Term::ANSIColor::colored($message, $color);
 289     } else {
 290         return $message;
 291     }
 292 }
 293
 294 sub any_flags_used {
 295     my ($line, @flags) = @_;
 296
 297     foreach my $flag (@flags) {
 298         return 1 if $line =~ /$flag/;
 299     }
 300
 301     return 0;
 302 }
 303 sub all_flags_used {
 304     my ($line, $missing_flags_ref, @flags) = @_;
 305
 306     my @missing_flags = ();
 307     foreach my $flag (@flags) {
 308         if (not $line =~ /$flag/) {
 309             push @missing_flags, $flag;
 310         }
 311     }
 312
 313     return 1 if scalar @missing_flags == 0;
 314
 315     @{$missing_flags_ref} = @missing_flags;
 316     return 0;
 317 }
 318
 319 # Modifies $missing_flags_ref array.
 320 sub pic_pie_conflict {
 321     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 322
 323     return 0 if not $pie;
 324     return 0 if not any_flags_used($line, @def_ldflags_pic);
 325
 326     my %flags = map { $_ => 1 } @flags_pie;
 327
 328     # Remove all PIE flags from @missing_flags as they are not required with
 329     # -fPIC.
 330     my @result = grep {
 331         not exists $flags{$_}
 332     } @{$missing_flags_ref};
 333     @{$missing_flags_ref} = @result;
 334
 335     # We got a conflict when no flags are left, thus only PIE flags were
 336     # missing. If other flags were missing abort because the conflict is not
 337     # the problem.
 338     return scalar @result == 0;
 339 }
 340
 341 sub is_non_verbose_build {
 342     my ($line, $next_line, $skip_ref) = @_;
 343
 344     if (not ($line =~ /^checking if you want to see long compiling messages\.\.\. no/
 345                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 346                 or $line =~ /^\s*(?:C|c)ompiling\s+(.+?)(?:\.\.\.)?$/
 347                 or $line =~ /^\s*(?:B|b)uilding (?:program|shared library)\s+(.+?)$/
 348                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 349         return 0;
 350     }
 351
 352     # False positives.
 353     #
 354     # C++ compiler setting.
 355     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 356     # "Compiling" with no file name.
 357     if ($line =~ /^\s*(?:C|c)ompiling\s+(.+?)(?:\.\.\.)?$/) {
 358         # $file_extension_regex may need spaces around the filename.
 359         return 0 if not " $1 " =~ /$file_extension_regex/o;
 360     }
 361
 362     my $file = $1;
 363
 364     # On the first pass we only check if this line is verbose or not.
 365     return 1 if not defined $next_line;
 366
 367     # Second pass, we have access to the next line.
 368     ${$skip_ref} = 0;
 369
 370     # CMake and other build systems print the non-verbose messages also when
 371     # building verbose. If a compiler and the file name occurs in the next
 372     # line, treat it as verbose build.
 373     if (defined $file) {
 374         # Get filename, we can't use the complete path as only parts of it are
 375         # used in the real compiler command.
 376         $file =~ m{/([^/\s]+)$};
 377         $file = $1;
 378
 379         if ($next_line =~ /\Q$file\E/ and $next_line =~ /$cc_regex/o) {
 380             # We still have to skip the current line as it doesn't contain any
 381             # compiler commands.
 382             ${$skip_ref} = 1;
 383             return 0;
 384         }
 385     }
 386
 387     return 1;
 388 }
 389
 390 sub compile_flag_regexp {
 391     my ($flag_renames_ref, @flags) = @_;
 392
 393     my @result = ();
 394     foreach my $flag (@flags) {
 395         # Store flag name in replacement string for correct flags in messages
 396         # with qr//ed flag regexps.
 397         $flag_renames_ref->{qr/\s$flag(?:\s|\\)/}
 398             = (exists $flag_renames_ref->{$flag})
 399                 ? $flag_renames_ref->{$flag}
 400                 : $flag;
 401
 402         # Compile flag regexp for faster execution.
 403         push @result, qr/\s$flag(?:\s|\\)/;
 404     }
 405     return @result;
 406 }
 407
 408 sub extension_found {
 409     my ($extensions_ref, @extensions) = @_;
 410
 411     my $found = 0;
 412     foreach my $extension (@extensions) {
 413         if (exists $extensions_ref->{$extension}) {
 414             $found = 1;
 415             last;
 416         }
 417     }
 418     return $found;
 419 }
 420
 421
 422 # MAIN
 423
 424 # Parse command line arguments.
 425 my $option_help    = 0;
 426 my $option_version = 0;
 427 my $option_pie     = 0;
 428 my $option_bindnow = 0;
 429 my $option_all     = 0;
 430 my $option_arch    = undef;
 431 my $option_buildd  = 0;
 432    $option_color   = 0;
 433 if (not Getopt::Long::GetOptions(
 434             'help|h|?' => \$option_help,
 435             'version'  => \$option_version,
 436             # Hardening options.
 437             'pie'      => \$option_pie,
 438             'bindnow'  => \$option_bindnow,
 439             'all'      => \$option_all,
 440             # Misc.
 441             'color'    => \$option_color,
 442             'arch=s'   => \$option_arch,
 443             'buildd'   => \$option_buildd,
 444         )
 445         or scalar @ARGV == 0) {
 446     require Pod::Usage;
 447     Pod::Usage::pod2usage(2);
 448 }
 449 if ($option_help) {
 450     require Pod::Usage;
 451     Pod::Usage::pod2usage(1);
 452 }
 453 if ($option_version) {
 454     print "blhc $VERSION  Copyright (C) 2012  Simon Ruderich
 455
 456 This program is free software: you can redistribute it and/or modify
 457 it under the terms of the GNU General Public License as published by
 458 the Free Software Foundation, either version 3 of the License, or
 459 (at your option) any later version.
 460
 461 This program is distributed in the hope that it will be useful,
 462 but WITHOUT ANY WARRANTY; without even the implied warranty of
 463 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 464 GNU General Public License for more details.
 465
 466 You should have received a copy of the GNU General Public License
 467 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 468 ";
 469     exit 0;
 470 }
 471
 472 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 473 # installed on Debian's buildds.
 474 if (not $option_buildd) {
 475     require Term::ANSIColor;
 476 }
 477
 478 if ($option_all) {
 479     $option_pie     = 1;
 480     $option_bindnow = 1;
 481 }
 482
 483 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 484 # faster with this.
 485 foreach my $flags (@flag_refs_all) {
 486     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 487 }
 488
 489 # Final exit code.
 490 my $exit = 0;
 491
 492 FILE: foreach my $file (@ARGV) {
 493     print "checking '$file'...\n" if scalar @ARGV > 1;
 494
 495     open my $fh, '<', $file or die "$!: $file";
 496
 497     # Architecture of this file.
 498     my $arch = $option_arch;
 499
 500     # Hardening options. Not all architectures support all hardening options.
 501     my $harden_format  = 1;
 502     my $harden_fortify = 1;
 503     my $harden_stack   = 1;
 504     my $harden_relro   = 1;
 505     my $harden_bindnow = $option_bindnow; # defaults to 0
 506     my $harden_pie     = $option_pie;     # defaults to 0
 507
 508     while (my $line = <$fh>) {
 509         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 510         # check for hardening flags in buildd mode if an older dpkg-dev is
 511         # used. Default flags (-g -O2) are still checked.
 512         #
 513         # Packages which were built before 1.16.1 but used their own hardening
 514         # flags are not checked.
 515         if ($option_buildd and $line =~ /^Toolchain package versions: /) {
 516             require Dpkg::Version;
 517             if ($line !~ /\bdpkg-dev_(\S+)/
 518                     or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
 519                 $harden_format  = 0;
 520                 $harden_fortify = 0;
 521                 $harden_stack   = 0;
 522                 $harden_relro   = 0;
 523                 $harden_bindnow = 0;
 524                 $harden_pie     = 0;
 525             }
 526         }
 527
 528         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 529         # this was later dropped because upstream rejected the patch. Thus
 530         # build logs with these versions will have fortify hardening flags
 531         # enabled, even though they may be not correctly set and are missing
 532         # when build with later CMake versions. Thanks to Aron Xu for letting
 533         # me know.
 534         if ($line =~ /^Package versions: /
 535                 and $line =~ /\bcmake_(\S+)/
 536                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 537             if (not $option_buildd) {
 538                 error_invalid_cmake($1);
 539             } else {
 540                 print "W-invalid-cmake-used $1\n";
 541             }
 542             $exit |= $exit_code{invalid_cmake};
 543         }
 544
 545         # If hardening wrapper is used (wraps calls to gcc and adds hardening
 546         # flags automatically) we can't perform any checks, abort.
 547         if ($line =~ /^Build-Depends: .*\bhardening-wrapper\b/) {
 548             if (not $option_buildd) {
 549                 error_hardening_wrapper();
 550             } else {
 551                 print "I-hardening-wrapper-used\n";
 552             }
 553             $exit |= $exit_code{hardening_wrapper};
 554             next FILE;
 555         }
 556
 557         # We skip over unimportant lines at the beginning of the log to
 558         # prevent false positives.
 559         last if $line =~ /^dpkg-buildpackage:/;
 560     }
 561
 562     # Input lines, contain only the lines with compiler commands.
 563     my @input = ();
 564
 565     my $continuation = 0;
 566     my $complete_line = undef;
 567     while (my $line = <$fh>) {
 568         # And stop at the end of the build log. Package details (reported by
 569         # the buildd logs) are not important for us. This also prevents false
 570         # positives.
 571         last if $line =~ /^Build finished at \d{8}-\d{4}$/;
 572
 573         # Detect architecture automatically unless overridden.
 574         if (not $arch
 575                 and $line =~ /^dpkg-buildpackage: host architecture (.+)$/) {
 576             $arch = $1;
 577         }
 578
 579         # Ignore compiler warnings for now.
 580         next if $line =~ /$warning_regex/o;
 581
 582         if (not $option_buildd and $line =~ /\033/) { # esc
 583             # Remove all ANSI color sequences which are sometimes used in
 584             # non-verbose builds.
 585             $line = Term::ANSIColor::colorstrip($line);
 586             # Also strip '\0xf' (delete previous character), used by Elinks'
 587             # build system.
 588             $line =~ s/\x0f//g;
 589             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 590             # what it does).
 591             $line =~ s/\033\(B//g;
 592         }
 593
 594         # Check if this line indicates a non verbose build.
 595         my $non_verbose = is_non_verbose_build($line);
 596
 597         # One line may contain multiple commands (";"). Treat each one as
 598         # single line. parse_line() is slow, only use it when necessary.
 599         my @line = (not $line =~ /;/)
 600                  ? ($line)
 601                  : map {
 602                        # Ensure newline at the line end - necessary for
 603                        # correct parsing later.
 604                        $_ =~ s/\s+$//;
 605                        $_ .= "\n";
 606                    } Text::ParseWords::parse_line(';', 1, $line);
 607         foreach $line (@line) {
 608             if ($continuation) {
 609                 $continuation = 0;
 610
 611                 # Join lines, but leave the "\" in place so it's clear where
 612                 # the original line break was.
 613                 chomp $complete_line;
 614                 $complete_line .= ' ' . $line;
 615             }
 616             # Line continuation, line ends with "\".
 617             if ($line =~ /\\\s*$/) {
 618                 $continuation = 1;
 619                 # Start line continuation.
 620                 if (not defined $complete_line) {
 621                     $complete_line = $line;
 622                 }
 623                 next;
 624             }
 625
 626             # Use the complete line if a line continuation occurred.
 627             if (defined $complete_line) {
 628                 $line = $complete_line;
 629                 $complete_line = undef;
 630             }
 631
 632             # Ignore lines with no compiler commands.
 633             next if not $non_verbose
 634                     and not $line =~ /\b$cc_regex(?:\s|\\)/o;
 635             # Ignore lines with no filenames with extensions. May miss
 636             # some non-verbose builds (e.g. "gcc -o test" [sic!]), but
 637             # shouldn't be a problem as the log will most likely contain
 638             # other non-verbose commands which are detected.
 639             next if not $non_verbose
 640                     and not $line =~ /$file_extension_regex/o;
 641
 642             # Ignore false positives.
 643             #
 644             # `./configure` output.
 645             next if not $non_verbose
 646                     and $line =~ /^(?:checking|(?:C|c)onfigure:) /;
 647             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 648                                 (?:C|c)ompiler[\s.]*:?\s+
 649                                 /xo;
 650             next if $line =~ /^\s*(?:- )?(?:HOST_)?(?:CC|CXX)\s*=\s*$cc_regex_full\s*$/o;
 651
 652             # Check if additional hardening options were used. Used to
 653             # ensure they are used for the complete build.
 654             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie, @def_ldflags_pie);
 655             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 656
 657             push @input, $line;
 658         }
 659     }
 660
 661     close $fh;
 662
 663     if (scalar @input == 0) {
 664         if (not $option_buildd) {
 665             print "No compiler commands!\n";
 666         } else {
 667             print "W-no-compiler-commands\n";
 668         }
 669         $exit |= $exit_code{no_compiler_commands};
 670         next FILE;
 671     }
 672
 673     if ($option_buildd) {
 674         $statistics{commands} += scalar @input;
 675     }
 676
 677     # Option or auto detected.
 678     if ($arch) {
 679         # The following was partially copied from dpkg-dev 1.16.1.2
 680         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 681         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 682         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 683         # later. Keep it in sync.
 684
 685         require Dpkg::Arch;
 686         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
 687
 688         # Disable unsupported hardening options.
 689         if ($cpu =~ /^(ia64|alpha|mips|mipsel|hppa)$/ or $arch eq 'arm') {
 690             $harden_stack = 0;
 691         }
 692         if ($cpu =~ /^(ia64|hppa|avr32)$/) {
 693             $harden_relro   = 0;
 694             $harden_bindnow = 0;
 695         }
 696     }
 697
 698     # Default values.
 699     my @cflags   = @def_cflags;
 700     my @cxxflags = @def_cxxflags;
 701     my @cppflags = @def_cppflags;
 702     my @ldflags  = @def_ldflags;
 703     # Check the specified hardening options, same order as dpkg-buildflags.
 704     if ($harden_pie) {
 705         @cflags   = (@cflags,   @def_cflags_pie);
 706         @cxxflags = (@cxxflags, @def_cflags_pie);
 707         @ldflags  = (@ldflags,  @def_ldflags_pie);
 708     }
 709     if ($harden_stack) {
 710         @cflags   = (@cflags,   @def_cflags_stack);
 711         @cxxflags = (@cxxflags, @def_cflags_stack);
 712     }
 713     if ($harden_fortify) {
 714         @cflags   = (@cflags,   @def_cflags_fortify);
 715         @cxxflags = (@cxxflags, @def_cflags_fortify);
 716         @cppflags = (@cppflags, @def_cppflags_fortify);
 717     }
 718     if ($harden_format) {
 719         @cflags   = (@cflags,   @def_cflags_format);
 720         @cxxflags = (@cxxflags, @def_cflags_format);
 721     }
 722     if ($harden_relro) {
 723         @ldflags = (@ldflags, @def_ldflags_relro);
 724     }
 725     if ($harden_bindnow) {
 726         @ldflags = (@ldflags, @def_ldflags_bindnow);
 727     }
 728
 729     for (my $i = 0; $i < scalar @input; $i++) {
 730         my $line = $input[$i];
 731
 732         my $skip = 0;
 733         if (is_non_verbose_build($line, $input[$i + 1], \$skip)) {
 734             if (not $option_buildd) {
 735                 error_non_verbose_build($line);
 736             } else {
 737                 $statistics{commands_nonverbose}++;
 738             }
 739             $exit |= $exit_code{non_verbose_build};
 740             next;
 741         }
 742         # Even if it's a verbose build, we might have to skip this line.
 743         next if $skip;
 744
 745         # Remove everything until and including the compiler command. Makes
 746         # checks easier and faster.
 747         $line =~ s/^.*?$cc_regex//o;
 748         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
 749         # the brace and similar characters.
 750         $line =~ s/['")]+$//;
 751
 752         # Skip unnecessary tests when only preprocessing.
 753         my $flag_preprocess = 0;
 754
 755         my $dependency = 0;
 756         my $preprocess = 0;
 757         my $compile    = 0;
 758         my $link       = 0;
 759
 760         # Preprocess, compile, assemble.
 761         if ($line =~ /\s(-E|-S|-c)\b/) {
 762             $preprocess      = 1;
 763             $flag_preprocess = 1 if $1 eq '-E';
 764             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
 765         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
 766         # -MT -MQ) are always used with -M/-MM.
 767         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
 768             $dependency = 1;
 769         # Otherwise assume we are linking.
 770         } else {
 771             $link = 1;
 772         }
 773
 774         # -MD/-MMD also cause dependency generation, but they don't imply -E!
 775         if ($line =~ /\s(?:-MD|-MMD)\b/) {
 776             $dependency      = 0;
 777             $flag_preprocess = 0;
 778         }
 779
 780         # Dependency generation for Makefiles, no preprocessing or other flags
 781         # needed.
 782         next if $dependency;
 783
 784         # Get all file extensions on this line.
 785         my @extensions = $line =~ /$file_extension_regex/go;
 786         # Ignore all unknown extensions to speedup the search below.
 787         @extensions = grep { exists $extension{$_} } @extensions;
 788
 789         # These file types don't require preprocessing.
 790         if (extension_found(\%extensions_no_preprocess, @extensions)) {
 791             $preprocess = 0;
 792         }
 793         # These file types require preprocessing.
 794         if (extension_found(\%extensions_preprocess, @extensions)) {
 795             $preprocess = 1;
 796         }
 797
 798         # If there are source files then it's compiling/linking in one step
 799         # and we must check both. We only check for source files here, because
 800         # header files cause too many false positives.
 801         if (not $flag_preprocess
 802                 and extension_found(\%extensions_compile_link, @extensions)) {
 803             # Assembly files don't need CFLAGS.
 804             if (not extension_found(\%extensions_compile, @extensions)
 805                     and extension_found(\%extensions_no_compile, @extensions)) {
 806                 $compile = 0;
 807             # But the rest does.
 808             } else {
 809                 $compile = 1;
 810             }
 811         }
 812
 813         # Assume CXXFLAGS are required when a C++ file is specified in the
 814         # compiler line.
 815         my $compile_cpp = 0;
 816         if ($compile
 817                 and extension_found(\%extensions_compile_cpp, @extensions)) {
 818             $compile     = 0;
 819             $compile_cpp = 1;
 820         }
 821
 822         if ($option_buildd) {
 823             $statistics{preprocess}++  if $preprocess;
 824             $statistics{compile}++     if $compile;
 825             $statistics{compile_cpp}++ if $compile_cpp;
 826             $statistics{link}++        if $link;
 827         }
 828
 829         # Check hardening flags.
 830         my @missing;
 831         if ($compile and not all_flags_used($line, \@missing, @cflags)
 832                 # Libraries linked with -fPIC don't have to (and can't) be
 833                 # linked with -fPIE as well. It's no error if only PIE flags
 834                 # are missing.
 835                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
 836                 # Assume dpkg-buildflags returns the correct flags.
 837                 and not $line =~ /`dpkg-buildflags --get CFLAGS`/) {
 838             if (not $option_buildd) {
 839                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 840             } else {
 841                 $statistics{compile_missing}++;
 842             }
 843             $exit |= $exit_code{flags_missing};
 844         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
 845                 # Libraries linked with -fPIC don't have to (and can't) be
 846                 # linked with -fPIE as well. It's no error if only PIE flags
 847                 # are missing.
 848                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
 849                 # Assume dpkg-buildflags returns the correct flags.
 850                 and not $line =~ /`dpkg-buildflags --get CXXFLAGS`/) {
 851             if (not $option_buildd) {
 852                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 853             } else {
 854                 $statistics{compile_cpp_missing}++;
 855             }
 856             $exit |= $exit_code{flags_missing};
 857         }
 858         if ($preprocess and not all_flags_used($line, \@missing, @cppflags)
 859                 # Assume dpkg-buildflags returns the correct flags.
 860                 and not $line =~ /`dpkg-buildflags --get CPPFLAGS`/) {
 861             if (not $option_buildd) {
 862                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 863             } else {
 864                 $statistics{preprocess_missing}++;
 865             }
 866             $exit |= $exit_code{flags_missing};
 867         }
 868         if ($link and not all_flags_used($line, \@missing, @ldflags)
 869                 # Same here, -fPIC conflicts with -fPIE.
 870                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
 871                 # Assume dpkg-buildflags returns the correct flags.
 872                 and not $line =~ /`dpkg-buildflags --get LDFLAGS`/) {
 873             if (not $option_buildd) {
 874                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 875             } else {
 876                 $statistics{link_missing}++;
 877             }
 878             $exit |= $exit_code{flags_missing};
 879         }
 880     }
 881 }
 882
 883 # Print statistics for buildd mode, only output in this mode.
 884 if ($option_buildd) {
 885     my @warning;
 886
 887     if ($statistics{preprocess_missing}) {
 888         push @warning, sprintf "CPPFLAGS %d (of %d)",
 889                                $statistics{preprocess_missing},
 890                                $statistics{preprocess};
 891     }
 892     if ($statistics{compile_missing}) {
 893         push @warning, sprintf "CFLAGS %d (of %d)",
 894                                $statistics{compile_missing},
 895                                $statistics{compile};
 896     }
 897     if ($statistics{compile_cpp_missing}) {
 898         push @warning, sprintf "CXXFLAGS %d (of %d)",
 899                                $statistics{compile_cpp_missing},
 900                                $statistics{compile_cpp};
 901     }
 902     if ($statistics{link_missing}) {
 903         push @warning, sprintf "LDFLAGS %d (of %d)",
 904                                $statistics{link_missing},
 905                                $statistics{link};
 906     }
 907     if (scalar @warning) {
 908         local $" = ', '; # array join string
 909         print "W-dpkg-buildflags-missing @warning missing\n";
 910     }
 911
 912     if ($statistics{commands_nonverbose}) {
 913         printf "W-compiler-flags-hidden %d (of %d) hidden\n",
 914                $statistics{commands_nonverbose},
 915                $statistics{commands},
 916     }
 917 }
 918
 919
 920 exit $exit;
 921
 922
 923 __END__
 924
 925 =head1 NAME
 926
 927 blhc - build log hardening check, checks build logs for missing hardening flags
 928
 929 =head1 SYNOPSIS
 930
 931 B<blhc> [I<options>] I<E<lt>dpkg-buildpackage build log fileE<gt>..>
 932
 933 =head1 DESCRIPTION
 934
 935 blhc is a small tool which checks build logs for missing hardening flags and
 936 other important warnings. It's licensed under the GPL 3 or later.
 937
 938 =head1 OPTIONS
 939
 940 =over 8
 941
 942 =item B<--all>
 943
 944 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
 945 auto detected.
 946
 947 =item B<--arch> I<architecture>
 948
 949 Set the specific architecture (e.g. amd64, armel, etc.), automatically
 950 disables hardening flags not available on this architecture. Is detected
 951 automatically if dpkg-buildpackage is used.
 952
 953 =item B<--bindnow>
 954
 955 Force check for all +bindnow hardening flags. By default it's auto detected.
 956
 957 =item B<--buildd>
 958
 959 Special mode for buildds when automatically parsing log files. The following
 960 changes are in effect:
 961
 962 =over 2
 963
 964 =item
 965
 966 Print tags instead of normal warnings, see README file for a list of possible
 967 tags.
 968
 969 =item
 970
 971 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
 972 detected).
 973
 974 =item
 975
 976 Don't require Term::ANSIColor.
 977
 978 =back
 979
 980 =item B<--color>
 981
 982 Use colored (ANSI) output for warning messages.
 983
 984 =item B<--pie>
 985
 986 Force check for all +pie hardening flags. By default it's auto detected.
 987
 988 =item B<-h -? --help>
 989
 990 Print available options.
 991
 992 =item B<--version>
 993
 994 Print version number and license.
 995
 996 =back
 997
 998 Auto detection for B<--pie> and B<--bindnow> only works if at least one
 999 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1000 all other commands as well.
1001
1002 =head1 EXIT STATUS
1003
1004 The exit status is a "bit mask", each listed status is ORed when the error
1005 condition occurs to get the result.
1006
1007 =over 4
1008
1009 =item B<0>
1010
1011 Success.
1012
1013 =item B<1>
1014
1015 No compiler commands were found.
1016
1017 =item B<2>
1018
1019 Invalid arguments/options given to blhc.
1020
1021 =item B<4>
1022
1023 Non verbose build.
1024
1025 =item B<8>
1026
1027 Missing hardening flags.
1028
1029 =item B<16>
1030
1031 Hardening wrapper detected, no tests performed.
1032
1033 =back
1034
1035 =head1 AUTHOR
1036
1037 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1038
1039 =head1 COPYRIGHT AND LICENSE
1040
1041 Copyright (C) 2012 by Simon Ruderich
1042
1043 This program is free software: you can redistribute it and/or modify
1044 it under the terms of the GNU General Public License as published by
1045 the Free Software Foundation, either version 3 of the License, or
1046 (at your option) any later version.
1047
1048 This program is distributed in the hope that it will be useful,
1049 but WITHOUT ANY WARRANTY; without even the implied warranty of
1050 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1051 GNU General Public License for more details.
1052
1053 You should have received a copy of the GNU General Public License
1054 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1055
1056 =cut