From 2cc93b7ada0b925d1ccecfa19a8b3f04cba13f2b Mon Sep 17 00:00:00 2001
From: Simon Ruderich <simon@ruderich.org>
Date: Tue, 10 May 2011 22:11:06 +0200
Subject: [PATCH] Switch plugins with more than one file to pathogen.

This stores them in dedicated directory per plugin in vim/bundle/.
---
 vim/autoload/pathogen.vim                     | 142 ++++++++++++++++++
 vim/{ => bundle/deb}/autoload/deb.vim         |   0
 vim/{ => bundle/deb}/plugin/debPlugin.vim     |   0
 vim/{ => bundle/deb}/syntax/deb.vim           |   0
 vim/{ => bundle/matchit}/doc/matchit.txt      |   0
 vim/{ => bundle/matchit}/plugin/matchit.vim   |   0
 .../nerdcommenter}/doc/NERD_commenter.txt     |   0
 .../nerdcommenter}/plugin/NERD_commenter.vim  |   0
 .../screenpaste}/doc/screenpaste.txt          |   0
 .../screenpaste}/plugin/screenpaste.vim       |   0
 vim/{ => bundle/surround}/doc/surround.txt    |   0
 vim/{ => bundle/surround}/plugin/surround.vim |   0
 vimrc                                         |   8 +
 13 files changed, 150 insertions(+)
 create mode 100644 vim/autoload/pathogen.vim
 rename vim/{ => bundle/deb}/autoload/deb.vim (100%)
 rename vim/{ => bundle/deb}/plugin/debPlugin.vim (100%)
 rename vim/{ => bundle/deb}/syntax/deb.vim (100%)
 rename vim/{ => bundle/matchit}/doc/matchit.txt (100%)
 rename vim/{ => bundle/matchit}/plugin/matchit.vim (100%)
 rename vim/{ => bundle/nerdcommenter}/doc/NERD_commenter.txt (100%)
 rename vim/{ => bundle/nerdcommenter}/plugin/NERD_commenter.vim (100%)
 rename vim/{ => bundle/screenpaste}/doc/screenpaste.txt (100%)
 rename vim/{ => bundle/screenpaste}/plugin/screenpaste.vim (100%)
 rename vim/{ => bundle/surround}/doc/surround.txt (100%)
 rename vim/{ => bundle/surround}/plugin/surround.vim (100%)

