bin/fcscs

   1 #!/usr/bin/perl
   2
   3 # fcscs - fast curses screen content select
   4
   5 # Copyright (C) 2013-2016  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use v5.10; # say, state
  25
  26 use Encode ();
  27 use Fcntl ();
  28 use I18N::Langinfo ();
  29
  30 use Curses ();
  31
  32 our $VERSION = '0.01';
  33
  34
  35 =head1 NAME
  36
  37 fcscs - fast curses screen content select
  38
  39 =head1 SYNOPSIS
  40
  41 B<fcscs> [I<options>] I<path/to/screen/capture/file>
  42
  43 =head1 DESCRIPTION
  44
  45 B<fcscs> is a small tool which allows quick selection of terminal screen
  46 contents (like URLs, paths, regex matches, etc.) and passes the selection to
  47 GNU Screen's or Tmux's buffer or any other program. The selection can then
  48 quickly be pasted, e.g. in the shell. Requires GNU Screen or Tmux. It's
  49 licensed under the GPL 3 or later.
  50
  51 =head1 OPTIONS
  52
  53 None so far.
  54
  55 =head1 USAGE
  56
  57 Short overview of the general usage, details below:
  58
  59     - start fcscs
  60     - configure actions (optional)
  61         - enable pasting
  62         - ...
  63     - select mode (optional, URL mode is used on startup):
  64         - f: file paths
  65         - i: IPs
  66         - u: URLs
  67         - ...
  68         - /: search mode
  69     - for `normal' modes:
  70         - select match by displayed number or <return> for lowest numbered
  71           match
  72         - configured action is run, e.g. URL is opened with browser
  73     - for `search' mode:
  74         - perform incremental search
  75         - on <return> go to `normal' mode to select a match
  76         - after the match is selected wait for confirmation or extension
  77         - confirmation: <return> run previously selected action
  78         - extension: change match, e.g. select complete word or line
  79
  80 GNU Screen setup (add to F<~/.screenrc>):
  81
  82     bind ^B eval "hardcopy $HOME/.tmp/screen-fcscs" "screen fcscs $HOME/.tmp/screen-fcscs"
  83
  84 Tmux setup (add to F<~/.tmux.conf>):
  85
  86     bind-key C-b capture-pane \; save-buffer ~/.tmp/tmux-fcscs \; delete-buffer \; new-window "fcscs ~/.tmp/tmux-fcscs"
  87
  88 This requires a writable ~/.tmp directory. Adapt the mapping according to your
  89 preferences. Ensure these files are not readable by others as they can contain
  90 private data (umask or protected directory). B<fcscs> must be in your C<$PATH>
  91 for the above mappings to work.
  92
  93 Pressing the configured mapping (Prefix Ctrl-B in this example) opens B<fcscs>
  94 in a new GNU screen/Tmux window. After selection, the content is either passed
  95 to external programs (e.g. for URLs) or copied to the paste buffer or directly
  96 pasted in your previous window and the new window is closed.
  97
  98 To select a match just type its number. If the match is unique, the entry is
  99 automatically selected (e.g. you press 2 and there are only 19 matches). If
 100 there are multiple matches left (e.g. you press 1 and there are more than ten
 101 matches available), press return to select the current match (1 in this case)
 102 or another number to select the longer match. Use backspace to remove the last
 103 entered number.
 104
 105 Press return before entering a number to select the last (lowest numbered)
 106 match (underlined by default). To abort without selecting any match use "q".
 107
 108 To change the selection mode (e.g. paths, files, etc.) use one of the mappings
 109 explained below. Per default URLs are selected, see options for a way to
 110 change this.
 111
 112 I<NOTE>: Opening URLs in the browser passes the URL via the command line which
 113 leaks URLs to other users on the current system via C<ps aux> or C<top>.
 114
 115 I<NOTE>: When yanking (copying) a temporary file is used to pass the data to
 116 GNU screen/Tmux without exposing it to C<ps aux> or C<top>. However this may
 117 leak data if those temporary files are written to disk. To prevent this change
 118 your C<$TMP> to point to a memory-only location or encrypted storage.
 119
 120 If no window appears, try running B<fcscs> manually to catch the error message
 121 and please report the bug:
 122
 123     fcscs /path/to/screen-or-tmux-fcscs-file
 124
 125
 126 =head1 MODES
 127
 128 =cut
 129
 130
 131 # CLASSES
 132
 133 # Helper class for drawing on the screen using Curses.
 134 package Screen {
 135     sub init {
 136         my ($class, $encoding) = @_;
 137
 138         # Prefer strict UTF-8 handling (see perldoc Encode); just in case.
 139         if (lc $encoding eq 'utf8') {
 140             $encoding = 'UTF-8';
 141         }
 142         # Get Encode object to speed up decode()/encode().
 143         my $encoding_object = Encode::find_encoding($encoding);
 144         die "unsupported encoding '$encoding'" unless ref $encoding_object;
 145
 146         my $curses = Curses->new or die $!;
 147
 148         my $self = {
 149             encoding        => $encoding,
 150             encoding_object => $encoding_object,
 151             curses          => $curses,
 152             debug           => 0,
 153             prompt          => {
 154                 flags => undef,
 155                 name  => undef,
 156                 value => undef,
 157             },
 158         };
 159         bless $self, $class;
 160
 161         Curses::start_color;
 162         # Allow default colors by passing -1 to init_pair. A default color is
 163         # not drawn on screen thus allowing terminals with pseudo-transparency
 164         # to use the transparent background in place of the default color.
 165         Curses::use_default_colors;
 166
 167         Curses::cbreak;
 168         Curses::noecho;
 169         $self->cursor(0);
 170
 171         return $self;
 172     }
 173     sub deinit {
 174         my ($self) = @_;
 175
 176         Curses::nocbreak;
 177         Curses::echo;
 178         $self->cursor(1);
 179
 180         Curses::endwin;
 181         return;
 182     }
 183
 184     # Convert between Perl's internal encoding and the terminal's encoding.
 185     sub encode {
 186         my ($self, $string) = @_;
 187         return $self->{encoding_object}->encode($string);
 188     }
 189     sub decode {
 190         my ($self, $string) = @_;
 191         return eval { # returns undef on decode failure
 192             $self->{encoding_object}->decode($string, Encode::FB_CROAK);
 193         };
 194     }
 195
 196     # Create attribute for the given fore-/background colors.
 197     sub color_pair {
 198         my ($self, $fg, $bg) = @_;
 199
 200         state $next_color_pair = 1; # must start at 1 for init_pair()
 201
 202         Curses::init_pair($next_color_pair, $fg, $bg);
 203         return Curses::COLOR_PAIR($next_color_pair++);
 204     }
 205
 206     # Draw a string which must fit in the current line. Wrapping/clipping is
 207     # not supported and must be handled by the caller.
 208     sub draw_simple {
 209         my ($self, $y, $x, $attributes, $string) = @_;
 210
 211         die if $string =~ /\n/;
 212         # FIXME: wide characters
 213         die if $x + length $string > $self->width;
 214
 215         $self->{curses}->attron($attributes) if defined $attributes;
 216         $self->{curses}->addstr($y, $x, $self->encode($string));
 217         $self->{curses}->attroff($attributes) if defined $attributes;
 218         return;
 219     }
 220     # Like draw_simple(), but the string is automatically clipped.
 221     sub draw_clipped {
 222         my ($self, $y, $x, $attributes, $string) = @_;
 223
 224         # FIXME: wide characters
 225         $string = substr $string, 0, $self->width - $x;
 226         $self->draw_simple($y, $x, $attributes, $string);
 227         return;
 228     }
 229     sub draw {
 230         my ($self, $y, $x, $attributes, $string) = @_;
 231
 232         die unless defined $string;
 233
 234         while (1) {
 235             my $offset;
 236             # We must print each line separately. Search for next newline or
 237             # line end, whichever is closer.
 238             if ($string =~ /\n/) {
 239                 $offset = $-[0];
 240             }
 241             # FIXME: wide characters
 242             if ($x + length $string > $self->width) {
 243                 my $new_offset = $self->width - $x;
 244                 if (not defined $offset or $offset > $new_offset) {
 245                     $offset = $new_offset;
 246                 }
 247             }
 248             last unless defined $offset;
 249
 250             # FIXME: wide characters
 251             $self->draw_simple($y, $x, $attributes, substr $string, 0, $offset);
 252
 253             # Don't draw "\n" itself.
 254             if ("\n" eq substr $string, $offset, 1) {
 255                 $offset++;
 256             }
 257
 258             $string = substr $string, $offset;
 259
 260             $y++;
 261             $x = 0;
 262         }
 263
 264         $self->draw_simple($y, $x, $attributes, $string);
 265         return $y;
 266     }
 267
 268     sub draw_prompt {
 269         my ($self, $config) = @_;
 270
 271         $self->debug('draw_prompt', 'started');
 272
 273         my $x = 0;
 274         my $y = $self->height - 1;
 275
 276         # Clear line for better visibility.
 277         $self->draw_simple($y, $x, undef, ' ' x $self->width);
 278
 279         # Draw prompt flags.
 280         if (defined (my $s = $self->{prompt}{flags})) {
 281             $s = "[$s]";
 282             $self->debug('draw_prompt', $s);
 283             $self->draw_clipped($y, $x, $config->{attribute}{prompt_flags}, $s);
 284             $x += length($s) + 1; # space between next element
 285         }
 286         # Draw prompt name.
 287         if (defined (my $s = $self->{prompt}{name})) {
 288             $s = "[$s]";
 289             $self->debug('draw_prompt', $s);
 290             $self->draw_clipped($y, $x, $config->{attribute}{prompt_name}, $s);
 291             $x += length($s) + 1;
 292         }
 293         # Draw prompt value, e.g. a search field.
 294         if (defined (my $s = $self->{prompt}{value})) {
 295             $self->debug('draw_prompt', $s);
 296             $self->draw_clipped($y, $x, undef, $s);
 297             $x += length($s) + 1;
 298         }
 299         return;
 300     }
 301
 302     sub draw_matches {
 303         my ($self, $config, $matches_remove, $matches_add) = @_;
 304
 305         foreach (@{$matches_remove}) {
 306             $self->draw($_->{y}, $_->{x}, Curses::A_NORMAL, $_->{string});
 307         }
 308
 309         my $attr_id     = $config->{attribute}{match_id};
 310         my $attr_string = $config->{attribute}{match_string};
 311         my $attr_last   = $config->{attribute}{match_last};
 312
 313         foreach (@{$matches_add}) {
 314             my $attr = (defined $_->{id} and $_->{id} == 1)
 315                      ? $attr_last
 316                      : $attr_string;
 317             $self->draw($_->{y}, $_->{x}, $attr, $_->{string});
 318             if (defined $_->{id}) {
 319                 $self->draw($_->{y}, $_->{x}, $attr_id, $_->{id});
 320             }
 321         }
 322         return;
 323     }
 324
 325     sub die {
 326         my ($self, @args) = @_;
 327
 328         my $attr = $self->color_pair(Curses::COLOR_RED, -1) | Curses::A_BOLD;
 329
 330         # Clear the screen to improve visibility of the error message.
 331         $self->{curses}->clear;
 332
 333         my $y = $self->draw(0, 0, $attr, "@args");
 334
 335         if ($self->{debug}) {
 336             my $msg;
 337             eval {
 338                 require Devel::StackTrace;
 339             };
 340             if ($@) {
 341                 $msg = "Devel::StackTrace missing, no stack trace.\n";
 342             } else {
 343                 my $trace = Devel::StackTrace->new;
 344                 $msg = "Stack trace:\n" . $trace->as_string;
 345             }
 346             $y = $self->draw($y + 1, 0, Curses::A_NORMAL, $msg);
 347         }
 348
 349         $self->draw($y + 1, 0, Curses::A_NORMAL,
 350                     'Press any key to terminate fcscs.');
 351         $self->refresh;
 352
 353         $self->getch;
 354         $self->deinit;
 355         exit 1;
 356     }
 357     sub debug {
 358         my ($self, $module, @args) = @_;
 359
 360         return if not $self->{debug};
 361
 362         state $fh; # only open the file once per run
 363         if (not defined $fh) {
 364             # Ignore errors if the directory doesn't exist.
 365             if (not open $fh, '>', "$ENV{HOME}/.config/fcscs/log") {
 366                 $fh = undef; # a failed open still writes a value to $fh
 367                 return;
 368             }
 369             $fh->autoflush(1);
 370         }
 371
 372         foreach (@args) {
 373             $_ = $self->encode($_);
 374         }
 375         say $fh "$module: @args" or CORE::die $!;
 376         return;
 377     }
 378
 379
 380     sub prompt {
 381         my ($self, %settings) = @_;
 382
 383         foreach (keys %settings) {
 384             CORE::die if not exists $self->{prompt}{$_};
 385             $self->{prompt}{$_} = $settings{$_};
 386         }
 387         return;
 388     }
 389
 390     # Wrapper for Curses.
 391     sub width   { return $Curses::COLS; }
 392     sub height  { return $Curses::LINES; }
 393     sub refresh { return $_[0]->{curses}->refresh; }
 394     sub getch   { return $_[0]->{curses}->getch; }
 395     sub cursor  { Curses::curs_set($_[1]); return; }
 396 }
 397
 398
 399
 400 # FUNCTIONS
 401
 402 sub prepare_input {
 403     my ($screen, $input_ref) = @_;
 404
 405     # Make sure the input fits on the screen by removing the top lines if
 406     # necessary.
 407     splice @{$input_ref}, 0, -$screen->height;
 408
 409     # Pad each line with spaces to the screen width to correctly handle
 410     # multi-line regexes.
 411     # FIXME: wide characters
 412     my @padded = map { sprintf '%-*s', $screen->width, $_ } @{$input_ref};
 413
 414     my $string = join "\n", @padded;
 415     return {
 416         string => $string,
 417         lines  => $input_ref,
 418         width  => $screen->width + 1,
 419                   # + 1 = "\n", used in input_match_offset_to_coordinates
 420     };
 421 }
 422
 423 sub input_match_offset_to_coordinates {
 424     my ($width, $offset) = @_;
 425
 426     die unless defined $offset;
 427
 428     my $y = int($offset / $width);
 429     my $x = $offset - $y * $width;
 430     return ($x, $y);
 431 }
 432
 433 sub get_regex_matches {
 434     my ($input, $regex) = @_;
 435
 436     my @matches;
 437     while ($input->{string} =~ /$regex/g) {
 438         my $offset = $-[1];
 439         die "Match group required in regex '$regex'" if not defined $offset;
 440
 441         my ($x, $y) = input_match_offset_to_coordinates($input->{width},
 442                                                         $offset);
 443         push @matches, { x => $x, y => $y, offset => $offset, string => $1 };
 444     }
 445     return @matches;
 446 }
 447
 448
 449 sub run_command {
 450     my ($screen, $cmd) = @_;
 451
 452     $screen->debug('run_command', "running @{$cmd}");
 453
 454     my $exit = do {
 455         # Perl's system() combined with a $SIG{__WARN__} which die()s has
 456         # issues due to the fork. The die() in the __WARN__ handler doesn't
 457         # die but the program continues after the system().
 458         #
 459         # If the forked process fails to exec (e.g. program not found) then
 460         # the __WARN__ handler is called (because a warning is about to be
 461         # displayed) and the die() should display a message and terminate the
 462         # process. But due to the fork it doesn't terminate the parent process
 463         # and instead changes the return value of system(); it's no longer -1
 464         # which makes it impossible to detect that case.
 465         #
 466         # Perl < 5.18 (found in 5.14) doesn't setup $$ during system() which
 467         # makes it impossible to detect if the handler was called from inside
 468         # the child.
 469         #
 470         # Instead, just ignore any warnings during the system(). Thanks to
 471         # mauke in #perl on Freenode (2013-10-29 23:30 CET) for the idea to
 472         # use no warnings and anno for testing a more recent Perl version with
 473         # a working $$.
 474         no warnings;
 475
 476         my @cmd = map { $screen->encode($_) } @{$cmd};
 477         system { $cmd[0] } @cmd;
 478     };
 479     if ($exit != 0) {
 480         my $msg;
 481         if ($? == -1) {
 482             $msg = 'failed to execute: ' . $!;
 483         } elsif ($? & 127) {
 484             $msg = 'killed by signal ' . ($? & 127);
 485         } else {
 486             $msg = 'exited with code ' . ($? >> 8);
 487         }
 488         die "system(@{$cmd}) $msg.";
 489     }
 490     return;
 491 }
 492 sub run_in_background {
 493     my ($screen, $sub) = @_;
 494
 495     $screen->debug('run_in_background', "running $sub");
 496
 497     my $pid = fork;
 498     defined $pid or die $!;
 499
 500     if ($pid == 0) {
 501         # The terminal multiplexer sends a SIGHUP to the process when it
 502         # closes the window (because the parent process has exited).
 503         local $SIG{HUP} = 'IGNORE';
 504
 505         # Necessary for GNU screen or it'll keep the window open until an
 506         # external command has run.
 507         require File::Spec;
 508         my $devnull = File::Spec->devnull();
 509         open STDIN,  '<', $devnull or die $!;
 510         open STDOUT, '>', $devnull or die $!;
 511         open STDERR, '>', $devnull or die $!;
 512
 513         # Double-fork to prevent zombies.
 514         my $pid = fork;
 515         defined $pid or die $!;
 516         if ($pid == 0) { # child
 517             $sub->();
 518         }
 519         exit;
 520     }
 521     waitpid $pid, 0 or die $!;
 522     return;
 523 }
 524
 525
 526 sub select_match {
 527     my ($name, $screen, $config, $input, $matches) = @_;
 528
 529     $screen->debug('select_match', 'started');
 530
 531     return if @{$matches} == 0;
 532     # Don't return on initial run to give the user a chance to select another
 533     # mode, e.g. to switch from URL selection to search selection.
 534     if (@{$matches} == 1 and not $config->{state}{initial}) {
 535         return { match => $matches->[0] };
 536     }
 537     $config->{state}{initial} = 0;
 538
 539     my @sorted = sort { $b->{y} <=> $a->{y} or $b->{x} <=> $a->{x} } @{$matches};
 540
 541     my $i = 1;
 542     foreach (@sorted) {
 543         $_->{id} = $i++;
 544     }
 545
 546     $screen->prompt(name => $name, value => undef);
 547     $screen->draw_prompt($config);
 548
 549     $screen->draw_matches($config, [], $matches);
 550     $screen->refresh;
 551
 552     my $number = 0;
 553     while (1) {
 554         my $char = $screen->getch;
 555         if ($char =~ /^\d$/) {
 556             $number = $number * 10 + $char;
 557         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
 558             $number = int($number / 10);
 559         } elsif ($char eq "\n"
 560                 or $char eq $config->{setting}{alternative_return}) {
 561             if ($number == 0) { # number without selection matches last entry
 562                 $number = 1;
 563             }
 564             last;
 565
 566         # Selecting a new mode requires falling through into the main input
 567         # loop and then starting the new mode.
 568         } elsif (defined $config->{mapping}{mode}{$char}) {
 569             $screen->draw_matches($config, $matches, []); # clear matches
 570             return { key => $char };
 571         # All other mappings stay in the current mode.
 572         } elsif (defined (my $m = $config->{mapping}{simple}{$char})) {
 573             $m->($char, $screen, $config, $input);
 574             next;
 575
 576         } else {
 577             next; # ignore unknown mappings
 578         }
 579
 580         last if $number > 0 and $number * 10 > @{$matches}; # unique match
 581
 582         my @remaining = $number == 0
 583                       ? @{$matches}
 584                       : grep { $_->{id} =~ /^$number/ } @{$matches};
 585         $screen->draw_matches($config, $matches, \@remaining);
 586         $screen->refresh;
 587     }
 588
 589     $screen->draw_matches($config, $matches, []); # remove matches
 590
 591     foreach (@{$matches}) {
 592         return { match => $_ } if $_->{id} == $number;
 593     }
 594     $screen->debug('select_match', 'no match selected');
 595     return { match => undef };
 596 }
 597
 598 sub extend_match_regex_left {
 599     my ($line, $match, $regex) = @_;
 600
 601     my $s = reverse substr $line, 0, $match->{x};
 602     if ($s =~ /^($regex)/) {
 603         $match->{string}  = reverse($1) . $match->{string};
 604         $match->{x}      -= length $1;
 605         $match->{offset} -= length $1;
 606     }
 607     return;
 608 }
 609 sub extend_match_regex_right {
 610     my ($line, $match, $regex) = @_;
 611
 612     my $s = substr $line, $match->{x} + length $match->{string};
 613     if ($s =~ /^($regex)/) {
 614         $match->{string} .= $1;
 615     }
 616     return;
 617 }
 618 sub extend_match {
 619     my ($screen, $config, $input, $match) = @_;
 620
 621     $screen->debug('extend_match', 'started');
 622
 623     return if not defined $match;
 624
 625     $screen->prompt(name => 'extend', value => undef);
 626     $screen->draw_prompt($config);
 627
 628     delete $match->{id}; # don't draw any match ids
 629     $screen->draw_matches($config, [], [$match]);
 630     $screen->refresh;
 631
 632     my $line = $input->{lines}[$match->{y}];
 633
 634     while (1) {
 635         my $match_old = \%{$match};
 636
 637         my $char = $screen->getch;
 638         if ($char eq "\n"
 639                 or $char eq $config->{setting}{alternative_return}) {
 640             last; # accept match
 641
 642         } elsif ($char eq 'w') { # select current word (both directions)
 643             extend_match_regex_left($line,  $match, qr/\w+/);
 644             extend_match_regex_right($line, $match, qr/\w+/);
 645         } elsif ($char eq 'b') { # select current word (only left)
 646             extend_match_regex_left($line,  $match, qr/\w+/);
 647         } elsif ($char eq 'e') { # select current word (only right)
 648             extend_match_regex_right($line, $match, qr/\w+/);
 649
 650         } elsif ($char eq 'W') { # select current WORD (both directions)
 651             extend_match_regex_left($line,  $match, qr/\S+/);
 652             extend_match_regex_right($line, $match, qr/\S+/);
 653         } elsif ($char eq 'B') { # select current WORD (only left)
 654             extend_match_regex_left($line,  $match, qr/\S+/);
 655         } elsif ($char eq 'E') { # select current WORD (only right)
 656             extend_match_regex_right($line, $match, qr/\S+/);
 657
 658         } elsif ($char eq '0') { # select to beginning of line
 659             extend_match_regex_left($line, $match, qr/.+/);
 660         } elsif ($char eq '$') { # select to end of line
 661             extend_match_regex_right($line, $match, qr/.+/);
 662
 663         # Allow mode changes if not overwritten by local mappings.
 664         } elsif (defined $config->{mapping}{mode}{$char}) {
 665             $screen->draw_matches($config, [$match_old], []); # clear match
 666             return { key => $char };
 667
 668         } else {
 669             next; # ignore unknown mappings
 670         }
 671
 672         $screen->draw_matches($config, [$match_old], [$match]);
 673         $screen->refresh;
 674     }
 675
 676     $screen->debug('extend_match', 'done');
 677
 678     return { match => $match };
 679 }
 680
 681
 682 sub mapping_paste {
 683     my ($key, $screen, $config, $input) = @_;
 684
 685     $screen->debug('mapping_paste', 'started');
 686
 687     $config->{state}{handler} = $config->{handler}{paste};
 688
 689     $screen->prompt(flags => 'P'); # paste
 690     $screen->draw_prompt($config);
 691     $screen->refresh;
 692
 693     return {};
 694 }
 695 sub mapping_yank {
 696     my ($key, $screen, $config, $input) = @_;
 697
 698     $screen->debug('mapping_yank', 'started');
 699
 700     $config->{state}{handler} = $config->{handler}{yank};
 701
 702     $screen->prompt(flags => 'Y'); # yank
 703     $screen->draw_prompt($config);
 704     $screen->refresh;
 705
 706     return {};
 707 }
 708
 709
 710 =head2 NORMAL MODES
 711
 712 Normal modes select matches by calling a function which returns them, e.g. by
 713 using a regex.
 714
 715 The following normal modes are available:
 716
 717 =over 4
 718
 719 =item B<path mode> select relative/absolute paths
 720
 721 =item B<url mode>  select URLs
 722
 723 =item B<ip mode>   select IPv4 and IPv6 addresses
 724
 725 =back
 726
 727 =cut
 728 sub mapping_mode_path {
 729     my ($key, $screen, $config, $input) = @_;
 730
 731     $screen->debug('mapping_mode_path', 'started');
 732
 733     my @matches = get_regex_matches($input, $config->{regex}{path});
 734     return {
 735         select  => 'path select',
 736         matches => \@matches,
 737         handler => $config->{handler}{yank},
 738     };
 739 }
 740 sub mapping_mode_url {
 741     my ($key, $screen, $config, $input) = @_;
 742
 743     $screen->debug('mapping_mode_url', 'started');
 744
 745     my @matches = get_regex_matches($input, $config->{regex}{url});
 746     return {
 747         select  => 'url select',
 748         matches => \@matches,
 749         handler => $config->{handler}{url},
 750     };
 751 }
 752 sub mapping_mode_ip {
 753     my ($key, $screen, $config, $input) = @_;
 754
 755     $screen->debug('mapping_mode_ip', 'started');
 756
 757     my @ipv4 = get_regex_matches($input, $config->{regex}{ipv4});
 758     my @ipv6 = get_regex_matches($input, $config->{regex}{ipv6});
 759     return {
 760         select  => 'ip select',
 761         matches => [@ipv4, @ipv6],
 762         handler => $config->{handler}{ip},
 763     };
 764 }
 765
 766 =head2 SEARCH MODE (AND EXTEND MODE)
 767
 768 Search mode is a special mode which lets you type a search string (a Perl
 769 regex) and then select one of the matches. Afterwards you can extend the
 770 match. For example select the complete word or to the end of the line. This
 771 allows quick selection of arbitrary text.
 772
 773 The following mappings are available during the extension mode (not
 774 configurable at the moment):
 775
 776 =over 4
 777
 778 =item B<w> select current word
 779
 780 =item B<b> extend word to the left
 781
 782 =item B<e> extend word to the right
 783
 784 =item B<W> select current WORD
 785
 786 =item B<B> extend WORD to the left
 787
 788 =item B<E> extend WORD to the right
 789
 790 =item B<0> extend to beginning of line
 791
 792 =item B<$> extend to end of line
 793
 794 =back
 795
 796 C<word> includes any characters matching C<\w+>, C<WORD> any non-whitespace
 797 characters (C<\S+>), just like in Vim.
 798
 799 =cut
 800 sub mapping_mode_search {
 801     my ($key, $screen, $config, $input) = @_;
 802
 803     $screen->debug('mapping_mode_search', 'started');
 804
 805     $screen->cursor(1);
 806
 807     my $search = ''; # encoded
 808     my @last_matches;
 809     while (1) {
 810         # getch doesn't return decoded characters but raw input bytes. Wait
 811         # until the input character is complete.
 812         my $value = $screen->decode($search);
 813         $value = '' unless defined $value; # undef on decode failure
 814
 815         $screen->prompt(name => 'search', value => $value);
 816         $screen->draw_prompt($config);
 817         $screen->refresh;
 818
 819         my $char = $screen->getch;
 820         # TODO: readline editing support
 821         if ($char eq "\n") {
 822             last;
 823         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
 824             # Remove a character, not a byte.
 825             $search = $screen->decode($search);
 826             chop $search;
 827             $search = $screen->encode($search);
 828         } else {
 829             $search .= $char;
 830             next unless defined $screen->decode($search);
 831         }
 832
 833         my @matches;
 834         if ($search ne '') {
 835             my $case = '';
 836             if (($config->{setting}{smartcase} and $search eq lc $search)
 837                     or $config->{setting}{ignorecase}) {
 838                 $case = '(?i)';
 839             }
 840             # Ignore invalid regexps.
 841             # TODO: display warning on error?
 842             eval {
 843                 @matches = get_regex_matches($input, qr/($case$search)/);
 844             };
 845         }
 846         $screen->draw_matches($config, \@last_matches, \@matches);
 847         @last_matches = @matches;
 848     }
 849
 850     $screen->cursor(0);
 851
 852     $screen->prompt(name => undef, value => undef); # clear prompt
 853     $screen->draw_prompt($config);
 854
 855     $screen->debug('mapping_mode_search', 'done');
 856
 857     return {
 858         select  => 'search',
 859         matches => \@last_matches,
 860         extend  => 1,
 861         handler => $config->{handler}{yank},
 862     };
 863 }
 864
 865 sub mapping_quit {
 866     my ($key, $screen, $config, $input) = @_;
 867
 868     # Key is necessary to fall through to main event loop which then quits.
 869     return { key => $key, quit => 1 };
 870 }
 871
 872
 873 sub handler_yank {
 874     my ($screen, $config, $match) = @_;
 875
 876     $screen->debug('handler_yank', 'started');
 877
 878     require File::Temp;
 879
 880     # Use a temporary file to prevent leaking the yanked data to other users
 881     # with the command line, e.g. ps aux or top.
 882     my ($fh, $tmp) = File::Temp::tempfile(); # dies on its own
 883     print $fh $screen->encode($match->{value}) or die $!;
 884     close $fh or die $!;
 885
 886     if ($config->{setting}{multiplexer} eq 'screen') {
 887         $screen->debug('handler_yank', 'using screen');
 888
 889         # GNU screen displays an annoying "Slurping X characters into buffer".
 890         # Use 'msgwait 0' as a hack to disable it.
 891         my $msgwait = $config->{setting}{screen_msgwait};
 892         run_command($screen, ['screen', '-X', 'msgwait', 0]);
 893         run_command($screen, ['screen', '-X', 'readbuf', $tmp]);
 894         run_command($screen, ['screen', '-X', 'msgwait', $msgwait]);
 895     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
 896         $screen->debug('handler_yank', 'using tmux');
 897
 898         run_command($screen, ['tmux', 'load-buffer', $tmp]);
 899     } else {
 900         die 'unsupported multiplexer';
 901     }
 902
 903     unlink $tmp or die $!;
 904
 905     if ($config->{setting}{yank_x11}) {
 906         $screen->debug('handler_yank', 'setting X11 selection');
 907
 908         my @xsel_cmd  = qw( xsel --input --primary );
 909         my @xclip_cmd = qw( xclip -in -selection primary );
 910
 911         my $fh;
 912         {
 913             # We don't care if a program doesn't exist.
 914             no warnings;
 915
 916             if (not open $fh, '|-', @xsel_cmd) {
 917                 if (not open $fh, '|-', @xclip_cmd) {
 918                     die "install xsel or xlip to yank to X11 selection\n";
 919                 }
 920             }
 921         }
 922         print $fh $match->{value} or die $!;
 923         close $fh or die $!;
 924     }
 925
 926     return;
 927 }
 928 sub handler_paste {
 929     my ($screen, $config, $match) = @_;
 930
 931     $screen->debug('handler_paste', 'started');
 932
 933     require Time::HiRes;
 934
 935     my @cmd;
 936     if ($config->{setting}{multiplexer} eq 'screen') {
 937         $screen->debug('handler_paste', 'using screen');
 938         @cmd = qw( screen -X paste . );
 939     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
 940         $screen->debug('handler_paste', 'using tmux');
 941         @cmd = qw( tmux paste-buffer );
 942     } else {
 943         die 'unsupported multiplexer';
 944     }
 945
 946     run_in_background($screen, sub {
 947         # We need to get the data in the paste buffer before we can paste
 948         # it.
 949         handler_yank($screen, $config, $match);
 950
 951         # Sleep until we switch back to the current window.
 952         Time::HiRes::usleep($config->{setting}{paste_sleep});
 953
 954         run_command($screen, \@cmd);
 955     });
 956     return;
 957 }
 958 sub handler_url {
 959     my ($screen, $config, $match) = @_;
 960
 961     $screen->debug('handler_url', "opening $match->{value}");
 962
 963     run_in_background($screen, sub {
 964         my @cmd = ( @{$config->{setting}{browser}}, $match->{value} );
 965         run_command($screen, \@cmd);
 966     });
 967     return;
 968 }
 969
 970
 971
 972 # CONFIGURATION DEFAULTS
 973
 974 =head1 CONFIGURATION
 975
 976 fcscs is configured through F<~/.fcscsrc> or F<~/.config/fcscs/fcscsrc> which
 977 is a normal Perl script with all of Perl's usual features.
 978
 979 All configuration values are stored in the hash C<%config>. All manually
 980 defined keys overwrite the default settings.
 981
 982 A simple F<~/.fcscsrc> could look like this (for details about the used
 983 settings see below):
 984
 985     use strict;
 986     use warnings;
 987
 988     use Curses; # for COLOR_* and A_* constants
 989
 990     our %config;
 991
 992     # Draw matches in blue.
 993     $config{attribute}{match_string} = color_pair(COLOR_BLUE, -1);
 994     # Draw numbers in bold yellow.
 995     $config{attribute}{match_id} = color_pair(COLOR_YELLOW, -1)
 996                                  | A_BOLD;
 997     # Disable Vim-like 'smartcase', ignore case until an upper character is
 998     # searched.
 999     $config{setting}{smartcase} = 0;
1000
1001     # Use chromium to open URLs if running under X, elinks otherwise.
1002     if (defined $ENV{DISPLAY}) {
1003         $config{setting}{browser} = ['chromium'];
1004     } else {
1005         $config{setting}{browser} = ['elinks', '-remote'];
1006     }
1007
1008     # Let fcscs know the file was loaded successfully.
1009     1;
1010
1011 =cut
1012
1013
1014 if (@ARGV != 1) {
1015     require Pod::Usage;
1016     Pod::Usage::pod2usage(2);
1017 }
1018
1019
1020 # Determine terminal encoding from the environment ($ENV{LANG} or similar).
1021 my $encoding = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET);
1022
1023 my $screen = Screen->init($encoding);
1024
1025 # We must restore the screen before exiting.
1026 local $SIG{INT} = sub {
1027     $screen->deinit;
1028     exit 128 + 2;
1029 };
1030 # Make all warnings fatal to make sure they don't get lost (stderr is normally
1031 # not displayed).
1032 local $SIG{__WARN__} = sub {
1033     $screen->die('warning', @_);
1034 };
1035
1036
1037
1038 =head2 MAPPINGS
1039
1040 I<NOTE>: Mappings are split in two categories: Mode mappings which change the
1041 selection and may receive additional input (e.g. a search string) and simple
1042 mappings which only change some config value. Mode mappings are configured via
1043 C<$config{mapping}{mode}>, simple mappings via C<$config{mapping}{simple}>.
1044
1045 The following mode mappings are available by default (the function to remap
1046 them in parentheses):
1047
1048 =over
1049
1050 =item B<f> select absolute/relative paths (C<\&mapping_mode_path>)
1051
1052 =item B<u> select URLs (C<\&mapping_mode_url>)
1053
1054 =item B<i> select IPv4 and IPv6 addresses (C<\&mapping_mode_ip>)
1055
1056 =item B</> search for regex to get selection (C<\&mapping_mode_search>)
1057
1058 =item B<q> quit fcscs (C<\&mapping_quit>)
1059
1060 =back
1061
1062 The following simple mappings are available by default:
1063
1064 =over
1065
1066 =item B<p> enable pasting (C<\&mapping_paste>)
1067
1068 =item B<y> enable yanking (copying) (C<\&mapping_yank>)
1069
1070 =back
1071
1072 Note that yanking only uses the GNU screen or Tmux paste buffer by default. To
1073 also copy to X11 selection, enable the B<yank_x11> option.
1074
1075 The following additional mappings are available by default:
1076
1077 =over
1078
1079 =item B<\n> accept current selection (not customizable)
1080
1081 =item B<s>  additional key to accept selection (B<alternative_return> option)
1082
1083 =back
1084
1085 All (single-byte) keys except numbers, backspace and return can be mapped.
1086
1087 Unknown mappings are ignored when pressing keys.
1088
1089 To remove a default mapping, delete it from the mapping hash.
1090
1091 Example:
1092
1093     # Map 'p' to select paths, 'P' to enable pasting.
1094     $config{mapping}{mode}{p} = \&mapping_mode_path;
1095     $config{mapping}{simple}{P} = \&mapping_paste;
1096
1097     # Disable 'f' mapping.
1098     delete $config{mapping}{mode}{f};
1099
1100 =cut
1101 my %mapping_mode = (
1102     f   => \&mapping_mode_path,
1103     u   => \&mapping_mode_url,
1104     i   => \&mapping_mode_ip,
1105     '/' => \&mapping_mode_search,
1106     q   => \&mapping_quit,
1107 );
1108 my %mapping_simple = (
1109     p => \&mapping_paste,
1110     y => \&mapping_yank,
1111 );
1112
1113 =head2 ATTRIBUTES
1114
1115 Attributes are used to style the output. They must be Curses attributes.
1116 Defaults in parentheses (foreground, background, attribute).
1117
1118 =over
1119
1120 =item B<match_id>      attribute for match numbers (red, default, bold)
1121
1122 =item B<match_string>  attribute for matches (yellow, default, normal)
1123
1124 =item B<match_last>    attribute for the match selected by return (yellow, default, underline)
1125
1126 =item B<prompt_name>   attribute for prompt name (standout)
1127
1128 =item B<prompt_flags>  attribute for prompt flags (standout)
1129
1130 =back
1131
1132 Example:
1133
1134     # Draw prompt flags in bold red with default background color.
1135     $config{attribute}{prompt_flags}
1136         = Curses::A_BOLD
1137         | color_pair(Curses::COLOR_RED, -1);
1138
1139 =cut
1140 my %attribute = (
1141     match_id     => $screen->color_pair(Curses::COLOR_RED, -1)
1142                     | Curses::A_BOLD,
1143     match_string => $screen->color_pair(Curses::COLOR_YELLOW, -1),
1144     match_last   => $screen->color_pair(Curses::COLOR_YELLOW, -1)
1145                     | Curses::A_UNDERLINE,
1146     prompt_name  => Curses::A_STANDOUT,
1147     prompt_flags => Curses::A_STANDOUT,
1148 );
1149
1150 =head2 SETTINGS
1151
1152 Defaults in parentheses.
1153
1154 =over
1155
1156 =item B<debug>              enable debug mode, writes to I<~/.config/fcscs/log> (C<0>)
1157
1158 =item B<initial_mode>       start in this mode, must be a valid mode mapping (C<\&mapping_mode_url>)
1159
1160 =item B<multiplexer>        set multiplexer ("screen" or "tmux") if not autodetected (C<undef>)
1161
1162 =item B<ignorecase>         ignore case when searching (C<0>)
1163
1164 =item B<smartcase>          ignore case unless one uppercase character is searched (C<1>)
1165
1166 =item B<yank_x11>           copy selection also to X11 primary selection when yanking (C<0>)
1167
1168 =item B<paste_sleep>        sleep x us before running paste command (C<100_000>)
1169
1170 =item B<screen_msgwait>     GNU Screen's msgwait variable, used when yanking (C<5>)
1171
1172 =item B<alternative_return> additional accept key like return, set to C<\n> to disable (C<s>)
1173
1174 =item B<browser>            browser command as array reference (C<['x-www-browser']>)
1175
1176 =back
1177
1178 Example:
1179
1180     # Select paths on startup instead of URLs.
1181     $config{setting}{initial_mode} = \&mapping_mode_path;
1182
1183 =cut
1184 my %setting = (
1185     # options
1186     debug              => 0,
1187     initial_mode       => \&mapping_mode_url,
1188     multiplexer        => undef,
1189     ignorecase         => 0,
1190     smartcase          => 1,
1191     yank_x11           => 0,
1192     paste_sleep        => 100_000,
1193     screen_msgwait     => 5,
1194     # global mappings
1195     alternative_return => 's',
1196     # commands
1197     browser            => ['x-www-browser'],
1198 );
1199
1200 =head2 REGEXPS
1201
1202 =over
1203
1204 =item B<url>  used by C<\&mapping_mode_url>
1205
1206 =item B<path> used by C<\&mapping_mode_path>
1207
1208 =item B<ipv4> used by C<\&mapping_mode_ip>
1209
1210 =item B<ipv6> used by C<\&mapping_mode_ip>
1211
1212 =back
1213
1214 Example:
1215
1216     # Select all non-whitespace characters when searching for paths.
1217     $config{regex}{path} = qr{(\S+)};
1218
1219 =cut
1220 my %regex = (
1221     # Taken from urlview's default configuration file, thanks.
1222     url  => qr{((?:(?:(?:http|https|ftp|gopher)|mailto):(?://)?[^ <>"\t]*|(?:www|ftp)[0-9]?\.[-a-z0-9.]+)[^ .,;\t\n\r<">\):]?[^, <>"\t]*[^ .,;\t\n\r<">\):])},
1223     path => qr{(~?[a-zA-Z0-9_./-]*/[a-zA-Z0-9_./-]+)},
1224     # IP addresses with optional prefix. Not perfectly accurate but good
1225     # enough.
1226     ipv4 => qr!\b(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}(?:/\d{1,2})?)\b!,
1227     ipv6 => qr!\b((?:[0-9a-fA-F]{1,4})?(?::+[0-9a-fA-F]{1,4})+(?:/\d{1,3})?)\b!,
1228 );
1229
1230 =head2 HANDLERS
1231
1232 Handlers are used to perform actions on the selected string.
1233
1234 The following handlers are available, defaults in parentheses.
1235
1236 =over
1237
1238 =item B<yank>  used to yank (copy) selection to paste buffer (C<\&handler_yank>)
1239
1240 =item B<paste> used to paste selection into window (C<\&handler_paste>)
1241
1242 =item B<url>   used to open URLs (e.g. in a browser) (C<\&handler_url>)
1243
1244 =item B<ip>    used to handle IPs (C<\&handler_yank>)
1245
1246 =back
1247
1248 Example:
1249
1250     # Download YouTube videos with a custom wrapper, handle all other URLs
1251     # with the default URL handler.
1252     $config{handler}{url} = sub {
1253         my ($screen, $config, $match) = @_;
1254
1255         if ($match->{value} =~ m{^https://www.youtube.com/}) {
1256             return run_in_background($screen, sub {
1257                 run_command($screen, ['youtube-dl-wrapper', $match->{value}]);
1258             });
1259         }
1260         handler_url(@_);
1261     };
1262
1263 =cut
1264 my %handler = (
1265     yank  => \&handler_yank,
1266     paste => \&handler_paste,
1267     url   => \&handler_url,
1268     ip    => \&handler_yank,
1269 );
1270
1271 my %state = (
1272     initial => 1, # used by select_match() for 'initial_mode'
1273     handler => undef,
1274 );
1275
1276
1277
1278 # CONFIGURATION "API"
1279
1280 =head2 FUNCTIONS
1281
1282 The following functions are available:
1283
1284     color_pair($fg, $bg)
1285
1286 Create a new Curses attribute with the given fore- and background color.
1287
1288     mapping_mode_path()
1289     mapping_mode_url()
1290     mapping_mode_ip()
1291     mapping_mode_search()
1292
1293     mapping_paste()
1294     mapping_yank()
1295     mapping_quit()
1296
1297 Used as mappings, see L</MAPPINGS> above.
1298
1299     handler_yank()
1300     handler_paste()
1301     handler_url()
1302
1303 Used as handler to yank, paste selection or open URL in browser.
1304
1305     get_regex_matches()
1306     select_match()
1307     run_command()
1308     run_in_background()
1309
1310 Helper functions when writing custom mappings, see the source for details.
1311
1312 Example:
1313
1314     # Enhance URL mode by updating the mapping.
1315     $config{mapping}{mode}{u} = sub {
1316         my ($key, $screen, $config, $input) = @_;
1317
1318         # First get matches of normal URL mode.
1319         my $result = mapping_mode_url(@_);
1320
1321         # Add all strings matching "CVE-1234-1234" with URLs pointing to the
1322         # Debian security tracker. "->{value}" is the string which is used as
1323         # result of the match (e.g. the URL in this case).
1324         my @matches = get_regex_matches($input, qr/\b(CVE-\d+-\d+)\b/);
1325         foreach (@matches) {
1326             $_->{value} = "https://security-tracker.debian.org/$_->{string}";
1327         }
1328         push @{$result->{matches}}, @matches;
1329
1330         # Change all YouTube links to use the custom "youtube" handler (see
1331         # below). This will allow us to automatically open YouTube URLs with a
1332         # custom program, like `youtube-dl` or `mpv`.
1333         foreach (@{$result->{matches}}) {
1334             if ($_->{string} =~ m{^https://www.youtube.com/}) {
1335                 $_->{handler} = $config{handler}{youtube};
1336             }
1337         }
1338
1339         return $result;
1340     }
1341     # Also update initial mode to use our new "URL mode".
1342     $config{setting}{initial_mode} = $config{mapping}{mode}{u};
1343
1344     # Special handler to download YouTube URLs with `youtube-dl`. You could
1345     # also use `mpv` here to immediately play them.
1346     $config{handler}{youtube} = sub {
1347         my ($screen, $config, $match) = @_;
1348
1349         return run_in_background($screen, sub {
1350             run_command($screen, ['youtube-dl', $match->{value}]);
1351         });
1352     };
1353
1354
1355
1356 =cut
1357
1358 # All variables and functions which are usable by ~/.fcscsrc.
1359 package Fcscs {
1360     our $screen; # "private"
1361     our %config;
1362
1363     sub color_pair { return $screen->color_pair(@_); }
1364
1365     sub mapping_mode_path { return main::mapping_mode_path(@_); }
1366     sub mapping_mode_url { return main::mapping_mode_url(@_); }
1367     sub mapping_mode_ip { return main::mapping_mode_ip(@_); }
1368     sub mapping_mode_search { return main::mapping_mode_search(@_); }
1369
1370     sub mapping_paste { return main::mapping_paste(@_); }
1371     sub mapping_yank { return main::mapping_yank(@_); }
1372     sub mapping_quit { return main::mapping_quit(@_); }
1373
1374     sub handler_yank { return main::handler_yank(@_); }
1375     sub handler_paste { return main::handler_paste(@_); }
1376     sub handler_url { return main::handler_url(@_); }
1377
1378     sub debug { return main::debug(@_); }
1379
1380     sub get_regex_matches { return main::get_regex_matches(@_); }
1381     sub select_match { return main::select_match(@_); }
1382
1383     sub run_command { return main::run_command(@_); }
1384     sub run_in_background { return main::run_in_background(@_); }
1385 }
1386 $Fcscs::screen = $screen;
1387
1388
1389
1390 # LOAD USER CONFIG
1391
1392 # Alias %config and %Fcscs::config. %config is less to type.
1393 our %config;
1394 local *config = \%Fcscs::config;
1395
1396 $config{mapping}{mode}   = \%mapping_mode;
1397 $config{mapping}{simple} = \%mapping_simple;
1398 $config{attribute}       = \%attribute;
1399 $config{setting}         = \%setting;
1400 $config{regex}           = \%regex;
1401 $config{handler}         = \%handler;
1402 $config{state}           = \%state;
1403
1404 package Fcscs {
1405     my @configs = ("$ENV{HOME}/.fcscsrc",
1406                    "$ENV{HOME}/.config/fcscs/fcscsrc");
1407     foreach my $path (@configs) {
1408         my $decoded = $screen->decode($path);
1409
1410         # Load configuration file. Checks have a race condition if the home
1411         # directory is writable by an attacker (but then the user is screwed
1412         # anyway).
1413         next unless -e $path;
1414         if (not -O $path) {
1415             $screen->die("Config '$decoded' not owned by current user!");
1416         }
1417         # Make sure the file is not writable by other users. Doesn't handle
1418         # ACLs and see comment above about race conditions.
1419         my @stat = stat $path or die $!;
1420         my $mode = $stat[2];
1421         if (($mode & Fcntl::S_IWGRP) or ($mode & Fcntl::S_IWOTH)) {
1422             die "Config '$decoded' must not be writable by other users.";
1423         }
1424
1425         my $result = do $path;
1426         if (not $result) {
1427             $screen->die("Failed to parse '$decoded': $@") if $@;
1428             $screen->die("Failed to do '$decoded': $!") unless defined $result;
1429             $screen->die("Failed to run '$decoded'.");
1430         }
1431
1432         last; # success, don't load more files
1433     }
1434 }
1435 $screen->{debug} = $config{setting}{debug};
1436
1437
1438 # MAIN
1439
1440 eval {
1441     # Auto-detect current multiplexer.
1442     if (not defined $config{setting}{multiplexer}) {
1443         if (defined $ENV{STY} and defined $ENV{TMUX}) {
1444             die 'Found both $STY and $TMUX, set $config{setting}{multiplexer}.';
1445         } elsif (defined $ENV{STY}) {
1446             $config{setting}{multiplexer} = 'screen';
1447         } elsif (defined $ENV{TMUX}) {
1448             $config{setting}{multiplexer} = 'tmux';
1449         } else {
1450             die 'No multiplexer found.';
1451         }
1452     }
1453
1454     my $binmode = $encoding;
1455     # GNU screen stores the screen dump for unknown reasons as ISO-8859-1
1456     # instead of the currently active encoding.
1457     if ($config{setting}{multiplexer} eq 'screen') {
1458         $binmode = 'ISO-8859-1';
1459     }
1460
1461     my @input_lines;
1462     open my $fh, '<', $ARGV[0] or die $!;
1463     binmode $fh, ":encoding($binmode)" or die $!;
1464     while (<$fh>) {
1465         chomp;
1466         push @input_lines, $_;
1467     }
1468     close $fh or die $!;
1469
1470     my $input = prepare_input($screen, \@input_lines);
1471
1472     # Display original screen content.
1473     my $y = 0;
1474     foreach (@{$input->{lines}}) {
1475         $screen->draw_simple($y++, 0, undef, $_);
1476     }
1477     $screen->refresh;
1478
1479
1480     my $mapping = $config{setting}{initial_mode};
1481
1482     my $key;
1483     while (1) {
1484         if (not defined $mapping) {
1485             $key = $screen->getch unless defined $key;
1486             $screen->debug('input', "got key '$key'");
1487
1488             $mapping = $config{mapping}{mode}{$key};
1489             $mapping = $config{mapping}{simple}{$key} unless defined $mapping;
1490             if (not defined $mapping) { # ignore unknown mappings
1491                 $key = undef;
1492                 next;
1493             }
1494         }
1495
1496         $screen->debug('input', 'running mapping');
1497         my $result = $mapping->($key, $screen, \%config, $input);
1498         $mapping = undef;
1499
1500 RESULT:
1501         if (defined $result->{quit}) {
1502             $screen->debug('input', 'quitting');
1503             last;
1504         }
1505         if (defined $result->{key}) {
1506             $key = $result->{key}; # lookup another mapping
1507             $screen->debug('input', "processing new key: '$key'");
1508             next;
1509         }
1510         if (defined $result->{select}) {
1511             $screen->debug('input', 'selecting match');
1512             my $tmp = $result;
1513             $result = select_match($result->{select},
1514                                    $screen, \%config, $input,
1515                                    $result->{matches});
1516             $result->{handler} = $tmp->{handler};
1517             $result->{extend}  = $tmp->{extend};
1518             goto RESULT; # reprocess special entries in result
1519         }
1520         if (defined $result->{extend}) {
1521             $screen->debug('input', 'extending match');
1522             $result = extend_match($screen, \%config, $input,
1523                                    $result->{match});
1524             goto RESULT; # reprocess special entries in result
1525         }
1526         if (defined $result->{match}) {
1527             if (not defined $result->{match}{value}) {
1528                 $result->{match}{value} = $result->{match}{string};
1529             }
1530
1531             $screen->debug('input', 'running handler');
1532
1533             # Choose handler with falling priority.
1534             my @handlers = (
1535                 $config{state}{handler},     # set by user
1536                 $result->{match}{handler},   # set by match
1537                 $result->{handler},          # set by mapping
1538                 $config{handler}{yank},      # fallback
1539             );
1540             foreach my $handler (@handlers) {
1541                 next unless defined $handler;
1542
1543                 $handler->($screen, \%config, $result->{match});
1544                 last;
1545             }
1546             last;
1547         }
1548
1549         $key = undef; # get next key from user
1550     }
1551 };
1552 if ($@) {
1553     $screen->die("$@");
1554 }
1555
1556 $screen->deinit;
1557
1558 __END__
1559
1560 =head1 EXIT STATUS
1561
1562 =over 4
1563
1564 =item B<0>
1565
1566 Success.
1567
1568 =item B<1>
1569
1570 An error occurred.
1571
1572 =item B<2>
1573
1574 Invalid arguments/options.
1575
1576 =back
1577
1578 =head1 AUTHOR
1579
1580 Simon Ruderich E<lt>simon@ruderich.orgE<gt>
1581
1582 =head1 LICENSE AND COPYRIGHT
1583
1584 Copyright (C) 2013-2016 by Simon Ruderich
1585
1586 This program is free software: you can redistribute it and/or modify
1587 it under the terms of the GNU General Public License as published by
1588 the Free Software Foundation, either version 3 of the License, or
1589 (at your option) any later version.
1590
1591 This program is distributed in the hope that it will be useful,
1592 but WITHOUT ANY WARRANTY; without even the implied warranty of
1593 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1594 GNU General Public License for more details.
1595
1596 You should have received a copy of the GNU General Public License
1597 along with this program.  If not, see E<lt>http://www.gnu.org/licenses/E<gt>.
1598
1599 =head1 SEE ALSO
1600
1601 L<screen(1)>, L<tmux(1)>, L<urlview(1)>
1602
1603 =cut