bin/fcscs

   1 #!/usr/bin/perl
   2
   3 # fcscs - fast curses screen content select
   4
   5 # Copyright (C) 2013-2016  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use v5.10; # say, state
  25
  26 use Encode ();
  27 use Fcntl ();
  28 use I18N::Langinfo ();
  29
  30 use Curses ();
  31
  32 our $VERSION = '0.01';
  33
  34
  35 =head1 NAME
  36
  37 fcscs - fast curses screen content select
  38
  39 =head1 SYNOPSIS
  40
  41 B<fcscs> [I<options>] I<path/to/screen/capture/file>
  42
  43 =head1 DESCRIPTION
  44
  45 B<fcscs> is a small tool which allows quick selection of terminal screen
  46 contents (like URLs, paths, regex matches, etc.) and passes the selection to
  47 GNU Screen's or Tmux's buffer or any other program. The selection can then
  48 quickly be pasted, e.g. in the shell. Requires GNU Screen or Tmux. It's
  49 licensed under the GPL 3 or later.
  50
  51 =head1 OPTIONS
  52
  53 None so far.
  54
  55 =head1 USAGE
  56
  57 Short overview of the general usage, details below:
  58
  59     - start fcscs
  60     - configure actions (optional)
  61         - enable pasting
  62         - ...
  63     - select mode (optional, URL mode is used on startup):
  64         - f: file paths
  65         - i: IPs
  66         - u: URLs
  67         - ...
  68         - /: search mode
  69     - for `normal' modes:
  70         - select match by displayed number or <return> for lowest numbered
  71           match
  72         - configured action is run, e.g. URL is opened with browser
  73     - for `search' mode:
  74         - perform incremental search
  75         - on <return> go to `normal' mode to select a match
  76         - after the match is selected wait for confirmation or extension
  77         - confirmation: <return> run previously selected action
  78         - extension: change match, e.g. select complete word or line
  79
  80 GNU Screen setup (add to F<~/.screenrc>):
  81
  82     bind ^B eval "hardcopy $HOME/.tmp/screen-fcscs" "screen fcscs $HOME/.tmp/screen-fcscs"
  83
  84 Tmux setup (add to F<~/.tmux.conf>):
  85
  86     bind-key C-b capture-pane \; save-buffer ~/.tmp/tmux-fcscs \; delete-buffer \; new-window "fcscs ~/.tmp/tmux-fcscs"
  87
  88 This requires a writable ~/.tmp directory. Adapt the mapping according to your
  89 preferences. Ensure these files are not readable by others as they can contain
  90 private data (umask or protected directory). B<fcscs> must be in your C<$PATH>
  91 for the above mappings to work.
  92
  93 Pressing the configured mapping (Prefix Ctrl-B in this example) opens B<fcscs>
  94 in a new GNU screen/Tmux window. After selection, the content is either passed
  95 to external programs (e.g. for URLs) or copied to the paste buffer or directly
  96 pasted in your previous window and the new window is closed.
  97
  98 To select a match just type its number. If the match is unique, the entry is
  99 automatically selected (e.g. you press 2 and there are only 19 matches). If
 100 there are multiple matches left (e.g. you press 1 and there are more than ten
 101 matches available), press return to select the current match (1 in this case)
 102 or another number to select the longer match. Use backspace to remove the last
 103 entered number.
 104
 105 Press return before entering a number to select the last (lowest numbered)
 106 match (underlined by default). To abort without selecting any match use "q".
 107
 108 To change the selection mode (e.g. paths, files, etc.) use one of the mappings
 109 explained below. Per default URLs are selected, see options for a way to
 110 change this.
 111
 112 I<NOTE>: Opening URLs in the browser passes the URL via the command line which
 113 leaks URLs to other users on the current system via C<ps aux> or C<top>.
 114
 115 I<NOTE>: When yanking (copying) a temporary file is used to pass the data to
 116 GNU screen/Tmux without exposing it to C<ps aux> or C<top>. However this may
 117 leak data if those temporary files are written to disk. To prevent this change
 118 your C<$TMP> to point to a memory-only location or encrypted storage.
 119
 120 If no window appears, try running B<fcscs> manually to catch the error message
 121 and please report the bug:
 122
 123     fcscs /path/to/screen-or-tmux-fcscs-file
 124
 125
 126 =head1 MODES
 127
 128 =cut
 129
 130
 131 # CLASSES
 132
 133 # Helper class for drawing on the screen using Curses.
 134 package Screen {
 135     sub init {
 136         my ($class, $encoding) = @_;
 137
 138         # Prefer strict UTF-8 handling (see perldoc Encode); just in case.
 139         if (lc $encoding eq 'utf8') {
 140             $encoding = 'UTF-8';
 141         }
 142         # Get Encode object to speed up decode()/encode().
 143         my $encoding_object = Encode::find_encoding($encoding);
 144         die "unsupported encoding '$encoding'" unless ref $encoding_object;
 145
 146         my $curses = Curses->new or die $!;
 147
 148         my $self = {
 149             encoding        => $encoding,
 150             encoding_object => $encoding_object,
 151             curses          => $curses,
 152             debug           => 0,
 153             prompt          => {
 154                 flags => undef,
 155                 name  => undef,
 156                 value => undef,
 157             },
 158         };
 159         bless $self, $class;
 160
 161         Curses::start_color;
 162         # Allow default colors by passing -1 to init_pair. A default color is
 163         # not drawn on screen thus allowing terminals with pseudo-transparency
 164         # to use the transparent background in place of the default color.
 165         Curses::use_default_colors;
 166
 167         Curses::cbreak;
 168         Curses::noecho;
 169         $self->cursor(0);
 170
 171         return $self;
 172     }
 173     sub deinit {
 174         my ($self) = @_;
 175
 176         Curses::nocbreak;
 177         Curses::echo;
 178         $self->cursor(1);
 179
 180         Curses::endwin;
 181         return;
 182     }
 183
 184     # Convert between Perl's internal encoding and the terminal's encoding.
 185     sub encode {
 186         my ($self, $string) = @_;
 187         return $self->{encoding_object}->encode($string);
 188     }
 189     sub decode {
 190         my ($self, $string) = @_;
 191         return eval { # returns undef on decode failure
 192             $self->{encoding_object}->decode($string, Encode::FB_CROAK);
 193         };
 194     }
 195
 196     # Create attribute for the given fore-/background colors.
 197     sub color_pair {
 198         my ($self, $fg, $bg) = @_;
 199
 200         state $next_color_pair = 1; # must start at 1 for init_pair()
 201
 202         Curses::init_pair($next_color_pair, $fg, $bg);
 203         return Curses::COLOR_PAIR($next_color_pair++);
 204     }
 205
 206     # Draw a string which must fit in the current line. Wrapping/clipping is
 207     # not supported and must be handled by the caller.
 208     sub draw_simple {
 209         my ($self, $y, $x, $attributes, $string) = @_;
 210
 211         die if $string =~ /\n/;
 212         # FIXME: wide characters
 213         die if $x + length $string > $self->width;
 214
 215         $self->{curses}->attron($attributes) if defined $attributes;
 216         $self->{curses}->addstr($y, $x, $self->encode($string));
 217         $self->{curses}->attroff($attributes) if defined $attributes;
 218         return;
 219     }
 220     # Like draw_simple(), but the string is automatically clipped.
 221     sub draw_clipped {
 222         my ($self, $y, $x, $attributes, $string) = @_;
 223
 224         # FIXME: wide characters
 225         $string = substr $string, 0, $self->width - $x;
 226         $self->draw_simple($y, $x, $attributes, $string);
 227         return;
 228     }
 229     sub draw {
 230         my ($self, $y, $x, $attributes, $string) = @_;
 231
 232         die unless defined $string;
 233
 234         while (1) {
 235             my $offset;
 236             # We must print each line separately. Search for next newline or
 237             # line end, whichever is closer.
 238             if ($string =~ /\n/) {
 239                 $offset = $-[0];
 240             }
 241             # FIXME: wide characters
 242             if ($x + length $string > $self->width) {
 243                 my $new_offset = $self->width - $x;
 244                 if (not defined $offset or $offset > $new_offset) {
 245                     $offset = $new_offset;
 246                 }
 247             }
 248             last unless defined $offset;
 249
 250             # FIXME: wide characters
 251             $self->draw_simple($y, $x, $attributes, substr $string, 0, $offset);
 252
 253             # Don't draw "\n" itself.
 254             if ("\n" eq substr $string, $offset, 1) {
 255                 $offset++;
 256             }
 257
 258             $string = substr $string, $offset;
 259
 260             $y++;
 261             $x = 0;
 262         }
 263
 264         $self->draw_simple($y, $x, $attributes, $string);
 265         return $y;
 266     }
 267
 268     sub draw_prompt {
 269         my ($self, $config) = @_;
 270
 271         $self->debug('draw_prompt', 'started');
 272
 273         my $x = 0;
 274         my $y = $self->height - 1;
 275
 276         # Clear line for better visibility.
 277         $self->draw_simple($y, $x, undef, ' ' x $self->width);
 278
 279         # Draw prompt flags.
 280         if (defined (my $s = $self->{prompt}{flags})) {
 281             $s = "[$s]";
 282             $self->debug('draw_prompt', $s);
 283             $self->draw_clipped($y, $x, $config->{attribute}{prompt_flags}, $s);
 284             $x += length($s) + 1; # space between next element
 285         }
 286         # Draw prompt name.
 287         if (defined (my $s = $self->{prompt}{name})) {
 288             $s = "[$s]";
 289             $self->debug('draw_prompt', $s);
 290             $self->draw_clipped($y, $x, $config->{attribute}{prompt_name}, $s);
 291             $x += length($s) + 1;
 292         }
 293         # Draw prompt value, e.g. a search field.
 294         if (defined (my $s = $self->{prompt}{value})) {
 295             $self->debug('draw_prompt', $s);
 296             $self->draw_clipped($y, $x, undef, $s);
 297             $x += length($s) + 1;
 298         }
 299         return;
 300     }
 301
 302     sub draw_matches {
 303         my ($self, $config, $matches_remove, $matches_add) = @_;
 304
 305         foreach (@{$matches_remove}) {
 306             $self->draw($_->{y}, $_->{x}, Curses::A_NORMAL, $_->{string});
 307         }
 308
 309         my $attr_id     = $config->{attribute}{match_id};
 310         my $attr_string = $config->{attribute}{match_string};
 311         my $attr_last   = $config->{attribute}{match_last};
 312
 313         foreach (@{$matches_add}) {
 314             my $attr = (defined $_->{id} and $_->{id} == 1)
 315                      ? $attr_last
 316                      : $attr_string;
 317             $self->draw($_->{y}, $_->{x}, $attr, $_->{string});
 318             if (defined $_->{id}) {
 319                 $self->draw($_->{y}, $_->{x}, $attr_id, $_->{id});
 320             }
 321         }
 322         return;
 323     }
 324
 325     sub die {
 326         my ($self, @args) = @_;
 327
 328         my $attr = $self->color_pair(Curses::COLOR_RED, -1) | Curses::A_BOLD;
 329
 330         # Clear the screen to improve visibility of the error message.
 331         $self->{curses}->clear;
 332
 333         my $y = $self->draw(0, 0, $attr, "@args");
 334
 335         if ($self->{debug}) {
 336             my $msg;
 337             eval {
 338                 require Devel::StackTrace;
 339             };
 340             if ($@) {
 341                 $msg = "Devel::StackTrace missing, no stack trace.\n";
 342             } else {
 343                 my $trace = Devel::StackTrace->new;
 344                 $msg = "Stack trace:\n" . $trace->as_string;
 345             }
 346             $y = $self->draw($y + 1, 0, Curses::A_NORMAL, $msg);
 347         }
 348
 349         $self->draw($y + 1, 0, Curses::A_NORMAL,
 350                     'Press any key to terminate fcscs.');
 351         $self->refresh;
 352
 353         $self->getch;
 354         $self->deinit;
 355         exit 1;
 356     }
 357     sub debug {
 358         my ($self, $module, @args) = @_;
 359
 360         return if not $self->{debug};
 361
 362         state $fh; # only open the file once per run
 363         if (not defined $fh) {
 364             # Ignore errors if the directory doesn't exist.
 365             if (not open $fh, '>', "$ENV{HOME}/.config/fcscs/log") {
 366                 $fh = undef; # a failed open still writes a value to $fh
 367                 return;
 368             }
 369         }
 370
 371         foreach (@args) {
 372             $_ = $self->encode($_);
 373         }
 374         say $fh "$module: @args" or CORE::die $!;
 375         return;
 376     }
 377
 378
 379     sub prompt {
 380         my ($self, %settings) = @_;
 381
 382         foreach (keys %settings) {
 383             CORE::die if not exists $self->{prompt}{$_};
 384             $self->{prompt}{$_} = $settings{$_};
 385         }
 386         return;
 387     }
 388
 389     # Wrapper for Curses.
 390     sub width   { return $Curses::COLS; }
 391     sub height  { return $Curses::LINES; }
 392     sub refresh { return $_[0]->{curses}->refresh; }
 393     sub getch   { return $_[0]->{curses}->getch; }
 394     sub cursor  { Curses::curs_set($_[1]); return; }
 395 }
 396
 397
 398
 399 # FUNCTIONS
 400
 401 sub prepare_input {
 402     my ($screen, $input_ref) = @_;
 403
 404     # Make sure the input fits on the screen by removing the top lines if
 405     # necessary.
 406     splice @{$input_ref}, 0, -$screen->height;
 407
 408     # Pad each line with spaces to the screen width to correctly handle
 409     # multi-line regexes.
 410     # FIXME: wide characters
 411     my @padded = map { sprintf '%-*s', $screen->width, $_ } @{$input_ref};
 412
 413     my $string = join "\n", @padded;
 414     return {
 415         string => $string,
 416         lines  => $input_ref,
 417         width  => $screen->width + 1,
 418                   # + 1 = "\n", used in input_match_offset_to_coordinates
 419     };
 420 }
 421
 422 sub input_match_offset_to_coordinates {
 423     my ($width, $offset) = @_;
 424
 425     die unless defined $offset;
 426
 427     my $y = int($offset / $width);
 428     my $x = $offset - $y * $width;
 429     return ($x, $y);
 430 }
 431
 432 sub get_regex_matches {
 433     my ($input, $regex) = @_;
 434
 435     my @matches;
 436     while ($input->{string} =~ /$regex/g) {
 437         my $offset = $-[1];
 438         die "Match group required in regex '$regex'" if not defined $offset;
 439
 440         my ($x, $y) = input_match_offset_to_coordinates($input->{width},
 441                                                         $offset);
 442         push @matches, { x => $x, y => $y, offset => $offset, string => $1 };
 443     }
 444     return @matches;
 445 }
 446
 447
 448 sub run_command {
 449     my ($screen, $cmd) = @_;
 450
 451     $screen->debug('run_command', "running @{$cmd}");
 452
 453     my $exit = do {
 454         # Perl's system() combined with a $SIG{__WARN__} which die()s has
 455         # issues due to the fork. The die() in the __WARN__ handler doesn't
 456         # die but the program continues after the system().
 457         #
 458         # If the forked process fails to exec (e.g. program not found) then
 459         # the __WARN__ handler is called (because a warning is about to be
 460         # displayed) and the die() should display a message and terminate the
 461         # process. But due to the fork it doesn't terminate the parent process
 462         # and instead changes the return value of system(); it's no longer -1
 463         # which makes it impossible to detect that case.
 464         #
 465         # Perl < 5.18 (found in 5.14) doesn't setup $$ during system() which
 466         # makes it impossible to detect if the handler was called from inside
 467         # the child.
 468         #
 469         # Instead, just ignore any warnings during the system(). Thanks to
 470         # mauke in #perl on Freenode (2013-10-29 23:30 CET) for the idea to
 471         # use no warnings and anno for testing a more recent Perl version with
 472         # a working $$.
 473         no warnings;
 474
 475         my @cmd = map { $screen->encode($_) } @{$cmd};
 476         system { $cmd[0] } @cmd;
 477     };
 478     if ($exit != 0) {
 479         my $msg;
 480         if ($? == -1) {
 481             $msg = 'failed to execute: ' . $!;
 482         } elsif ($? & 127) {
 483             $msg = 'killed by signal ' . ($? & 127);
 484         } else {
 485             $msg = 'exited with code ' . ($? >> 8);
 486         }
 487         die "system(@{$cmd}) $msg.";
 488     }
 489     return;
 490 }
 491 sub run_in_background {
 492     my ($screen, $sub) = @_;
 493
 494     $screen->debug('run_in_background', "running $sub");
 495
 496     my $pid = fork;
 497     defined $pid or die $!;
 498
 499     if ($pid == 0) {
 500         # The terminal multiplexer sends a SIGHUP to the process when it
 501         # closes the window (because the parent process has exited).
 502         local $SIG{HUP} = 'IGNORE';
 503
 504         # Necessary for GNU screen or it'll keep the window open until an
 505         # external command has run.
 506         require File::Spec;
 507         my $devnull = File::Spec->devnull();
 508         open STDIN,  '<', $devnull or die $!;
 509         open STDOUT, '>', $devnull or die $!;
 510         open STDERR, '>', $devnull or die $!;
 511
 512         # Double-fork to prevent zombies.
 513         my $pid = fork;
 514         defined $pid or die $!;
 515         if ($pid == 0) { # child
 516             $sub->();
 517         }
 518         exit;
 519     }
 520     waitpid $pid, 0 or die $!;
 521     return;
 522 }
 523
 524
 525 sub select_match {
 526     my ($name, $screen, $config, $input, $matches) = @_;
 527
 528     $screen->debug('select_match', 'started');
 529
 530     return if @{$matches} == 0;
 531     # Don't return on initial run to give the user a chance to select another
 532     # mode, e.g. to switch from URL selection to search selection.
 533     if (@{$matches} == 1 and not $config->{state}{initial}) {
 534         return { match => $matches->[0] };
 535     }
 536     $config->{state}{initial} = 0;
 537
 538     my @sorted = sort { $b->{y} <=> $a->{y} or $b->{x} <=> $a->{x} } @{$matches};
 539
 540     my $i = 1;
 541     foreach (@sorted) {
 542         $_->{id} = $i++;
 543     }
 544
 545     $screen->prompt(name => $name, value => undef);
 546     $screen->draw_prompt($config);
 547
 548     $screen->draw_matches($config, [], $matches);
 549     $screen->refresh;
 550
 551     my $number = 0;
 552     while (1) {
 553         my $char = $screen->getch;
 554         if ($char =~ /^\d$/) {
 555             $number = $number * 10 + $char;
 556         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
 557             $number = int($number / 10);
 558         } elsif ($char eq "\n"
 559                 or $char eq $config->{setting}{alternative_return}) {
 560             if ($number == 0) { # number without selection matches last entry
 561                 $number = 1;
 562             }
 563             last;
 564
 565         # Selecting a new mode requires falling through into the main input
 566         # loop and then starting the new mode.
 567         } elsif (defined $config->{mapping}{mode}{$char}) {
 568             $screen->draw_matches($config, $matches, []); # clear matches
 569             return { key => $char };
 570         # All other mappings stay in the current mode.
 571         } elsif (defined (my $m = $config->{mapping}{simple}{$char})) {
 572             $m->($char, $screen, $config, $input);
 573             next;
 574
 575         } else {
 576             next; # ignore unknown mappings
 577         }
 578
 579         last if $number > 0 and $number * 10 > @{$matches}; # unique match
 580
 581         my @remaining = $number == 0
 582                       ? @{$matches}
 583                       : grep { $_->{id} =~ /^$number/ } @{$matches};
 584         $screen->draw_matches($config, $matches, \@remaining);
 585         $screen->refresh;
 586     }
 587
 588     $screen->draw_matches($config, $matches, []); # remove matches
 589
 590     foreach (@{$matches}) {
 591         return { match => $_ } if $_->{id} == $number;
 592     }
 593     $screen->debug('select_match', 'no match selected');
 594     return { match => undef };
 595 }
 596
 597 sub extend_match_regex_left {
 598     my ($line, $match, $regex) = @_;
 599
 600     my $s = reverse substr $line, 0, $match->{x};
 601     if ($s =~ /^($regex)/) {
 602         $match->{string}  = reverse($1) . $match->{string};
 603         $match->{x}      -= length $1;
 604         $match->{offset} -= length $1;
 605     }
 606     return;
 607 }
 608 sub extend_match_regex_right {
 609     my ($line, $match, $regex) = @_;
 610
 611     my $s = substr $line, $match->{x} + length $match->{string};
 612     if ($s =~ /^($regex)/) {
 613         $match->{string} .= $1;
 614     }
 615     return;
 616 }
 617 sub extend_match {
 618     my ($screen, $config, $input, $match) = @_;
 619
 620     $screen->debug('extend_match', 'started');
 621
 622     return if not defined $match;
 623
 624     $screen->prompt(name => 'extend', value => undef);
 625     $screen->draw_prompt($config);
 626
 627     delete $match->{id}; # don't draw any match ids
 628     $screen->draw_matches($config, [], [$match]);
 629     $screen->refresh;
 630
 631     my $line = $input->{lines}[$match->{y}];
 632
 633     while (1) {
 634         my $match_old = \%{$match};
 635
 636         my $char = $screen->getch;
 637         if ($char eq "\n"
 638                 or $char eq $config->{setting}{alternative_return}) {
 639             last; # accept match
 640
 641         } elsif ($char eq 'w') { # select current word (both directions)
 642             extend_match_regex_left($line,  $match, qr/\w+/);
 643             extend_match_regex_right($line, $match, qr/\w+/);
 644         } elsif ($char eq 'b') { # select current word (only left)
 645             extend_match_regex_left($line,  $match, qr/\w+/);
 646         } elsif ($char eq 'e') { # select current word (only right)
 647             extend_match_regex_right($line, $match, qr/\w+/);
 648
 649         } elsif ($char eq 'W') { # select current WORD (both directions)
 650             extend_match_regex_left($line,  $match, qr/\S+/);
 651             extend_match_regex_right($line, $match, qr/\S+/);
 652         } elsif ($char eq 'B') { # select current WORD (only left)
 653             extend_match_regex_left($line,  $match, qr/\S+/);
 654         } elsif ($char eq 'E') { # select current WORD (only right)
 655             extend_match_regex_right($line, $match, qr/\S+/);
 656
 657         } elsif ($char eq '0') { # select to beginning of line
 658             extend_match_regex_left($line, $match, qr/.+/);
 659         } elsif ($char eq '$') { # select to end of line
 660             extend_match_regex_right($line, $match, qr/.+/);
 661
 662         # Allow mode changes if not overwritten by local mappings.
 663         } elsif (defined $config->{mapping}{mode}{$char}) {
 664             $screen->draw_matches($config, [$match_old], []); # clear match
 665             return { key => $char };
 666
 667         } else {
 668             next; # ignore unknown mappings
 669         }
 670
 671         $screen->draw_matches($config, [$match_old], [$match]);
 672         $screen->refresh;
 673     }
 674
 675     $screen->debug('extend_match', 'done');
 676
 677     return { match => $match };
 678 }
 679
 680
 681 sub mapping_paste {
 682     my ($key, $screen, $config, $input) = @_;
 683
 684     $screen->debug('mapping_paste', 'started');
 685
 686     $config->{state}{handler} = $config->{handler}{paste};
 687
 688     $screen->prompt(flags => 'P'); # paste
 689     $screen->draw_prompt($config);
 690     $screen->refresh;
 691
 692     return {};
 693 }
 694 sub mapping_yank {
 695     my ($key, $screen, $config, $input) = @_;
 696
 697     $screen->debug('mapping_yank', 'started');
 698
 699     $config->{state}{handler} = $config->{handler}{yank};
 700
 701     $screen->prompt(flags => 'Y'); # yank
 702     $screen->draw_prompt($config);
 703     $screen->refresh;
 704
 705     return {};
 706 }
 707
 708
 709 =head2 NORMAL MODES
 710
 711 Normal modes select matches by calling a function which returns them, e.g. by
 712 using a regex.
 713
 714 The following normal modes are available:
 715
 716 =over 4
 717
 718 =item B<path mode> select relative/absolute paths
 719
 720 =item B<url mode>  select URLs
 721
 722 =item B<ip mode>   select IPv4 and IPv6 addresses
 723
 724 =back
 725
 726 =cut
 727 sub mapping_mode_path {
 728     my ($key, $screen, $config, $input) = @_;
 729
 730     $screen->debug('mapping_mode_path', 'started');
 731
 732     my @matches = get_regex_matches($input, $config->{regex}{path});
 733     return {
 734         select  => 'path select',
 735         matches => \@matches,
 736         handler => $config->{handler}{yank},
 737     };
 738 }
 739 sub mapping_mode_url {
 740     my ($key, $screen, $config, $input) = @_;
 741
 742     $screen->debug('mapping_mode_url', 'started');
 743
 744     my @matches = get_regex_matches($input, $config->{regex}{url});
 745     return {
 746         select  => 'url select',
 747         matches => \@matches,
 748         handler => $config->{handler}{url},
 749     };
 750 }
 751 sub mapping_mode_ip {
 752     my ($key, $screen, $config, $input) = @_;
 753
 754     $screen->debug('mapping_mode_ip', 'started');
 755
 756     my @ipv4 = get_regex_matches($input, $config->{regex}{ipv4});
 757     my @ipv6 = get_regex_matches($input, $config->{regex}{ipv6});
 758     return {
 759         select  => 'ip select',
 760         matches => [@ipv4, @ipv6],
 761         handler => $config->{handler}{ip},
 762     };
 763 }
 764
 765 =head2 SEARCH MODE (AND EXTEND MODE)
 766
 767 Search mode is a special mode which lets you type a search string (a Perl
 768 regex) and then select one of the matches. Afterwards you can extend the
 769 match. For example select the complete word or to the end of the line. This
 770 allows quick selection of arbitrary text.
 771
 772 The following mappings are available during the extension mode (not
 773 configurable at the moment):
 774
 775 =over 4
 776
 777 =item B<w> select current word
 778
 779 =item B<b> extend word to the left
 780
 781 =item B<e> extend word to the right
 782
 783 =item B<W> select current WORD
 784
 785 =item B<B> extend WORD to the left
 786
 787 =item B<E> extend WORD to the right
 788
 789 =item B<0> extend to beginning of line
 790
 791 =item B<$> extend to end of line
 792
 793 =back
 794
 795 C<word> includes any characters matching C<\w+>, C<WORD> any non-whitespace
 796 characters (C<\S+>), just like in Vim.
 797
 798 =cut
 799 sub mapping_mode_search {
 800     my ($key, $screen, $config, $input) = @_;
 801
 802     $screen->debug('mapping_mode_search', 'started');
 803
 804     $screen->cursor(1);
 805
 806     my $search = ''; # encoded
 807     my @last_matches;
 808     while (1) {
 809         # getch doesn't return decoded characters but raw input bytes. Wait
 810         # until the input character is complete.
 811         my $value = $screen->decode($search);
 812         $value = '' unless defined $value; # undef on decode failure
 813
 814         $screen->prompt(name => 'search', value => $value);
 815         $screen->draw_prompt($config);
 816         $screen->refresh;
 817
 818         my $char = $screen->getch;
 819         # TODO: readline editing support
 820         if ($char eq "\n") {
 821             last;
 822         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
 823             # Remove a character, not a byte.
 824             $search = $screen->decode($search);
 825             chop $search;
 826             $search = $screen->encode($search);
 827         } else {
 828             $search .= $char;
 829             next unless defined $screen->decode($search);
 830         }
 831
 832         my @matches;
 833         if ($search ne '') {
 834             my $case = '';
 835             if (($config->{setting}{smartcase} and $search eq lc $search)
 836                     or $config->{setting}{ignorecase}) {
 837                 $case = '(?i)';
 838             }
 839             # Ignore invalid regexps.
 840             # TODO: display warning on error?
 841             eval {
 842                 @matches = get_regex_matches($input, qr/($case$search)/);
 843             };
 844         }
 845         $screen->draw_matches($config, \@last_matches, \@matches);
 846         @last_matches = @matches;
 847     }
 848
 849     $screen->cursor(0);
 850
 851     $screen->prompt(name => undef, value => undef); # clear prompt
 852     $screen->draw_prompt($config);
 853
 854     $screen->debug('mapping_mode_search', 'done');
 855
 856     return {
 857         select  => 'search',
 858         matches => \@last_matches,
 859         extend  => 1,
 860         handler => $config->{handler}{yank},
 861     };
 862 }
 863
 864 sub mapping_quit {
 865     my ($key, $screen, $config, $input) = @_;
 866
 867     # Key is necessary to fall through to main event loop which then quits.
 868     return { key => $key, quit => 1 };
 869 }
 870
 871
 872 sub handler_yank {
 873     my ($screen, $config, $match) = @_;
 874
 875     $screen->debug('handler_yank', 'started');
 876
 877     require File::Temp;
 878
 879     # Use a temporary file to prevent leaking the yanked data to other users
 880     # with the command line, e.g. ps aux or top.
 881     my ($fh, $tmp) = File::Temp::tempfile(); # dies on its own
 882     print $fh $screen->encode($match->{value}) or die $!;
 883     close $fh or die $!;
 884
 885     if ($config->{setting}{multiplexer} eq 'screen') {
 886         $screen->debug('handler_yank', 'using screen');
 887
 888         # GNU screen displays an annoying "Slurping X characters into buffer".
 889         # Use 'msgwait 0' as a hack to disable it.
 890         my $msgwait = $config->{setting}{screen_msgwait};
 891         run_command($screen, ['screen', '-X', 'msgwait', 0]);
 892         run_command($screen, ['screen', '-X', 'readbuf', $tmp]);
 893         run_command($screen, ['screen', '-X', 'msgwait', $msgwait]);
 894     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
 895         $screen->debug('handler_yank', 'using tmux');
 896
 897         run_command($screen, ['tmux', 'load-buffer', $tmp]);
 898     } else {
 899         die 'unsupported multiplexer';
 900     }
 901
 902     unlink $tmp or die $!;
 903
 904     if ($config->{setting}{yank_x11}) {
 905         $screen->debug('handler_yank', 'setting X11 selection');
 906
 907         my @xsel_cmd  = qw( xsel --input --primary );
 908         my @xclip_cmd = qw( xclip -in -selection primary );
 909
 910         my $fh;
 911         {
 912             # We don't care if a program doesn't exist.
 913             no warnings;
 914
 915             if (not open $fh, '|-', @xsel_cmd) {
 916                 if (not open $fh, '|-', @xclip_cmd) {
 917                     die "install xsel or xlip to yank to X11 selection\n";
 918                 }
 919             }
 920         }
 921         print $fh $match->{value} or die $!;
 922         close $fh or die $!;
 923     }
 924
 925     return;
 926 }
 927 sub handler_paste {
 928     my ($screen, $config, $match) = @_;
 929
 930     $screen->debug('handler_paste', 'started');
 931
 932     require Time::HiRes;
 933
 934     my @cmd;
 935     if ($config->{setting}{multiplexer} eq 'screen') {
 936         $screen->debug('handler_paste', 'using screen');
 937         @cmd = qw( screen -X paste . );
 938     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
 939         $screen->debug('handler_paste', 'using tmux');
 940         @cmd = qw( tmux paste-buffer );
 941     } else {
 942         die 'unsupported multiplexer';
 943     }
 944
 945     run_in_background($screen, sub {
 946         # We need to get the data in the paste buffer before we can paste
 947         # it.
 948         handler_yank($screen, $config, $match);
 949
 950         # Sleep until we switch back to the current window.
 951         Time::HiRes::usleep($config->{setting}{paste_sleep});
 952
 953         run_command($screen, \@cmd);
 954     });
 955     return;
 956 }
 957 sub handler_url {
 958     my ($screen, $config, $match) = @_;
 959
 960     $screen->debug('handler_url', "opening $match->{value}");
 961
 962     run_in_background($screen, sub {
 963         my @cmd = ( @{$config->{setting}{browser}}, $match->{value} );
 964         run_command($screen, \@cmd);
 965     });
 966     return;
 967 }
 968
 969
 970
 971 # CONFIGURATION DEFAULTS
 972
 973 =head1 CONFIGURATION
 974
 975 fcscs is configured through F<~/.fcscsrc> or F<~/.config/fcscs/fcscsrc> which
 976 is a normal Perl script with all of Perl's usual features.
 977
 978 All configuration values are stored in the hash C<%config>. All manually
 979 defined keys overwrite the default settings.
 980
 981 A simple F<~/.fcscsrc> could look like this (for details about the used
 982 settings see below):
 983
 984     use strict;
 985     use warnings;
 986
 987     use Curses; # for COLOR_* and A_* constants
 988
 989     our %config;
 990
 991     # Draw matches in blue.
 992     $config{attribute}{match_string} = color_pair(COLOR_BLUE, -1);
 993     # Draw numbers in bold yellow.
 994     $config{attribute}{match_id} = color_pair(COLOR_YELLOW, -1)
 995                                  | A_BOLD;
 996     # Disable Vim-like 'smartcase', ignore case until an upper character is
 997     # searched.
 998     $config{setting}{smartcase} = 0;
 999
1000     # Use chromium to open URLs if running under X, elinks otherwise.
1001     if (defined $ENV{DISPLAY}) {
1002         $config{setting}{browser} = ['chromium'];
1003     } else {
1004         $config{setting}{browser} = ['elinks', '-remote'];
1005     }
1006
1007     # Let fcscs know the file was loaded successfully.
1008     1;
1009
1010 =cut
1011
1012
1013 if (@ARGV != 1) {
1014     require Pod::Usage;
1015     Pod::Usage::pod2usage(2);
1016 }
1017
1018
1019 # Determine terminal encoding from the environment ($ENV{LANG} or similar).
1020 my $encoding = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET);
1021
1022 my $screen = Screen->init($encoding);
1023
1024 # We must restore the screen before exiting.
1025 local $SIG{INT} = sub {
1026     $screen->deinit;
1027     exit 128 + 2;
1028 };
1029 # Make all warnings fatal to make sure they don't get lost (stderr is normally
1030 # not displayed).
1031 local $SIG{__WARN__} = sub {
1032     $screen->die('warning', @_);
1033 };
1034
1035
1036
1037 =head2 MAPPINGS
1038
1039 I<NOTE>: Mappings are split in two categories: Mode mappings which change the
1040 selection and may receive additional input (e.g. a search string) and simple
1041 mappings which only change some config value. Mode mappings are configured via
1042 C<$config{mapping}{mode}>, simple mappings via C<$config{mapping}{simple}>.
1043
1044 The following mode mappings are available by default (the function to remap
1045 them in parentheses):
1046
1047 =over
1048
1049 =item B<f> select absolute/relative paths (C<\&mapping_mode_path>)
1050
1051 =item B<u> select URLs (C<\&mapping_mode_url>)
1052
1053 =item B<i> select IPv4 and IPv6 addresses (C<\&mapping_mode_ip>)
1054
1055 =item B</> search for regex to get selection (C<\&mapping_mode_search>)
1056
1057 =item B<q> quit fcscs (C<\&mapping_quit>)
1058
1059 =back
1060
1061 The following simple mappings are available by default:
1062
1063 =over
1064
1065 =item B<p> enable pasting (C<\&mapping_paste>)
1066
1067 =item B<y> enable yanking (copying) (C<\&mapping_yank>)
1068
1069 =back
1070
1071 Note that yanking only uses the GNU screen or Tmux paste buffer by default. To
1072 also copy to X11 selection, enable the B<yank_x11> option.
1073
1074 The following additional mappings are available by default:
1075
1076 =over
1077
1078 =item B<\n> accept current selection (not customizable)
1079
1080 =item B<s>  additional key to accept selection (B<alternative_return> option)
1081
1082 =back
1083
1084 All (single-byte) keys except numbers, backspace and return can be mapped.
1085
1086 Unknown mappings are ignored when pressing keys.
1087
1088 To remove a default mapping, delete it from the mapping hash.
1089
1090 Example:
1091
1092     # Map 'p' to select paths, 'P' to enable pasting.
1093     $config{mapping}{mode}{p} = \&mapping_mode_path;
1094     $config{mapping}{simple}{P} = \&mapping_paste;
1095
1096     # Disable 'f' mapping.
1097     delete $config{mapping}{mode}{f};
1098
1099 =cut
1100 my %mapping_mode = (
1101     f   => \&mapping_mode_path,
1102     u   => \&mapping_mode_url,
1103     i   => \&mapping_mode_ip,
1104     '/' => \&mapping_mode_search,
1105     q   => \&mapping_quit,
1106 );
1107 my %mapping_simple = (
1108     p => \&mapping_paste,
1109     y => \&mapping_yank,
1110 );
1111
1112 =head2 ATTRIBUTES
1113
1114 Attributes are used to style the output. They must be Curses attributes.
1115 Defaults in parentheses (foreground, background, attribute).
1116
1117 =over
1118
1119 =item B<match_id>      attribute for match numbers (red, default, bold)
1120
1121 =item B<match_string>  attribute for matches (yellow, default, normal)
1122
1123 =item B<match_last>    attribute for the match selected by return (yellow, default, underline)
1124
1125 =item B<prompt_name>   attribute for prompt name (standout)
1126
1127 =item B<prompt_flags>  attribute for prompt flags (standout)
1128
1129 =back
1130
1131 Example:
1132
1133     # Draw prompt flags in bold red with default background color.
1134     $config{attribute}{prompt_flags}
1135         = Curses::A_BOLD
1136         | color_pair(Curses::COLOR_RED, -1);
1137
1138 =cut
1139 my %attribute = (
1140     match_id     => $screen->color_pair(Curses::COLOR_RED, -1)
1141                     | Curses::A_BOLD,
1142     match_string => $screen->color_pair(Curses::COLOR_YELLOW, -1),
1143     match_last   => $screen->color_pair(Curses::COLOR_YELLOW, -1)
1144                     | Curses::A_UNDERLINE,
1145     prompt_name  => Curses::A_STANDOUT,
1146     prompt_flags => Curses::A_STANDOUT,
1147 );
1148
1149 =head2 SETTINGS
1150
1151 Defaults in parentheses.
1152
1153 =over
1154
1155 =item B<debug>              enable debug mode, writes to I<~/.config/fcscs/log> (C<0>)
1156
1157 =item B<initial_mode>       start in this mode, must be a valid mode mapping (C<\&mapping_mode_url>)
1158
1159 =item B<multiplexer>        set multiplexer ("screen" or "tmux") if not autodetected (C<undef>)
1160
1161 =item B<ignorecase>         ignore case when searching (C<0>)
1162
1163 =item B<smartcase>          ignore case unless one uppercase character is searched (C<1>)
1164
1165 =item B<yank_x11>           copy selection also to X11 primary selection when yanking (C<0>)
1166
1167 =item B<paste_sleep>        sleep x us before running paste command (C<100_000>)
1168
1169 =item B<screen_msgwait>     GNU Screen's msgwait variable, used when yanking (C<5>)
1170
1171 =item B<alternative_return> additional accept key like return, set to C<\n> to disable (C<s>)
1172
1173 =item B<browser>            browser command as array reference (C<['x-www-browser']>)
1174
1175 =back
1176
1177 Example:
1178
1179     # Select paths on startup instead of URLs.
1180     $config{setting}{initial_mode} = \&mapping_mode_path;
1181
1182 =cut
1183 my %setting = (
1184     # options
1185     debug              => 0,
1186     initial_mode       => \&mapping_mode_url,
1187     multiplexer        => undef,
1188     ignorecase         => 0,
1189     smartcase          => 1,
1190     yank_x11           => 0,
1191     paste_sleep        => 100_000,
1192     screen_msgwait     => 5,
1193     # global mappings
1194     alternative_return => 's',
1195     # commands
1196     browser            => ['x-www-browser'],
1197 );
1198
1199 =head2 REGEXPS
1200
1201 =over
1202
1203 =item B<url>  used by C<\&mapping_mode_url>
1204
1205 =item B<path> used by C<\&mapping_mode_path>
1206
1207 =item B<ipv4> used by C<\&mapping_mode_ip>
1208
1209 =item B<ipv6> used by C<\&mapping_mode_ip>
1210
1211 =back
1212
1213 Example:
1214
1215     # Select all non-whitespace characters when searching for paths.
1216     $config{regex}{path} = qr{(\S+)};
1217
1218 =cut
1219 my %regex = (
1220     # Taken from urlview's default configuration file, thanks.
1221     url  => qr{((?:(?:(?:http|https|ftp|gopher)|mailto):(?://)?[^ <>"\t]*|(?:www|ftp)[0-9]?\.[-a-z0-9.]+)[^ .,;\t\n\r<">\):]?[^, <>"\t]*[^ .,;\t\n\r<">\):])},
1222     path => qr{(~?[a-zA-Z0-9_./-]*/[a-zA-Z0-9_./-]+)},
1223     # IP addresses with optional prefix. Not perfectly accurate but good
1224     # enough.
1225     ipv4 => qr!\b(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}(?:/\d{1,2})?)\b!,
1226     ipv6 => qr!\b((?:[0-9a-fA-F]{1,4})?(?::+[0-9a-fA-F]{1,4})+(?:/\d{1,3})?)\b!,
1227 );
1228
1229 =head2 HANDLERS
1230
1231 Handlers are used to perform actions on the selected string.
1232
1233 The following handlers are available, defaults in parentheses.
1234
1235 =over
1236
1237 =item B<yank>  used to yank (copy) selection to paste buffer (C<\&handler_yank>)
1238
1239 =item B<paste> used to paste selection into window (C<\&handler_paste>)
1240
1241 =item B<url>   used to open URLs (e.g. in a browser) (C<\&handler_url>)
1242
1243 =item B<ip>    used to handle IPs (C<\&handler_yank>)
1244
1245 =back
1246
1247 Example:
1248
1249     # Download YouTube videos with a custom wrapper, handle all other URLs
1250     # with the default URL handler.
1251     $config{handler}{url} = sub {
1252         my ($screen, $config, $match) = @_;
1253
1254         if ($match->{value} =~ m{^https://www.youtube.com/}) {
1255             return run_in_background($screen, sub {
1256                 run_command($screen, ['youtube-dl-wrapper', $match->{value}]);
1257             });
1258         }
1259         handler_url(@_);
1260     };
1261
1262 =cut
1263 my %handler = (
1264     yank  => \&handler_yank,
1265     paste => \&handler_paste,
1266     url   => \&handler_url,
1267     ip    => \&handler_yank,
1268 );
1269
1270 my %state = (
1271     initial => 1, # used by select_match() for 'initial_mode'
1272     handler => undef,
1273 );
1274
1275
1276
1277 # CONFIGURATION "API"
1278
1279 =head2 FUNCTIONS
1280
1281 The following functions are available:
1282
1283     color_pair($fg, $bg)
1284
1285 Create a new Curses attribute with the given fore- and background color.
1286
1287     mapping_mode_path()
1288     mapping_mode_url()
1289     mapping_mode_ip()
1290     mapping_mode_search()
1291
1292     mapping_paste()
1293     mapping_yank()
1294     mapping_quit()
1295
1296 Used as mappings, see L</MAPPINGS> above.
1297
1298     handler_yank()
1299     handler_paste()
1300     handler_url()
1301
1302 Used as handler to yank, paste selection or open URL in browser.
1303
1304     get_regex_matches()
1305     select_match()
1306     run_command()
1307     run_in_background()
1308
1309 Helper functions when writing custom mappings, see the source for details.
1310
1311 Example:
1312
1313     # Enhance URL mode by updating the mapping.
1314     $config{mapping}{mode}{u} = sub {
1315         my ($key, $screen, $config, $input) = @_;
1316
1317         # First get matches of normal URL mode.
1318         my $result = mapping_mode_url(@_);
1319
1320         # Add all strings matching "CVE-1234-1234" with URLs pointing to the
1321         # Debian security tracker. "->{value}" is the string which is used as
1322         # result of the match (e.g. the URL in this case).
1323         my @matches = get_regex_matches($input, qr/\b(CVE-\d+-\d+)\b/);
1324         foreach (@matches) {
1325             $_->{value} = "https://security-tracker.debian.org/$_->{string}";
1326         }
1327         push @{$result->{matches}}, @matches;
1328
1329         # Change all YouTube links to use the custom "youtube" handler (see
1330         # below). This will allow us to automatically open YouTube URLs with a
1331         # custom program, like `youtube-dl` or `mpv`.
1332         foreach (@{$result->{matches}}) {
1333             if ($_->{string} =~ m{^https://www.youtube.com/}) {
1334                 $_->{handler} = $config{handler}{youtube};
1335             }
1336         }
1337
1338         return $result;
1339     }
1340     # Also update initial mode to use our new "URL mode".
1341     $config{setting}{initial_mode} = $config{mapping}{mode}{u};
1342
1343     # Special handler to download YouTube URLs with `youtube-dl`. You could
1344     # also use `mpv` here to immediately play them.
1345     $config{handler}{youtube} = sub {
1346         my ($screen, $config, $match) = @_;
1347
1348         return run_in_background($screen, sub {
1349             run_command($screen, ['youtube-dl', $match->{value}]);
1350         });
1351     };
1352
1353
1354
1355 =cut
1356
1357 # All variables and functions which are usable by ~/.fcscsrc.
1358 package Fcscs {
1359     our $screen; # "private"
1360     our %config;
1361
1362     sub color_pair { return $screen->color_pair(@_); }
1363
1364     sub mapping_mode_path { return main::mapping_mode_path(@_); }
1365     sub mapping_mode_url { return main::mapping_mode_url(@_); }
1366     sub mapping_mode_ip { return main::mapping_mode_ip(@_); }
1367     sub mapping_mode_search { return main::mapping_mode_search(@_); }
1368
1369     sub mapping_paste { return main::mapping_paste(@_); }
1370     sub mapping_yank { return main::mapping_yank(@_); }
1371     sub mapping_quit { return main::mapping_quit(@_); }
1372
1373     sub handler_yank { return main::handler_yank(@_); }
1374     sub handler_paste { return main::handler_paste(@_); }
1375     sub handler_url { return main::handler_url(@_); }
1376
1377     sub debug { return main::debug(@_); }
1378
1379     sub get_regex_matches { return main::get_regex_matches(@_); }
1380     sub select_match { return main::select_match(@_); }
1381
1382     sub run_command { return main::run_command(@_); }
1383     sub run_in_background { return main::run_in_background(@_); }
1384 }
1385 $Fcscs::screen = $screen;
1386
1387
1388
1389 # LOAD USER CONFIG
1390
1391 # Alias %config and %Fcscs::config. %config is less to type.
1392 our %config;
1393 local *config = \%Fcscs::config;
1394
1395 $config{mapping}{mode}   = \%mapping_mode;
1396 $config{mapping}{simple} = \%mapping_simple;
1397 $config{attribute}       = \%attribute;
1398 $config{setting}         = \%setting;
1399 $config{regex}           = \%regex;
1400 $config{handler}         = \%handler;
1401 $config{state}           = \%state;
1402
1403 package Fcscs {
1404     my @configs = ("$ENV{HOME}/.fcscsrc",
1405                    "$ENV{HOME}/.config/fcscs/fcscsrc");
1406     foreach my $path (@configs) {
1407         my $decoded = $screen->decode($path);
1408
1409         # Load configuration file. Checks have a race condition if the home
1410         # directory is writable by an attacker (but then the user is screwed
1411         # anyway).
1412         next unless -e $path;
1413         if (not -O $path) {
1414             $screen->die("Config '$decoded' not owned by current user!");
1415         }
1416         # Make sure the file is not writable by other users. Doesn't handle
1417         # ACLs and see comment above about race conditions.
1418         my @stat = stat $path or die $!;
1419         my $mode = $stat[2];
1420         if (($mode & Fcntl::S_IWGRP) or ($mode & Fcntl::S_IWOTH)) {
1421             die "Config '$decoded' must not be writable by other users.";
1422         }
1423
1424         my $result = do $path;
1425         if (not $result) {
1426             $screen->die("Failed to parse '$decoded': $@") if $@;
1427             $screen->die("Failed to do '$decoded': $!") unless defined $result;
1428             $screen->die("Failed to run '$decoded'.");
1429         }
1430
1431         last; # success, don't load more files
1432     }
1433 }
1434 $screen->{debug} = $config{setting}{debug};
1435
1436
1437 # MAIN
1438
1439 eval {
1440     # Auto-detect current multiplexer.
1441     if (not defined $config{setting}{multiplexer}) {
1442         if (defined $ENV{STY} and defined $ENV{TMUX}) {
1443             die 'Found both $STY and $TMUX, set $config{setting}{multiplexer}.';
1444         } elsif (defined $ENV{STY}) {
1445             $config{setting}{multiplexer} = 'screen';
1446         } elsif (defined $ENV{TMUX}) {
1447             $config{setting}{multiplexer} = 'tmux';
1448         } else {
1449             die 'No multiplexer found.';
1450         }
1451     }
1452
1453     my $binmode = $encoding;
1454     # GNU screen stores the screen dump for unknown reasons as ISO-8859-1
1455     # instead of the currently active encoding.
1456     if ($config{setting}{multiplexer} eq 'screen') {
1457         $binmode = 'ISO-8859-1';
1458     }
1459
1460     my @input_lines;
1461     open my $fh, '<', $ARGV[0] or die $!;
1462     binmode $fh, ":encoding($binmode)" or die $!;
1463     while (<$fh>) {
1464         chomp;
1465         push @input_lines, $_;
1466     }
1467     close $fh or die $!;
1468
1469     my $input = prepare_input($screen, \@input_lines);
1470
1471     # Display original screen content.
1472     my $y = 0;
1473     foreach (@{$input->{lines}}) {
1474         $screen->draw_simple($y++, 0, undef, $_);
1475     }
1476     $screen->refresh;
1477
1478
1479     my $mapping = $config{setting}{initial_mode};
1480
1481     my $key;
1482     while (1) {
1483         if (not defined $mapping) {
1484             $key = $screen->getch unless defined $key;
1485             $screen->debug('input', "got key '$key'");
1486
1487             $mapping = $config{mapping}{mode}{$key};
1488             $mapping = $config{mapping}{simple}{$key} unless defined $mapping;
1489             if (not defined $mapping) { # ignore unknown mappings
1490                 $key = undef;
1491                 next;
1492             }
1493         }
1494
1495         $screen->debug('input', 'running mapping');
1496         my $result = $mapping->($key, $screen, \%config, $input);
1497         $mapping = undef;
1498
1499 RESULT:
1500         if (defined $result->{quit}) {
1501             $screen->debug('input', 'quitting');
1502             last;
1503         }
1504         if (defined $result->{key}) {
1505             $key = $result->{key}; # lookup another mapping
1506             $screen->debug('input', "processing new key: '$key'");
1507             next;
1508         }
1509         if (defined $result->{select}) {
1510             $screen->debug('input', 'selecting match');
1511             my $tmp = $result;
1512             $result = select_match($result->{select},
1513                                    $screen, \%config, $input,
1514                                    $result->{matches});
1515             $result->{handler} = $tmp->{handler};
1516             $result->{extend}  = $tmp->{extend};
1517             goto RESULT; # reprocess special entries in result
1518         }
1519         if (defined $result->{extend}) {
1520             $screen->debug('input', 'extending match');
1521             $result = extend_match($screen, \%config, $input,
1522                                    $result->{match});
1523             goto RESULT; # reprocess special entries in result
1524         }
1525         if (defined $result->{match}) {
1526             if (not defined $result->{match}{value}) {
1527                 $result->{match}{value} = $result->{match}{string};
1528             }
1529
1530             $screen->debug('input', 'running handler');
1531
1532             # Choose handler with falling priority.
1533             my @handlers = (
1534                 $config{state}{handler},     # set by user
1535                 $result->{match}{handler},   # set by match
1536                 $result->{handler},          # set by mapping
1537                 $config{handler}{yank},      # fallback
1538             );
1539             foreach my $handler (@handlers) {
1540                 next unless defined $handler;
1541
1542                 $handler->($screen, \%config, $result->{match});
1543                 last;
1544             }
1545             last;
1546         }
1547
1548         $key = undef; # get next key from user
1549     }
1550 };
1551 if ($@) {
1552     $screen->die("$@");
1553 }
1554
1555 $screen->deinit;
1556
1557 __END__
1558
1559 =head1 EXIT STATUS
1560
1561 =over 4
1562
1563 =item B<0>
1564
1565 Success.
1566
1567 =item B<1>
1568
1569 An error occurred.
1570
1571 =item B<2>
1572
1573 Invalid arguments/options.
1574
1575 =back
1576
1577 =head1 AUTHOR
1578
1579 Simon Ruderich E<lt>simon@ruderich.orgE<gt>
1580
1581 =head1 LICENSE AND COPYRIGHT
1582
1583 Copyright (C) 2013-2016 by Simon Ruderich
1584
1585 This program is free software: you can redistribute it and/or modify
1586 it under the terms of the GNU General Public License as published by
1587 the Free Software Foundation, either version 3 of the License, or
1588 (at your option) any later version.
1589
1590 This program is distributed in the hope that it will be useful,
1591 but WITHOUT ANY WARRANTY; without even the implied warranty of
1592 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1593 GNU General Public License for more details.
1594
1595 You should have received a copy of the GNU General Public License
1596 along with this program.  If not, see E<lt>http://www.gnu.org/licenses/E<gt>.
1597
1598 =head1 SEE ALSO
1599
1600 L<screen(1)>, L<tmux(1)>, L<urlview(1)>
1601
1602 =cut