bin/fcscs

   1 #!/usr/bin/perl
   2
   3 # fcscs - fast curses screen content select
   4
   5 # Copyright (C) 2013-2016  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use v5.10; # say, state
  25
  26 use Encode ();
  27 use Fcntl ();
  28 use I18N::Langinfo ();
  29
  30 use Curses ();
  31
  32 our $VERSION = '0.01';
  33
  34
  35 =head1 NAME
  36
  37 fcscs - fast curses screen content select
  38
  39 =head1 SYNOPSIS
  40
  41 B<fcscs> [I<options>] I<path/to/screen/capture/file>
  42
  43 =head1 DESCRIPTION
  44
  45 B<fcscs> is a small tool which allows quick selection of terminal screen
  46 contents (like URLs, paths, regex matches, etc.) and passes the selection to
  47 GNU Screen's or Tmux's buffer or any other program. The selection can then
  48 quickly be pasted, e.g. in the shell. Requires GNU Screen or Tmux. It's
  49 licensed under the GPL 3 or later.
  50
  51 =head1 OPTIONS
  52
  53 None so far.
  54
  55 =head1 USAGE
  56
  57 Short overview of the general usage, details below:
  58
  59     - start fcscs
  60     - configure actions (optional)
  61         - enable pasting
  62         - ...
  63     - select mode (optional, URL mode is used on startup):
  64         - f: file paths
  65         - u: URLs
  66         - ...
  67         - /: search mode
  68     - for `normal' modes:
  69         - select match by displayed number or <return> for lowest numbered
  70           match
  71         - configured action is run, e.g. URL is opened with browser
  72     - for `search' mode:
  73         - perform incremental search
  74         - on <return> go to `normal' mode to select a match
  75         - after the match is selected wait for confirmation or extension
  76         - confirmation: <return> run previously selected action
  77         - extension: change match, e.g. select complete word or line
  78
  79 GNU Screen setup (add to F<~/.screenrc>):
  80
  81     bind ^B eval "hardcopy $HOME/.tmp/screen-fcscs" "screen fcscs $HOME/.tmp/screen-fcscs"
  82
  83 Tmux setup (add to F<~/.tmux.conf>):
  84
  85     bind-key C-b capture-pane \; save-buffer ~/.tmp/tmux-fcscs \; delete-buffer \; new-window "fcscs ~/.tmp/tmux-fcscs"
  86
  87 This requires a writable ~/.tmp directory. Adapt the mapping according to your
  88 preferences. Ensure these files are not readable by others as they can contain
  89 private data (umask or protected directory). B<fcscs> must be in your C<$PATH>
  90 for the above mappings to work.
  91
  92 Pressing the configured mapping (Prefix Ctrl-B in this example) opens B<fcscs>
  93 in a new GNU screen/Tmux window. After selection, the content is either passed
  94 to external programs (e.g. for URLs) or copied to the paste buffer or directly
  95 pasted in your previous window and the new window is closed.
  96
  97 To select a match just type its number. If the match is unique, the entry is
  98 automatically selected (e.g. you press 2 and there are only 19 matches). If
  99 there are multiple matches left (e.g. you press 1 and there are more than ten
 100 matches available), press return to select the current match (1 in this case)
 101 or another number to select the longer match. Use backspace to remove the last
 102 entered number.
 103
 104 Press return before entering a number to select the last (lowest numbered)
 105 match (underlined by default). To abort without selecting any match use "q".
 106
 107 To change the selection mode (e.g. paths, files, etc.) use one of the mappings
 108 explained below. Per default URLs are selected, see options for a way to
 109 change this.
 110
 111 I<NOTE>: Opening URLs in the browser passes the URL via the command line which
 112 leaks URLs to other users on the current system via C<ps aux> or C<top>.
 113
 114 I<NOTE>: When yanking (copying) a temporary file is used to pass the data to
 115 GNU screen/Tmux without exposing it to C<ps aux> or C<top>. However this may
 116 leak data if those temporary files are written to disk. To prevent this change
 117 your C<$TMP> to point to a memory-only location or encrypted storage.
 118
 119 If no window appears, try running B<fcscs> manually to catch the error message
 120 and please report the bug:
 121
 122     fcscs /path/to/screen-or-tmux-fcscs-file
 123
 124
 125 =head1 MODES
 126
 127 =cut
 128
 129
 130 # CLASSES
 131
 132 # Helper class for drawing on the screen using Curses.
 133 package Screen {
 134     sub init {
 135         my ($class, $encoding) = @_;
 136
 137         # Prefer strict UTF-8 handling (see perldoc Encode); just in case.
 138         if (lc $encoding eq 'utf8') {
 139             $encoding = 'UTF-8';
 140         }
 141         # Get Encode object to speed up decode()/encode().
 142         my $encoding_object = Encode::find_encoding($encoding);
 143         die "unsupported encoding '$encoding'" unless ref $encoding_object;
 144
 145         my $curses = Curses->new or die $!;
 146
 147         my $self = {
 148             encoding        => $encoding,
 149             encoding_object => $encoding_object,
 150             curses          => $curses,
 151             debug           => 0,
 152             prompt          => {
 153                 flags => undef,
 154                 name  => undef,
 155                 value => undef,
 156             },
 157         };
 158         bless $self, $class;
 159
 160         Curses::start_color;
 161         # Allow default colors by passing -1 to init_pair. A default color is
 162         # not drawn on screen thus allowing terminals with pseudo-transparency
 163         # to use the transparent background in place of the default color.
 164         Curses::use_default_colors;
 165
 166         Curses::cbreak;
 167         Curses::noecho;
 168         $self->cursor(0);
 169
 170         return $self;
 171     }
 172     sub deinit {
 173         my ($self) = @_;
 174
 175         Curses::nocbreak;
 176         Curses::echo;
 177         $self->cursor(1);
 178
 179         Curses::endwin;
 180         return;
 181     }
 182
 183     # Convert between Perl's internal encoding and the terminal's encoding.
 184     sub encode {
 185         my ($self, $string) = @_;
 186         return $self->{encoding_object}->encode($string);
 187     }
 188     sub decode {
 189         my ($self, $string) = @_;
 190         return eval { # returns undef on decode failure
 191             $self->{encoding_object}->decode($string, Encode::FB_CROAK);
 192         };
 193     }
 194
 195     # Create attribute for the given fore-/background colors.
 196     sub color_pair {
 197         my ($self, $fg, $bg) = @_;
 198
 199         state $next_color_pair = 1; # must start at 1 for init_pair()
 200
 201         Curses::init_pair($next_color_pair, $fg, $bg);
 202         return Curses::COLOR_PAIR($next_color_pair++);
 203     }
 204
 205     # Draw a string which must fit in the current line. Wrapping/clipping is
 206     # not supported and must be handled by the caller.
 207     sub draw_simple {
 208         my ($self, $y, $x, $attributes, $string) = @_;
 209
 210         die if $string =~ /\n/;
 211         # FIXME: wide characters
 212         die if $x + length $string > $self->width;
 213
 214         $self->{curses}->attron($attributes) if defined $attributes;
 215         $self->{curses}->addstr($y, $x, $self->encode($string));
 216         $self->{curses}->attroff($attributes) if defined $attributes;
 217         return;
 218     }
 219     # Like draw_simple(), but the string is automatically clipped.
 220     sub draw_clipped {
 221         my ($self, $y, $x, $attributes, $string) = @_;
 222
 223         # FIXME: wide characters
 224         $string = substr $string, 0, $self->width - $x;
 225         $self->draw_simple($y, $x, $attributes, $string);
 226         return;
 227     }
 228     sub draw {
 229         my ($self, $y, $x, $attributes, $string) = @_;
 230
 231         die unless defined $string;
 232
 233         while (1) {
 234             my $offset;
 235             # We must print each line separately. Search for next newline or
 236             # line end, whichever is closer.
 237             if ($string =~ /\n/) {
 238                 $offset = $-[0];
 239             }
 240             # FIXME: wide characters
 241             if ($x + length $string > $self->width) {
 242                 my $new_offset = $self->width - $x;
 243                 if (not defined $offset or $offset > $new_offset) {
 244                     $offset = $new_offset;
 245                 }
 246             }
 247             last unless defined $offset;
 248
 249             # FIXME: wide characters
 250             $self->draw_simple($y, $x, $attributes, substr $string, 0, $offset);
 251
 252             # Don't draw "\n" itself.
 253             if ("\n" eq substr $string, $offset, 1) {
 254                 $offset++;
 255             }
 256
 257             $string = substr $string, $offset;
 258
 259             $y++;
 260             $x = 0;
 261         }
 262
 263         $self->draw_simple($y, $x, $attributes, $string);
 264         return $y;
 265     }
 266
 267     sub draw_prompt {
 268         my ($self, $config) = @_;
 269
 270         $self->debug('draw_prompt', 'started');
 271
 272         my $x = 0;
 273         my $y = $self->height - 1;
 274
 275         # Clear line for better visibility.
 276         $self->draw_simple($y, $x, undef, ' ' x $self->width);
 277
 278         # Draw prompt flags.
 279         if (defined (my $s = $self->{prompt}{flags})) {
 280             $s = "[$s]";
 281             $self->debug('draw_prompt', $s);
 282             $self->draw_clipped($y, $x, $config->{attribute}{prompt_flags}, $s);
 283             $x += length($s) + 1; # space between next element
 284         }
 285         # Draw prompt name.
 286         if (defined (my $s = $self->{prompt}{name})) {
 287             $s = "[$s]";
 288             $self->debug('draw_prompt', $s);
 289             $self->draw_clipped($y, $x, $config->{attribute}{prompt_name}, $s);
 290             $x += length($s) + 1;
 291         }
 292         # Draw prompt value, e.g. a search field.
 293         if (defined (my $s = $self->{prompt}{value})) {
 294             $self->debug('draw_prompt', $s);
 295             $self->draw_clipped($y, $x, undef, $s);
 296             $x += length($s) + 1;
 297         }
 298         return;
 299     }
 300
 301     sub draw_matches {
 302         my ($self, $config, $matches_remove, $matches_add) = @_;
 303
 304         foreach (@{$matches_remove}) {
 305             $self->draw($_->{y}, $_->{x}, Curses::A_NORMAL, $_->{string});
 306         }
 307
 308         my $attr_id     = $config->{attribute}{match_id};
 309         my $attr_string = $config->{attribute}{match_string};
 310         my $attr_last   = $config->{attribute}{match_last};
 311
 312         foreach (@{$matches_add}) {
 313             my $attr = (defined $_->{id} and $_->{id} == 1)
 314                      ? $attr_last
 315                      : $attr_string;
 316             $self->draw($_->{y}, $_->{x}, $attr, $_->{string});
 317             if (defined $_->{id}) {
 318                 $self->draw($_->{y}, $_->{x}, $attr_id, $_->{id});
 319             }
 320         }
 321         return;
 322     }
 323
 324     sub die {
 325         my ($self, @args) = @_;
 326
 327         my $attr = $self->color_pair(Curses::COLOR_RED, -1) | Curses::A_BOLD;
 328
 329         # Clear the screen to improve visibility of the error message.
 330         $self->{curses}->clear;
 331
 332         my $y = $self->draw(0, 0, $attr, "@args");
 333
 334         if ($self->{debug}) {
 335             my $msg;
 336             eval {
 337                 require Devel::StackTrace;
 338             };
 339             if ($@) {
 340                 $msg = "Devel::StackTrace missing, no stack trace.\n";
 341             } else {
 342                 my $trace = Devel::StackTrace->new;
 343                 $msg = "Stack trace:\n" . $trace->as_string;
 344             }
 345             $y = $self->draw($y + 1, 0, Curses::A_NORMAL, $msg);
 346         }
 347
 348         $self->draw($y + 1, 0, Curses::A_NORMAL,
 349                     'Press any key to terminate fcscs.');
 350         $self->refresh;
 351
 352         $self->getch;
 353         $self->deinit;
 354         exit 1;
 355     }
 356     sub debug {
 357         my ($self, $module, @args) = @_;
 358
 359         return if not $self->{debug};
 360
 361         state $fh; # only open the file once per run
 362         if (not defined $fh) {
 363             # Ignore errors if the directory doesn't exist.
 364             if (not open $fh, '>', "$ENV{HOME}/.config/fcscs/log") {
 365                 $fh = undef; # a failed open still writes a value to $fh
 366                 return;
 367             }
 368         }
 369
 370         foreach (@args) {
 371             $_ = $self->encode($_);
 372         }
 373         say $fh "$module: @args";
 374         return;
 375     }
 376
 377
 378     sub prompt {
 379         my ($self, %settings) = @_;
 380
 381         foreach (keys %settings) {
 382             CORE::die if not exists $self->{prompt}{$_};
 383             $self->{prompt}{$_} = $settings{$_};
 384         }
 385         return;
 386     }
 387
 388     # Wrapper for Curses.
 389     sub width   { return $Curses::COLS; }
 390     sub height  { return $Curses::LINES; }
 391     sub refresh { return $_[0]->{curses}->refresh; }
 392     sub getch   { return $_[0]->{curses}->getch; }
 393     sub cursor  { Curses::curs_set($_[1]); return; }
 394 }
 395
 396
 397
 398 # FUNCTIONS
 399
 400 sub prepare_input {
 401     my ($screen, $input_ref) = @_;
 402
 403     # Make sure the input fits on the screen by removing the top lines if
 404     # necessary.
 405     splice @{$input_ref}, 0, -$screen->height;
 406
 407     # Pad each line with spaces to the screen width to correctly handle
 408     # multi-line regexes.
 409     # FIXME: wide characters
 410     my @padded = map { sprintf '%-*s', $screen->width, $_ } @{$input_ref};
 411
 412     my $string = join "\n", @padded;
 413     return {
 414         string => $string,
 415         lines  => $input_ref,
 416         width  => $screen->width + 1,
 417                   # + 1 = "\n", used in input_match_offset_to_coordinates
 418     };
 419 }
 420
 421 sub input_match_offset_to_coordinates {
 422     my ($width, $offset) = @_;
 423
 424     die unless defined $offset;
 425
 426     my $y = int($offset / $width);
 427     my $x = $offset - $y * $width;
 428     return ($x, $y);
 429 }
 430
 431 sub get_regex_matches {
 432     my ($input, $regex) = @_;
 433
 434     my @matches;
 435     while ($input->{string} =~ /$regex/g) {
 436         my $offset = $-[1];
 437         die "Match group required in regex '$regex'" if not defined $offset;
 438
 439         my ($x, $y) = input_match_offset_to_coordinates($input->{width},
 440                                                         $offset);
 441         push @matches, { x => $x, y => $y, offset => $offset, string => $1 };
 442     }
 443     return @matches;
 444 }
 445
 446
 447 sub run_command {
 448     my ($screen, $cmd) = @_;
 449
 450     $screen->debug('run_command', "running @{$cmd}");
 451
 452     my $exit = do {
 453         # Perl's system() combined with a $SIG{__WARN__} which die()s has
 454         # issues due to the fork. The die() in the __WARN__ handler doesn't
 455         # die but the program continues after the system().
 456         #
 457         # If the forked process fails to exec (e.g. program not found) then
 458         # the __WARN__ handler is called (because a warning is about to be
 459         # displayed) and the die() should display a message and terminate the
 460         # process. But due to the fork it doesn't terminate the parent process
 461         # and instead changes the return value of system(); it's no longer -1
 462         # which makes it impossible to detect that case.
 463         #
 464         # Perl < 5.18 (found in 5.14) doesn't setup $$ during system() which
 465         # makes it impossible to detect if the handler was called from inside
 466         # the child.
 467         #
 468         # Instead, just ignore any warnings during the system(). Thanks to
 469         # mauke in #perl on Freenode (2013-10-29 23:30 CET) for the idea to
 470         # use no warnings and anno for testing a more recent Perl version with
 471         # a working $$.
 472         no warnings;
 473
 474         my @cmd = map { $screen->encode($_) } @{$cmd};
 475         system { $cmd[0] } @cmd;
 476     };
 477     if ($exit != 0) {
 478         my $msg;
 479         if ($? == -1) {
 480             $msg = 'failed to execute: ' . $!;
 481         } elsif ($? & 127) {
 482             $msg = 'killed by signal ' . ($? & 127);
 483         } else {
 484             $msg = 'exited with code ' . ($? >> 8);
 485         }
 486         die "system(@{$cmd}) $msg.";
 487     }
 488     return;
 489 }
 490 sub run_in_background {
 491     my ($screen, $sub) = @_;
 492
 493     $screen->debug('run_in_background', "running $sub");
 494
 495     my $pid = fork;
 496     defined $pid or die $!;
 497
 498     if ($pid == 0) {
 499         # The terminal multiplexer sends a SIGHUP to the process when it
 500         # closes the window (because the parent process has exited).
 501         local $SIG{HUP} = 'IGNORE';
 502
 503         # Necessary for GNU screen or it'll keep the window open until an
 504         # external command has run.
 505         require File::Spec;
 506         my $devnull = File::Spec->devnull();
 507         open STDIN,  '<', $devnull or die $!;
 508         open STDOUT, '>', $devnull or die $!;
 509         open STDERR, '>', $devnull or die $!;
 510
 511         # Double-fork to prevent zombies.
 512         my $pid = fork;
 513         defined $pid or die $!;
 514         if ($pid == 0) { # child
 515             $sub->();
 516         }
 517         exit;
 518     }
 519     waitpid $pid, 0 or die $!;
 520     return;
 521 }
 522
 523
 524 sub select_match {
 525     my ($name, $screen, $config, $input, $matches) = @_;
 526
 527     $screen->debug('select_match', 'started');
 528
 529     return if @{$matches} == 0;
 530     # Don't return on initial run to give the user a chance to select another
 531     # mode, e.g. to switch from URL selection to search selection.
 532     if (@{$matches} == 1 and not $config->{state}{initial}) {
 533         return { match => $matches->[0] };
 534     }
 535     $config->{state}{initial} = 0;
 536
 537     my @sorted = sort { $b->{y} <=> $a->{y} or $b->{x} <=> $a->{x} } @{$matches};
 538
 539     my $i = 1;
 540     foreach (@sorted) {
 541         $_->{id} = $i++;
 542     }
 543
 544     $screen->prompt(name => $name, value => undef);
 545     $screen->draw_prompt($config);
 546
 547     $screen->draw_matches($config, [], $matches);
 548     $screen->refresh;
 549
 550     my $number = 0;
 551     while (1) {
 552         my $char = $screen->getch;
 553         if ($char =~ /^\d$/) {
 554             $number = $number * 10 + $char;
 555         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
 556             $number = int($number / 10);
 557         } elsif ($char eq "\n"
 558                 or $char eq $config->{setting}{alternative_return}) {
 559             if ($number == 0) { # number without selection matches last entry
 560                 $number = 1;
 561             }
 562             last;
 563
 564         # Selecting a new mode requires falling through into the main input
 565         # loop and then starting the new mode.
 566         } elsif (defined $config->{mapping}{mode}{$char}) {
 567             $screen->draw_matches($config, $matches, []); # clear matches
 568             return { key => $char };
 569         # All other mappings stay in the current mode.
 570         } elsif (defined (my $m = $config->{mapping}{simple}{$char})) {
 571             $m->($char, $screen, $config, $input);
 572             next;
 573
 574         } else {
 575             next; # ignore unknown mappings
 576         }
 577
 578         last if $number > 0 and $number * 10 > @{$matches}; # unique match
 579
 580         my @remaining = $number == 0
 581                       ? @{$matches}
 582                       : grep { $_->{id} =~ /^$number/ } @{$matches};
 583         $screen->draw_matches($config, $matches, \@remaining);
 584         $screen->refresh;
 585     }
 586
 587     $screen->draw_matches($config, $matches, []); # remove matches
 588
 589     foreach (@{$matches}) {
 590         return { match => $_ } if $_->{id} == $number;
 591     }
 592     $screen->debug('select_match', 'no match selected');
 593     return { match => undef };
 594 }
 595
 596 sub extend_match_regex_left {
 597     my ($line, $match, $regex) = @_;
 598
 599     my $s = reverse substr $line, 0, $match->{x};
 600     if ($s =~ /^($regex)/) {
 601         $match->{string}  = reverse($1) . $match->{string};
 602         $match->{x}      -= length $1;
 603         $match->{offset} -= length $1;
 604     }
 605     return;
 606 }
 607 sub extend_match_regex_right {
 608     my ($line, $match, $regex) = @_;
 609
 610     my $s = substr $line, $match->{x} + length $match->{string};
 611     if ($s =~ /^($regex)/) {
 612         $match->{string} .= $1;
 613     }
 614     return;
 615 }
 616 sub extend_match {
 617     my ($screen, $config, $input, $match) = @_;
 618
 619     $screen->debug('extend_match', 'started');
 620
 621     return if not defined $match;
 622
 623     $screen->prompt(name => 'extend', value => undef);
 624     $screen->draw_prompt($config);
 625
 626     delete $match->{id}; # don't draw any match ids
 627     $screen->draw_matches($config, [], [$match]);
 628     $screen->refresh;
 629
 630     my $line = $input->{lines}[$match->{y}];
 631
 632     while (1) {
 633         my $match_old = \%{$match};
 634
 635         my $char = $screen->getch;
 636         if ($char eq "\n"
 637                 or $char eq $config->{setting}{alternative_return}) {
 638             last; # accept match
 639
 640         } elsif ($char eq 'w') { # select current word (both directions)
 641             extend_match_regex_left($line,  $match, qr/\w+/);
 642             extend_match_regex_right($line, $match, qr/\w+/);
 643         } elsif ($char eq 'b') { # select current word (only left)
 644             extend_match_regex_left($line,  $match, qr/\w+/);
 645         } elsif ($char eq 'e') { # select current word (only right)
 646             extend_match_regex_right($line, $match, qr/\w+/);
 647
 648         } elsif ($char eq 'W') { # select current WORD (both directions)
 649             extend_match_regex_left($line,  $match, qr/\S+/);
 650             extend_match_regex_right($line, $match, qr/\S+/);
 651         } elsif ($char eq 'B') { # select current WORD (only left)
 652             extend_match_regex_left($line,  $match, qr/\S+/);
 653         } elsif ($char eq 'E') { # select current WORD (only right)
 654             extend_match_regex_right($line, $match, qr/\S+/);
 655
 656         } elsif ($char eq '0') { # select to beginning of line
 657             extend_match_regex_left($line, $match, qr/.+/);
 658         } elsif ($char eq '$') { # select to end of line
 659             extend_match_regex_right($line, $match, qr/.+/);
 660
 661         # Allow mode changes if not overwritten by local mappings.
 662         } elsif (defined $config->{mapping}{mode}{$char}) {
 663             $screen->draw_matches($config, [$match_old], []); # clear match
 664             return { key => $char };
 665
 666         } else {
 667             next; # ignore unknown mappings
 668         }
 669
 670         $screen->draw_matches($config, [$match_old], [$match]);
 671         $screen->refresh;
 672     }
 673
 674     $screen->debug('extend_match', 'done');
 675
 676     return { match => $match };
 677 }
 678
 679
 680 sub mapping_paste {
 681     my ($key, $screen, $config, $input) = @_;
 682
 683     $screen->debug('mapping_paste', 'started');
 684
 685     $config->{state}{handler} = $config->{handler}{paste};
 686
 687     $screen->prompt(flags => 'P'); # paste
 688     $screen->draw_prompt($config);
 689     $screen->refresh;
 690
 691     return {};
 692 }
 693 sub mapping_yank {
 694     my ($key, $screen, $config, $input) = @_;
 695
 696     $screen->debug('mapping_yank', 'started');
 697
 698     $config->{state}{handler} = $config->{handler}{yank};
 699
 700     $screen->prompt(flags => 'Y'); # yank
 701     $screen->draw_prompt($config);
 702     $screen->refresh;
 703
 704     return {};
 705 }
 706
 707
 708 =head2 NORMAL MODES
 709
 710 Normal modes select matches by calling a function which returns them, e.g. by
 711 using a regex.
 712
 713 The following normal modes are available:
 714
 715 =over 4
 716
 717 =item B<path mode> select relative/absolute paths
 718
 719 =item B<url mode>  select URLs
 720
 721 =item B<ip mode>   select IPv4 and IPv6 addresses
 722
 723 =back
 724
 725 =cut
 726 sub mapping_mode_path {
 727     my ($key, $screen, $config, $input) = @_;
 728
 729     $screen->debug('mapping_mode_path', 'started');
 730
 731     my @matches = get_regex_matches($input, $config->{regex}{path});
 732     return {
 733         select  => 'path select',
 734         matches => \@matches,
 735         handler => $config->{handler}{yank},
 736     };
 737 }
 738 sub mapping_mode_url {
 739     my ($key, $screen, $config, $input) = @_;
 740
 741     $screen->debug('mapping_mode_url', 'started');
 742
 743     my @matches = get_regex_matches($input, $config->{regex}{url});
 744     return {
 745         select  => 'url select',
 746         matches => \@matches,
 747         handler => $config->{handler}{url},
 748     };
 749 }
 750 sub mapping_mode_ip {
 751     my ($key, $screen, $config, $input) = @_;
 752
 753     $screen->debug('mapping_mode_ip', 'started');
 754
 755     my @ipv4 = get_regex_matches($input, $config->{regex}{ipv4});
 756     my @ipv6 = get_regex_matches($input, $config->{regex}{ipv6});
 757     return {
 758         select  => 'ip select',
 759         matches => [@ipv4, @ipv6],
 760         handler => $config->{handler}{ip},
 761     };
 762 }
 763
 764 =head2 SEARCH MODE (AND EXTEND MODE)
 765
 766 Search mode is a special mode which lets you type a search string (a Perl
 767 regex) and then select one of the matches. Afterwards you can extend the
 768 match. For example select the complete word or to the end of the line. This
 769 allows quick selection of arbitrary text.
 770
 771 The following mappings are available during the extension mode (not
 772 configurable at the moment):
 773
 774 =over 4
 775
 776 =item B<w> select current word
 777
 778 =item B<b> extend word to the left
 779
 780 =item B<e> extend word to the right
 781
 782 =item B<W> select current WORD
 783
 784 =item B<B> extend WORD to the left
 785
 786 =item B<E> extend WORD to the right
 787
 788 =item B<0> extend to beginning of line
 789
 790 =item B<$> extend to end of line
 791
 792 =back
 793
 794 C<word> includes any characters matching C<\w+>, C<WORD> any non-whitespace
 795 characters (C<\S+>), just like in Vim.
 796
 797 =cut
 798 sub mapping_mode_search {
 799     my ($key, $screen, $config, $input) = @_;
 800
 801     $screen->debug('mapping_mode_search', 'started');
 802
 803     $screen->cursor(1);
 804
 805     my $search = ''; # encoded
 806     my @last_matches;
 807     while (1) {
 808         # getch doesn't return decoded characters but raw input bytes. Wait
 809         # until the input character is complete.
 810         my $value = $screen->decode($search);
 811         $value = '' unless defined $value; # undef on decode failure
 812
 813         $screen->prompt(name => 'search', value => $value);
 814         $screen->draw_prompt($config);
 815         $screen->refresh;
 816
 817         my $char = $screen->getch;
 818         # TODO: readline editing support
 819         if ($char eq "\n") {
 820             last;
 821         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
 822             # Remove a character, not a byte.
 823             $search = $screen->decode($search);
 824             chop $search;
 825             $search = $screen->encode($search);
 826         } else {
 827             $search .= $char;
 828             next unless defined $screen->decode($search);
 829         }
 830
 831         my @matches;
 832         if ($search ne '') {
 833             my $case = '';
 834             if (($config->{setting}{smartcase} and $search eq lc $search)
 835                     or $config->{setting}{ignorecase}) {
 836                 $case = '(?i)';
 837             }
 838             # Ignore invalid regexps.
 839             # TODO: display warning on error?
 840             eval {
 841                 @matches = get_regex_matches($input, qr/($case$search)/);
 842             };
 843         }
 844         $screen->draw_matches($config, \@last_matches, \@matches);
 845         @last_matches = @matches;
 846     }
 847
 848     $screen->cursor(0);
 849
 850     $screen->prompt(name => undef, value => undef); # clear prompt
 851     $screen->draw_prompt($config);
 852
 853     $screen->debug('mapping_mode_search', 'done');
 854
 855     return {
 856         select  => 'search',
 857         matches => \@last_matches,
 858         extend  => 1,
 859         handler => $config->{handler}{yank},
 860     };
 861 }
 862
 863 sub mapping_quit {
 864     my ($key, $screen, $config, $input) = @_;
 865
 866     # Key is necessary to fall through to main event loop which then quits.
 867     return { key => $key, quit => 1 };
 868 }
 869
 870
 871 sub handler_yank {
 872     my ($screen, $config, $match) = @_;
 873
 874     $screen->debug('handler_yank', 'started');
 875
 876     require File::Temp;
 877
 878     # Use a temporary file to prevent leaking the yanked data to other users
 879     # with the command line, e.g. ps aux or top.
 880     my ($fh, $tmp) = File::Temp::tempfile(); # dies on its own
 881     print $fh $screen->encode($match->{value});
 882     close $fh or die $!;
 883
 884     if ($config->{setting}{multiplexer} eq 'screen') {
 885         $screen->debug('handler_yank', 'using screen');
 886
 887         # GNU screen displays an annoying "Slurping X characters into buffer".
 888         # Use 'msgwait 0' as a hack to disable it.
 889         my $msgwait = $config->{setting}{screen_msgwait};
 890         run_command($screen, ['screen', '-X', 'msgwait', 0]);
 891         run_command($screen, ['screen', '-X', 'readbuf', $tmp]);
 892         run_command($screen, ['screen', '-X', 'msgwait', $msgwait]);
 893     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
 894         $screen->debug('handler_yank', 'using tmux');
 895
 896         run_command($screen, ['tmux', 'load-buffer', $tmp]);
 897     } else {
 898         die 'unsupported multiplexer';
 899     }
 900
 901     unlink $tmp or die $!;
 902     return;
 903 }
 904 sub handler_paste {
 905     my ($screen, $config, $match) = @_;
 906
 907     $screen->debug('handler_paste', 'started');
 908
 909     require Time::HiRes;
 910
 911     my @cmd;
 912     if ($config->{setting}{multiplexer} eq 'screen') {
 913         $screen->debug('handler_paste', 'using screen');
 914         @cmd = qw( screen -X paste . );
 915     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
 916         $screen->debug('handler_paste', 'using tmux');
 917         @cmd = qw( tmux paste-buffer );
 918     } else {
 919         die 'unsupported multiplexer';
 920     }
 921
 922     run_in_background($screen, sub {
 923         # We need to get the data in the paste buffer before we can paste
 924         # it.
 925         handler_yank($screen, $config, $match);
 926
 927         # Sleep until we switch back to the current window.
 928         Time::HiRes::usleep($config->{setting}{paste_sleep});
 929
 930         run_command($screen, \@cmd);
 931     });
 932     return;
 933 }
 934 sub handler_url {
 935     my ($screen, $config, $match) = @_;
 936
 937     $screen->debug('handler_url', "opening $match->{value}");
 938
 939     run_in_background($screen, sub {
 940         my @cmd = ( @{$config->{setting}{browser}}, $match->{value} );
 941         run_command($screen, \@cmd);
 942     });
 943     return;
 944 }
 945
 946
 947
 948 # CONFIGURATION DEFAULTS
 949
 950 =head1 CONFIGURATION
 951
 952 fcscs is configured through F<~/.fcscsrc> or F<~/.config/fcscs/fcscsrc> which
 953 is a normal Perl script with all of Perl's usual features.
 954
 955 All configuration values are stored in the hash C<%config>. All manually
 956 defined keys overwrite the default settings.
 957
 958 A simple F<~/.fcscsrc> could look like this (for details about the used
 959 settings see below):
 960
 961     use strict;
 962     use warnings;
 963
 964     use Curses; # for COLOR_* and A_* constants
 965
 966     our %config;
 967
 968     # Draw matches in blue.
 969     $config{attribute}{match_string} = color_pair(COLOR_BLUE, -1);
 970     # Enable Vim-like 'smartcase', ignore case until an upper character is
 971     # searched.
 972     $config{setting}{smartcase} = 1;
 973
 974     # Use chromium to open URLs if running under X, elinks otherwise.
 975     if (defined $ENV{DISPLAY}) {
 976         $config{setting}{browser} = ['chromium'];
 977     } else {
 978         $config{setting}{browser} = ['elinks'];
 979     }
 980
 981     # Let fcscs know the file was loaded successfully.
 982     1;
 983
 984 =cut
 985
 986
 987 if (@ARGV != 1) {
 988     require Pod::Usage;
 989     Pod::Usage::pod2usage(2);
 990 }
 991
 992
 993 # Determine terminal encoding from the environment ($ENV{LANG} or similar).
 994 my $encoding = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET);
 995
 996 my $screen = Screen->init($encoding);
 997
 998 # We must restore the screen before exiting.
 999 local $SIG{INT} = sub {
1000     $screen->deinit;
1001     exit 128 + 2;
1002 };
1003 # Make all warnings fatal to make sure they don't get lost (stderr is normally
1004 # not displayed).
1005 local $SIG{__WARN__} = sub {
1006     $screen->die('warning', @_);
1007 };
1008
1009
1010
1011 =head2 MAPPINGS
1012
1013 I<NOTE>: Mappings are split in two categories: Mode mappings which change the
1014 selection and may receive additional input (e.g. a search string) and simple
1015 mappings which only change some value. Mode mappings are configured via
1016 C<$config{mapping}{mode}>, simple mappings via C<$config{mapping}{simple}>.
1017
1018 The following mode mappings are available by default (the function to remap
1019 them in parentheses):
1020
1021 =over
1022
1023 =item B<f> select absolute/relative paths (C<\&mapping_mode_path>)
1024
1025 =item B<u> select URLs (C<\&mapping_mode_url>)
1026
1027 =item B<i> select IPv4 and IPv6 addresses (C<\&mapping_mode_ip>)
1028
1029 =item B</> search for regex to get selection (C<\&mapping_mode_search>)
1030
1031 =item B<q> quit fcscs (C<\&mapping_quit>)
1032
1033 =back
1034
1035 The following simple mappings are available by default:
1036
1037 =over
1038
1039 =item B<p> enable pasting (C<\&mapping_paste>)
1040
1041 =item B<y> enable yanking (copying) (C<\&mapping_yank>)
1042
1043 =back
1044
1045 The following additional mappings are available by default:
1046
1047 =over
1048
1049 =item B<\n> accept current selection (not customizable)
1050
1051 =item B<s>  additional key to accept selection (B<alternative_return> option)
1052
1053 =back
1054
1055 All (single-byte) keys except numbers, backspace and return can be mapped.
1056
1057 Unknown mappings are ignored when pressing keys.
1058
1059 To remove a default mapping, delete it from the mapping hash.
1060
1061 Example:
1062
1063     # Map 'p' to select paths, 'P' to enable pasting.
1064     $config{mapping}{mode}{p} = \&mapping_mode_path;
1065     $config{mapping}{simple}{P} = \&mapping_paste;
1066
1067     # Disable 'f' mapping.
1068     delete $config{mapping}{mode}{f};
1069
1070 =cut
1071 my %mapping_mode = (
1072     f   => \&mapping_mode_path,
1073     u   => \&mapping_mode_url,
1074     i   => \&mapping_mode_ip,
1075     '/' => \&mapping_mode_search,
1076     q   => \&mapping_quit,
1077 );
1078 my %mapping_simple = (
1079     p => \&mapping_paste,
1080     y => \&mapping_yank,
1081 );
1082
1083 =head2 ATTRIBUTES
1084
1085 Attributes are used to style the output. They must be Curses attributes.
1086 Defaults in parentheses (foreground, background, attribute).
1087
1088 =over
1089
1090 =item B<match_id>      attribute for match numbers (red, default, bold)
1091
1092 =item B<match_string>  attribute for matches (yellow, default, normal)
1093
1094 =item B<match_last>    attribute for the match selected by return (yellow, default, underline)
1095
1096 =item B<prompt_name>   attribute for prompt name (standout)
1097
1098 =item B<prompt_flags>  attribute for prompt flags (standout)
1099
1100 =back
1101
1102 Example:
1103
1104     # Draw prompt flags in bold red with default background color.
1105     $config{attribute}{prompt_flags}
1106         = Curses::A_BOLD
1107         | color_pair(Curses::COLOR_RED, -1);
1108
1109 =cut
1110 my %attribute = (
1111     match_id     => $screen->color_pair(Curses::COLOR_RED, -1)
1112                     | Curses::A_BOLD,
1113     match_string => $screen->color_pair(Curses::COLOR_YELLOW, -1),
1114     match_last   => $screen->color_pair(Curses::COLOR_YELLOW, -1)
1115                     | Curses::A_UNDERLINE,
1116     prompt_name  => Curses::A_STANDOUT,
1117     prompt_flags => Curses::A_STANDOUT,
1118 );
1119
1120 =head2 SETTINGS
1121
1122 Defaults in parentheses.
1123
1124 =over
1125
1126 =item B<debug>              enable debug mode, writes to I<~/.config/fcscs/log> (C<0>)
1127
1128 =item B<initial_mode>       start in this mode, must be a valid mode mapping (C<\&mapping_mode_url>)
1129
1130 =item B<multiplexer>        set multiplexer ("screen" or "tmux") if not autodetected (C<undef>)
1131
1132 =item B<ignorecase>         ignore case when searching (C<0>)
1133
1134 =item B<smartcase>          ignore case unless one uppercase character is searched (C<1>)
1135
1136 =item B<paste_sleep>        sleep x us before running paste command (C<100_000>)
1137
1138 =item B<screen_msgwait>     GNU Screen's msgwait variable, used when yanking (C<5>)
1139
1140 =item B<alternative_return> additional accept key like return, set to C<\n> to disable (C<s>)
1141
1142 =item B<browser>            browser command as array reference (C<['x-www-browser']>)
1143
1144 =back
1145
1146 Example:
1147
1148     # Select paths on startup instead of URLs.
1149     $config{setting}{initial_mode} = \&mapping_mode_path;
1150
1151 =cut
1152 my %setting = (
1153     # options
1154     debug              => 0,
1155     initial_mode       => \&mapping_mode_url,
1156     multiplexer        => undef,
1157     ignorecase         => 0,
1158     smartcase          => 1,
1159     paste_sleep        => 100_000,
1160     screen_msgwait     => 5,
1161     # global mappings
1162     alternative_return => 's',
1163     # commands
1164     browser            => ['x-www-browser'],
1165 );
1166
1167 =head2 REGEXPS
1168
1169 =over
1170
1171 =item B<url>  used by C<\&mapping_mode_url>
1172
1173 =item B<path> used by C<\&mapping_mode_path>
1174
1175 =item B<ipv4> used by C<\&mapping_mode_ip>
1176
1177 =item B<ipv6> used by C<\&mapping_mode_ip>
1178
1179 =back
1180
1181 Example:
1182
1183     # Select all non-whitespace characters when searching for paths.
1184     $config{regex}{path} = qr{(\S+)};
1185
1186 =cut
1187 my %regex = (
1188     # Taken from urlview's default configuration file, thanks.
1189     url  => qr{((?:(?:(?:http|https|ftp|gopher)|mailto):(?://)?[^ <>"\t]*|(?:www|ftp)[0-9]?\.[-a-z0-9.]+)[^ .,;\t\n\r<">\):]?[^, <>"\t]*[^ .,;\t\n\r<">\):])},
1190     path => qr{(~?[a-zA-Z0-9_./-]*/[a-zA-Z0-9_./-]+)},
1191     # IP addresses with optional prefix. Not perfectly accurate but good
1192     # enough.
1193     ipv4 => qr!\b(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}(?:/\d{1,2})?)\b!,
1194     ipv6 => qr!\b((?:[0-9a-fA-F]{1,4})?(?::+[0-9a-fA-F]{1,4})+(?:/\d{1,3})?)\b!,
1195 );
1196
1197 =head2 HANDLERS
1198
1199 Handlers are used to perform actions on the selected string.
1200
1201 The following handlers are available, defaults in parentheses.
1202
1203 =over
1204
1205 =item B<yank>  used to yank (copy) selection to paste buffer (C<\&handler_yank>)
1206
1207 =item B<paste> used to paste selection into window (C<\&handler_paste>)
1208
1209 =item B<url>   used to open URLs (e.g. in a browser) (C<\&handler_url>)
1210
1211 =item B<ip>    used to handle IPs (C<\&handler_yank>)
1212
1213 =back
1214
1215 Example:
1216
1217     # Download YouTube videos with a custom wrapper, handle all other URLs
1218     # with the default URL handler.
1219     $config{handler}{url} = sub {
1220         my ($screen, $config, $match) = @_;
1221
1222         if ($match->{value} =~ m{^https://www.youtube.com/}) {
1223             return run_in_background($screen, sub {
1224                 run_command($screen, ['youtube-dl-wrapper', $match->{value}]);
1225             });
1226         }
1227         handler_url(@_);
1228     };
1229
1230 =cut
1231 my %handler = (
1232     yank  => \&handler_yank,
1233     paste => \&handler_paste,
1234     url   => \&handler_url,
1235     ip    => \&handler_yank,
1236 );
1237
1238 my %state = (
1239     initial => 1, # used by select_match() for 'initial_mode'
1240     handler => undef,
1241 );
1242
1243
1244
1245 # CONFIGURATION "API"
1246
1247 =head2 FUNCTIONS
1248
1249 The following functions are available:
1250
1251     color_pair($fg, $bg)
1252
1253 Create a new Curses attribute with the given fore- and background color.
1254
1255     mapping_mode_path()
1256     mapping_mode_url()
1257     mapping_mode_ip()
1258     mapping_mode_search()
1259
1260     mapping_paste()
1261     mapping_yank()
1262     mapping_quit()
1263
1264 Used as mappings, see L</MAPPINGS> above.
1265
1266     handler_yank()
1267     handler_paste()
1268     handler_url()
1269
1270 Used as handler to yank, paste selection or open URL in browser.
1271
1272     debug()
1273     get_regex_matches()
1274     select_match()
1275     run_command()
1276     run_in_background()
1277
1278 Helper functions when writing custom mappings, see the source for details.
1279
1280 Example:
1281
1282     TODO
1283
1284 =cut
1285
1286 # All variables and functions which are usable by ~/.fcscsrc.
1287 package Fcscs {
1288     our $screen; # "private"
1289     our %config;
1290
1291     sub color_pair { return $screen->color_pair(@_); }
1292
1293     sub mapping_mode_path { return main::mapping_mode_path(@_); }
1294     sub mapping_mode_url { return main::mapping_mode_url(@_); }
1295     sub mapping_mode_ip { return main::mapping_mode_ip(@_); }
1296     sub mapping_mode_search { return main::mapping_mode_search(@_); }
1297
1298     sub mapping_paste { return main::mapping_paste(@_); }
1299     sub mapping_yank { return main::mapping_yank(@_); }
1300     sub mapping_quit { return main::mapping_quit(@_); }
1301
1302     sub handler_yank { return main::handler_yank(@_); }
1303     sub handler_paste { return main::handler_paste(@_); }
1304     sub handler_url { return main::handler_url(@_); }
1305
1306     sub debug { return main::debug(@_); }
1307
1308     sub get_regex_matches { return main::get_regex_matches(@_); }
1309     sub select_match { return main::select_match(@_); }
1310
1311     sub run_command { return main::run_command(@_); }
1312     sub run_in_background { return main::run_in_background(@_); }
1313 }
1314 $Fcscs::screen = $screen;
1315
1316
1317
1318 # LOAD USER CONFIG
1319
1320 # Alias %config and %Fcscs::config. %config is less to type.
1321 our %config;
1322 local *config = \%Fcscs::config;
1323
1324 $config{mapping}{mode}   = \%mapping_mode;
1325 $config{mapping}{simple} = \%mapping_simple;
1326 $config{attribute}       = \%attribute;
1327 $config{setting}         = \%setting;
1328 $config{regex}           = \%regex;
1329 $config{handler}         = \%handler;
1330 $config{state}           = \%state;
1331
1332 package Fcscs {
1333     my @configs = ("$ENV{HOME}/.fcscsrc",
1334                    "$ENV{HOME}/.config/fcscs/fcscsrc");
1335     foreach my $path (@configs) {
1336         my $decoded = $screen->decode($path);
1337
1338         # Load configuration file. Checks have a race condition if the home
1339         # directory is writable by an attacker (but then the user is screwed
1340         # anyway).
1341         next unless -e $path;
1342         if (not -O $path) {
1343             $screen->die("Config '$decoded' not owned by current user!");
1344         }
1345         # Make sure the file is not writable by other users. Doesn't handle
1346         # ACLs and see comment above about race conditions.
1347         my @stat = stat $path or die $!;
1348         my $mode = $stat[2];
1349         if (($mode & Fcntl::S_IWGRP) or ($mode & Fcntl::S_IWOTH)) {
1350             die "Config '$decoded' must not be writable by other users.";
1351         }
1352
1353         my $result = do $path;
1354         if (not $result) {
1355             $screen->die("Failed to parse '$decoded': $@") if $@;
1356             $screen->die("Failed to do '$decoded': $!") unless defined $result;
1357             $screen->die("Failed to run '$decoded'.");
1358         }
1359
1360         last; # success, don't load more files
1361     }
1362 }
1363 $screen->{debug} = $config{setting}{debug};
1364
1365
1366 # MAIN
1367
1368 eval {
1369     # Auto-detect current multiplexer.
1370     if (not defined $config{setting}{multiplexer}) {
1371         if (defined $ENV{STY} and defined $ENV{TMUX}) {
1372             die 'Found both $STY and $TMUX, set $config{setting}{multiplexer}.';
1373         } elsif (defined $ENV{STY}) {
1374             $config{setting}{multiplexer} = 'screen';
1375         } elsif (defined $ENV{TMUX}) {
1376             $config{setting}{multiplexer} = 'tmux';
1377         } else {
1378             die 'No multiplexer found.';
1379         }
1380     }
1381
1382     my $binmode = $encoding;
1383     # GNU screen stores the screen dump for unknown reasons as ISO-8859-1
1384     # instead of the currently active encoding.
1385     if ($config{setting}{multiplexer} eq 'screen') {
1386         $binmode = 'ISO-8859-1';
1387     }
1388
1389     my @input_lines;
1390     open my $fh, '<', $ARGV[0] or die $!;
1391     binmode $fh, ":encoding($binmode)" or die $!;
1392     while (<$fh>) {
1393         chomp;
1394         push @input_lines, $_;
1395     }
1396     close $fh or die $!;
1397
1398     my $input = prepare_input($screen, \@input_lines);
1399
1400     # Display original screen content.
1401     my $y = 0;
1402     foreach (@{$input->{lines}}) {
1403         $screen->draw_simple($y++, 0, undef, $_);
1404     }
1405     $screen->refresh;
1406
1407
1408     my $mapping = $config{setting}{initial_mode};
1409
1410     my $key;
1411     while (1) {
1412         if (not defined $mapping) {
1413             $key = $screen->getch unless defined $key;
1414             $screen->debug('input', "got key '$key'");
1415
1416             $mapping = $config{mapping}{mode}{$key};
1417             $mapping = $config{mapping}{simple}{$key} unless defined $mapping;
1418             if (not defined $mapping) { # ignore unknown mappings
1419                 $key = undef;
1420                 next;
1421             }
1422         }
1423
1424         $screen->debug('input', 'running mapping');
1425         my $result = $mapping->($key, $screen, \%config, $input);
1426         $mapping = undef;
1427
1428 RESULT:
1429         if (defined $result->{quit}) {
1430             $screen->debug('input', 'quitting');
1431             last;
1432         }
1433         if (defined $result->{key}) {
1434             $key = $result->{key}; # lookup another mapping
1435             $screen->debug('input', "processing new key: '$key'");
1436             next;
1437         }
1438         if (defined $result->{select}) {
1439             $screen->debug('input', 'selecting match');
1440             my $tmp = $result;
1441             $result = select_match($result->{select},
1442                                    $screen, \%config, $input,
1443                                    $result->{matches});
1444             $result->{handler} = $tmp->{handler};
1445             $result->{extend}  = $tmp->{extend};
1446             goto RESULT; # reprocess special entries in result
1447         }
1448         if (defined $result->{extend}) {
1449             $screen->debug('input', 'extending match');
1450             $result = extend_match($screen, \%config, $input,
1451                                    $result->{match});
1452             goto RESULT; # reprocess special entries in result
1453         }
1454         if (defined $result->{match}) {
1455             if (not defined $result->{match}{value}) {
1456                 $result->{match}{value} = $result->{match}{string};
1457             }
1458
1459             $screen->debug('input', 'running handler');
1460
1461             # Choose handler with falling priority.
1462             my @handlers = (
1463                 $config{state}{handler},     # set by user
1464                 $result->{match}{handler},   # set by match
1465                 $result->{handler},          # set by mapping
1466                 $config{handler}{yank},      # fallback
1467             );
1468             foreach my $handler (@handlers) {
1469                 next unless defined $handler;
1470
1471                 $handler->($screen, \%config, $result->{match});
1472                 last;
1473             }
1474             last;
1475         }
1476
1477         $key = undef; # get next key from user
1478     }
1479 };
1480 if ($@) {
1481     $screen->die("$@");
1482 }
1483
1484 $screen->deinit;
1485
1486 __END__
1487
1488 =head1 EXIT STATUS
1489
1490 =over 4
1491
1492 =item B<0>
1493
1494 Success.
1495
1496 =item B<1>
1497
1498 An error occurred.
1499
1500 =item B<2>
1501
1502 Invalid arguments/options.
1503
1504 =back
1505
1506 =head1 AUTHOR
1507
1508 Simon Ruderich E<lt>simon@ruderich.orgE<gt>
1509
1510 =head1 LICENSE AND COPYRIGHT
1511
1512 Copyright (C) 2013-2016 by Simon Ruderich
1513
1514 This program is free software: you can redistribute it and/or modify
1515 it under the terms of the GNU General Public License as published by
1516 the Free Software Foundation, either version 3 of the License, or
1517 (at your option) any later version.
1518
1519 This program is distributed in the hope that it will be useful,
1520 but WITHOUT ANY WARRANTY; without even the implied warranty of
1521 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1522 GNU General Public License for more details.
1523
1524 You should have received a copy of the GNU General Public License
1525 along with this program.  If not, see E<lt>http://www.gnu.org/licenses/E<gt>.
1526
1527 =head1 SEE ALSO
1528
1529 L<screen(1)>, L<tmux(1)>, L<urlview(1)>
1530
1531 =cut