# Zsh configuration file.


# Use Vi(m) style key bindings.
bindkey -v

# Use history and store it in ~/.zsh/history.
HISTSIZE=1000
SAVEHIST=1000
HISTFILE=~/.zsh/history
# Append to the history file instead of overwriting it and do it immediately
# when a command is executed.
setopt appendhistory
setopt incappendhistory
# If the same command is run multiple times store it only once in the history.
setopt histignoredups
# Vim like completions of previous executed commands.
bindkey "^P" history-beginning-search-backward
bindkey "^N" history-beginning-search-forward

# Prevent overwriting existing files with '> filename'.
setopt noclobber

# Entering the name of a directory (if it's not a command) will automatically
# cd to that directory.
setopt autocd

# When entering a nonexistent command name automatically try to find a similar
# one.
setopt correct

# Use colorized output, necessary for prompts and completions.
autoload -U colors && colors

# Set the default prompt. The current host and working directory is displayed,
# the exit code of the last command if it wasn't 0 and a + if this shell is
# running inside another shell.
# The prompt is in green and blue to make easily detectable, the error exit
# code in red and bold.
PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
%{${fg[blue]}%}%B%~%b%{${fg[default]}%} %(2L.+.)%# \
%(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"

# Use new completion system.
autoload -U compinit && compinit
# Load the complist module which provides additions to completion lists
# (coloring, scrollable).
zmodload zsh/complist
# Make sure the list of possible completions is displayed after pressing <TAB>
# the first time.
setopt nolistambiguous
# Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
# completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
bindkey "^I" expand-or-complete-prefix
# Use cache to speed up completions.
zstyle ':completion:*' use-cache on
zstyle ':completion:*' cache-path ~/.zsh/cache
# Ignore case if currently typed string doesn't match.
zstyle ':completion:*' matcher-list '' 'm:{a-zA-Z}={A-Za-z}'
# Ignore completion functions.
zstyle ':completion:*:functions' ignored-patterns '_*'
# Ignore parent directory.
zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
# Use ls like colors for completions.
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
# Make completion lists scrollable so "do you wish to see all n possibilities"
# is no longer displayed.
zstyle ':completion:*' list-prompt '%p'

# Enable zsh's extended glob abilities.
setopt extendedglob

# If ^C is pressed while typing a command, add it to the history so it can be
# easily retrieved later and then abort like ^C normally does. This is useful
# when I want to abort an command to do something in between and then finish
# typing the command.
TRAPINT() {
    # Store the current buffer in the history.
    zle && print -s $BUFFER

    # Return the default exit code so zsh aborts the current command.
    return $1
}

# Simplify calls to less, automatically redirects all output.
alias -g L='2>&1 | less'
# Simplify calls to colordiff, output is also piped through less.
alias -g D='2>&1 | colordiff L'
# Simplify calls to grep.
alias -g G='| grep'

# Improved ls which displays the files in columns (-C), visualises directories,
# links and other special files (-F) and pages everything through less (L).
function ls() {
    command ls -C -F $* L
}
# Helper function to list all files.
function la() {
    ls -a $*
}
# Helper function to list all files in list format with access rights, etc.
function ll() {
    la -l $*
}


# If a rc file for the current hostname (first part before a dot) exists load
# it, otherwise load rc.local if available.
host=${$(hostname)//.*/}
if [[ -f ~/.zsh/rc.$host ]]; then;
    source ~/.zsh/rc.$host
elif [[ -f ~/.zsh/rc.local ]]; then;
    source ~/.zsh/rc.local
fi