vim/vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2016  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value. Not sure what exactly Vim is
  25 " doing there.
  26 if has('eval')
  27     let s:save_runtimepath = &runtimepath
  28     let s:save_diff = &diff
  29 endif
  30 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  31 " system wide configuration file doesn't change default values.
  32 set all&
  33 " And restore it after all other options were reset.
  34 if has('eval')
  35     let &runtimepath = s:save_runtimepath
  36     let &diff = s:save_diff
  37     unlet s:save_runtimepath
  38     unlet s:save_diff
  39 endif
  40
  41 " Make sure Vim (and not Vi) settings are used.
  42 set nocompatible
  43
  44 " Disallow :autocmd, shell and write commands in .vimrc and .exrc files in the
  45 " current directory. Only used if 'exrc' is enabled (off by default),
  46 " precaution just in case somebody enables 'exrc'.
  47 set secure
  48
  49 " Try to use pipes instead of temporary files. Prevents some auto commands
  50 " from running for temporary files but also prevents the file's content to be
  51 " written to disk.
  52 set noshelltemp
  53
  54 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  55 " affect reading files in different encodings, see 'fileencodings' for that.
  56 set encoding=utf-8
  57
  58 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  59 " runtime files) if available.
  60 set runtimepath-=~/.vim
  61 set runtimepath^=~/.vim,~/.vim/runtime
  62
  63 " Don't store swap files in the same directory as the edited file, but only if
  64 " we have a "safe" writable directory available.
  65 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  66     set directory-=.
  67 endif
  68 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  69 set directory^=~/.tmp
  70 " Never use /tmp which gets cleaned on reboot.
  71 set directory-=/tmp
  72
  73 " Disable modelines as they may cause security problems. Instead use
  74 " securemodelines (Vim script #1876).
  75 set nomodeline
  76
  77 " Complete to longest common string (list:longest) and then complete all full
  78 " matches after another (full). Thanks to pbrisbin
  79 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  80 set wildmode=list:longest,full
  81 " Ignore case when completing files/directories.
  82 if exists('+wildignorecase')
  83     set wildignorecase
  84 endif
  85
  86 " Ignore files with the following extensions because I almost never want to
  87 " edit them in Vim (specifying them manually still works of course).
  88 set wildignore=
  89 " C
  90 set wildignore+=*.o,*.d,*.so
  91 " Java
  92 set wildignore+=*.class
  93 " LaTeX
  94 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  95 " Python
  96 set wildignore+=*.pyc
  97
  98 " Show completion menu even if only one entry matches.
  99 if exists('+completeopt')
 100     set completeopt+=menuone
 101 endif
 102
 103 " Increase history of executed commands (:) and search patterns (/).
 104 set history=1000
 105
 106 " Increase number of possible undos.
 107 set undolevels=1000
 108
 109 " Remember marks (including the last cursor position) for more files. ^= is
 110 " necessary because 'viminfo' is parsed from the beginning and the first match
 111 " is used.
 112 if has('viminfo')
 113     set viminfo^='1000
 114 endif
 115
 116 " Use strong encryption if possible, also used for swap/undo files.
 117 if exists('+cryptmethod')
 118     set cryptmethod=blowfish
 119 endif
 120
 121 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 122 " is used multiple times. Necessary to support reloading the vimrc.
 123 if has('autocmd')
 124     augroup vimrc
 125         autocmd!
 126     augroup END
 127 endif
 128
 129
 130 " HELPER FUNCTIONS
 131
 132 if has('eval')
 133 " Check if the given syntax group is available. Thanks to bairui in #vim on
 134 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 135     function! s:HasSyntaxGroup(group)
 136         try
 137             execute 'silent highlight ' . a:group
 138         " \a = [A-Za-z]
 139         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 140             return 0
 141         endtry
 142         return 1
 143     endfunction
 144
 145 " Check if the given Vim version and patch is available.
 146     function! s:HasVersionAndPatch(version, patch)
 147         return v:version > a:version
 148             \ || (v:version == a:version && has('patch' . a:patch))
 149     endfunction
 150 endif
 151
 152
 153 " TERMINAL SETTINGS
 154
 155 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
 156 " connections.
 157 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
 158     set ttyfast
 159 endif
 160
 161
 162 " EDIT SETTINGS
 163
 164 " Enable automatic file detection, plugin and indention support.
 165 if has('autocmd')
 166     filetype off " necessary for pathogen to force a reload of ftplugins
 167     filetype plugin indent on
 168 endif
 169
 170 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 171 " existing files.
 172 set fileencodings=utf-8,latin1
 173
 174 " Always use unix line-endings for new files. DOS line endings in existing
 175 " files are recognized.
 176 set fileformats=unix,dos
 177
 178 " Wrap text after 78 characters.
 179 set textwidth=78
 180
 181 " Set tabs to 4 spaces, use softtabs.
 182 set shiftwidth=4
 183 set softtabstop=4
 184 set expandtab
 185 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 186 set shiftround
 187 " Use the default value for real tabs.
 188 set tabstop=8
 189
 190 " Enable auto indention.
 191 set autoindent
 192
 193 " When joining lines only add one space after a sentence.
 194 set nojoinspaces
 195
 196 " Allow backspacing over autoindent and line breaks.
 197 set backspace=indent,eol
 198
 199 " Start a comment when hitting enter after a commented line (r) and when using
 200 " o or O around a commented line (o).
 201 set formatoptions+=ro
 202 " Don't break a line if was already longer then 'textwidth' when insert mode
 203 " started.
 204 set formatoptions+=l
 205 " Remove comment leader when joining lines where it makes sense.
 206 if s:HasVersionAndPatch(703, 541)
 207     set formatoptions+=j
 208 endif
 209
 210 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 211 " no character) in visual block mode.
 212 set virtualedit=block
 213
 214 " Already display matches while typing the search command. This makes spotting
 215 " typos easy and searching faster.
 216 set incsearch
 217
 218 " Activate syntax folding.
 219 if has('folding')
 220     set foldmethod=syntax
 221     " Only use fold column if we have enough space (for example not in a
 222     " (virtual) terminal which has only 80 columns).
 223     if &columns > 80
 224         set foldcolumn=2
 225     endif
 226     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 227                      " folding which is not what I want
 228     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 229     set foldopen-=block
 230 endif
 231
 232 " Only check case if the searched word contains a capital character.
 233 set ignorecase
 234 set smartcase
 235
 236 " Activate spell checking, use English as default.
 237 if exists('+spell') && has('syntax')
 238     " But not when diffing because spell checking is distracting in this case.
 239     if !&diff
 240         set spell
 241     endif
 242     set spelllang=en_us
 243 endif
 244
 245 " Allow buffers with changes to be hidden. Very important for efficient
 246 " editing with multiple buffers. Prevents the "E37: No write since last change
 247 " (add ! to override)" warning when switching modified buffers.
 248 set hidden
 249
 250 " When splitting vertically put the new window right of the current one.
 251 if has('vertsplit')
 252     set splitright
 253 endif
 254
 255
 256 " DISPLAY SETTINGS
 257
 258 " Use a dark background. Doesn't change the background color, only sets text
 259 " colors for a dark terminal.
 260 set background=dark
 261
 262 " Use my color scheme if 256 colors are available.
 263 if &t_Co == 256 || has('gui_running')
 264     colorscheme simon
 265 endif
 266
 267 " Display line numbers.
 268 set number
 269 " But use as little space as possible for the numbers column. Thanks to James
 270 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 271 if exists('+numberwidth')
 272     set numberwidth=1
 273 endif
 274 " Display the ruler with current line/file position. If 'statusline' is used,
 275 " then this only affects <C-G>.
 276 set ruler
 277 " Display partial commands in the status line.
 278 set showcmd
 279
 280 " Don't redraw screen when executing macros; increases speed. Thanks to James
 281 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 282 set lazyredraw
 283
 284 " Visualize the line the cursor is currently in.
 285 if exists('+cursorline')
 286     set cursorline
 287 endif
 288
 289 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 290 " remove the highlighting until the next search.
 291 set hlsearch
 292
 293 " Display some special characters.
 294 set list
 295 set listchars=
 296 " Display tabs as ">--------".
 297 set listchars+=tab:>-
 298 " Display trailing whitespace as "-".
 299 set listchars+=trail:-
 300 " Display markers for long lines when wrapping is disabled.
 301 set listchars+=extends:>,precedes:<
 302 " Display non-breakable space as "!".
 303 if v:version >= 700
 304     set listchars+=nbsp:!
 305 endif
 306
 307 " Don't draw the vertical split separator by using space as character. Thanks
 308 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 309 " non-breakable space. But a simple space works as well, as long as the
 310 " current color scheme is not reset.
 311 if has('windows') && has('folding')
 312     set fillchars+=vert:\  " comment to prevent trailing whitespace
 313 endif
 314
 315 if has('statusline')
 316     " Always display the status line even if there is only one window.
 317     set laststatus=2
 318
 319     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 320     " is the highest buffer number, otherwise return nothing. Used in
 321     " 'statusline' to get an overview of available buffer numbers.
 322     function! s:StatuslineBufferCount()
 323         let l:bufnr = bufnr('$')
 324         if l:bufnr > 1
 325             let l:result = '/'
 326             if exists('*printf')
 327                 let l:result .= printf('%02d', l:bufnr)
 328             else
 329                 " Older Vims don't have printf() (and no .= either). Emulate
 330                 " "%02d".
 331                 if l:bufnr < 10
 332                     let l:result = l:result . '0'
 333                 endif
 334                 let l:result = l:result . l:bufnr
 335             endif
 336             return l:result
 337         else
 338             return ''
 339         endif
 340     endfunction
 341
 342     " Like %f but use relative filename if it's shorter than the absolute path
 343     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 344     " not enough because it doesn't create '../'s.
 345     function! s:StatuslineRelativeFilename()
 346         " Display only filename for help files.
 347         if &buftype == 'help'
 348             return expand('%:t')
 349         endif
 350         " Special case for scratch files.
 351         if &buftype == 'nofile'
 352             return '[Scratch]'
 353         endif
 354
 355         let l:path = expand('%')
 356         " No file.
 357         if l:path == ''
 358             return '[No Name]'
 359         endif
 360         " Path is already relative, nothing to do.
 361         if stridx(l:path, '/') != 0
 362             return l:path
 363         endif
 364
 365         " Absolute path to this file.
 366         let l:path = expand('%:p')
 367         " Shortened path to this file, thanks to bairui in #vim on Freenode
 368         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 369         " Vim normally uses as %f (minus some exceptions).
 370         let l:original_path = fnamemodify(l:path, ':~')
 371         " Absolute path to the current working directory.
 372         let l:cwd = getcwd()
 373
 374         " Working directory completely contained in path, replace it with a
 375         " relative path. Happens for example when opening a file with netrw.
 376         " %f displays this as absolute path, but we want a relative path of
 377         " course.
 378         if stridx(l:path, l:cwd) == 0
 379             return strpart(l:path, strlen(l:cwd) + 1)
 380         endif
 381
 382         let l:path_list = split(l:path, '/')
 383         let l:cwd_list  = split(l:cwd,  '/')
 384
 385         " Remove the common path.
 386         while l:path_list[0] == l:cwd_list[0]
 387             call remove(l:path_list, 0)
 388             call remove(l:cwd_list,  0)
 389         endwhile
 390
 391         " Add as many '..' as necessary for the relative path and join the
 392         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 393         " the hint to use repeat() instead of a loop.
 394         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 395
 396         " Use the shorter path, either relative or absolute.
 397         if strlen(l:path) < strlen(l:original_path)
 398             return l:path
 399         else
 400             return l:original_path
 401         endif
 402     endfunction
 403
 404     " Display unexpected 'fileformat', 'fileencoding' and 'bomb' settings.
 405     function! s:StatuslineFileFormat()
 406         if &fileformat != 'unix'
 407             return '[' . &fileformat . ']'
 408         else
 409             return ''
 410         endif
 411     endfunction
 412     function! s:StatuslineFileEncoding()
 413         if &fileencoding != '' && &fileencoding != 'utf-8'
 414                 \ && &filetype != 'help'
 415             return '[' . &fileencoding . ']'
 416         else
 417             return ''
 418         endif
 419     endfunction
 420     function! s:StatuslineFileBOMB()
 421         if exists('+bomb') && &bomb
 422             return '[BOM]'
 423         else
 424             return ''
 425         endif
 426     endfunction
 427
 428     " Return current syntax group in brackets or nothing if there's none.
 429     function! s:StatuslineSyntaxGroup()
 430         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 431         if l:group != ''
 432             return '[' . l:group . '] '
 433         else
 434             return ''
 435         endif
 436     endfunction
 437
 438     " Short function names to make 'statusline' more readable.
 439     function! SBC()
 440         return s:StatuslineBufferCount()
 441     endfunction
 442     function! SRF()
 443         return s:StatuslineRelativeFilename()
 444     endfunction
 445     function! SFF()
 446         return s:StatuslineFileFormat()
 447     endfunction
 448     function! SFE()
 449         return s:StatuslineFileEncoding()
 450     endfunction
 451     function! SFB()
 452         return s:StatuslineFileBOMB()
 453     endfunction
 454     function! SSG()
 455         return s:StatuslineSyntaxGroup()
 456     endfunction
 457
 458     set statusline=
 459     " on the left
 460     set statusline+=%02n              " buffer number
 461     set statusline+=%{SBC()}          " highest buffer number
 462     set statusline+=:
 463     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 464         set statusline+=%{SRF()}      " path to current file
 465     else
 466         set statusline+=%f            " path to current file in buffer
 467     endif
 468     set statusline+=\                 " space after path
 469     set statusline+=%h                " [help] if buffer is help file
 470     set statusline+=%w                " [Preview] if buffer is preview buffer
 471     set statusline+=%m                " [+] if buffer was modified,
 472                                       " [-] if 'modifiable' is off
 473     set statusline+=%r                " [RO] if buffer is read only
 474     if v:version >= 700               " %#..# needs 7.0
 475         set statusline+=%#Error#      " display warnings
 476         set statusline+=%{SFF()}      "   - unexpected file format
 477         set statusline+=%{SFE()}      "   - unexpected file encoding
 478         set statusline+=%{SFB()}      "   - unexpected file byte order mask
 479         set statusline+=%##           " continue with normal colors
 480     endif
 481
 482     " on the right
 483     set statusline+=%=                " right align
 484     set statusline+=0x%-8B\           " current character under cursor as hex
 485     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 486                                       " column number (%c),
 487                                       " virtual column number if different
 488                                       "                       than %c (%V)
 489     set statusline+=%P                " position in file in percent
 490 endif
 491
 492
 493 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 494
 495 " noremap is used to make sure the right side is executed as is and can't be
 496 " modified by a plugin or other settings. Except for <Nop> which isn't
 497 " affected by mappings.
 498
 499 " Easy way to exit insert mode (jj is too slow).
 500 inoremap jk <Esc>
 501 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 502 " (2010-10-15).
 503 cnoremap jk <C-C>
 504 " And fix my typos ...
 505 inoremap JK <Esc>
 506 inoremap Jk <Esc>
 507 inoremap jK <Esc>
 508 cnoremap JK <C-C>
 509 cnoremap Jk <C-C>
 510 cnoremap jK <C-C>
 511
 512 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 513 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 514 map <Right>  <Nop>
 515 map <Left>   <Nop>
 516 map <Up>     <Nop>
 517 map <Down>   <Nop>
 518 imap <Right> <Nop>
 519 imap <Left>  <Nop>
 520 imap <Up>    <Nop>
 521 imap <Down>  <Nop>
 522 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 523 " below).
 524 cmap <Up>    <Nop>
 525 cmap <Down>  <Nop>
 526 cmap <Right> <Nop>
 527 cmap <Left>  <Nop>
 528
 529 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 530 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 531 cnoremap <C-P> <Up>
 532 cnoremap <C-N> <Down>
 533
 534 " Use :tjump to lookup tags (instead of :tag) which lists all available tags
 535 " if there's more than one match. This is really helpful in larger projects
 536 " where tags may occur multiple times.
 537 nnoremap <C-]> g<C-]>
 538
 539 if has('eval')
 540 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 541 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 542 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 543 " directly because it also enables that feature for other commands which I
 544 " don't want.
 545
 546     " Set 'nostartofline' for a single movement.
 547     function! s:TemporaryNostartofline(movement)
 548         let l:startofline = &startofline
 549         set nostartofline
 550         execute 'normal! ' . a:movement
 551         let &startofline = l:startofline
 552     endfunction
 553
 554     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 555     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 556     nnoremap <silent> <C-F>
 557         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 558     nnoremap <silent> <C-B>
 559         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 560     nnoremap <silent> <C-D>
 561         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 562     nnoremap <silent> <C-U>
 563         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 564 endif
 565
 566 " Let Y yank to the end of the line, similar to D and C. Use yy if you want to
 567 " yank a line. This fixes a weird inconsistency in Vi(m).
 568 nnoremap Y y$
 569
 570 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 571 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 572 " Only the current buffer is written, thus switching to another buffer works
 573 " too.
 574 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 575
 576 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 577 " in #vim on Freenode (2011-08-15 00:17 CEST).
 578 nnoremap <C-G> 2<C-G>
 579
 580 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 581 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 582 nmap <Space> <C-F>
 583 nmap - <C-B>
 584
 585 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 586 " (2010-05-16 18:38 CEST) for this idea.
 587 nnoremap <silent> gb :bnext<CR>
 588 nnoremap <silent> gB :bprevious<CR>
 589 if has('eval')
 590     " But when starting again at the first buffer, print a warning which
 591     " reminds me that I've already seen that buffer.
 592     function! s:NextBuffer()
 593         " Are we currently on the last buffer and moving to the first?
 594         let l:last_buffer = 0
 595         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 596             let l:last_buffer = 1
 597         endif
 598
 599         " Go to the next buffer.
 600         if !l:last_buffer
 601             bnext
 602
 603         " Go to the first buffer, silent is necessary or the following message
 604         " won't be displayed because it's overwritten by the status message
 605         " displayed when entering a buffer.
 606         else
 607             silent bnext
 608
 609             echohl WarningMsg
 610             echo 'Starting again at first buffer.'
 611             echohl None
 612         endif
 613     endfunction
 614     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 615 endif
 616
 617 " Fast access to buffers.
 618 nnoremap <silent> <Leader>1 :1buffer<CR>
 619 nnoremap <silent> <Leader>2 :2buffer<CR>
 620 nnoremap <silent> <Leader>3 :3buffer<CR>
 621 nnoremap <silent> <Leader>4 :4buffer<CR>
 622 nnoremap <silent> <Leader>5 :5buffer<CR>
 623 nnoremap <silent> <Leader>6 :6buffer<CR>
 624 nnoremap <silent> <Leader>7 :7buffer<CR>
 625 nnoremap <silent> <Leader>8 :8buffer<CR>
 626 nnoremap <silent> <Leader>9 :9buffer<CR>
 627 nnoremap <silent> <Leader>0 :10buffer<CR>
 628
 629 " Use real tabs instead of soft tabs.
 630 if has('eval')
 631 " Switch from soft tabs to real tabs.
 632     function! s:UseTabs()
 633         setlocal noexpandtab shiftwidth=8 softtabstop=8
 634     endfunction
 635     nnoremap <silent> <Leader>t :call <SID>UseTabs()<CR>
 636 endif
 637 " Enable "verbatim" mode. Used to view files with long lines or without syntax
 638 " coloring. 'list' is not changed, see next mapping.
 639 nnoremap <silent> <Leader>v :setlocal nowrap nospell synmaxcol=0<CR>
 640                           \ :2match<CR>
 641 " Toggle 'list'.
 642 nnoremap <silent> <Leader>l :set invlist<CR>
 643
 644 " Make last active window the only window. Similar to <C-W> o.
 645 nnoremap <C-W>O <C-W>p<C-W>o
 646
 647 " Maps to change spell language between English and German and disable spell
 648 " checking.
 649 if exists('+spell')
 650     nnoremap <silent> <Leader>sn :set nospell<CR>
 651     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 652     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 653 " If no spell support is available, these mappings do nothing.
 654 else
 655     nmap <Leader>sn <Nop>
 656     nmap <Leader>se <Nop>
 657     nmap <Leader>sd <Nop>
 658 endif
 659
 660 if has('eval')
 661 " * and # for selections in visual mode. Thanks to
 662 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 663 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 664     function! s:VSetSearch()
 665         let l:temp = @@ " unnamed register
 666         normal! gvy
 667         " Added \C to force 'noignorecase' while searching the current visual
 668         " selection. I want to search for the exact string in this case.
 669         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 670         let @@ = l:temp
 671     endfunction
 672     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 673     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 674
 675 " Use 'noignorecase' for * and #. See comment in s:VSetSearch() for details.
 676 " Thanks to the writers of s:VSetSearch(), see above.
 677     function! s:NSetSearch()
 678         let l:cword = expand('<cword>')
 679         let l:regex = substitute(escape(l:cword, '\'), '\n', '\\n', 'g')
 680         let @/ = '\C\V'. '\<' . l:regex . '\>'
 681     endfunction
 682     nnoremap * :call <SID>NSetSearch()<CR>//<CR>
 683     nnoremap # :call <SID>NSetSearch()<CR>??<CR>
 684 endif
 685
 686 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 687 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 688 " mailing list for the commands.
 689 if v:version < 700
 690     cnoreabbrev W w
 691     cnoreabbrev Wa wa
 692     cnoreabbrev Wq wq
 693     cnoreabbrev Wqa wqa
 694 else
 695     cnoreabbrev <expr> W
 696         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 697     cnoreabbrev <expr> Wa
 698         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 699     cnoreabbrev <expr> Wq
 700         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 701     cnoreabbrev <expr> Wqa
 702         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 703 endif
 704 " Also fix my typo with "Q".
 705 if v:version < 700
 706     cnoreabbrev Q q
 707     cnoreabbrev Qa qa
 708 else
 709     cnoreabbrev <expr> Q
 710         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 711     cnoreabbrev <expr> Qa
 712         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 713 endif
 714
 715 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 716 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 717 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 718
 719 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 720 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 721 " Vim's source.
 722 inoremap <C-U> <C-G>u<C-U>
 723 " Same for <C-@> (insert previously inserted text and leave insert mode).
 724 inoremap <C-@> <C-G>u<C-@>
 725 " And for <C-A> (insert previously inserted text).
 726 inoremap <C-A> <C-G>u<C-A>
 727 " And for <C-W> (delete word before cursor).
 728 inoremap <C-W> <C-G>u<C-W>
 729
 730 if has('eval')
 731 " New text-objects ii and ai to work on text with the same indentation. Thanks
 732 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 733 " (visited on 2011-11-19).
 734     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 735     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 736     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 737     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 738
 739     function! s:IndTxtObj(inner)
 740         let curline = line(".")
 741         let lastline = line("$")
 742         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 743         let i = i < 0 ? 0 : i
 744         if getline(".") !~ "^\\s*$"
 745             let p = line(".") - 1
 746             let nextblank = getline(p) =~ "^\\s*$"
 747             while p > 0
 748                     \ && ((i == 0 && !nextblank)
 749                         \ || (i > 0 && ((indent(p) >= i
 750                             \ && !(nextblank && a:inner))
 751                             \ || (nextblank && !a:inner))))
 752                 -
 753                 let p = line(".") - 1
 754                 let nextblank = getline(p) =~ "^\\s*$"
 755             endwhile
 756             normal! 0V
 757             call cursor(curline, 0)
 758             let p = line(".") + 1
 759             let nextblank = getline(p) =~ "^\\s*$"
 760             while p <= lastline
 761                     \ && ((i == 0 && !nextblank)
 762                         \ || (i > 0 && ((indent(p) >= i
 763                             \ && !(nextblank && a:inner))
 764                             \ || (nextblank && !a:inner))))
 765                 +
 766                 let p = line(".") + 1
 767                 let nextblank = getline(p) =~ "^\\s*$"
 768             endwhile
 769             normal! $
 770         endif
 771     endfunction
 772 endif
 773
 774
 775 " ABBREVIATIONS
 776
 777 " Fix some of my spelling mistakes (German).
 778 inoreabbrev relle reelle
 779 inoreabbrev reele reelle
 780 " Fix some of my spelling mistakes (English).
 781 inoreabbrev completly completely
 782
 783
 784 " SYNTAX SETTINGS
 785
 786 " Activate syntax coloring.
 787 if has('syntax')
 788     " But only if it wasn't already active. Prevents breaking the syntax
 789     " coloring when reloading the vimrc. Thanks to johnLate for the idea.
 790     if !exists('g:syntax_on')
 791         syntax enable
 792     endif
 793
 794 " Don't highlight more than 500 columns as I normally don't have that long
 795 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 796 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 797     if exists('+synmaxcol')
 798         set synmaxcol=500
 799     endif
 800
 801 " Use (limited) syntax based omni completion if no other omni completion is
 802 " available. Taken from :help ft-syntax-omni.
 803     if has('autocmd') && exists('+omnifunc')
 804         augroup vimrc
 805             autocmd FileType *
 806                 \ if &omnifunc == '' |
 807                 \     setlocal omnifunc=syntaxcomplete#Complete |
 808                 \ endif
 809         augroup END
 810     endif
 811
 812 " Function to enable all custom highlights. Necessary as highlights are
 813 " window-local and thus must be set for each new window.
 814     function! s:CustomSyntaxHighlights()
 815         " Not the first time called, nothing to do.
 816         if exists('w:vimrc_syntax_run')
 817             return
 818         endif
 819         let w:vimrc_syntax_run = 1
 820
 821 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 822 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 823 " disabled when necessary with :2match (in Vim >= 700).
 824         if !&diff && exists(':2match')
 825             " Use ColorColumn for overlong lines if available and my color
 826             " scheme is used.
 827             if &t_Co == 256 && s:HasSyntaxGroup('ColorColumn')
 828                 2match ColorColumn /\%>78v./
 829             else
 830                 2match Todo /\%>78v./
 831             endif
 832         elseif !&diff
 833             match Todo /\%>78v./
 834         endif
 835
 836         if exists('*matchadd')
 837 " Highlight some important keywords in all documents.
 838             let l:todos = ['TODO', 'XXX', 'FIXME', 'NOTE',
 839                          \ 'CHANGED', 'REMOVED', 'DELETED']
 840             " Compatibility fix for Vim 6.4 which can't parse for in functions
 841             " (without function it's ignored).
 842             execute '  for l:x in l:todos'
 843                   \ '|     call matchadd("Todo", l:x)'
 844                   \ '| endfor'
 845
 846 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 847             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 848                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 849                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 850                           \ '205f', '2060', '3000', 'feff']
 851             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 852             " it won't work!
 853             execute '  for l:x in l:spaces'
 854                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 855                   \ '| endfor'
 856
 857 " Special highlight for tabs to reduce their visibility in contrast to other
 858 " SpecialKey characters (e.g. ^L).
 859             if &t_Co == 256 && s:HasSyntaxGroup('specialKeyTab')
 860                 call matchadd('specialKeyTab', '\t')
 861             endif
 862         endif
 863     endfunction
 864 " Enable highlights for the current and all new windows. Thanks to bairui in
 865 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 866     call s:CustomSyntaxHighlights()
 867     if has('autocmd')
 868         augroup vimrc
 869             autocmd WinEnter * call s:CustomSyntaxHighlights()
 870         augroup END
 871     endif
 872
 873 " Settings for specific filetypes.
 874
 875     " C
 876     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 877     " Haskell
 878     let g:hs_highlight_delimiters = 1
 879     let g:hs_highlight_boolean = 1
 880     let g:hs_highlight_types = 1
 881     let g:hs_highlight_more_types = 1
 882     " Java
 883     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 884     " Perl
 885     let g:perl_fold = 1
 886     let g:perl_fold_blocks = 1
 887     let g:perl_nofold_packages = 1
 888     let g:perl_include_pod = 1 " syntax coloring for PODs
 889     " PHP
 890     let g:php_folding = 3    " fold functions
 891     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 892     let g:php_sql_query = 1  " highlight SQL queries in strings
 893     " Python
 894     let g:python_highlight_all = 1
 895     " Shell
 896     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 897     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 898     let g:is_posix = 1        " POSIX shell (e.g. dash) is compatible enough
 899     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 900     " Vim
 901     let g:vimsyn_embed = 0      " don't highlight embedded languages
 902     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 903     " XML
 904     let g:xml_syntax_folding = 1
 905 endif
 906
 907
 908 " PLUGIN SETTINGS
 909
 910 if has('eval')
 911 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 912 " installing/removing/updating plugins simple. (Used for plugins with more
 913 " than one file.) Ignore errors in case pathogen is not installed.
 914     if v:version >= 700
 915         silent! execute 'call pathogen#infect()'
 916     endif
 917
 918 " Settings for securemodelines.
 919     " Only allow items I need (also includes spl which is not enabled by
 920     " default).
 921     if v:version >= 700 " need lists
 922         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 923                                               \ 'sw', 'sts', 'noet']
 924     endif
 925
 926 " Settings for gnupg.
 927     " Don't use temporary files for sensitive data.
 928     let g:GPGUsePipes = 1
 929
 930 " Settings for the NERD commenter.
 931     " Don't create any mappings I don't want to use.
 932     let g:NERDCreateDefaultMappings = 0
 933     " Map toggle comment.
 934     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 935
 936 " XPTemplate settings.
 937     " Try to maintain snippet rendering even after editing outside of a
 938     " snippet.
 939     let g:xptemplate_strict = 0
 940     " Don't complete any braces automatically.
 941     let g:xptemplate_brace_complete = 0
 942     " Only highlight the current placeholder.
 943     let g:xptemplate_highlight = 'current'
 944
 945 " CtrlP settings.
 946     " Don't manage the working directory (the default setting is too slow for
 947     " me).
 948     let g:ctrlp_working_path_mode = 0
 949
 950     " Path to cache directory. I prefer to keep generated files as local as
 951     " possible.
 952     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 953     " Permanent cache, cleared by a crontab entry. Use <F5> to update the
 954     " cache manually.
 955     let g:ctrlp_clear_cache_on_exit = 0
 956
 957     " Don't switch the window if the selected buffer is already open. I want
 958     " to open another view on this buffer in most cases.
 959     let g:ctrlp_switch_buffer = 0
 960
 961 " FSWitch settings.
 962     " Defaults don't work well for my projects.
 963     augroup vimrc
 964         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 965                           \ | let b:fswitchlocs = './'
 966         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 967                           \ | let b:fswitchlocs = './'
 968     augroup END
 969
 970     " Switch to corresponding header/source file.
 971     nnoremap <silent> <Leader>h :FSHere<CR>
 972
 973 " netrw settings.
 974     " Don't create ~/.vim/.netrwhist history file.
 975     let g:netrw_dirhistmax = 0
 976 endif
 977
 978
 979 " AUTO COMMANDS
 980
 981 " Use a custom auto group to prevent problems when the vimrc files is sourced
 982 " multiple times.
 983 if has('autocmd')
 984     augroup vimrc
 985
 986 " Go to last position of opened files. Taken from :help last-position-jump.
 987         autocmd BufReadPost *
 988             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 989             \     execute "normal! g'\"" |
 990             \ endif
 991 " But not for Git commits, go to beginning of the file.
 992         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 993
 994 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 995 " when switching to a help buffer which is in the background with :buffer as
 996 " these options are local to windows (and not only to buffers). This happens
 997 " because I often want to use only one window and thus the help buffer is in
 998 " the background.
 999         autocmd BufWinEnter *.txt
