#!/usr/bin/perl

# Build log hardening check, checks build logs for missing hardening flags.

# Copyright (C) 2012  Simon Ruderich
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.


use strict;
use warnings;

use Getopt::Long ();
use Term::ANSIColor ();
use Text::ParseWords ();

our $VERSION = '0.01';


# CONSTANTS/VARIABLES

# Regex to catch compiler commands.
my $cc_regex = qr/(?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
                  (?<!\.)(?:cc|gcc|g\+\+|c\+\+)
                  (?:-[\d.]+)?/x;
# Regex to catch (GCC) compiler warnings.
my $warning_regex = qr/^(.+?):([0-9]+):[0-9]+: warning: (.+?) \[(.+?)\]$/;

# List of source file extensions which require preprocessing.
my @source_preprocess_compile_cpp = (
    # C++
    qw( cc cp cxx cpp CPP c++ C ),
    # Objective-C++
    qw( mm Mr),
);
my @source_preprocess_compile = (
    # C
    qw( c ),
    # Objective-C
    qw( m ),
    # (Objective-)C++
    @source_preprocess_compile_cpp,
    # Fortran
    qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
);
my @source_preprocess_no_compile = (
    # Assembly
    qw( s ),
);
my @source_preprocess = (
    @source_preprocess_compile,
    @source_preprocess_no_compile,
);
# List of source file extensions which don't require preprocessing.
my @source_no_preprocess_compile_cpp = (
    # C++
    qw( ii ),
    # Objective-C++
    qw( mii ),
);
my @source_no_preprocess_compile = (
    # C
    qw( i ),
    # (Objective-)C++
    @source_no_preprocess_compile_cpp,
    # Objective-C
    qw( mi ),
    # Fortran
    qw( f for ftn f90 f95 f03 f08 ),
);
my @source_no_preprocess_no_compile = (
    # Assembly
    qw( S sx ),
);
my @source_no_preprocess = (
    @source_no_preprocess_compile,
    @source_no_preprocess_no_compile,
);
# List of header file extensions which require preprocessing.
my @header_preprocess = (
    # C, C++, Objective-C, Objective-C++
    qw( h ),
    # C++
    qw( hh H hp hxx hpp HPP h++ tcc ),
);

# Hashes for fast extensions lookup to check if a file falls in one of these
# categories.
my %extensions_no_preprocess = map { $_ => 1 } (
    @source_no_preprocess,
);
my %extensions_preprocess = map { $_ => 1 } (
    @header_preprocess,
    @source_preprocess,
);
my %extensions_compile_link = map { $_ => 1 } (
    @source_preprocess,
    @source_no_preprocess,
);
my %extensions_compile = map { $_ => 1 } (
    @source_preprocess_compile,
    @source_no_preprocess_compile,
);
my %extensions_no_compile = map { $_ => 1 } (
    @source_preprocess_no_compile,
    @source_no_preprocess_no_compile,
);
my %extensions_compile_cpp = map { $_ => 1 } (
    @source_preprocess_compile_cpp,
    @source_no_preprocess_compile_cpp,
);
my %extension = map { $_ => 1 } (
    @source_no_preprocess,
    @source_no_preprocess_compile,
    @source_no_preprocess_compile_cpp,
    @source_no_preprocess_no_compile,
    @header_preprocess,
    @source_preprocess,
    @source_preprocess_compile,
    @source_preprocess_compile_cpp,
    @source_preprocess_no_compile,
);

# Regexp to match file extensions.
my $file_extension_regex = qr/
    \s
    \S+         # Filename without extension.
    \.
    ([^\\.\s]+) # File extension.
    (?=\s|\\)   # At end of word. Can't use \b because some files have non
                # word characters at the end and because \b matches double
                # extensions (like .cpp.o). Works always as all lines are
                # terminated with "\n".
    /x;

# Expected (hardening) flags. All flags are used as regexps.
my @cflags = (
    '-g',
    '-O(?:2|3)',
);
my @cflags_format = (
    '-Wformat',
    '-Wformat-security',
    '-Werror=format-security',
);
my @cflags_fortify = (
    # fortify needs at least -O1, but -O2 is recommended anyway
);
my @cflags_stack = (
    '-fstack-protector',
    '--param=ssp-buffer-size=4',
);
my @cflags_pie = (
    '-fPIE',
);
my @cxxflags = (
    '-g',
    '-O(?:2|3)',
);
# @cxxflags_* is the same as @cflags_*.
my @cppflags = ();
my @cppflags_fortify = (
    '-D_FORTIFY_SOURCE=2',
);
my @ldflags = ();
my @ldflags_relro = (
    '-Wl,(-z,)?relro',
);
my @ldflags_bindnow = (
    '-Wl,(-z,)?now',
);
my @ldflags_pie = (
    '-fPIE',
    '-pie',
);
# Renaming rules for the output so the regex parts are not visible.
my %flag_renames = (
    '-O(?:2|3)'       => '-O2',
    '-Wl,(-z,)?relro' => '-Wl,-z,relro',
    '-Wl,(-z,)?now'   => '-Wl,-z,now',
);

# Use colored (ANSI) output?
my $option_color;


# FUNCTIONS

sub error_flags {
    my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;

    # Rename flags if requested.
    my @missing_flags = map {
        (exists $flag_renames_ref->{$_})
            ? $flag_renames_ref->{$_}
            : $_
    } @{$missing_flags_ref};

    my $flags = join ' ', @missing_flags;
    printf "%s (%s)%s %s",
           error_color($message, 'red'), $flags, error_color(':', 'yellow'),
           $line;
}
sub error_non_verbose_build {
    my ($line) = @_;

    printf "%s%s %s",
           error_color('NONVERBOSE BUILD', 'red'),
           error_color(':', 'yellow'),
           $line;
}
sub error_hardening_wrapper {
    printf "%s%s %s\n",
            error_color('HARDENING WRAPPER', 'red'),
            error_color(':', 'yellow'),
            'no checks possible, aborting';
}
sub error_color {
    my ($message, $color) = @_;

    if ($option_color) {
        return Term::ANSIColor::colored($message, $color);
    } else {
        return $message;
    }
}

sub any_flags_used {
    my ($line, @flags) = @_;

    foreach my $flag (@flags) {
        return 1 if $line =~ /\s$flag(?:\s|\\)/;
    }

    return 0;
}
sub all_flags_used {
    my ($line, $missing_flags_ref, @flags) = @_;

    my @missing_flags = ();
    foreach my $flag (@flags) {
        if ($line !~ /\s$flag(?:\s|\\)/) {
            push @missing_flags, $flag;
        }
    }

    return 1 if scalar @missing_flags == 0;

    @{$missing_flags_ref} = @missing_flags;
    return 0;
}

# Modifies $missing_flags_ref array.
sub pic_pie_conflict {
    my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;

    return 0 if not $pie;
    return 0 if not any_flags_used($line, ('-fPIC', '-fpic'));

    my %flags = map { $_ => 1 } @flags_pie;

    # Remove all PIE flags from @missing_flags as they are not required with
    # -fPIC.
    my @result = grep {
        not exists $flags{$_}
    } @{$missing_flags_ref};
    @{$missing_flags_ref} = @result;

    # We got a conflict when no flags are left, thus only PIE flags were
    # missing. If other flags were missing abort because the conflict is not
    # the problem.
    return scalar @result == 0;
}

sub is_non_verbose_build {
    my ($line, $next_line, $skip_ref) = @_;

    if (not ($line =~ /^checking if you want to see long compiling messages\.\.\. no/
                or $line =~ /^\s*\[?(?:CC|CCLD|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
                or $line =~ /^\s*(?:C|c)ompiling\s+(.+?)(?:\.\.\.)?$/
                or $line =~ /^\s*(?:B|b)uilding (?:program|shared library)\s+(.+?)$/
                or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
        return 0;
    }

    my $file = $1;

    # On the first pass we only check if this line is verbose or not.
    return 1 if not defined $next_line;

    # Second pass, we have access to the next line.
    ${$skip_ref} = 0;

    # CMake and other build systems print the non-verbose messages also when
    # building verbose. If a compiler and the file name occurs in the next
    # line, treat it as verbose build.
    if (defined $file) {
        # Get filename, we can't use the complete path as only parts of it are
        # used in the real compiler command.
        $file =~ m{/([a-zA-Z0-9._-]+)$};
        $file = $1;

        if ($next_line =~ /\Q$file\E/ and $next_line =~ /$cc_regex/o) {
            # We still have to skip the current line as it doesn't contain any
            # compiler commands.
            ${$skip_ref} = 1;
            return 0;
        }
    }

    return 1;
}

sub extension_found {
    my ($extensions_ref, @extensions) = @_;

    my $found = 0;
    foreach my $extension (@extensions) {
        if (exists $extensions_ref->{$extension}) {
            $found = 1;
            last;
        }
    }
    return $found;
}


# MAIN

# Hardening options. Not all architectures support all hardening options.
my $harden_format  = 1;
my $harden_fortify = 1;
my $harden_stack   = 1;
my $harden_relro   = 1;
my $harden_bindnow = 0;
my $harden_pie     = 0;

# Parse command line arguments.
my $option_help    = 0;
my $option_version = 0;
my $option_all     = 0;
my $option_arch    = undef;
my $option_buildd  = 0;
   $option_color   = 0;
if (not Getopt::Long::GetOptions(
            'help|h|?' => \$option_help,
            'version'  => \$option_version,
            # Hardening options.
            'pie'      => \$harden_pie,
            'bindnow'  => \$harden_bindnow,
            'all'      => \$option_all,
            # Misc.
            'color'    => \$option_color,
            'arch=s'   => \$option_arch,
            'buildd'   => \$option_buildd,
        )) {
    require Pod::Usage;
    Pod::Usage::pod2usage(2);
}
if ($option_help) {
    require Pod::Usage;
    Pod::Usage::pod2usage(1);
}
if ($option_version) {
    print "blhc $VERSION  Copyright (C) 2012  Simon Ruderich

This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program.  If not, see <http://www.gnu.org/licenses/>.
";
    exit 0;
}

if ($option_all) {
    $harden_pie     = 1;
    $harden_bindnow = 1;
}

# Final exit code.
my $exit = 0;

# Input lines, contain only the lines with compiler commands.
my @input = ();

my $start = 0;
my $continuation = 0;
my $complete_line = undef;
while (my $line = <>) {
    # dpkg-buildflags only provides hardening flags since 1.16.1, don't check
    # for hardening flags in buildd mode if an older dpkg-dev is used. Default
    # flags (-g -O2) are still checked.
    #
    # Packages which were built before 1.16.1 but used their own hardening
    # flags are not checked.
    if ($option_buildd and not $start
            and $line =~ /^Toolchain package versions: /) {
        require Dpkg::Version;
        if ($line !~ /dpkg-dev_(\S+)/
                or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
            $harden_format  = 0;
            $harden_fortify = 0;
            $harden_stack   = 0;
            $harden_relro   = 0;
            $harden_bindnow = 0;
            $harden_pie     = 0;
        }
    }

    # If hardening wrapper is used (wraps calls to gcc and adds hardening
    # flags automatically) we can't perform any checks, abort.
    if (not $start and $line =~ /^Build-Depends: .*\bhardening-wrapper\b/) {
        error_hardening_wrapper();
        $exit |= 1 << 4;
        exit $exit;
    }

    # We skip over unimportant lines at the beginning of the log to prevent
    # false positives.
    $start = 1 if $line =~ /^dpkg-buildpackage:/;
    next if not $start;
    # And stop at the end of the build log. Package details (reported by the
    # buildd logs) are not important for us. This also prevents false
    # positives.
    last if $line =~ /^Build finished at \d{8}-\d{4}$/;

    # Detect architecture automatically unless overridden.
    if (not $option_arch
            and $line =~ /^dpkg-buildpackage: host architecture (.+)$/) {
        $option_arch = $1;
    }

    # Ignore compiler warnings for now.
    next if $line =~ /$warning_regex/o;

    if ($line =~ /\033/) { # esc
        # Remove all ANSI color sequences which are sometimes used in
        # non-verbose builds.
        $line = Term::ANSIColor::colorstrip($line);
        # Also strip '\0xf' (delete previous character), used by Elinks' build
        # system.
        $line =~ s/\x0f//g;
        # And "ESC(B" which seems to be used on armhf and hurd (not sure what
        # it does).
        $line =~ s/\033\(B//g;
    }

    # Check if this line indicates a non verbose build.
    my $non_verbose = is_non_verbose_build($line);

    # One line may contain multiple commands (";"). Treat each one as single
    # line. parse_line() is slow, only use it when necessary.
    my @line = (not $line =~ /;/)
             ? ($line)
             : map {
                   # Ensure newline at the line end - necessary for correct
                   # parsing later.
                   $_ =~ s/\s+$//;
                   $_ .= "\n";
               } Text::ParseWords::parse_line(';', 1, $line);
    foreach $line (@line) {
        if ($continuation) {
            $continuation = 0;

            # Join lines, but leave the "\" in place so it's clear where the
            # original line break was.
            chomp $complete_line;
            $complete_line .= ' ' . $line;
        }
        # Line continuation, line ends with "\".
        if ($line =~ /\\\s*$/) {
            $continuation = 1;
            # Start line continuation.
            if (not defined $complete_line) {
                $complete_line = $line;
            }
            next;
        }

        if (not $continuation) {
            # Use the complete line if a line continuation occurred.
            if (defined $complete_line) {
                $line = $complete_line;
                $complete_line = undef;
            }

            # Ignore lines with no compiler commands.
            next if $line !~ /\b$cc_regex(?:\s|\\)/o and not $non_verbose;

            # Ignore false positives.
            #
            # `./configure` output.
            next if not $non_verbose
                    and $line =~ /^(?:checking|(?:C|c)onfigure:) /;
            next if $line =~ /^\s*(?:Host\s+)?(?:C\s+)?
                               (?:C|c)ompiler[\s.]*:?\s+
                               $cc_regex
                               (?:\s-std=[a-z0-9:+]+)?\s*$
                             /xo
                    or $line =~ /^\s*(?:- )?(?:HOST_)?(?:CC|CXX)\s*=\s*$cc_regex\s*$/o
                    or $line =~ /^\s*-- Check for working (?:C|CXX) compiler: /
                    or $line =~ /^\s*(?:echo )?Using [A-Z_]+\s*=\s*/;
            # `make` output.
            next if $line =~ /^Making [a-z]+ in \S+/; # e.g. "[...] in c++"

            # Check if additional hardening options were used. Used to ensure
            # they are used for the complete build.
            $harden_pie     = 1 if any_flags_used($line, @cflags_pie, @ldflags_pie);
            $harden_bindnow = 1 if any_flags_used($line, @ldflags_bindnow);

            push @input, $line;
        }
    }
}

if (scalar @input == 0) {
    print "No compiler commands!\n";
    $exit |= 1;
    exit $exit;
}

# Option or auto detected.
if ($option_arch) {
    # The following was partially copied from dpkg-dev 1.16.1.2
    # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
    # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
    # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
    # later. Keep it in sync.

    require Dpkg::Arch;
    my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($option_arch);

    # Disable unsupported hardening options.
    if ($cpu =~ /^(ia64|alpha|mips|mipsel|hppa)$/ or $option_arch eq 'arm') {
        $harden_stack = 0;
    }
    if ($cpu =~ /^(ia64|hppa|avr32)$/) {
        $harden_relro   = 0;
        $harden_bindnow = 0;
    }
}

# Check the specified hardening options, same order as dpkg-buildflags.
if ($harden_pie) {
    @cflags   = (@cflags,   @cflags_pie);
    @cxxflags = (@cxxflags, @cflags_pie);
    @ldflags  = (@ldflags,  @ldflags_pie);
}
if ($harden_stack) {
    @cflags   = (@cflags,   @cflags_stack);
    @cxxflags = (@cxxflags, @cflags_stack);
}
if ($harden_fortify) {
    @cflags   = (@cflags,   @cflags_fortify);
    @cxxflags = (@cxxflags, @cflags_fortify);
    @cppflags = (@cppflags, @cppflags_fortify);
}
if ($harden_format) {
    @cflags   = (@cflags,   @cflags_format);
    @cxxflags = (@cxxflags, @cflags_format);
}
if ($harden_relro) {
    @ldflags = (@ldflags, @ldflags_relro);
}
if ($harden_bindnow) {
    @ldflags = (@ldflags, @ldflags_bindnow);
}

for (my $i = 0; $i < scalar @input; $i++) {
    my $line = $input[$i];

    my $skip = 0;
    if (is_non_verbose_build($line, $input[$i + 1], \$skip)) {
        error_non_verbose_build($line);
        $exit |= 1 << 2;
        next;
    }
    # Even if it's a verbose build, we might have to skip this line.
    next if $skip;

    # Remove everything until and including the compiler command. Makes checks
    # easier and faster.
    $line =~ s/^.*?$cc_regex//o;

    # Skip unnecessary tests when only preprocessing.
    my $flag_preprocess = 0;

    my $preprocess = 0;
    my $compile    = 0;
    my $link       = 0;

    # Preprocess, compile, assemble.
    if ($line =~ /\s(-E|-S|-c)\b/) {
        $preprocess      = 1;
        $flag_preprocess = 1 if $1 eq '-E';
        $compile         = 1 if $1 eq '-S' or $1 eq '-c';
    # Otherwise assume we are linking.
    } else {
        $link = 1;
    }

    # Get all file extensions on this line.
    my @extensions = $line =~ /$file_extension_regex/go;
    # Ignore all unknown extensions to speedup the search below.
    @extensions = grep { exists $extension{$_} } @extensions;

    # These file types don't require preprocessing.
    if (extension_found(\%extensions_no_preprocess, @extensions)) {
        $preprocess = 0;
    }
    # These file types require preprocessing.
    if (extension_found(\%extensions_preprocess, @extensions)) {
        $preprocess = 1;
    }

    # If there are source files then it's compiling/linking in one step and we
    # must check both. We only check for source files here, because header
    # files cause too many false positives.
    if (not $flag_preprocess
            and extension_found(\%extensions_compile_link, @extensions)) {
        # Assembly files don't need CFLAGS.
        if (not extension_found(\%extensions_compile, @extensions)
                and extension_found(\%extensions_no_compile, @extensions)) {
            $compile = 0;
        # But the rest does.
        } else {
            $compile = 1;
        }
    }

    # Assume CXXFLAGS are required when a C++ file is specified in the
    # compiler line.
    my $compile_cpp = 0;
    if ($compile
            and extension_found(\%extensions_compile_cpp, @extensions)) {
        $compile     = 0;
        $compile_cpp = 1;
    }

    # Check hardening flags.
    my @missing;
    if ($compile and not all_flags_used($line, \@missing, @cflags)
            # Libraries linked with -fPIC don't have to (and can't) be linked
            # with -fPIE as well. It's no error if only PIE flags are missing.
            and not pic_pie_conflict($line, $harden_pie, \@missing, @cflags_pie)
            # Assume dpkg-buildflags returns the correct flags.
            and not $line =~ /`dpkg-buildflags --get CFLAGS`/) {
        error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
        $exit |= 1 << 3;
    } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
            # Libraries linked with -fPIC don't have to (and can't) be linked
            # with -fPIE as well. It's no error if only PIE flags are missing.
            and not pic_pie_conflict($line, $harden_pie, \@missing, @cflags_pie)
            # Assume dpkg-buildflags returns the correct flags.
            and not $line =~ /`dpkg-buildflags --get CXXFLAGS`/) {
        error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
        $exit |= 1 << 3;
    }
    if ($preprocess and not all_flags_used($line, \@missing, @cppflags)
            # Assume dpkg-buildflags returns the correct flags.
            and not $line =~ /`dpkg-buildflags --get CPPFLAGS`/) {
        error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
        $exit |= 1 << 3;
    }
    if ($link and not all_flags_used($line, \@missing, @ldflags)
            # Same here, -fPIC conflicts with -fPIE.
            and not pic_pie_conflict($line, $harden_pie, \@missing, @ldflags_pie)
            # Assume dpkg-buildflags returns the correct flags.
            and not $line =~ /`dpkg-buildflags --get LDFLAGS`/) {
        error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
        $exit |= 1 << 3;
    }
}

exit $exit;


__END__

=head1 NAME

blhc - build log hardening check, checks build logs for missing hardening flags

=head1 SYNOPSIS

B<blhc> [options] <dpkg-buildpackage build log file>

    --all                   force +all (+pie, +bindnow) check
    --arch                  set architecture (autodetected)
    --bindnow               force +bindbow check
    --buildd                parser mode for buildds
    --color                 use colored output
    --pie                   force +pie check
    --help                  available options
    --version               version number and license

=head1 DESCRIPTION

blhc is a small tool which checks build logs for missing hardening flags and
other important warnings. It's licensed under the GPL 3 or later.

=head1 OPTIONS

=over 8

=item B<--all>

Force check for all +all (+pie, +bindnow) hardening flags. By default it's
auto detected.

=item B<--arch>

Set the specific architecture (e.g. amd64, armel, etc.), automatically
disables hardening flags not available on this architecture. Is detected
automatically if dpkg-buildpackage is used.

=item B<--bindnow>

Force check for all +bindnow hardening flags. By default it's auto detected.

=item B<--buildd>

Special mode for buildds when automatically parsing log files. The following
changes are in effect:

=over 2

=item

Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
detected).

=back

=item B<--color>

Use colored (ANSI) output for warning messages.

=item B<--pie>

Force check for all +pie hardening flags. By default it's auto detected.

=item B<-h -? --help>

Print available options.

=item B<--version>

Print version number and license.

=back

Auto detection for B<--pie> and B<--bindnow> only works if at least one
command uses the required hardening flag (e.g. -fPIE). Then it's required for
all other commands as well.

=head1 EXIT STATUS

The exit status is a "bit mask", each listed status is ORed when the error
condition occurs to get the result.

=over 4

=item B<0>

Success.

=item B<1>

No compiler commands were found.

=item B<2>

Invalid arguments/options given to blhc.

=item B<4>

Non verbose build.

=item B<8>

Missing hardening flags.

=item B<16>

Hardening wrapper detected, no tests performed.

=back

=head1 AUTHOR

Simon Ruderich, E<lt>simon@ruderich.orgE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2012 by Simon Ruderich

This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program.  If not, see <http://www.gnu.org/licenses/>.

=cut