" Vim main configuration file.


" EDITOR SETTINGS

" Prevent editing as root as it may cause security problems. Use sudoedit
" instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21 CEST).
if $HOME == '/root' || exists('$SUDO_USER')
    echomsg 'Running as root is forbidden! Use sudoedit.'
    qall
endif


" Save 'runtimepath' in case it was changed by the system's configuration
" files.
if has('eval')
    let s:save_runtimepath = &runtimepath
endif
" Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
" system wide configuration file doesn't change default values.
set all&
" And restore it after all other options were reset.
if has('eval')
    let &runtimepath = s:save_runtimepath
endif

" Make sure Vim (and not Vi) settings are used.
set nocompatible

" Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
" runtime files).
set runtimepath-=~/.vim
set runtimepath^=~/.vim,~/.vim/runtime

" Don't store swap files in the same directory as the edited file.
set directory-=.
" But store them in ~/.tmp if available.
set directory^=~/.tmp

" Disable modelines as they may cause security problems. Instead use
" securemodelines (Vim script #1876).
set nomodeline

" Complete to longest common string (list:longest) and then complete all full
" matches after another (full). Thanks to pbrisbin
" (http://pbrisbin.com:8080/dotfiles/vimrc).
set wildmode=list:longest,full

" Increase history of executed commands (:).
set history=1000

" Increase number of possible undos.
set undolevels=1000

" Use strong encryption if possible, also used for swap/undo files.
if exists('+cryptmethod')
    set cryptmethod=blowfish
endif


" EDIT SETTINGS

" Enable automatic file detection, plugin and indention support.
if has('autocmd')
    filetype off " necessary for pathogen to force a reload of ftplugins
    filetype plugin indent on
endif

" Use UTF-8 file encoding for all files. Automatically recognize latin1 in
" existing files.
set fileencodings=utf-8,latin1

" Wrap text after 78 characters.
set textwidth=78

" Set tabs to 4 spaces, use softtabs.
set shiftwidth=4
set softtabstop=4
set expandtab
" When < and > is used indent/deindent to the next 'shiftwidth' boundary.
set shiftround
" Use the default value for real tabs.
set tabstop=8

" Enable auto indention.
set autoindent

" When joining lines only add one space after a sentence.
set nojoinspaces

" Allow backspacing over autoindent and line breaks.
set backspace=indent,eol

" Start a comment when hitting enter after a commented line (r) and when using
" o or O around a commented line (o).
set formatoptions+=ro
" Don't break a line if was already longer then 'textwidth' when insert mode
" started.
set formatoptions+=l

" Allow virtual editing (cursor can be positioned anywhere, even when there is
" no character) in visual block mode.
set virtualedit=block

" Already display matches while typing the search command. This makes spotting
" errors easy.
set incsearch

" Activate syntax folding.
if has('folding')
    set foldmethod=syntax
    set foldcolumn=2
    set foldlevel=99 " no closed folds at default, 'foldenable' would disable
                     " folding which is not what I want
endif

" Only check for case if the searched word contains a capital character.
set ignorecase
set smartcase

" Activate spell checking, use English as default. Don't use spell checking
" when diffing.
if exists('+spell') && has('syntax') && !&diff
    set spell
    set spelllang=en_us
endif

" Allow buffers with changes to be hidden. Very important for effective
" editing with multiple buffers.
set hidden


" DISPLAY SETTINGS

" Use a dark background. Doesn't change the background color, only sets text
" colors for a dark terminal.
set background=dark

" Display line numbers.
set number
" But use as little space as necessary for the numbers column. Thanks to James
" Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
if exists('+numberwidth')
    set numberwidth=1
endif
" Display the ruler with current line/file position. If 'statusline' is used
" then this only affects <C-G>.
set ruler
" Display partial commands in the status line.
set showcmd

" Don't redraw screen when executing macros; increases speed. Thanks to James
" Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
set lazyredraw

" Visualize the line the cursor is currently in.
if exists('+cursorline')
    set cursorline
endif

" Display tabs, trailing space, non breakable spaces and long lines (when
" wrapping is disabled).
set list
set listchars=trail:-,extends:>
if v:version >= 700
    set listchars+=nbsp:!
endif

if has('statusline')
    " Always display the status line even if there is only one window.
    set laststatus=2

    set statusline=
    " on the left
    set statusline+=%02n: " buffer number
    set statusline+=%f\   " path to current file in buffer
    set statusline+=%h    " [help] if buffer is help file
    set statusline+=%w    " [Preview] if buffer is preview buffer
    set statusline+=%m    " [+] if buffer was modified,
                          " [-] if 'modifiable' is off
    set statusline+=%r    " [RO] if buffer is read only

    " on the right
    set statusline+=%=                " right align
    set statusline+=0x%-8B\           " current character under cursor as hex
    set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
                                      " column number (%c),
                                      " virtual column number if different
                                      "                       than %c (%V)
    set statusline+=%P                " position in file in percent