diff --git a/vim/autoload/pathogen.vim b/vim/autoload/pathogen.vim
new file mode 100644
index 0000000..e10fac9
--- /dev/null
+++ b/vim/autoload/pathogen.vim
@@ -0,0 +1,142 @@
+" pathogen.vim - path option manipulation
+" Maintainer:   Tim Pope <vimNOSPAM@tpope.org>
+" Version:      1.3
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" API is documented below.
+
+if exists("g:loaded_pathogen") || &cp
+  finish
+endif
+let g:loaded_pathogen = 1
+
+" Split a path into a list.
+function! pathogen#split(path) abort " {{{1
+  if type(a:path) == type([]) | return a:path | endif
+  let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+  return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction " }}}1
+
+" Convert a list to a path.
+function! pathogen#join(...) abort " {{{1
+  if type(a:1) == type(1) && a:1
+    let i = 1
+    let space = ' '
+  else
+    let i = 0
+    let space = ''
+  endif
+  let path = ""
+  while i < a:0
+    if type(a:000[i]) == type([])
+      let list = a:000[i]
+      let j = 0
+      while j < len(list)
+        let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+        let path .= ',' . escaped
+        let j += 1
+      endwhile
+    else
+      let path .= "," . a:000[i]
+    endif
+    let i += 1
+  endwhile
+  return substitute(path,'^,','','')
+endfunction " }}}1
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort " {{{1
+  return call('pathogen#join',[1] + a:000)
+endfunction " }}}1
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort " {{{1
+  let i = 0
+  let seen = {}
+  while i < len(a:list)
+    if has_key(seen,a:list[i])
+      call remove(a:list,i)
+    else
+      let seen[a:list[i]] = 1
+      let i += 1
+    endif
+  endwhile
+  return a:list
+endfunction " }}}1
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#separator() abort " {{{1
+  return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction " }}}1
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort " {{{1
+  let files = split(glob(a:pattern),"\n")
+  return map(files,'substitute(v:val,"[".pathogen#separator()."/]$","","")')
+endfunction "}}}1
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort " {{{1
+  return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction "}}}1
+
+" Checks if a bundle is 'disabled'. A bundle is considered 'disabled' if
+" its 'basename()' is included in g:pathogen_disabled[]'.
+function! pathogen#is_disabled(path) " {{{1
+  if !exists("g:pathogen_disabled")
+    return 0
+  endif
+  let sep = pathogen#separator()
+  return index(g:pathogen_disabled, strpart(a:path, strridx(a:path, sep)+1)) != -1
+endfunction "}}}1
+
+" Prepend all subdirectories of path to the rtp, and append all 'after'
+" directories in those subdirectories.
+function! pathogen#runtime_prepend_subdirectories(path) " {{{1
+  let sep    = pathogen#separator()
+  let before = filter(pathogen#glob_directories(a:path.sep."*[^~]"), '!pathogen#is_disabled(v:val)')
+  let after  = filter(pathogen#glob_directories(a:path.sep."*[^~]".sep."after"), '!pathogen#is_disabled(v:val[0:-7])')
+  let rtp = pathogen#split(&rtp)
+  let path = expand(a:path)
+  call filter(rtp,'v:val[0:strlen(path)-1] !=# path')
+  let &rtp = pathogen#join(pathogen#uniq(before + rtp + after))
+  return &rtp
+endfunction " }}}1
+
+" For each directory in rtp, check for a subdirectory named dir.  If it
+" exists, add all subdirectories of that subdirectory to the rtp, immediately
+" after the original directory.  If no argument is given, 'bundle' is used.
+" Repeated calls with the same arguments are ignored.
+function! pathogen#runtime_append_all_bundles(...) " {{{1
+  let sep = pathogen#separator()
+  let name = a:0 ? a:1 : 'bundle'
+  if "\n".s:done_bundles =~# "\\M\n".name."\n"
+    return ""
+  endif
+  let s:done_bundles .= name . "\n"
+  let list = []
+  for dir in pathogen#split(&rtp)
+    if dir =~# '\<after$'
+      let list +=  filter(pathogen#glob_directories(substitute(dir,'after$',name,'').sep.'*[^~]'.sep.'after'), '!pathogen#is_disabled(v:val[0:-7])') + [dir]
+    else
+      let list +=  [dir] + filter(pathogen#glob_directories(dir.sep.name.sep.'*[^~]'), '!pathogen#is_disabled(v:val)')
+    endif
+  endfor
+  let &rtp = pathogen#join(pathogen#uniq(list))
+  return 1
+endfunction
+
+let s:done_bundles = ''
+" }}}1
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() " {{{1
+  for dir in pathogen#split(&rtp)
+    if dir[0 : strlen($VIM)-1] !=# $VIM && isdirectory(dir.'/doc') && !empty(glob(dir.'/doc/*')) && (!filereadable(dir.'/doc/tags') || filewritable(dir.'/doc/tags'))
+      helptags `=dir.'/doc'`
+    endif
+  endfor
+endfunction " }}}1
+
+" vim:set ft=vim ts=8 sw=2 sts=2:
diff --git a/vim/autoload/deb.vim b/vim/bundle/deb/autoload/deb.vim
similarity index 100%
rename from vim/autoload/deb.vim
rename to vim/bundle/deb/autoload/deb.vim
diff --git a/vim/plugin/debPlugin.vim b/vim/bundle/deb/plugin/debPlugin.vim
similarity index 100%
rename from vim/plugin/debPlugin.vim
rename to vim/bundle/deb/plugin/debPlugin.vim
diff --git a/vim/syntax/deb.vim b/vim/bundle/deb/syntax/deb.vim
similarity index 100%
rename from vim/syntax/deb.vim
rename to vim/bundle/deb/syntax/deb.vim
diff --git a/vim/doc/matchit.txt b/vim/bundle/matchit/doc/matchit.txt
similarity index 100%
rename from vim/doc/matchit.txt
rename to vim/bundle/matchit/doc/matchit.txt
diff --git a/vim/plugin/matchit.vim b/vim/bundle/matchit/plugin/matchit.vim
similarity index 100%
rename from vim/plugin/matchit.vim
rename to vim/bundle/matchit/plugin/matchit.vim
diff --git a/vim/doc/NERD_commenter.txt b/vim/bundle/nerdcommenter/doc/NERD_commenter.txt
similarity index 100%
rename from vim/doc/NERD_commenter.txt
rename to vim/bundle/nerdcommenter/doc/NERD_commenter.txt
diff --git a/vim/plugin/NERD_commenter.vim b/vim/bundle/nerdcommenter/plugin/NERD_commenter.vim
similarity index 100%
rename from vim/plugin/NERD_commenter.vim
rename to vim/bundle/nerdcommenter/plugin/NERD_commenter.vim
diff --git a/vim/doc/screenpaste.txt b/vim/bundle/screenpaste/doc/screenpaste.txt
similarity index 100%
rename from vim/doc/screenpaste.txt
rename to vim/bundle/screenpaste/doc/screenpaste.txt
diff --git a/vim/plugin/screenpaste.vim b/vim/bundle/screenpaste/plugin/screenpaste.vim
similarity index 100%
rename from vim/plugin/screenpaste.vim
rename to vim/bundle/screenpaste/plugin/screenpaste.vim
diff --git a/vim/doc/surround.txt b/vim/bundle/surround/doc/surround.txt
similarity index 100%
rename from vim/doc/surround.txt
rename to vim/bundle/surround/doc/surround.txt
diff --git a/vim/plugin/surround.vim b/vim/bundle/surround/plugin/surround.vim
similarity index 100%
rename from vim/plugin/surround.vim
rename to vim/bundle/surround/plugin/surround.vim
diff --git a/vimrc b/vimrc
index b4e44dc..97d0c37 100644
--- a/vimrc
+++ b/vimrc
@@ -60,6 +60,7 @@ endif
 
 " Enable automatic file detection, plugin and indention support.
 if has('autocmd')
+    filetype off " necessary for pathogen to force a reload of ftplugins
     filetype plugin indent on
 endif
 
@@ -359,6 +360,13 @@ endif
 
 " PLUGIN SETTINGS
 
+" Use pathogen which allows one 'runtimepath' entry per plugin. This makes
+" installing/removing/updating plugins simple. (Used for plugins with more
+" than one file.)
+if has('eval')
+    call pathogen#runtime_append_all_bundles()
+endif
+
 " Settings for the NERD commenter.
 " Don't create any mappings I don't want to use.
 if has('eval')
-- 
2.44.1