-- XMonad configuration file.
--
-- Should work fine with XMonad 0.7 and above.


import XMonad
-- Necessary for reflectVert.
import XMonad.Layout.Reflect
-- Necessary for avoidMaster.
import qualified XMonad.StackSet as W
-- Necessary for toggleLayouts.
import XMonad.Layout.ToggleLayouts
-- Necessary for smartBorders.
import XMonad.Layout.NoBorders
-- Necessary for composeOne and -?>.
import XMonad.Hooks.ManageHelpers
-- Necessary for `additionalKeys`.
import XMonad.Util.EZConfig


-- Prevent new windows from spawning in the master pane. Taken from
-- http://haskell.org/haskellwiki/Xmonad/Frequently_asked_questions on
-- 2009-06-30. Thanks. Modified to not steal focus from the master pane when a
-- new window is created, thanks to vav in #xmonad on Freenode (2010-04-15
-- 21:59).
avoidMaster :: W.StackSet i l a s sd -> W.StackSet i l a s sd
avoidMaster = W.modify' $ \c -> case c of
    W.Stack t [] (r:rs) -> W.Stack r [] (t:rs)
    otherwise           -> c

-- Create my custom layout.
--
-- Only use horizontal (Mirror tiled) and fullscreen layouts.
--
-- The master pane is at the top of the screen. To make sure new windows don't
-- spawn in the master pane avoidMaster (see below) is used. Borders are only
-- drawn when the screen has more then one window (smartBorders).
--
-- Thanks to jrick in #xmonad on Freenode (2009-06-29 22:19) for telling me
-- how to remove the vertical tiled layout.
--
-- toggleLayouts is used to allow switching to vertical tiled layout but not
-- using it with meta-space (see below in key bindings). Thanks to ml| in
-- #xmonad on Freenode (2010-06-14 09:49) how to use toggleLayouts.
myLayoutHook = toggleLayouts tiled $ smartBorders $ Mirror tiled ||| Full
    where
    -- Default tiling algorithm partitions the screen into two panes.
    tiled   = Tall nmaster delta ratio
    -- The default number of windows in the master pane.
    nmaster = 1
    -- Percent of screen to increment by when resizing panes.
    delta   = 3/100
    -- Default proportion of screen occupied by master pane.
    ratio   = 1/2

-- Don't spawn new windows in the master pane (which is at the top of the
-- screen). Thanks to dschoepe, aavogt and especially vav in #xmonad on
-- Freenode (2009-06-30 02:10f).
--
-- Also some applications are spawned on specific workspaces. Thanks to
-- dschoepe and ivanm in #xmonad on Freenode (2009-07-12 14:50).
myManageHook = composeOne
    [ className =? "Iceweasel" -?> doF (W.shift "2")
    , className =? "Wireshark" -?> doF (W.shift "3")

    -- Don't span new windows in the master pane.
    , return True -?> doF avoidMaster
    -- Prevent windows which get moved to other workspaces from removing the
    -- focus of the currently selected window. Thanks to vav in #xmonad on
    -- Freenode (2010-04-15 21:04).
    , return True -?> doF W.focusDown
    ]

main = xmonad $ defaultConfig
    -- Use Windows key as main key so it doesn't conflict with any other key
    -- bindings.
    { modMask = mod4Mask
    -- Inactive borders are black - invisible on my black screen.
    , normalBorderColor = "#000000"
    -- Active border is dark red.
    , focusedBorderColor = "#990000"
    -- Use my layout and manage hooks (see above).
    , layoutHook = myLayoutHook
    , manageHook = myManageHook
    -- Use unicode rxvt as my terminal.
    , terminal = "urxvt"
    }
    `additionalKeys` [
        -- Switch to additional layout (vertical tiled) defined by
        -- toggleLayouts above.
        ((mod4Mask, xK_v), sendMessage ToggleLayout)
    ]