endif


" MAPPINGS (except for plugins, see PLUGIN SETTINGS below)

" Easy way to exit insert mode.
inoremap jj <Esc>
inoremap jk <Esc>
" Also for command mode, thanks to http://github.com/mitechie/pyvim
" (2010-10-15).
cnoremap jj <C-C>
cnoremap jk <C-C>

" Disable arrow keys for all modes except command modes. Thanks to James Vega
" (http://git.jamessan.com/?p=etc/vim.git;a=summary).
map <Right>  <Nop>
map <Left>   <Nop>
map <Up>     <Nop>
map <Down>   <Nop>
imap <Right> <Nop>
imap <Left>  <Nop>
imap <Up>    <Nop>
imap <Down>  <Nop>
" Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
" below).
cmap <Up>    <Nop>
cmap <Down>  <Nop>
cmap <Right> <Nop>
cmap <Left>  <Nop>

" Use Ctrl-P/Ctrl-N as replacement for <Up>/<Down> in command mode. Thanks to
" abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
cnoremap <C-P> <Up>
cnoremap <C-N> <Down>

" Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
" 20:02 CEST). To suspend without saving either unmap it or use :stop<CR>.
nnoremap <C-Z> :update<CR>:stop<CR>

" 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
" in #vim on Freenode (2011-08-15 00:17 CEST).
nnoremap <C-G> 2<C-G>

" Use <Space> to move down a page and - to move up one like in mutt.
nnoremap <Space> <C-F>
nnoremap - <C-B>

" Go to next and previous buffer. Thanks to elik in #vim on Freenode
" (2010-05-16 18:38 CEST) for this idea.
nnoremap <silent> gb :bnext<CR>
nnoremap <silent> gB :bprev<CR>

" Fast access to buffers.
nnoremap <Leader>1 :1b<CR>
nnoremap <Leader>2 :2b<CR>
nnoremap <Leader>3 :3b<CR>
nnoremap <Leader>4 :4b<CR>
nnoremap <Leader>5 :5b<CR>
nnoremap <Leader>6 :6b<CR>
nnoremap <Leader>7 :7b<CR>
nnoremap <Leader>8 :8b<CR>
nnoremap <Leader>9 :9b<CR>
nnoremap <Leader>0 :10b<CR>

" Make last active window the only window. Similar to <C-w> o.
nnoremap <C-W>O <C-W>p<C-W>o

" Maps to change spell language between English and German and disable spell
" checking.
if exists('+spell')
    noremap <Leader>sn :set nospell<CR>
    noremap <Leader>se :set spell spelllang=en_us<CR>
    noremap <Leader>sd :set spell spelllang=de_de<CR>
endif

" Add semicolon to the end of the line. Thanks to
" http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
" on Freenode for an improved version which doesn't clobber any marks.
nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>

" * and # for selections in visual mode. Thanks to
" http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
" and all nerds involved (godlygeek, strull in #vim on Freenode).
if has('eval')
    function! s:VSetSearch()
        let temp = @@
        normal! gvy
        let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
        let @@ = temp
    endfunction
    vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
    vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
endif

" I often type "W" instead of "w" when trying to save a file. Fix my mistake.
" Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
" mailing list for the commands.
if v:version < 700
    cnoreabbrev W w
    cnoreabbrev Wa wa
    cnoreabbrev Wq wq
    cnoreabbrev Wqa wqa
else
    cnoreabbrev <expr> W
        \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
    cnoreabbrev <expr> Wa
        \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
    cnoreabbrev <expr> Wq
        \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
    cnoreabbrev <expr> Wqa
        \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
endif
" Also fix my typo with "Q".
if v:version < 700
    cnoreabbrev Q q
    cnoreabbrev Qa qa
else
    cnoreabbrev <expr> Q
        \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
    cnoreabbrev <expr> Qa
        \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
endif

" Make sure xa0 (alt + space) is automatically changed to a normal whitespace
" if pressed accidentally while in insert mode (happens on Mac when alt
" doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
" no longer set on the console.
if has('mac') || filereadable('/Users/.localized')
    inoremap <Char-0xa0> <Space>
endif

" Disable Apple style movements in MacVim.
if has('gui_macvim') && has('eval')
    let macvim_skip_cmd_opt_movement = 1