1000             \ if &filetype == 'help' |
1001             \     setlocal nolist |
1002             \     setlocal nonumber |
1003             \ endif
1004
1005 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
1006 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
1007 " want to paste once and then 'paste' gets automatically unset. InsertLeave
1008 " doesn't exist in older Vims. Use "*p to paste X11's selection, no need for
1009 " 'paste' in this case.
1010         if exists('##InsertLeave')
1011             autocmd InsertLeave * set nopaste
1012         endif
1013
1014 " Write all files when running :mak[e] before 'makeprg' is called.
1015 " QuickFixCmdPre doesn't exist in older Vims.
1016         if exists('##QuickFixCmdPre')
1017             autocmd QuickFixCmdPre * wall
1018         endif
1019
1020 " Don't ignore case while in insert mode, but ignore case in all other modes.
1021 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
1022 " capitalization. But while searching (/) 'ignorecase' is used.
1023 " InsertEnter/InsertLeave doesn't exist in older Vims.
1024         if exists('##InsertEnter') && exists('##InsertLeave')
1025             autocmd InsertEnter * set noignorecase
1026             autocmd InsertLeave * set   ignorecase
1027         endif
1028
1029 " Display a warning when editing a file which contains "do not edit" (ignoring
1030 " the case) and similar messages in the first lines of the file, for example
1031 " template files which were preprocessed or auto-generated files. Especially
1032 " useful when the header is not displayed on the first screen, e.g. when the
1033 " old position is restored.
1034         function! s:SearchForDoNotEditHeader()
1035             " Only search the first 20 lines to prevent false positives, e.g.
1036             " in scripts which write files containing this warning and ignore
1037             " the case (\c). (Can't use search()'s {stopline} as we might not
1038             " start searching from the top.)
1039             let l:search = '\c\(do not \(edit\|modify\)\|autogenerated by\)'
1040             let l:match = search(l:search, 'n')
1041             if l:match == 0 || l:match > 20
1042                 return
1043             endif
1044
1045             echoerr 'Do not edit this file! (Maybe a template file.)'
1046         endfunction
1047         autocmd BufRead * call s:SearchForDoNotEditHeader()
1048
1049 " AFTER/FTPLUGIN AUTO COMMANDS
1050
1051 " Disable spell checking for files which don't need it.
1052         autocmd FileType deb  setlocal nospell
1053         autocmd FileType diff setlocal nospell
1054         autocmd FileType tar  setlocal nospell
1055 " Fix to allow Vim edit crontab files as crontab doesn't work with
1056 " backupcopy=auto.
1057         autocmd FileType crontab setlocal backupcopy=yes
1058 " Don't use the modeline in git commits as the diff created by `git commit -v`
1059 " may contain one which could change the filetype or other settings of the
1060 " commit buffer. Also make sure we use only 72 characters per line which is
1061 " the recommendation for git commit messages (http://tpope.net/node/106).
1062         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
1063                                  \ setlocal textwidth=72
1064 " Fix 'include' setting for shell files to recognize '.' and 'source'
1065 " commands.
1066         autocmd FileType sh let &l:include = '^\s*\(\.\|source\)\s\+'
1067 " Use the same comment string as for Vim files in Vimperator files.
1068         autocmd FileType vimperator setlocal commentstring=\"%s
1069 " Use TeX compiler for (La)TeX files.
1070         autocmd FileType tex compiler tex
1071
1072 " FTDETECT AUTO COMMANDS
1073
1074 " Recognize .md as markdown files (Vim default is .mkd).
1075         autocmd BufRead,BufNewFile *.md set filetype=mkd
1076 " Recognize .test as Tcl files.
1077         autocmd BufRead,BufNewFile *.test set filetype=tcl
1078
1079 " OTHER AUTO COMMANDS
1080
1081 " Disable spell checking, displaying of list characters and long lines when
1082 " viewing documentation.
1083         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
1084
1085 " Use diff filetype for mercurial patches in patch queue.
1086         autocmd BufReadPost */.hg/patches/* set filetype=diff
1087
1088     augroup END
1089 endif
1090
1091
1092 " CUSTOM FUNCTIONS AND COMMANDS
1093
1094 if has('eval')
1095 " Convenient command to see the difference between the current buffer and the
1096 " file it was loaded from, thus the changes you made. Thanks to the
1097 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
1098 " for the diffed file as the filetype for the original file.
1099     if !exists(':DiffOrig')
1100         command DiffOrig
1101             \ let s:diff_orig_filetype = &filetype
1102             \ | vertical new
1103             \ | let &filetype = s:diff_orig_filetype
1104             \ | unlet s:diff_orig_filetype
1105             \ | set buftype=nofile
1106             \ | read ++edit #
1107             \ | 0d_
1108             \ | diffthis
1109             \ | wincmd p
1110             \ | diffthis
1111     endif
1112 endif