bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.03';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full = qr/
  42     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  43     $cc_regex
  44     /x;
  45 # Regex to check if a line contains a compiler command.
  46 my $cc_regex_normal = qr/
  47     \b$cc_regex(?:\s|\\)
  48     /x;
  49 # Regex to catch (GCC) compiler warnings.
  50 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  51
  52 # List of source file extensions which require preprocessing.
  53 my @source_preprocess_compile_cpp = (
  54     # C++
  55     qw( cc cp cxx cpp CPP c++ C ),
  56     # Objective-C++
  57     qw( mm M ),
  58 );
  59 my @source_preprocess_compile = (
  60     # C
  61     qw( c ),
  62     # Objective-C
  63     qw( m ),
  64     # (Objective-)C++
  65     @source_preprocess_compile_cpp,
  66     # Fortran
  67     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  68 );
  69 my @source_preprocess_no_compile = (
  70     # Assembly
  71     qw( S sx ),
  72 );
  73 my @source_preprocess = (
  74     @source_preprocess_compile,
  75     @source_preprocess_no_compile,
  76 );
  77 # List of source file extensions which don't require preprocessing.
  78 my @source_no_preprocess_compile_cpp = (
  79     # C++
  80     qw( ii ),
  81     # Objective-C++
  82     qw( mii ),
  83 );
  84 my @source_no_preprocess_compile_ada = (
  85     # Ada body
  86     qw( adb ),
  87     # If you add another file, fix use of @source_no_preprocess_compile_ada
  88     # below (search for $compile_ada).
  89 );
  90 my @source_no_preprocess_compile = (
  91     # C
  92     qw( i ),
  93     # (Objective-)C++
  94     @source_no_preprocess_compile_cpp,
  95     # Objective-C
  96     qw( mi ),
  97     # Fortran
  98     qw( f for ftn f90 f95 f03 f08 ),
  99     # Ada
 100     @source_no_preprocess_compile_ada,
 101 );
 102 my @source_no_preprocess_no_compile = (
 103     # Assembly
 104     qw( s ),
 105     # Ada specification
 106     qw( ads ),
 107 );
 108 my @source_no_preprocess = (
 109     @source_no_preprocess_compile,
 110     @source_no_preprocess_no_compile,
 111 );
 112 # List of header file extensions which require preprocessing.
 113 my @header_preprocess = (
 114     # C, C++, Objective-C, Objective-C++
 115     qw( h ),
 116     # C++
 117     qw( hh H hp hxx hpp HPP h++ tcc ),
 118 );
 119 # Object files.
 120 my @object = (
 121     # Normal object files.
 122     qw ( o ),
 123     # Libtool object files.
 124     qw ( lo la ),
 125     # Dynamic libraries. bzip2 uses .sho.
 126     qw ( so sho ),
 127     # Static libraries.
 128     qw ( a ),
 129 );
 130
 131 # Hashes for fast extensions lookup to check if a file falls in one of these
 132 # categories.
 133 my %extensions_no_preprocess = map { $_ => 1 } (
 134     # There's no @header_no_preprocess.
 135     @source_no_preprocess,
 136 );
 137 my %extensions_preprocess = map { $_ => 1 } (
 138     @header_preprocess,
 139     @source_preprocess,
 140 );
 141 my %extensions_compile_link = map { $_ => 1 } (
 142     @source_preprocess,
 143     @source_no_preprocess,
 144 );
 145 my %extensions_compile = map { $_ => 1 } (
 146     @source_preprocess_compile,
 147     @source_no_preprocess_compile,
 148 );
 149 my %extensions_no_compile = map { $_ => 1 } (
 150     @source_preprocess_no_compile,
 151     @source_no_preprocess_no_compile,
 152 );
 153 my %extensions_compile_cpp = map { $_ => 1 } (
 154     @source_preprocess_compile_cpp,
 155     @source_no_preprocess_compile_cpp,
 156 );
 157 my %extensions_object = map { $_ => 1 } (
 158     @object,
 159 );
 160 my %extension = map { $_ => 1 } (
 161     @source_no_preprocess,
 162     @header_preprocess,
 163     @source_preprocess,
 164     @object,
 165 );
 166
 167 # Regexp to match file extensions.
 168 my $file_extension_regex = qr/
 169     \s
 170     \S+             # Filename without extension.
 171     \.
 172     ([^\/\\.,;:\s]+)# File extension.
 173     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 174                     # word characters at the end and because \b matches double
 175                     # extensions (like .cpp.o). Works always as all lines are
 176                     # terminated with "\n".
 177     /x;
 178
 179 # Expected (hardening) flags. All flags are used as regexps.
 180 my @def_cflags = (
 181     '-g',
 182     '-O(?:2|3)',
 183 );
 184 my @def_cflags_format = (
 185     '-Wformat',
 186     '-Werror=format-security', # implies -Wformat-security
 187 );
 188 my @def_cflags_fortify = (
 189     # fortify needs at least -O1, but -O2 is recommended anyway
 190 );
 191 my @def_cflags_stack = (
 192     '-fstack-protector',
 193     '--param=ssp-buffer-size=4',
 194 );
 195 my @def_cflags_pie = (
 196     '-fPIE',
 197 );
 198 my @def_cxxflags = (
 199     @def_cflags,
 200 );
 201 # @def_cxxflags_* is the same as @def_cflags_*.
 202 my @def_cppflags = ();
 203 my @def_cppflags_fortify = (
 204     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 205     # If you add another flag fix hack below (search for "Hack to fix").
 206 );
 207 my @def_cppflags_fortify_bad = (
 208     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 209     '-U_FORTIFY_SOURCE',
 210     '-D_FORTIFY_SOURCE=0',
 211     '-D_FORTIFY_SOURCE=1',
 212 );
 213 my @def_ldflags = ();
 214 my @def_ldflags_relro = (
 215     '-Wl,(?:-z,)?relro',
 216 );
 217 my @def_ldflags_bindnow = (
 218     '-Wl,(?:-z,)?now',
 219 );
 220 my @def_ldflags_pie = (
 221     '-fPIE',
 222     '-pie',
 223 );
 224 my @def_ldflags_pic = (
 225     '-fPIC',
 226     '-fpic',
 227     '-shared',
 228 );
 229 # References to all flags checked by the flag checker.
 230 my @flag_refs = (
 231     \@def_cflags,
 232     \@def_cflags_format,
 233     \@def_cflags_fortify,
 234     \@def_cflags_stack,
 235     \@def_cflags_pie,
 236     \@def_cxxflags,
 237     \@def_cppflags,
 238     \@def_cppflags_fortify,
 239     \@def_ldflags,
 240     \@def_ldflags_relro,
 241     \@def_ldflags_bindnow,
 242     \@def_ldflags_pie,
 243 );
 244 # References to all used flags.
 245 my @flag_refs_all = (
 246     @flag_refs,
 247     \@def_cppflags_fortify_bad,
 248     \@def_ldflags_pic,
 249 );
 250 # Renaming rules for the output so the regex parts are not visible. Also
 251 # stores string values of flag regexps above, see compile_flag_regexp().
 252 my %flag_renames = (
 253     '-O(?:2|3)'         => '-O2',
 254     '-Wl,(?:-z,)?relro' => '-Wl,-z,relro',
 255     '-Wl,(?:-z,)?now'   => '-Wl,-z,now',
 256 );
 257
 258 my %exit_code = (
 259     no_compiler_commands => 1 << 0,
 260     # used by POD::Usage => 1 << 1,
 261     non_verbose_build    => 1 << 2,
 262     flags_missing        => 1 << 3,
 263     hardening_wrapper    => 1 << 4,
 264     invalid_cmake        => 1 << 5,
 265 );
 266
 267 my %buildd_tag = (
 268     no_compiler_commands => 'I-no-compiler-commands',
 269     non_verbose_build    => 'W-compiler-flags-hidden',
 270     flags_missing        => 'W-dpkg-buildflags-missing',
 271     hardening_wrapper    => 'I-hardening-wrapper-used',
 272     invalid_cmake        => 'I-invalid-cmake-used',
 273 );
 274
 275 # Statistics of missing flags and non-verbose build commands. Used for
 276 # $option_buildd.
 277 my %statistics = (
 278     preprocess          => 0,
 279     preprocess_missing  => 0,
 280     compile             => 0,
 281     compile_missing     => 0,
 282     compile_cpp         => 0,
 283     compile_cpp_missing => 0,
 284     link                => 0,
 285     link_missing        => 0,
 286     commands            => 0,
 287     commands_nonverbose => 0,
 288 );
 289
 290 # Use colored (ANSI) output?
 291 my $option_color;
 292
 293
 294 # FUNCTIONS
 295
 296 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 297 sub array_equal {
 298     my ($first_ref, $second_ref) = @_;
 299
 300     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 301
 302     my $length = scalar @{$first_ref};
 303     for (my $i = 0; $i < $length; $i++) {
 304         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 305     }
 306
 307     return 1;
 308 }
 309
 310 sub error_flags {
 311     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 312
 313     # Get string value of qr//-escaped regexps and if requested rename them.
 314     my @missing_flags = map {
 315             $flag_renames_ref->{$_}
 316         } @{$missing_flags_ref};
 317
 318     my $flags = join ' ', @missing_flags;
 319     printf '%s (%s)%s %s',
 320            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 321            $line;
 322
 323     return;
 324 }
 325 sub error_non_verbose_build {
 326     my ($line) = @_;
 327
 328     printf '%s%s %s',
 329            error_color('NONVERBOSE BUILD', 'red'),
 330            error_color(':', 'yellow'),
 331            $line;
 332
 333     return;
 334 }
 335 sub error_invalid_cmake {
 336     my ($version) = @_;
 337
 338     printf "%s%s %s\n",
 339             error_color('INVALID CMAKE', 'red'),
 340             error_color(':', 'yellow'),
 341             $version;
 342
 343     return;
 344 }
 345 sub error_hardening_wrapper {
 346     printf "%s%s %s\n",
 347             error_color('HARDENING WRAPPER', 'red'),
 348             error_color(':', 'yellow'),
 349             'no checks possible, aborting';
 350
 351     return;
 352 }
 353 sub error_color {
 354     my ($message, $color) = @_;
 355
 356     if ($option_color) {
 357         return Term::ANSIColor::colored($message, $color);
 358     } else {
 359         return $message;
 360     }
 361 }
 362
 363 sub any_flags_used {
 364     my ($line, @flags) = @_;
 365
 366     foreach my $flag (@flags) {
 367         return 1 if $line =~ /$flag/;
 368     }
 369
 370     return 0;
 371 }
 372 sub all_flags_used {
 373     my ($line, $missing_flags_ref, @flags) = @_;
 374
 375     my @missing_flags = ();
 376     foreach my $flag (@flags) {
 377         if (not $line =~ /$flag/) {
 378             push @missing_flags, $flag;
 379         }
 380     }
 381
 382     return 1 if scalar @missing_flags == 0;
 383
 384     @{$missing_flags_ref} = @missing_flags;
 385     return 0;
 386 }
 387
 388 sub cppflags_fortify_broken {
 389     my ($line, $missing_flags) = @_;
 390
 391     # This doesn't take the position into account, but is a simple solution.
 392     # And if the build system tries to force -D_FORTIFY_SOURCE=0/1, something
 393     # is wrong anyway.
 394
 395     if (any_flags_used($line, @def_cppflags_fortify_bad)) {
 396         # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 397         push @{$missing_flags}, $def_cppflags_fortify[0];
 398         return 1;
 399     }
 400
 401     return 0;
 402 }
 403
 404 # Modifies $missing_flags_ref array.
 405 sub pic_pie_conflict {
 406     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 407
 408     return 0 if not $pie;
 409     return 0 if not any_flags_used($line, @def_ldflags_pic);
 410
 411     my %flags = map { $_ => 1 } @flags_pie;
 412
 413     # Remove all PIE flags from @missing_flags as they are not required with
 414     # -fPIC.
 415     my @result = grep {
 416         not exists $flags{$_}
 417     } @{$missing_flags_ref};
 418     @{$missing_flags_ref} = @result;
 419
 420     # We got a conflict when no flags are left, thus only PIE flags were
 421     # missing. If other flags were missing abort because the conflict is not
 422     # the problem.
 423     return scalar @result == 0;
 424 }
 425
 426 sub is_non_verbose_build {
 427     my ($line, $next_line, $skip_ref) = @_;
 428
 429     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 430                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 431                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 432                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 433                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 434         return 0;
 435     }
 436
 437     # False positives.
 438     #
 439     # C++ compiler setting.
 440     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 441     # "Compiling" with no file name.
 442     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 443         # $file_extension_regex may need spaces around the filename.
 444         return 0 if not " $1 " =~ /$file_extension_regex/o;
 445     }
 446
 447     my $file = $1;
 448
 449     # On the first pass we only check if this line is verbose or not.
 450     return 1 if not defined $next_line;
 451
 452     # Second pass, we have access to the next line.
 453     ${$skip_ref} = 0;
 454
 455     # CMake and other build systems print the non-verbose messages also when
 456     # building verbose. If a compiler and the file name occurs in the next
 457     # line, treat it as verbose build.
 458     if (defined $file) {
 459         # Get filename, we can't use the complete path as only parts of it are
 460         # used in the real compiler command.
 461         $file =~ m{/([^/\s]+)$};
 462         $file = $1;
 463
 464         if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 465             # Not a non-verbose line, but we still have to skip the current line
 466             # as it doesn't contain any compiler commands.
 467             ${$skip_ref} = 1;
 468             return 0;
 469         }
 470     }
 471
 472     return 1;
 473 }
 474
 475 sub remove_flags {
 476     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 477
 478     my %removes = map { $_ => 1 } @flags;
 479     foreach my $flags (@{$flag_refs_ref}) {
 480         @{$flags} = grep {
 481             # Flag found as string.
 482             not exists $removes{$_}
 483             # Flag found as string representation of regexp.
 484                 and (not defined $flag_renames_ref->{$_}
 485                         or not exists $removes{$flag_renames_ref->{$_}})
 486         } @{$flags};
 487     }
 488
 489     return;
 490 }
 491
 492 sub compile_flag_regexp {
 493     my ($flag_renames_ref, @flags) = @_;
 494
 495     my @result = ();
 496     foreach my $flag (@flags) {
 497         # Store flag name in replacement string for correct flags in messages
 498         # with qr//ed flag regexps.
 499         $flag_renames_ref->{qr/\s$flag(?:\s|\\)/}
 500             = (exists $flag_renames_ref->{$flag})
 501                 ? $flag_renames_ref->{$flag}
 502                 : $flag;
 503
 504         # Compile flag regexp for faster execution.
 505         push @result, qr/\s$flag(?:\s|\\)/;
 506     }
 507     return @result;
 508 }
 509
 510 sub extension_found {
 511     my ($extensions_ref, @extensions) = @_;
 512
 513     my $found = 0;
 514     foreach my $extension (@extensions) {
 515         if (exists $extensions_ref->{$extension}) {
 516             $found = 1;
 517             last;
 518         }
 519     }
 520     return $found;
 521 }
 522
 523
 524 # MAIN
 525
 526 # Parse command line arguments.
 527 my $option_help             = 0;
 528 my $option_version          = 0;
 529 my $option_pie              = 0;
 530 my $option_bindnow          = 0;
 531 my @option_ignore_arch      = ();
 532 my @option_ignore_flag      = ();
 533 my @option_ignore_arch_flag = ();
 534 my @option_ignore_line      = ();
 535 my @option_ignore_arch_line = ();
 536 my $option_all              = 0;
 537 my $option_arch             = undef;
 538 my $option_buildd           = 0;
 539    $option_color            = 0;
 540 if (not Getopt::Long::GetOptions(
 541             'help|h|?'           => \$option_help,
 542             'version'            => \$option_version,
 543             # Hardening options.
 544             'pie'                => \$option_pie,
 545             'bindnow'            => \$option_bindnow,
 546             'all'                => \$option_all,
 547             # Ignore.
 548             'ignore-arch=s'      => \@option_ignore_arch,
 549             'ignore-flag=s'      => \@option_ignore_flag,
 550             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 551             'ignore-line=s'      => \@option_ignore_line,
 552             'ignore-arch-line=s' => \@option_ignore_arch_line,
 553             # Misc.
 554             'color'              => \$option_color,
 555             'arch=s'             => \$option_arch,
 556             'buildd'             => \$option_buildd,
 557         )) {
 558     require Pod::Usage;
 559     Pod::Usage::pod2usage(2);
 560 }
 561 if ($option_help) {
 562     require Pod::Usage;
 563     Pod::Usage::pod2usage(1);
 564 }
 565 if ($option_version) {
 566     print "blhc $VERSION  Copyright (C) 2012  Simon Ruderich
 567
 568 This program is free software: you can redistribute it and/or modify
 569 it under the terms of the GNU General Public License as published by
 570 the Free Software Foundation, either version 3 of the License, or
 571 (at your option) any later version.
 572
 573 This program is distributed in the hope that it will be useful,
 574 but WITHOUT ANY WARRANTY; without even the implied warranty of
 575 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 576 GNU General Public License for more details.
 577
 578 You should have received a copy of the GNU General Public License
 579 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 580 ";
 581     exit 0;
 582 }
 583
 584 # Arguments missing.
 585 if (scalar @ARGV == 0) {
 586     require Pod::Usage;
 587     Pod::Usage::pod2usage(2);
 588 }
 589
 590 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 591 # installed on Debian's buildds.
 592 if (not $option_buildd) {
 593     require Term::ANSIColor;
 594 }
 595
 596 if ($option_all) {
 597     $option_pie     = 1;
 598     $option_bindnow = 1;
 599 }
 600
 601 # Precompiled ignores for faster lookup.
 602 my %option_ignore_arch_flag = ();
 603 my %option_ignore_arch_line = ();
 604
 605 # Strip flags which should be ignored.
 606 if (scalar @option_ignore_flag > 0) {
 607     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 608 }
 609 # Same for arch specific ignore flags, but only prepare here.
 610 if (scalar @option_ignore_arch_flag > 0) {
 611     foreach my $ignore (@option_ignore_arch_flag) {
 612         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 613
 614         if (not $ignore_arch or not $ignore_flag) {
 615             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 616                         . '("arch:flag" expected)' . "\n", $ignore;
 617             require Pod::Usage;
 618             Pod::Usage::pod2usage(2);
 619         }
 620
 621         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 622     }
 623 }
 624
 625 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 626 # faster with this.
 627 foreach my $flags (@flag_refs_all) {
 628     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 629 }
 630
 631 # Precompile ignore line regexps, also anchor at beginning and end of line.
 632 foreach my $ignore (@option_ignore_line) {
 633     $ignore = qr/^$ignore$/;
 634 }
 635 # Same for arch specific ignore lines.
 636 if (scalar @option_ignore_arch_line > 0) {
 637     foreach my $ignore (@option_ignore_arch_line) {
 638         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 639
 640         if (not $ignore_arch or not $ignore_line) {
 641             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 642                         . '("arch:line" expected)' . "\n", $ignore;
 643             require Pod::Usage;
 644             Pod::Usage::pod2usage(2);
 645         }
 646
 647         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 648     }
 649 }
 650
 651 # Final exit code.
 652 my $exit = 0;
 653
 654 FILE:
 655 foreach my $file (@ARGV) {
 656     print "checking '$file'...\n" if scalar @ARGV > 1;
 657
 658     -f $file or die "No such file: $file";
 659
 660     open my $fh, '<', $file or die $!;
 661
 662     # Architecture of this file.
 663     my $arch = $option_arch;
 664
 665     # Hardening options. Not all architectures support all hardening options.
 666     my $harden_format  = 1;
 667     my $harden_fortify = 1;
 668     my $harden_stack   = 1;
 669     my $harden_relro   = 1;
 670     my $harden_bindnow = $option_bindnow; # defaults to 0
 671     my $harden_pie     = $option_pie;     # defaults to 0
 672
 673     # Does this build log use ada? Ada also uses gcc as compiler but uses
 674     # different CFLAGS. But only perform ada checks if an ada compiler used
 675     # for performance reasons.
 676     my $ada = 0;
 677
 678     while (my $line = <$fh>) {
 679         # Detect architecture automatically unless overridden. For buildd logs
 680         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 681         # build logs which aren't built (wrong architecture, build error,
 682         # etc.).
 683         if (not $arch and index($line, 'Architecture: ') == 0) {
 684             $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 685         }
 686
 687         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 688         # check for hardening flags in buildd mode if an older dpkg-dev is
 689         # used. Default flags (-g -O2) are still checked.
 690         #
 691         # Packages which were built before 1.16.1 but used their own hardening
 692         # flags are not checked.
 693         if ($option_buildd
 694                 and index($line, 'Toolchain package versions: ') == 0) {
 695             require Dpkg::Version;
 696             if (not $line =~ /\bdpkg-dev_(\S+)/
 697                     or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
 698                 $harden_format  = 0;
 699                 $harden_fortify = 0;
 700                 $harden_stack   = 0;
 701                 $harden_relro   = 0;
 702                 $harden_bindnow = 0;
 703                 $harden_pie     = 0;
 704             }
 705         }
 706
 707         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 708         # this was later dropped because upstream rejected the patch. Thus
 709         # build logs with these versions will have fortify hardening flags
 710         # enabled, even though they may be not correctly set and are missing
 711         # when build with later CMake versions. Thanks to Aron Xu for letting
 712         # me know.
 713         if (index($line, 'Package versions: ') == 0
 714                 and $line =~ /\bcmake_(\S+)/
 715                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 716             if (not $option_buildd) {
 717                 error_invalid_cmake($1);
 718                 $exit |= $exit_code{invalid_cmake};
 719             } else {
 720                 print "$buildd_tag{invalid_cmake}|$1|\n";
 721             }
 722         }
 723
 724         if (index($line, 'Build-Depends: ') == 0) {
 725             # If hardening wrapper is used (wraps calls to gcc and adds
 726             # hardening flags automatically) we can't perform any checks,
 727             # abort.
 728             if ($line =~ /\bhardening-wrapper\b/) {
 729                 if (not $option_buildd) {
 730                     error_hardening_wrapper();
 731                     $exit |= $exit_code{hardening_wrapper};
 732                 } else {
 733                     print "$buildd_tag{hardening_wrapper}||\n";
 734                 }
 735                 next FILE;
 736             }
 737
 738             # Ada compiler.
 739             if ($line =~ /\bgnat\b/) {
 740                 $ada = 1;
 741             }
 742         }
 743
 744         # We skip over unimportant lines at the beginning of the log to
 745         # prevent false positives.
 746         last if index($line, 'dpkg-buildpackage: ') == 0;
 747     }
 748
 749     # Input lines, contain only the lines with compiler commands.
 750     my @input = ();
 751     # Non-verbose lines in the input. Used to reduce calls to
 752     # is_non_verbose_build() (which is quite slow) in the second loop when
 753     # it's already clear if a line is non-verbose or not.
 754     my @input_nonverbose = ();
 755
 756     my $continuation = 0;
 757     my $complete_line = undef;
 758     while (my $line = <$fh>) {
 759         # And stop at the end of the build log. Package details (reported by
 760         # the buildd logs) are not important for us. This also prevents false
 761         # positives.
 762         last if index($line, 'Build finished at ') == 0
 763                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 764
 765         # Detect architecture automatically unless overridden.
 766         if (not $arch
 767                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 768             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 769         }
 770
 771         # Ignore compiler warnings for now.
 772         next if $line =~ /$warning_regex/o;
 773
 774         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 775             # Remove all ANSI color sequences which are sometimes used in
 776             # non-verbose builds.
 777             $line = Term::ANSIColor::colorstrip($line);
 778             # Also strip '\0xf' (delete previous character), used by Elinks'
 779             # build system.
 780             $line =~ s/\x0f//g;
 781             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 782             # what it does).
 783             $line =~ s/\033\(B//g;
 784         }
 785
 786         # Check if this line indicates a non verbose build.
 787         my $non_verbose = is_non_verbose_build($line);
 788
 789         # One line may contain multiple commands (";"). Treat each one as
 790         # single line. parse_line() is slow, only use it when necessary.
 791         my @line = (index($line, ';') == -1)
 792                  ? ($line)
 793                  : map {
 794                        # Ensure newline at the line end - necessary for
 795                        # correct parsing later.
 796                        $_ =~ s/\s+$//;
 797                        $_ .= "\n";
 798                    } Text::ParseWords::parse_line(';', 1, $line);
 799         foreach my $line (@line) {
 800             if ($continuation) {
 801                 $continuation = 0;
 802
 803                 # Join lines, but leave the "\" in place so it's clear where
 804                 # the original line break was.
 805                 chomp $complete_line;
 806                 $complete_line .= ' ' . $line;
 807             }
 808             # Line continuation, line ends with "\".
 809             if ($line =~ /\\$/) {
 810                 $continuation = 1;
 811                 # Start line continuation.
 812                 if (not defined $complete_line) {
 813                     $complete_line = $line;
 814                 }
 815                 next;
 816             }
 817
 818             # Use the complete line if a line continuation occurred.
 819             if (defined $complete_line) {
 820                 $line = $complete_line;
 821                 $complete_line = undef;
 822             }
 823
 824             # Ignore lines with no compiler commands.
 825             next if not $non_verbose
 826                     and not $line =~ /$cc_regex_normal/o;
 827             # Ignore lines with no filenames with extensions. May miss some
 828             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
 829             # a problem as the log will most likely contain other non-verbose
 830             # commands which are detected.
 831             next if not $non_verbose
 832                     and not $line =~ /$file_extension_regex/o;
 833
 834             # Ignore false positives.
 835             #
 836             # `./configure` output.
 837             next if not $non_verbose
 838                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
 839             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 840                                 [Cc]ompiler[\s.]*:?\s+
 841                                 /x;
 842             next if $line =~ /^\s*(?:- )?(?:HOST_)?(?:CC|CXX)\s*=\s*$cc_regex_full\s*$/o;
 843             # `moc-qt4`, contains '-I/usr/share/qt4/mkspecs/linux-g++' (or
 844             # similar for other architectures) which gets recognized as a
 845             # compiler line. Ignore it.
 846             next if $line =~ m{^/usr/bin/moc-qt4
 847                                \s.+\s
 848                                -I/usr/share/qt4/mkspecs/[a-z]+-g\++(?:-64)?
 849                                \s}x;
 850             # Ignore false positives when the line contains only CC=gcc but no
 851             # other gcc command.
 852             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
 853                 my $before = $1;
 854                 my $after  = $2;
 855                 next if     not $before =~ /$cc_regex_normal/o
 856                         and not $after  =~ /$cc_regex_normal/o;
 857             }
 858
 859             # Check if additional hardening options were used. Used to ensure
 860             # they are used for the complete build.
 861             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
 862                                                          @def_ldflags_pie);
 863             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 864
 865             push @input, $line;
 866             push @input_nonverbose, $non_verbose;
 867         }
 868     }
 869
 870     close $fh or die $!;
 871
 872     # Ignore arch if requested.
 873     if (scalar @option_ignore_arch > 0 and $arch) {
 874         foreach my $ignore (@option_ignore_arch) {
 875             if ($arch eq $ignore) {
 876                 print "ignoring architecture '$arch'\n";
 877                 next FILE;
 878             }
 879         }
 880     }
 881
 882     if (scalar @input == 0) {
 883         if (not $option_buildd) {
 884             print "No compiler commands!\n";
 885             $exit |= $exit_code{no_compiler_commands};
 886         } else {
 887             print "$buildd_tag{no_compiler_commands}||\n";
 888         }
 889         next FILE;
 890     }
 891
 892     if ($option_buildd) {
 893         $statistics{commands} += scalar @input;
 894     }
 895
 896     # Option or auto detected.
 897     if ($arch) {
 898         # The following was partially copied from dpkg-dev 1.16.4.3
 899         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 900         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 901         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 902         # later. Keep it in sync.
 903
 904         require Dpkg::Arch;
 905         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
 906
 907         # Disable unsupported hardening options.
 908         if ($cpu =~ /^(?:ia64|alpha|mips|mipsel|hppa)$/ or $arch eq 'arm') {
 909             $harden_stack = 0;
 910         }
 911         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
 912             $harden_relro   = 0;
 913             $harden_bindnow = 0;
 914         }
 915     }
 916
 917     # Default values.
 918     my @cflags   = @def_cflags;
 919     my @cxxflags = @def_cxxflags;
 920     my @cppflags = @def_cppflags;
 921     my @ldflags  = @def_ldflags;
 922     # Check the specified hardening options, same order as dpkg-buildflags.
 923     if ($harden_pie) {
 924         @cflags   = (@cflags,   @def_cflags_pie);
 925         @cxxflags = (@cxxflags, @def_cflags_pie);
 926         @ldflags  = (@ldflags,  @def_ldflags_pie);
 927     }
 928     if ($harden_stack) {
 929         @cflags   = (@cflags,   @def_cflags_stack);
 930         @cxxflags = (@cxxflags, @def_cflags_stack);
 931     }
 932     if ($harden_fortify) {
 933         @cflags   = (@cflags,   @def_cflags_fortify);
 934         @cxxflags = (@cxxflags, @def_cflags_fortify);
 935         @cppflags = (@cppflags, @def_cppflags_fortify);
 936     }
 937     if ($harden_format) {
 938         @cflags   = (@cflags,   @def_cflags_format);
 939         @cxxflags = (@cxxflags, @def_cflags_format);
 940     }
 941     if ($harden_relro) {
 942         @ldflags = (@ldflags, @def_ldflags_relro);
 943     }
 944     if ($harden_bindnow) {
 945         @ldflags = (@ldflags, @def_ldflags_bindnow);
 946     }
 947
 948     # Stores normal CFLAGS when @cflags_ada are temporarily used.
 949     my @cflags_backup;
 950     # Ada CFLAGS.
 951     my @cflags_ada = @cflags;
 952     # Ada doesn't support format hardening flags, see #680117 for more
 953     # information. Filter them out if ada is used.
 954     if ($ada and $harden_format) {
 955         @cflags_ada = grep {
 956             my $ok = 1;
 957             foreach my $flag (@def_cflags_format) {
 958                 $ok = 0 if $_ eq $flag;
 959             }
 960             $ok;
 961         } @cflags;
 962     }
 963
 964     # Hack to fix cppflags_fortify_broken() if --ignore-flag
 965     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
 966     # as long as @def_cppflags_fortify contains only one variable.
 967     if (scalar @def_cppflags_fortify == 0) {
 968         $harden_fortify = 0;
 969     }
 970
 971     # Ignore flags for this arch if requested.
 972     if ($arch and exists $option_ignore_arch_flag{$arch}) {
 973         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
 974
 975         remove_flags(\@local_flag_refs,
 976                      \%flag_renames,
 977                      @{$option_ignore_arch_flag{$arch}});
 978     }
 979
 980     my @ignore_line = @option_ignore_line;
 981     # Ignore lines for this arch if requested.
 982     if ($arch and exists $option_ignore_arch_line{$arch}) {
 983         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
 984     }
 985
 986 LINE:
 987     for (my $i = 0; $i < scalar @input; $i++) {
 988         my $line = $input[$i];
 989
 990         # Ignore line if requested.
 991         foreach my $ignore (@ignore_line) {
 992             next LINE if $line =~ /$ignore/;
 993         }
 994
 995         my $skip = 0;
 996         if ($input_nonverbose[$i]
 997                 and is_non_verbose_build($line, $input[$i + 1], \$skip)) {
 998             if (not $option_buildd) {
 999                 error_non_verbose_build($line);
1000                 $exit |= $exit_code{non_verbose_build};
1001             } else {
1002                 $statistics{commands_nonverbose}++;
1003             }
1004             next;
1005         }
1006         # Even if it's a verbose build, we might have to skip this line.
1007         next if $skip;
1008
1009         # Remove everything until and including the compiler command. Makes
1010         # checks easier and faster.
1011         $line =~ s/^.*?$cc_regex//o;
1012         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1013         # the brace and similar characters at the line end.
1014         $line =~ s/['")]+$//;
1015
1016         # Skip unnecessary tests when only preprocessing.
1017         my $flag_preprocess = 0;
1018
1019         my $dependency = 0;
1020         my $preprocess = 0;
1021         my $compile    = 0;
1022         my $link       = 0;
1023
1024         # Preprocess, compile, assemble.
1025         if ($line =~ /\s(-E|-S|-c)\b/) {
1026             $preprocess      = 1;
1027             $flag_preprocess = 1 if $1 eq '-E';
1028             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1029         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1030         # -MT -MQ) are always used with -M/-MM.
1031         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1032             $dependency = 1;
1033         # Otherwise assume we are linking.
1034         } else {
1035             $link = 1;
1036         }
1037
1038         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1039         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1040             $dependency      = 0;
1041             $flag_preprocess = 0;
1042         }
1043
1044         # Dependency generation for Makefiles, no preprocessing or other flags
1045         # needed.
1046         next if $dependency;
1047
1048         # Get all file extensions on this line.
1049         my @extensions = $line =~ /$file_extension_regex/go;
1050         # Ignore all unknown extensions to speedup the search below.
1051         @extensions = grep { exists $extension{$_} } @extensions;
1052
1053         # These file types don't require preprocessing.
1054         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1055             $preprocess = 0;
1056         }
1057         # These file types require preprocessing.
1058         if (extension_found(\%extensions_preprocess, @extensions)) {
1059             $preprocess = 1;
1060         }
1061
1062         if (not $flag_preprocess) {
1063             # If there are source files then it's compiling/linking in one
1064             # step and we must check both. We only check for source files
1065             # here, because header files cause too many false positives.
1066             if (extension_found(\%extensions_compile_link, @extensions)) {
1067                 # Assembly files don't need CFLAGS.
1068                 if (not extension_found(\%extensions_compile, @extensions)
1069                         and extension_found(\%extensions_no_compile, @extensions)) {
1070                     $compile = 0;
1071                 # But the rest does.
1072                 } else {
1073                     $compile = 1;
1074                 }
1075             # No compilable extensions found, either linking or compiling
1076             # header flags.
1077             #
1078             # If there are also no object files we are just compiling headers
1079             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1080             # to our liberal checks for compiler lines, this also reduces the
1081             # number of false positives considerably.
1082             } elsif ($link
1083                     and not extension_found(\%extensions_object, @extensions)) {
1084                 $link = 0;
1085             }
1086         }
1087
1088         my $compile_cpp = 0;
1089         my $compile_ada = 0;
1090         # Assume CXXFLAGS are required when a C++ file is specified in the
1091         # compiler line.
1092         if ($compile
1093                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1094             $compile     = 0;
1095             $compile_cpp = 1;
1096         # Ada needs special CFLAGS, use them if only ada files are compiled.
1097         } elsif ($ada
1098                     and $compile
1099                     and array_equal(\@extensions,
1100                                     \@source_no_preprocess_compile_ada)) {
1101             $compile_ada = 1;
1102             @cflags_backup = @cflags;
1103             @cflags        = @cflags_ada;
1104         }
1105
1106         if ($option_buildd) {
1107             $statistics{preprocess}++  if $preprocess;
1108             $statistics{compile}++     if $compile;
1109             $statistics{compile_cpp}++ if $compile_cpp;
1110             $statistics{link}++        if $link;
1111         }
1112
1113         # Check hardening flags.
1114         my @missing;
1115         if ($compile and not all_flags_used($line, \@missing, @cflags)
1116                 # Libraries linked with -fPIC don't have to (and can't) be
1117                 # linked with -fPIE as well. It's no error if only PIE flags
1118                 # are missing.
1119                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1120                 # Assume dpkg-buildflags returns the correct flags.
1121                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1122             if (not $option_buildd) {
1123                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1124                 $exit |= $exit_code{flags_missing};
1125             } else {
1126                 $statistics{compile_missing}++;
1127             }
1128         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1129                 # Libraries linked with -fPIC don't have to (and can't) be
1130                 # linked with -fPIE as well. It's no error if only PIE flags
1131                 # are missing.
1132                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1133                 # Assume dpkg-buildflags returns the correct flags.
1134                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1135             if (not $option_buildd) {
1136                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1137                 $exit |= $exit_code{flags_missing};
1138             } else {
1139                 $statistics{compile_cpp_missing}++;
1140             }
1141         }
1142         if ($preprocess
1143                 and (not all_flags_used($line, \@missing, @cppflags)
1144                     # The fortify flag might be overwritten, detect that.
1145                      or ($harden_fortify
1146                          and cppflags_fortify_broken($line, \@missing)))
1147                 # Assume dpkg-buildflags returns the correct flags.
1148                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1149             if (not $option_buildd) {
1150                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1151                 $exit |= $exit_code{flags_missing};
1152             } else {
1153                 $statistics{preprocess_missing}++;
1154             }
1155         }
1156         if ($link and not all_flags_used($line, \@missing, @ldflags)
1157                 # Same here, -fPIC conflicts with -fPIE.
1158                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1159                 # Assume dpkg-buildflags returns the correct flags.
1160                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1161             if (not $option_buildd) {
1162                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1163                 $exit |= $exit_code{flags_missing};
1164             } else {
1165                 $statistics{link_missing}++;
1166             }
1167         }
1168
1169         # Restore normal CFLAGS.
1170         if ($compile_ada) {
1171             @cflags = @cflags_backup;
1172         }
1173     }
1174 }
1175
1176 # Print statistics for buildd mode, only output in this mode.
1177 if ($option_buildd) {
1178     my @warning;
1179
1180     if ($statistics{preprocess_missing}) {
1181         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1182                                $statistics{preprocess_missing},
1183                                $statistics{preprocess};
1184     }
1185     if ($statistics{compile_missing}) {
1186         push @warning, sprintf 'CFLAGS %d (of %d)',
1187                                $statistics{compile_missing},
1188                                $statistics{compile};
1189     }
1190     if ($statistics{compile_cpp_missing}) {
1191         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1192                                $statistics{compile_cpp_missing},
1193                                $statistics{compile_cpp};
1194     }
1195     if ($statistics{link_missing}) {
1196         push @warning, sprintf 'LDFLAGS %d (of %d)',
1197                                $statistics{link_missing},
1198                                $statistics{link};
1199     }
1200     if (scalar @warning) {
1201         local $" = ', '; # array join string
1202         print "$buildd_tag{flags_missing}|@warning missing|\n";
1203     }
1204
1205     if ($statistics{commands_nonverbose}) {
1206         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1207                $statistics{commands_nonverbose},
1208                $statistics{commands},
1209     }
1210 }
1211
1212
1213 exit $exit;
1214
1215
1216 __END__
1217
1218 =head1 NAME
1219
1220 blhc - build log hardening check, checks build logs for missing hardening flags
1221
1222 =head1 SYNOPSIS
1223
1224 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1225
1226 =head1 DESCRIPTION
1227
1228 blhc is a small tool which checks build logs for missing hardening flags. It's
1229 licensed under the GPL 3 or later.
1230
1231 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1232 tools using dpkg-buildpackage like pbuilder or the official buildd build logs)
1233 to help maintainers detect missing hardening flags in their packages.
1234
1235 Only gcc is detected as compiler at the moment. If other compilers support
1236 hardening flags as well, please report them.
1237
1238 If there's no output, no flags are missing and the build log is fine.
1239
1240 =head1 OPTIONS
1241
1242 =over 8
1243
1244 =item B<--all>
1245
1246 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1247 auto detected.
1248
1249 =item B<--arch> I<architecture>
1250
1251 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1252 disables hardening flags not available on this architecture. Is detected
1253 automatically if dpkg-buildpackage is used.
1254
1255 =item B<--bindnow>
1256
1257 Force check for all +bindnow hardening flags. By default it's auto detected.
1258
1259 =item B<--buildd>
1260
1261 Special mode for buildds when automatically parsing log files. The following
1262 changes are in effect:
1263
1264 =over 2
1265
1266 =item *
1267
1268 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1269 possible tags.
1270
1271 =item *
1272
1273 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1274 detected).
1275
1276 =item *
1277
1278 Don't require Term::ANSIColor.
1279
1280 =item *
1281
1282 Return exit code 0, unless there was a error (-I, -W messages don't count as
1283 error).
1284
1285 =back
1286
1287 =item B<--color>
1288
1289 Use colored (ANSI) output for warning messages.
1290
1291 =item B<--ignore-arch> I<arch>
1292
1293 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1294
1295 Used to prevent false positives. This option can be specified multiple times.
1296
1297 =item B<--ignore-arch-flag> I<arch>:I<flag>
1298
1299 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1300
1301 =item B<--ignore-arch-line> I<arch>:I<line>
1302
1303 Like B<--ignore-line>, but only ignore line on I<arch>.
1304
1305 =item B<--ignore-flag> I<flag>
1306
1307 Don't print an error when the specific flag is missing in a compiler line.
1308 I<flag> is a string.
1309
1310 Used to prevent false positives. This option can be specified multiple times.
1311
1312 =item B<--ignore-line> I<regex>
1313
1314 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1315 at the beginning and end of the line to prevent false negatives.
1316
1317 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1318 warnings (which have line continuation resolved).
1319
1320 Used to prevent false positives. This option can be specified multiple times.
1321
1322 =item B<--pie>
1323
1324 Force check for all +pie hardening flags. By default it's auto detected.
1325
1326 =item B<-h -? --help>
1327
1328 Print available options.
1329
1330 =item B<--version>
1331
1332 Print version number and license.
1333
1334 =back
1335
1336 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1337 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1338 all other commands as well.
1339
1340 =head1 EXAMPLES
1341
1342 Normal usage, parse a single log file.
1343
1344     blhc path/to/log/file
1345
1346 If there's no output, no flags are missing and the build log is fine.
1347
1348 Parse multiple log files. The exit code is ORed over all files.
1349
1350     blhc path/to/directory/with/log/files/*
1351
1352 Don't treat missing C<-g> as error:
1353
1354     blhc --ignore-flag -g path/to/log/file
1355
1356 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1357
1358     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1359
1360 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1361 false positive.
1362
1363     blhc --ignore-line '\./script gcc file' path/to/log/file
1364
1365 Ignore lines matching C<./script gcc file> somewhere in the line.
1366
1367     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1368
1369 Use blhc with pbuilder.
1370
1371     pbuilder path/to/package.dsc | tee path/log/file
1372     blhc path/to/file || echo flags missing
1373
1374 =head1 BUILDD TAGS
1375
1376 The following tags are used in I<--buildd> mode. In braces the additional data
1377 which is displayed.
1378
1379 =over 2
1380
1381 =item B<I-hardening-wrapper-used>
1382
1383 The package uses hardening-wrapper which intercepts calls to gcc and adds
1384 hardening flags. The build log doesn't contain any hardening flags and thus
1385 can't be checked by blhc.
1386
1387 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1388
1389 Build log contains lines which hide the real compiler flags. For example:
1390
1391     CC test-a.c
1392     CC test-b.c
1393     CC test-c.c
1394     LD test
1395
1396 Most of the time either C<export V=1> or C<export verbose=1> in
1397 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1398 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1399 patched to remove the C<@>s hiding the real compiler commands.
1400
1401 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1402
1403 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1404
1405 =item B<I-invalid-cmake-used> (version)
1406
1407 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1408 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1409 patch was rejected by upstream and later reverted in Debian. Thus those two
1410 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1411 handle them (for example by passing them to CFLAGS). To prevent false
1412 negatives just blacklist those two versions.
1413
1414 =item B<I-no-compiler-commands>
1415
1416 No compiler commands were detected. Either the log contains none or they were
1417 not correctly detected by blhc (please report the bug in this case).
1418
1419 =back
1420
1421 =head1 EXIT STATUS
1422
1423 The exit status is a "bit mask", each listed status is ORed when the error
1424 condition occurs to get the result.
1425
1426 =over 4
1427
1428 =item B<0>
1429
1430 Success.
1431
1432 =item B<1>
1433
1434 No compiler commands were found.
1435
1436 =item B<2>
1437
1438 Invalid arguments/options given to blhc.
1439
1440 =item B<4>
1441
1442 Non verbose build.
1443
1444 =item B<8>
1445
1446 Missing hardening flags.
1447
1448 =item B<16>
1449
1450 Hardening wrapper detected, no tests performed.
1451
1452 =item B<32>
1453
1454 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1455 TAGS"> for a detailed explanation.
1456
1457 =back
1458
1459 =head1 AUTHOR
1460
1461 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1462
1463 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1464 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1465
1466 =head1 LICENSE AND COPYRIGHT
1467
1468 Copyright (C) 2012 by Simon Ruderich
1469
1470 This program is free software: you can redistribute it and/or modify
1471 it under the terms of the GNU General Public License as published by
1472 the Free Software Foundation, either version 3 of the License, or
1473 (at your option) any later version.
1474
1475 This program is distributed in the hope that it will be useful,
1476 but WITHOUT ANY WARRANTY; without even the implied warranty of
1477 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1478 GNU General Public License for more details.
1479
1480 You should have received a copy of the GNU General Public License
1481 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1482
1483 =head1 SEE ALSO
1484
1485 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1486
1487 =cut