endif

" In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
" vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
noremap <silent> <C-L> :nohlsearch<CR><C-L>


" ABBREVIATIONS

" Fix some of my spelling mistakes.
iabbrev relle reelle
iabbrev reele reelle


" SYNTAX SETTINGS

" Activate syntax coloring.
if has('syntax')
    syntax enable

" Don't highlight more than 500 columns as I normally don't have that long
" lines and they slow down syntax coloring. Thanks to Derek Wyatt
" (http://www.derekwyatt.org/vim/the-vimrc-file/).
    if exists('+synmaxcol')
        set synmaxcol=500
    endif

" Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
" <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
" disabled when necessary with :2match (in Vim >= 700).
    if exists(':2match')
        2match Todo /\%>78v./
    else
        match Todo /\%>78v./
    endif

    if exists('*matchadd')
" Highlight some important keywords in all documents.
        for x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
            call matchadd('Todo', x)
        endfor
    endif

" Settings for specific filetypes.

    " Perl.
    let g:perl_fold = 1
    let g:perl_fold_blocks = 1
    let g:perl_nofold_packages = 1
    let g:perl_include_pod = 1 " syntax coloring for PODs

endif


" PLUGIN SETTINGS

" Use pathogen which allows one 'runtimepath' entry per plugin. This makes
" installing/removing/updating plugins simple. (Used for plugins with more
" than one file.)
if has('eval') && v:version >= 700
    execute 'call pathogen#runtime_append_all_bundles()'
endif

" Settings for the NERD commenter.
" Don't create any mappings I don't want to use.
if has('eval')
    let NERDCreateDefaultMappings = 0
endif
" Map toggle comment.
map <Leader><Leader> <Plug>NERDCommenterToggle

" XPTemplate settings.
if has('eval')
    " Try to maintain snippet rendering even after editing outside of a
    " snippet.
    let g:xptemplate_strict = 0
    " Don't complete any braces automatically.
    let g:xptemplate_brace_complete = 0
    " Only highlight the current placeholder.
    let g:xptemplate_highlight = 'current'
endif


" AUTO COMMANDS

" Use a custom auto group to prevent problems when the vimrc files is sourced
" twice.
if has('autocmd')
    augroup vimrc
        autocmd!

" Go to last position of opened files. Taken from :help last-position-jump.
        autocmd BufReadPost *
            \ if line("'\"") > 1 && line("'\"") <= line("$") |
            \     execute "normal! g'\"" |
            \ endif
" But not for Git commits, go to beginning of the file.
        autocmd BufReadPost COMMIT_EDITMSG normal! gg

" Make sure 'list' and 'number' is disabled in help files. This is necessary
" when switching to a help buffer which is in the background with :buffer as
" these options are local to windows (and not only to buffers). This happens
" because I often want to use only one window and thus the help buffer is in
" the background.
        autocmd BufWinEnter *.txt
            \ if &filetype == 'help' |
            \     setlocal nolist |
            \     setlocal nonumber |
            \ endif

" Automatically disable 'paste' mode when leaving insert mode. Thanks to
" Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
" want to paste once and then 'paste' gets automatically unset.
        if exists('#InsertLeave')
            autocmd InsertLeave * set nopaste
        endif

" AFTER/FTPLUGIN AUTO COMMANDS

" Disable spell checking for files which don't need it.
        autocmd FileType deb  setlocal nospell
        autocmd FileType diff setlocal nospell
        autocmd FileType tar  setlocal nospell
" Fix to allow Vim edit crontab files as crontab doesn't work with
" backupcopy=auto.
        autocmd FileType crontab setlocal backupcopy=yes
" Don't use the modeline in git commits as the diff created by `git commit -v`
" may contain one which could change the filetype or other settings of the
" commit buffer. Also make sure we use only 72 characters per line which is
" the recommendation for git commit messages (http://tpope.net/node/106).
        autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
                                 \ setlocal textwidth=72
" Use the same comment string as for Vim files in Vimperator files.
        autocmd FileType vimperator setlocal commentstring=\"%s

" FTDETECT AUTO COMMANDS

" Recognize .md as markdown files (Vim default is .mkd).
        autocmd BufRead,BufNewFile *.md set filetype=mkd
" Recognize .test as Tcl files.
        autocmd BufRead,BufNewFile *.test set filetype=tcl

" OTHER AUTO COMMANDS

" Disable spell checking, displaying of list characters and long lines when
" viewing documentation.
        autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match

" Use diff filetype for mercurial patches in patch queue.
        autocmd BufReadPost */.hg/patches/* set filetype=diff

    augroup END
endif