bin/fcscs

   1 #!/usr/bin/perl
   2
   3 # fcscs - fast curses screen content select
   4
   5 # Copyright (C) 2013-2016  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use v5.10; # say, state
  25
  26 use Encode ();
  27 use Fcntl ();
  28 use I18N::Langinfo ();
  29
  30 use Curses ();
  31
  32 our $VERSION = '0.01';
  33
  34
  35 =head1 NAME
  36
  37 fcscs - fast curses screen content select
  38
  39 =head1 SYNOPSIS
  40
  41 B<fcscs> [I<options>] I<path/to/screen/capture/file>
  42
  43 =head1 DESCRIPTION
  44
  45 B<fcscs> is a small tool which allows quick selection of terminal screen
  46 contents (like URLs, paths, regex matches, etc.) and passes the selection to
  47 GNU Screen's or Tmux's buffer or any other program. The selection can then
  48 quickly be pasted, e.g. in the shell. Requires GNU Screen or Tmux. It's
  49 licensed under the GPL 3 or later.
  50
  51 =head1 OPTIONS
  52
  53 None so far.
  54
  55 =head1 USAGE
  56
  57 Short overview of the general usage, details below:
  58
  59     - start fcscs
  60     - configure actions (optional)
  61         - enable pasting
  62         - ...
  63     - select mode (optional, URL mode is used on startup):
  64         - f: file paths
  65         - i: IPs
  66         - u: URLs
  67         - c: checksums (e.g. MD5, SHA1, ..)
  68         - ...
  69         - /: search mode
  70     - for `normal' modes:
  71         - select match by displayed number or <return> for lowest numbered
  72           match
  73         - configured action is run, e.g. URL is opened with browser
  74     - for `search' mode:
  75         - perform incremental search
  76         - on <return> go to `normal' mode to select a match
  77         - after the match is selected wait for confirmation or extension
  78         - confirmation: <return> run previously selected action
  79         - extension: change match, e.g. select complete word or line
  80
  81 GNU Screen setup (add to F<~/.screenrc>):
  82
  83     bind ^B eval "hardcopy $HOME/.tmp/screen-fcscs" "screen fcscs $HOME/.tmp/screen-fcscs"
  84
  85 Tmux setup (add to F<~/.tmux.conf>):
  86
  87     bind-key C-b capture-pane \; save-buffer ~/.tmp/tmux-fcscs \; delete-buffer \; new-window "fcscs ~/.tmp/tmux-fcscs"
  88
  89 This requires a writable ~/.tmp directory. Adapt the mapping according to your
  90 preferences. Ensure these files are not readable by others as they can contain
  91 private data (umask or protected directory). B<fcscs> must be in your C<$PATH>
  92 for the above mappings to work.
  93
  94 Pressing the configured mapping (Prefix Ctrl-B in this example) opens B<fcscs>
  95 in a new GNU screen/Tmux window. After selection, the content is either passed
  96 to external programs (e.g. for URLs) or copied to the paste buffer or directly
  97 pasted in your previous window and the new window is closed.
  98
  99 To select a match just type its number. If the match is unique, the entry is
 100 automatically selected (e.g. you press 2 and there are only 19 matches). If
 101 there are multiple matches left (e.g. you press 1 and there are more than ten
 102 matches available), press return to select the current match (1 in this case)
 103 or another number to select the longer match. Use backspace to remove the last
 104 entered number.
 105
 106 Press return before entering a number to select the last (lowest numbered)
 107 match (underlined by default). To abort without selecting any match use "q".
 108
 109 To change the selection mode (e.g. paths, files, etc.) use one of the mappings
 110 explained below. Per default URLs are selected, see options for a way to
 111 change this.
 112
 113 I<NOTE>: Opening URLs in the browser passes the URL via the command line which
 114 leaks URLs to other users on the current system via C<ps aux> or C<top>.
 115
 116 I<NOTE>: When yanking (copying) a temporary file is used to pass the data to
 117 GNU screen/Tmux without exposing it to C<ps aux> or C<top>. However this may
 118 leak data if those temporary files are written to disk. To prevent this change
 119 your C<$TMP> to point to a memory-only location or encrypted storage.
 120
 121 If no window appears, try running B<fcscs> manually to catch the error message
 122 and please report the bug:
 123
 124     fcscs /path/to/screen-or-tmux-fcscs-file
 125
 126
 127 =head1 MODES
 128
 129 =cut
 130
 131
 132 # CLASSES
 133
 134 # Helper class for drawing on the screen using Curses.
 135 package Screen {
 136     sub init {
 137         my ($class, $encoding) = @_;
 138
 139         # Prefer strict UTF-8 handling (see perldoc Encode); just in case.
 140         if (lc $encoding eq 'utf8') {
 141             $encoding = 'UTF-8';
 142         }
 143         # Get Encode object to speed up decode()/encode().
 144         my $encoding_object = Encode::find_encoding($encoding);
 145         die "unsupported encoding '$encoding'" unless ref $encoding_object;
 146
 147         my $curses = Curses->new or die $!;
 148
 149         my $self = {
 150             encoding        => $encoding,
 151             encoding_object => $encoding_object,
 152             curses          => $curses,
 153             debug           => 0,
 154             prompt          => {
 155                 flags => undef,
 156                 name  => undef,
 157                 value => undef,
 158             },
 159         };
 160         bless $self, $class;
 161
 162         Curses::start_color;
 163         # Allow default colors by passing -1 to init_pair. A default color is
 164         # not drawn on screen thus allowing terminals with pseudo-transparency
 165         # to use the transparent background in place of the default color.
 166         Curses::use_default_colors;
 167
 168         Curses::cbreak;
 169         Curses::noecho;
 170         $self->cursor(0);
 171
 172         return $self;
 173     }
 174     sub deinit {
 175         my ($self) = @_;
 176
 177         Curses::nocbreak;
 178         Curses::echo;
 179         $self->cursor(1);
 180
 181         Curses::endwin;
 182         return;
 183     }
 184
 185     # Convert between Perl's internal encoding and the terminal's encoding.
 186     sub encode {
 187         my ($self, $string) = @_;
 188         return $self->{encoding_object}->encode($string);
 189     }
 190     sub decode {
 191         my ($self, $string) = @_;
 192         return eval { # returns undef on decode failure
 193             $self->{encoding_object}->decode($string, Encode::FB_CROAK);
 194         };
 195     }
 196
 197     # Create attribute for the given fore-/background colors.
 198     sub color_pair {
 199         my ($self, $fg, $bg) = @_;
 200
 201         state $next_color_pair = 1; # must start at 1 for init_pair()
 202
 203         Curses::init_pair($next_color_pair, $fg, $bg);
 204         return Curses::COLOR_PAIR($next_color_pair++);
 205     }
 206
 207     # Draw a string which must fit in the current line. Wrapping/clipping is
 208     # not supported and must be handled by the caller.
 209     sub draw_simple {
 210         my ($self, $y, $x, $attributes, $string) = @_;
 211
 212         die if $string =~ /\n/;
 213         # FIXME: wide characters
 214         die if $x + length $string > $self->width;
 215
 216         $self->{curses}->attron($attributes) if defined $attributes;
 217         $self->{curses}->addstr($y, $x, $self->encode($string));
 218         $self->{curses}->attroff($attributes) if defined $attributes;
 219         return;
 220     }
 221     # Like draw_simple(), but the string is automatically clipped.
 222     sub draw_clipped {
 223         my ($self, $y, $x, $attributes, $string) = @_;
 224
 225         # FIXME: wide characters
 226         $string = substr $string, 0, $self->width - $x;
 227         $self->draw_simple($y, $x, $attributes, $string);
 228         return;
 229     }
 230     sub draw {
 231         my ($self, $y, $x, $attributes, $string) = @_;
 232
 233         die unless defined $string;
 234
 235         while (1) {
 236             my $offset;
 237             # We must print each line separately. Search for next newline or
 238             # line end, whichever is closer.
 239             if ($string =~ /\n/) {
 240                 $offset = $-[0];
 241             }
 242             # FIXME: wide characters
 243             if ($x + length $string > $self->width) {
 244                 my $new_offset = $self->width - $x;
 245                 if (not defined $offset or $offset > $new_offset) {
 246                     $offset = $new_offset;
 247                 }
 248             }
 249             last unless defined $offset;
 250
 251             # FIXME: wide characters
 252             $self->draw_simple($y, $x, $attributes, substr $string, 0, $offset);
 253
 254             # Don't draw "\n" itself.
 255             if ("\n" eq substr $string, $offset, 1) {
 256                 $offset++;
 257             }
 258
 259             $string = substr $string, $offset;
 260
 261             $y++;
 262             $x = 0;
 263         }
 264
 265         $self->draw_simple($y, $x, $attributes, $string);
 266         return $y;
 267     }
 268
 269     sub draw_prompt {
 270         my ($self, $config) = @_;
 271
 272         $self->debug('draw_prompt', 'started');
 273
 274         my $x = 0;
 275         my $y = $self->height - 1;
 276
 277         # Clear line for better visibility.
 278         $self->draw_simple($y, $x, undef, ' ' x $self->width);
 279
 280         # Draw prompt flags.
 281         if (defined (my $s = $self->{prompt}{flags})) {
 282             $s = "[$s]";
 283             $self->debug('draw_prompt', $s);
 284             $self->draw_clipped($y, $x, $config->{attribute}{prompt_flags}, $s);
 285             $x += length($s) + 1; # space between next element
 286         }
 287         # Draw prompt name.
 288         if (defined (my $s = $self->{prompt}{name})) {
 289             $s = "[$s]";
 290             $self->debug('draw_prompt', $s);
 291             $self->draw_clipped($y, $x, $config->{attribute}{prompt_name}, $s);
 292             $x += length($s) + 1;
 293         }
 294         # Draw prompt value, e.g. a search field.
 295         if (defined (my $s = $self->{prompt}{value})) {
 296             $self->debug('draw_prompt', $s);
 297             $self->draw_clipped($y, $x, undef, $s);
 298             $x += length($s) + 1;
 299         }
 300         return;
 301     }
 302
 303     sub draw_matches {
 304         my ($self, $config, $matches_remove, $matches_add) = @_;
 305
 306         foreach (@{$matches_remove}) {
 307             $self->draw($_->{y}, $_->{x}, Curses::A_NORMAL, $_->{string});
 308         }
 309
 310         my $attr_id     = $config->{attribute}{match_id};
 311         my $attr_string = $config->{attribute}{match_string};
 312         my $attr_last   = $config->{attribute}{match_last};
 313
 314         foreach (@{$matches_add}) {
 315             my $attr = (defined $_->{id} and $_->{id} == 1)
 316                      ? $attr_last
 317                      : $attr_string;
 318             $self->draw($_->{y}, $_->{x}, $attr, $_->{string});
 319             if (defined $_->{id}) {
 320                 $self->draw($_->{y}, $_->{x}, $attr_id, $_->{id});
 321             }
 322         }
 323         return;
 324     }
 325
 326     sub die {
 327         my ($self, @args) = @_;
 328
 329         my $attr = $self->color_pair(Curses::COLOR_RED, -1) | Curses::A_BOLD;
 330
 331         # Clear the screen to improve visibility of the error message.
 332         $self->{curses}->clear;
 333
 334         my $y = $self->draw(0, 0, $attr, "@args");
 335
 336         if ($self->{debug}) {
 337             my $msg;
 338             eval {
 339                 require Devel::StackTrace;
 340             };
 341             if ($@) {
 342                 $msg = "Devel::StackTrace missing, no stack trace.\n";
 343             } else {
 344                 my $trace = Devel::StackTrace->new;
 345                 $msg = "Stack trace:\n" . $trace->as_string;
 346             }
 347             $y = $self->draw($y + 1, 0, Curses::A_NORMAL, $msg);
 348         }
 349
 350         $self->draw($y + 1, 0, Curses::A_NORMAL,
 351                     'Press any key to terminate fcscs.');
 352         $self->refresh;
 353
 354         $self->getch;
 355         $self->deinit;
 356         exit 1;
 357     }
 358     sub debug {
 359         my ($self, $module, @args) = @_;
 360
 361         return if not $self->{debug};
 362
 363         state $fh; # only open the file once per run
 364         if (not defined $fh) {
 365             # Ignore errors if the directory doesn't exist.
 366             if (not open $fh, '>', "$ENV{HOME}/.config/fcscs/log") {
 367                 $fh = undef; # a failed open still writes a value to $fh
 368                 return;
 369             }
 370             $fh->autoflush(1);
 371         }
 372
 373         foreach (@args) {
 374             $_ = $self->encode($_);
 375         }
 376         say $fh "$module: @args" or CORE::die $!;
 377         return;
 378     }
 379
 380
 381     sub prompt {
 382         my ($self, %settings) = @_;
 383
 384         foreach (keys %settings) {
 385             CORE::die if not exists $self->{prompt}{$_};
 386             $self->{prompt}{$_} = $settings{$_};
 387         }
 388         return;
 389     }
 390
 391     # Wrapper for Curses.
 392     sub width   { return $Curses::COLS; }
 393     sub height  { return $Curses::LINES; }
 394     sub refresh { return $_[0]->{curses}->refresh; }
 395     sub getch   { return $_[0]->{curses}->getch; }
 396     sub cursor  { Curses::curs_set($_[1]); return; }
 397 }
 398
 399
 400
 401 # FUNCTIONS
 402
 403 sub prepare_input {
 404     my ($screen, $input_ref) = @_;
 405
 406     # Make sure the input fits on the screen by removing the top lines if
 407     # necessary.
 408     splice @{$input_ref}, 0, -$screen->height;
 409
 410     # Pad each line with spaces to the screen width to correctly handle
 411     # multi-line regexes.
 412     # FIXME: wide characters
 413     my @padded = map { sprintf '%-*s', $screen->width, $_ } @{$input_ref};
 414
 415     my $string = join "\n", @padded;
 416     return {
 417         string => $string,
 418         lines  => $input_ref,
 419         width  => $screen->width + 1,
 420                   # + 1 = "\n", used in input_match_offset_to_coordinates
 421     };
 422 }
 423
 424 sub input_match_offset_to_coordinates {
 425     my ($width, $offset) = @_;
 426
 427     die unless defined $offset;
 428
 429     my $y = int($offset / $width);
 430     my $x = $offset - $y * $width;
 431     return ($x, $y);
 432 }
 433
 434 sub get_regex_matches {
 435     my ($input, $regex) = @_;
 436
 437     my @matches;
 438     while ($input->{string} =~ /$regex/g) {
 439         my $offset = $-[1];
 440         die "Match group required in regex '$regex'" if not defined $offset;
 441
 442         my ($x, $y) = input_match_offset_to_coordinates($input->{width},
 443                                                         $offset);
 444         push @matches, { x => $x, y => $y, offset => $offset, string => $1 };
 445     }
 446     return @matches;
 447 }
 448
 449
 450 sub run_command {
 451     my ($screen, $cmd) = @_;
 452
 453     $screen->debug('run_command', "running @{$cmd}");
 454
 455     my $exit = do {
 456         # Perl's system() combined with a $SIG{__WARN__} which die()s has
 457         # issues due to the fork. The die() in the __WARN__ handler doesn't
 458         # die but the program continues after the system().
 459         #
 460         # If the forked process fails to exec (e.g. program not found) then
 461         # the __WARN__ handler is called (because a warning is about to be
 462         # displayed) and the die() should display a message and terminate the
 463         # process. But due to the fork it doesn't terminate the parent process
 464         # and instead changes the return value of system(); it's no longer -1
 465         # which makes it impossible to detect that case.
 466         #
 467         # Perl < 5.18 (found in 5.14) doesn't setup $$ during system() which
 468         # makes it impossible to detect if the handler was called from inside
 469         # the child.
 470         #
 471         # Instead, just ignore any warnings during the system(). Thanks to
 472         # mauke in #perl on Freenode (2013-10-29 23:30 CET) for the idea to
 473         # use no warnings and anno for testing a more recent Perl version with
 474         # a working $$.
 475         no warnings;
 476
 477         my @cmd = map { $screen->encode($_) } @{$cmd};
 478         system { $cmd[0] } @cmd;
 479     };
 480     if ($exit != 0) {
 481         my $msg;
 482         if ($? == -1) {
 483             $msg = 'failed to execute: ' . $!;
 484         } elsif ($? & 127) {
 485             $msg = 'killed by signal ' . ($? & 127);
 486         } else {
 487             $msg = 'exited with code ' . ($? >> 8);
 488         }
 489         die "system(@{$cmd}) $msg.";
 490     }
 491     return;
 492 }
 493 sub run_in_background {
 494     my ($screen, $sub) = @_;
 495
 496     $screen->debug('run_in_background', "running $sub");
 497
 498     my $pid = fork;
 499     defined $pid or die $!;
 500
 501     if ($pid == 0) {
 502         # The terminal multiplexer sends a SIGHUP to the process when it
 503         # closes the window (because the parent process has exited).
 504         local $SIG{HUP} = 'IGNORE';
 505
 506         # Necessary for GNU screen or it'll keep the window open until an
 507         # external command has run.
 508         require File::Spec;
 509         my $devnull = File::Spec->devnull();
 510         open STDIN,  '<', $devnull or die $!;
 511         open STDOUT, '>', $devnull or die $!;
 512         open STDERR, '>', $devnull or die $!;
 513
 514         # Double-fork to prevent zombies.
 515         my $pid = fork;
 516         defined $pid or die $!;
 517         if ($pid == 0) { # child
 518             $sub->();
 519         }
 520         exit;
 521     }
 522     waitpid $pid, 0 or die $!;
 523     return;
 524 }
 525
 526
 527 sub select_match {
 528     my ($name, $screen, $config, $input, $matches) = @_;
 529
 530     $screen->debug('select_match', 'started');
 531
 532     return if @{$matches} == 0;
 533     # Don't return on initial run to give the user a chance to select another
 534     # mode, e.g. to switch from URL selection to search selection.
 535     if (@{$matches} == 1 and not $config->{state}{initial}) {
 536         return { match => $matches->[0] };
 537     }
 538     $config->{state}{initial} = 0;
 539
 540     my @sorted = sort { $b->{y} <=> $a->{y} or $b->{x} <=> $a->{x} } @{$matches};
 541
 542     my $i = 1;
 543     foreach (@sorted) {
 544         $_->{id} = $i++;
 545     }
 546
 547     $screen->prompt(name => $name, value => undef);
 548     $screen->draw_prompt($config);
 549
 550     $screen->draw_matches($config, [], $matches);
 551     $screen->refresh;
 552
 553     my $number = 0;
 554     while (1) {
 555         my $char = $screen->getch;
 556         if ($char =~ /^\d$/) {
 557             $number = $number * 10 + $char;
 558         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
 559             $number = int($number / 10);
 560         } elsif ($char eq "\n"
 561                 or $char eq $config->{setting}{alternative_return}) {
 562             last;
 563
 564         # Selecting a new mode requires falling through into the main input
 565         # loop and then starting the new mode.
 566         } elsif (defined $config->{mapping}{mode}{$char}) {
 567             $screen->draw_matches($config, $matches, []); # clear matches
 568             return { key => $char };
 569         # All other mappings stay in the current mode.
 570         } elsif (defined (my $m = $config->{mapping}{simple}{$char})) {
 571             my $result = $m->($char, $screen, $config, $input);
 572             last if defined $result->{select_match};
 573             next;
 574
 575         } else {
 576             next; # ignore unknown mappings
 577         }
 578
 579         last if $number > 0 and $number * 10 > @{$matches}; # unique match
 580
 581         my @remaining = $number == 0
 582                       ? @{$matches}
 583                       : grep { $_->{id} =~ /^$number/ } @{$matches};
 584         $screen->draw_matches($config, $matches, \@remaining);
 585         $screen->refresh;
 586     }
 587     # Number without selection matches last entry.
 588     if ($number == 0) {
 589         $number = 1;
 590     }
 591
 592     $screen->draw_matches($config, $matches, []); # remove matches
 593
 594     foreach (@{$matches}) {
 595         return { match => $_ } if $_->{id} == $number;
 596     }
 597     $screen->debug('select_match', 'no match selected');
 598     return { match => undef };
 599 }
 600
 601 sub extend_match_regex_left {
 602     my ($line, $match, $regex) = @_;
 603
 604     my $s = reverse substr $line, 0, $match->{x};
 605     if ($s =~ /^($regex)/) {
 606         $match->{string}  = reverse($1) . $match->{string};
 607         $match->{x}      -= length $1;
 608         $match->{offset} -= length $1;
 609     }
 610     return;
 611 }
 612 sub extend_match_regex_right {
 613     my ($line, $match, $regex) = @_;
 614
 615     my $s = substr $line, $match->{x} + length $match->{string};
 616     if ($s =~ /^($regex)/) {
 617         $match->{string} .= $1;
 618     }
 619     return;
 620 }
 621 sub extend_match {
 622     my ($screen, $config, $input, $match) = @_;
 623
 624     $screen->debug('extend_match', 'started');
 625
 626     return if not defined $match;
 627
 628     $screen->prompt(name => 'extend', value => undef);
 629     $screen->draw_prompt($config);
 630
 631     delete $match->{id}; # don't draw any match ids
 632     $screen->draw_matches($config, [], [$match]);
 633     $screen->refresh;
 634
 635     my $line = $input->{lines}[$match->{y}];
 636
 637     while (1) {
 638         my $match_old = \%{$match};
 639
 640         my $char = $screen->getch;
 641         if ($char eq "\n"
 642                 or $char eq $config->{setting}{alternative_return}) {
 643             last; # accept match
 644
 645         } elsif ($char eq 'w') { # select current word (both directions)
 646             extend_match_regex_left($line,  $match, qr/\w+/);
 647             extend_match_regex_right($line, $match, qr/\w+/);
 648         } elsif ($char eq 'b') { # select current word (only left)
 649             extend_match_regex_left($line,  $match, qr/\w+/);
 650         } elsif ($char eq 'e') { # select current word (only right)
 651             extend_match_regex_right($line, $match, qr/\w+/);
 652
 653         } elsif ($char eq 'W') { # select current WORD (both directions)
 654             extend_match_regex_left($line,  $match, qr/\S+/);
 655             extend_match_regex_right($line, $match, qr/\S+/);
 656         } elsif ($char eq 'B') { # select current WORD (only left)
 657             extend_match_regex_left($line,  $match, qr/\S+/);
 658         } elsif ($char eq 'E') { # select current WORD (only right)
 659             extend_match_regex_right($line, $match, qr/\S+/);
 660
 661         } elsif ($char eq '0') { # select to beginning of line
 662             extend_match_regex_left($line, $match, qr/.+/);
 663         } elsif ($char eq '$') { # select to end of line
 664             extend_match_regex_right($line, $match, qr/.+/);
 665
 666         # Allow mode changes if not overwritten by local mappings.
 667         } elsif (defined $config->{mapping}{mode}{$char}) {
 668             $screen->draw_matches($config, [$match_old], []); # clear match
 669             return { key => $char };
 670
 671         } else {
 672             next; # ignore unknown mappings
 673         }
 674
 675         $screen->draw_matches($config, [$match_old], [$match]);
 676         $screen->refresh;
 677     }
 678
 679     $screen->debug('extend_match', 'done');
 680
 681     return { match => $match };
 682 }
 683
 684
 685 sub mapping_state_helper {
 686     my ($name, $flags, $key, $screen, $config, $input) = @_;
 687
 688     $screen->debug("mapping_$name", 'started');
 689
 690     $config->{state}{handler} = $config->{handler}{$name};
 691
 692     $screen->prompt(flags => $flags);
 693     $screen->draw_prompt($config);
 694     $screen->refresh;
 695
 696     return {};
 697 }
 698 sub mapping_state_now_helper {
 699     my ($name, $key, $screen, $config, $input) = @_;
 700
 701     $screen->debug("mapping_${name}_now", 'started');
 702
 703     $config->{state}{handler} = $config->{handler}{$name};
 704
 705     return {
 706         select_match => 1,
 707     };
 708 }
 709
 710 sub mapping_paste {
 711     return mapping_state_helper('paste', 'P', @_);
 712 }
 713 sub mapping_paste_now {
 714     return mapping_state_now_helper('paste', @_);
 715 }
 716
 717 sub mapping_yank {
 718     return mapping_state_helper('yank', 'Y', @_);
 719 }
 720 sub mapping_yank_now {
 721     return mapping_state_now_helper('yank', @_);
 722 }
 723
 724
 725 =head2 NORMAL MODES
 726
 727 Normal modes select matches by calling a function which returns them, e.g. by
 728 using a regex.
 729
 730 The following normal modes are available:
 731
 732 =over 4
 733
 734 =item B<path mode>     select relative/absolute paths
 735
 736 =item B<url mode>      select URLs
 737
 738 =item B<ip mode>       select IPv4 and IPv6 addresses
 739
 740 =item B<checksum mode> select checksums (MD5, SHA1, SHA256, SHA512)
 741
 742 =back
 743
 744 =cut
 745 sub mapping_mode_helper {
 746     my ($name, $select, $key, $screen, $config, $input) = @_;
 747
 748     $screen->debug("mapping_mode_$name", 'started');
 749
 750     my @matches = get_regex_matches($input, $config->{regex}{$name});
 751     return {
 752         select  => $select,
 753         matches => \@matches,
 754         handler => $config->{handler}{$name},
 755     };
 756 }
 757 sub mapping_mode_path {
 758     return mapping_mode_helper('path', 'path select', @_);
 759 }
 760 sub mapping_mode_url {
 761     return mapping_mode_helper('url', 'url select', @_);
 762 }
 763 sub mapping_mode_ip {
 764     my ($key, $screen, $config, $input) = @_;
 765
 766     $screen->debug('mapping_mode_ip', 'started');
 767
 768     my @ipv4 = get_regex_matches($input, $config->{regex}{ipv4});
 769     my @ipv6 = get_regex_matches($input, $config->{regex}{ipv6});
 770     return {
 771         select  => 'ip select',
 772         matches => [@ipv4, @ipv6],
 773         handler => $config->{handler}{ip},
 774     };
 775 }
 776 sub mapping_mode_checksum {
 777     return mapping_mode_helper('checksum', 'checksum select', @_);
 778 }
 779
 780 =head2 SEARCH MODE (AND EXTEND MODE)
 781
 782 Search mode is a special mode which lets you type a search string (a Perl
 783 regex) and then select one of the matches. Afterwards you can extend the
 784 match. For example select the complete word or to the end of the line. This
 785 allows quick selection of arbitrary text.
 786
 787 The following mappings are available during the extension mode (not
 788 configurable at the moment):
 789
 790 =over 4
 791
 792 =item B<w> select current word
 793
 794 =item B<b> extend word to the left
 795
 796 =item B<e> extend word to the right
 797
 798 =item B<W> select current WORD
 799
 800 =item B<B> extend WORD to the left
 801
 802 =item B<E> extend WORD to the right
 803
 804 =item B<0> extend to beginning of line
 805
 806 =item B<$> extend to end of line
 807
 808 =back
 809
 810 C<word> includes any characters matching C<\w+>, C<WORD> any non-whitespace
 811 characters (C<\S+>), just like in Vim.
 812
 813 =cut
 814 sub mapping_mode_search {
 815     my ($key, $screen, $config, $input) = @_;
 816
 817     $screen->debug('mapping_mode_search', 'started');
 818
 819     $screen->cursor(1);
 820
 821     my $search = ''; # encoded
 822     my @last_matches;
 823     while (1) {
 824         # getch doesn't return decoded characters but raw input bytes. Wait
 825         # until the input character is complete.
 826         my $value = $screen->decode($search);
 827         $value = '' unless defined $value; # undef on decode failure
 828
 829         $screen->prompt(name => 'search', value => $value);
 830         $screen->draw_prompt($config);
 831         $screen->refresh;
 832
 833         my $char = $screen->getch;
 834         # TODO: readline editing support
 835         if ($char eq "\n") {
 836             last;
 837         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
 838             # Remove a character, not a byte.
 839             $search = $screen->decode($search);
 840             chop $search;
 841             $search = $screen->encode($search);
 842         } else {
 843             $search .= $char;
 844             next unless defined $screen->decode($search);
 845         }
 846
 847         my @matches;
 848         if ($search ne '') {
 849             my $case = '';
 850             if (($config->{setting}{smartcase} and $search eq lc $search)
 851                     or $config->{setting}{ignorecase}) {
 852                 $case = '(?i)';
 853             }
 854             # Ignore invalid regexps.
 855             # TODO: display warning on error?
 856             eval {
 857                 @matches = get_regex_matches($input, qr/($case$search)/);
 858             };
 859         }
 860         $screen->draw_matches($config, \@last_matches, \@matches);
 861         @last_matches = @matches;
 862     }
 863
 864     $screen->cursor(0);
 865
 866     $screen->prompt(name => undef, value => undef); # clear prompt
 867     $screen->draw_prompt($config);
 868
 869     $screen->debug('mapping_mode_search', 'done');
 870
 871     return {
 872         select  => 'search',
 873         matches => \@last_matches,
 874         extend  => 1,
 875         handler => $config->{handler}{yank},
 876     };
 877 }
 878
 879 sub mapping_quit {
 880     my ($key, $screen, $config, $input) = @_;
 881
 882     # Key is necessary to fall through to main event loop which then quits.
 883     return { key => $key, quit => 1 };
 884 }
 885
 886
 887 sub handler_yank {
 888     my ($screen, $config, $match) = @_;
 889
 890     $screen->debug('handler_yank', 'started');
 891
 892     require File::Temp;
 893
 894     # Use a temporary file to prevent leaking the yanked data to other users
 895     # with the command line, e.g. ps aux or top.
 896     my ($fh, $tmp) = File::Temp::tempfile(); # dies on its own
 897     print $fh $screen->encode($match->{value}) or die $!;
 898     close $fh or die $!;
 899
 900     if ($config->{setting}{multiplexer} eq 'screen') {
 901         $screen->debug('handler_yank', 'using screen');
 902
 903         # GNU screen displays an annoying "Slurping X characters into buffer".
 904         # Use 'msgwait 0' as a hack to disable it.
 905         my $msgwait = $config->{setting}{screen_msgwait};
 906         run_command($screen, ['screen', '-X', 'msgwait', 0]);
 907         run_command($screen, ['screen', '-X', 'readbuf', $tmp]);
 908         run_command($screen, ['screen', '-X', 'msgwait', $msgwait]);
 909     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
 910         $screen->debug('handler_yank', 'using tmux');
 911
 912         run_command($screen, ['tmux', 'load-buffer', $tmp]);
 913     } else {
 914         die 'unsupported multiplexer';
 915     }
 916
 917     unlink $tmp or die $!;
 918
 919     if ($config->{setting}{yank_x11}) {
 920         $screen->debug('handler_yank', 'setting X11 selection');
 921
 922         my @xsel_cmd  = qw( xsel --input --primary );
 923         my @xclip_cmd = qw( xclip -in -selection primary );
 924
 925         my $fh;
 926         {
 927             # We don't care if a program doesn't exist.
 928             no warnings;
 929
 930             if (not open $fh, '|-', @xsel_cmd) {
 931                 if (not open $fh, '|-', @xclip_cmd) {
 932                     die "install xsel or xlip to yank to X11 selection\n";
 933                 }
 934             }
 935         }
 936         print $fh $match->{value} or die $!;
 937         close $fh or die $!;
 938     }
 939
 940     return;
 941 }
 942 sub handler_paste {
 943     my ($screen, $config, $match) = @_;
 944
 945     $screen->debug('handler_paste', 'started');
 946
 947     require Time::HiRes;
 948
 949     my @cmd;
 950     if ($config->{setting}{multiplexer} eq 'screen') {
 951         $screen->debug('handler_paste', 'using screen');
 952         @cmd = qw( screen -X paste . );
 953     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
 954         $screen->debug('handler_paste', 'using tmux');
 955         @cmd = qw( tmux paste-buffer );
 956     } else {
 957         die 'unsupported multiplexer';
 958     }
 959
 960     run_in_background($screen, sub {
 961         # We need to get the data in the paste buffer before we can paste
 962         # it.
 963         handler_yank($screen, $config, $match);
 964
 965         # Sleep until we switch back to the current window.
 966         Time::HiRes::usleep($config->{setting}{paste_sleep});
 967
 968         run_command($screen, \@cmd);
 969     });
 970     return;
 971 }
 972 sub handler_url {
 973     my ($screen, $config, $match) = @_;
 974
 975     $screen->debug('handler_url', "opening $match->{value}");
 976
 977     run_in_background($screen, sub {
 978         my @cmd = ( @{$config->{setting}{browser}}, $match->{value} );
 979         run_command($screen, \@cmd);
 980     });
 981     return;
 982 }
 983
 984
 985
 986 # CONFIGURATION DEFAULTS
 987
 988 =head1 CONFIGURATION
 989
 990 fcscs is configured through F<~/.fcscsrc> or F<~/.config/fcscs/fcscsrc> which
 991 is a normal Perl script with all of Perl's usual features.
 992
 993 All configuration values are stored in the hash C<%config>. All manually
 994 defined keys overwrite the default settings.
 995
 996 A simple F<~/.fcscsrc> could look like this (for details about the used
 997 settings see below):
 998
 999     use strict;
1000     use warnings;
1001
1002     use Curses; # for COLOR_* and A_* constants
1003
1004     our %config;
1005
1006     # Draw matches in blue.
1007     $config{attribute}{match_string} = color_pair(COLOR_BLUE, -1);
1008     # Draw numbers in bold yellow.
1009     $config{attribute}{match_id} = color_pair(COLOR_YELLOW, -1)
1010                                  | A_BOLD;
1011     # Disable Vim-like 'smartcase', ignore case until an upper character is
1012     # searched.
1013     $config{setting}{smartcase} = 0;
1014
1015     # Use chromium to open URLs if running under X, elinks otherwise.
1016     if (defined $ENV{DISPLAY}) {
1017         $config{setting}{browser} = ['chromium'];
1018     } else {
1019         $config{setting}{browser} = ['elinks', '-remote'];
1020     }
1021
1022     # Let fcscs know the file was loaded successfully.
1023     1;
1024
1025 =cut
1026
1027
1028 if (@ARGV != 1) {
1029     require Pod::Usage;
1030     Pod::Usage::pod2usage(2);
1031 }
1032
1033
1034 # Determine terminal encoding from the environment ($ENV{LANG} or similar).
1035 my $encoding = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET);
1036
1037 my $screen = Screen->init($encoding);
1038
1039 # We must restore the screen before exiting.
1040 local $SIG{INT} = sub {
1041     $screen->deinit;
1042     exit 128 + 2;
1043 };
1044 # Make all warnings fatal to make sure they don't get lost (stderr is normally
1045 # not displayed).
1046 local $SIG{__WARN__} = sub {
1047     $screen->die('warning', @_);
1048 };
1049
1050
1051
1052 =head2 MAPPINGS
1053
1054 I<NOTE>: Mappings are split in two categories: Mode mappings which change the
1055 selection and may receive additional input (e.g. a search string) and simple
1056 mappings which only change some config value. Mode mappings are configured via
1057 C<$config{mapping}{mode}>, simple mappings via C<$config{mapping}{simple}>.
1058
1059 The following mode mappings are available by default (the function to remap
1060 them in parentheses):
1061
1062 =over
1063
1064 =item B<f> select absolute/relative paths (C<\&mapping_mode_path>)
1065
1066 =item B<u> select URLs (C<\&mapping_mode_url>)
1067
1068 =item B<i> select IPv4 and IPv6 addresses (C<\&mapping_mode_ip>)
1069
1070 =item B<c> select checksums (e.g. MD5, SHA) (C<\&mapping_mode_checksum>)
1071
1072 =item B</> search for regex to get selection (C<\&mapping_mode_search>)
1073
1074 =item B<q> quit fcscs (C<\&mapping_quit>)
1075
1076 =back
1077
1078 The following simple mappings are available by default:
1079
1080 =over
1081
1082 =item B<p> enable pasting (C<\&mapping_paste>)
1083
1084 =item B<P> paste current selection (like C<\n> but paste) (C<\&mapping_paste_now>)
1085
1086 =item B<y> enable yanking (copying) (C<\&mapping_yank>)
1087
1088 =item B<Y> yank current selection (like C<\n> but yank) (C<\&mapping_yank_now>)
1089
1090 =back
1091
1092 Note that yanking only uses the GNU screen or Tmux paste buffer by default. To
1093 also copy to X11 selection, enable the B<yank_x11> option.
1094
1095 The following additional mappings are available by default:
1096
1097 =over
1098
1099 =item B<\n> accept current selection (not customizable)
1100
1101 =item B<s>  additional key to accept selection (B<alternative_return> option)
1102
1103 =back
1104
1105 All (single-byte) keys except numbers, backspace and return can be mapped.
1106
1107 Unknown mappings are ignored when pressing keys.
1108
1109 To remove a default mapping, delete it from the mapping hash.
1110
1111 Example:
1112
1113     # Map 'p' to select paths, 'P' to enable pasting.
1114     $config{mapping}{mode}{p} = \&mapping_mode_path;
1115     $config{mapping}{simple}{P} = \&mapping_paste;
1116
1117     # Disable 'f' mapping.
1118     delete $config{mapping}{mode}{f};
1119
1120 =cut
1121 my %mapping_mode = (
1122     f   => \&mapping_mode_path,
1123     u   => \&mapping_mode_url,
1124     i   => \&mapping_mode_ip,
1125     c   => \&mapping_mode_checksum,
1126     '/' => \&mapping_mode_search,
1127     q   => \&mapping_quit,
1128 );
1129 my %mapping_simple = (
1130     p => \&mapping_paste,
1131     P => \&mapping_paste_now,
1132     y => \&mapping_yank,
1133     Y => \&mapping_yank_now,
1134 );
1135
1136 =head2 ATTRIBUTES
1137
1138 Attributes are used to style the output. They must be Curses attributes.
1139 Defaults in parentheses (foreground, background, attribute).
1140
1141 =over
1142
1143 =item B<match_id>      attribute for match numbers (red, default, bold)
1144
1145 =item B<match_string>  attribute for matches (yellow, default, normal)
1146
1147 =item B<match_last>    attribute for the match selected by return (yellow, default, underline)
1148
1149 =item B<prompt_name>   attribute for prompt name (standout)
1150
1151 =item B<prompt_flags>  attribute for prompt flags (standout)
1152
1153 =back
1154
1155 Example:
1156
1157     # Draw prompt flags in bold red with default background color.
1158     $config{attribute}{prompt_flags}
1159         = Curses::A_BOLD
1160         | color_pair(Curses::COLOR_RED, -1);
1161
1162 =cut
1163 my %attribute = (
1164     match_id     => $screen->color_pair(Curses::COLOR_RED, -1)
1165                     | Curses::A_BOLD,
1166     match_string => $screen->color_pair(Curses::COLOR_YELLOW, -1),
1167     match_last   => $screen->color_pair(Curses::COLOR_YELLOW, -1)
1168                     | Curses::A_UNDERLINE,
1169     prompt_name  => Curses::A_STANDOUT,
1170     prompt_flags => Curses::A_STANDOUT,
1171 );
1172
1173 =head2 SETTINGS
1174
1175 Defaults in parentheses.
1176
1177 =over
1178
1179 =item B<debug>              enable debug mode, writes to I<~/.config/fcscs/log> (C<0>)
1180
1181 =item B<initial_mode>       start in this mode, must be a valid mode mapping (C<\&mapping_mode_url>)
1182
1183 =item B<multiplexer>        set multiplexer ("screen" or "tmux"), defaults to autodetection (C<undef>)
1184
1185 =item B<ignorecase>         ignore case when searching (C<0>)
1186
1187 =item B<smartcase>          ignore case unless one uppercase character is searched (C<1>)
1188
1189 =item B<yank_x11>           copy selection also to X11 primary selection when yanking (C<0>)
1190
1191 =item B<paste_sleep>        sleep x us before running paste command (C<100_000>)
1192
1193 =item B<screen_msgwait>     GNU Screen's msgwait variable, used when yanking (C<5>)
1194
1195 =item B<alternative_return> additional accept key like return, set to C<\n> to disable (C<s>)
1196
1197 =item B<browser>            browser command as array reference (C<['x-www-browser']>)
1198
1199 =back
1200
1201 Example:
1202
1203     # Select paths on startup instead of URLs.
1204     $config{setting}{initial_mode} = \&mapping_mode_path;
1205
1206 =cut
1207 my %setting = (
1208     # options
1209     debug              => 0,
1210     initial_mode       => \&mapping_mode_url,
1211     multiplexer        => undef,
1212     ignorecase         => 0,
1213     smartcase          => 1,
1214     yank_x11           => 0,
1215     paste_sleep        => 100_000,
1216     screen_msgwait     => 5,
1217     # global mappings
1218     alternative_return => 's',
1219     # commands
1220     browser            => ['x-www-browser'],
1221 );
1222
1223 =head2 REGEXPS
1224
1225 =over
1226
1227 =item B<url>  used by C<\&mapping_mode_url>
1228
1229 =item B<path> used by C<\&mapping_mode_path>
1230
1231 =item B<ipv4> used by C<\&mapping_mode_ip>
1232
1233 =item B<ipv6> used by C<\&mapping_mode_ip>
1234
1235 =back
1236
1237 Example:
1238
1239     # Select all non-whitespace characters when searching for paths.
1240     $config{regex}{path} = qr{(\S+)};
1241
1242 =cut
1243 my %regex = (
1244     # Taken from urlview's default configuration file, thanks.
1245     url  => qr{((?:(?:(?:http|https|ftp|gopher)|mailto):(?://)?[^ <>"\t]*|(?:www|ftp)[0-9]?\.[-a-z0-9.]+)[^ .,;\t\n\r<">\):]?[^, <>"\t]*[^ .,;\t\n\r<">\):])},
1246     path => qr{(~?[a-zA-Z0-9_./-]*/[a-zA-Z0-9_./-]+)},
1247     # IP addresses with optional prefix. Not perfectly accurate but good
1248     # enough.
1249     ipv4 => qr!\b(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}(?:/\d{1,2})?)\b!,
1250     ipv6 => qr!\b((?:[0-9a-fA-F]{1,4})?(?::+[0-9a-fA-F]{1,4})+(?:/\d{1,3})?)\b!,
1251     # MD5, SHA1, SHA256, SHA512
1252     checksum => qr!\b([0-9a-fA-F]{32}|[0-9a-fA-F]{40}|[0-9a-fA-F]{64}|[0-9a-fA-F]{128})\b!,
1253 );
1254
1255 =head2 HANDLERS
1256
1257 Handlers are used to perform actions on the selected string.
1258
1259 The following handlers are available, defaults in parentheses.
1260
1261 =over
1262
1263 =item B<yank>     used to yank (copy) selection to paste buffer (C<\&handler_yank>)
1264
1265 =item B<paste>    used to paste selection into window (C<\&handler_paste>)
1266
1267 =item B<path>     used to handle paths (C<\&handler_yank>)
1268
1269 =item B<url>      used to open URLs (e.g. in a browser) (C<\&handler_url>)
1270
1271 =item B<ip>       used to handle IPs (C<\&handler_yank>)
1272
1273 =item B<checksum> used to handle checksums (C<\&handler_yank>)
1274
1275 =back
1276
1277 Example:
1278
1279     # Download YouTube videos with a custom wrapper, handle all other URLs
1280     # with the default URL handler.
1281     $config{handler}{url} = sub {
1282         my ($screen, $config, $match) = @_;
1283
1284         if ($match->{value} =~ m{^https://www.youtube.com/}) {
1285             return run_in_background($screen, sub {
1286                 run_command($screen, ['youtube-dl-wrapper', $match->{value}]);
1287             });
1288         }
1289         handler_url(@_);
1290     };
1291
1292 =cut
1293 my %handler = (
1294     yank     => \&handler_yank,
1295     paste    => \&handler_paste,
1296     path     => \&handler_yank,
1297     url      => \&handler_url,
1298     ip       => \&handler_yank,
1299     checksum => \&handler_yank,
1300 );
1301
1302 my %state = (
1303     initial => 1, # used by select_match() for 'initial_mode'
1304     handler => undef,
1305 );
1306
1307
1308
1309 # CONFIGURATION "API"
1310
1311 =head2 FUNCTIONS
1312
1313 The following functions are available:
1314
1315     color_pair($fg, $bg)
1316
1317 Create a new Curses attribute with the given fore- and background color.
1318
1319     mapping_mode_path()
1320     mapping_mode_url()
1321     mapping_mode_ip()
1322     mapping_mode_checksum()
1323     mapping_mode_search()
1324
1325     mapping_paste()
1326     mapping_paste_now()
1327     mapping_yank()
1328     mapping_yank_now()
1329     mapping_quit()
1330
1331 Used as mappings, see L</MAPPINGS> above.
1332
1333     handler_yank()
1334     handler_paste()
1335     handler_url()
1336
1337 Used as handler to yank, paste selection or open URL in browser.
1338
1339     get_regex_matches()
1340     select_match()
1341     run_command()
1342     run_in_background()
1343
1344 Helper functions when writing custom mappings, see the source and example for
1345 details.
1346
1347 Example:
1348
1349     # Enhance URL mode by updating the mapping.
1350     $config{mapping}{mode}{u} = sub {
1351         my ($key, $screen, $config, $input) = @_;
1352
1353         # First get matches of normal URL mode.
1354         my $result = mapping_mode_url(@_);
1355
1356         # Add all strings matching "CVE-1234-1234" with URLs pointing to the
1357         # Debian security tracker. "->{value}" is the string which is used as
1358         # result of the match (e.g. the URL in this case).
1359         my @matches = get_regex_matches($input, qr/\b(CVE-\d+-\d+)\b/);
1360         foreach (@matches) {
1361             $_->{value} = "https://security-tracker.debian.org/$_->{string}";
1362         }
1363         push @{$result->{matches}}, @matches;
1364
1365         # Change all YouTube links to use the custom "youtube" handler (see
1366         # below). This will allow us to automatically open YouTube URLs with a
1367         # custom program, like `youtube-dl` or `mpv`.
1368         foreach (@{$result->{matches}}) {
1369             if ($_->{string} =~ m{^https://www.youtube.com/}) {
1370                 $_->{handler} = $config{handler}{youtube};
1371             }
1372         }
1373
1374         return $result;
1375     };
1376     # Also update initial mode to use our new "URL mode".
1377     $config{setting}{initial_mode} = $config{mapping}{mode}{u};
1378
1379     # Special handler to download YouTube URLs with `youtube-dl`. You could
1380     # also use `mpv` here to immediately play them.
1381     $config{handler}{youtube} = sub {
1382         my ($screen, $config, $match) = @_;
1383
1384         return run_in_background($screen, sub {
1385             run_command($screen, ['youtube-dl', $match->{value}]);
1386         });
1387     };
1388
1389 =cut
1390
1391 # All variables and functions which are usable by ~/.fcscsrc.
1392 package Fcscs {
1393     our $screen; # "private"
1394     our %config;
1395
1396     sub color_pair { return $screen->color_pair(@_); }
1397
1398     sub mapping_mode_path { return main::mapping_mode_path(@_); }
1399     sub mapping_mode_url { return main::mapping_mode_url(@_); }
1400     sub mapping_mode_ip { return main::mapping_mode_ip(@_); }
1401     sub mapping_mode_checksum { return main::mapping_mode_checksum(@_); }
1402     sub mapping_mode_search { return main::mapping_mode_search(@_); }
1403
1404     sub mapping_paste { return main::mapping_paste(@_); }
1405     sub mapping_paste_now { return main::mapping_paste_now(@_); }
1406     sub mapping_yank { return main::mapping_yank(@_); }
1407     sub mapping_yank_now { return main::mapping_yank_now(@_); }
1408     sub mapping_quit { return main::mapping_quit(@_); }
1409
1410     sub handler_yank { return main::handler_yank(@_); }
1411     sub handler_paste { return main::handler_paste(@_); }
1412     sub handler_url { return main::handler_url(@_); }
1413
1414     sub get_regex_matches { return main::get_regex_matches(@_); }
1415     sub select_match { return main::select_match(@_); }
1416
1417     sub run_command { return main::run_command(@_); }
1418     sub run_in_background { return main::run_in_background(@_); }
1419 }
1420 $Fcscs::screen = $screen;
1421
1422
1423
1424 # LOAD USER CONFIG
1425
1426 # Alias %config and %Fcscs::config. %config is less to type.
1427 our %config;
1428 local *config = \%Fcscs::config;
1429
1430 $config{mapping}{mode}   = \%mapping_mode;
1431 $config{mapping}{simple} = \%mapping_simple;
1432 $config{attribute}       = \%attribute;
1433 $config{setting}         = \%setting;
1434 $config{regex}           = \%regex;
1435 $config{handler}         = \%handler;
1436 $config{state}           = \%state;
1437
1438 package Fcscs {
1439     my @configs = ("$ENV{HOME}/.fcscsrc",
1440                    "$ENV{HOME}/.config/fcscs/fcscsrc");
1441     foreach my $path (@configs) {
1442         my $decoded = $screen->decode($path);
1443
1444         # Load configuration file. Checks have a race condition if the home
1445         # directory is writable by an attacker (but then the user is screwed
1446         # anyway).
1447         next unless -e $path;
1448         if (not -O $path) {
1449             $screen->die("Config '$decoded' not owned by current user!");
1450         }
1451         # Make sure the file is not writable by other users. Doesn't handle
1452         # ACLs and see comment above about race conditions.
1453         my @stat = stat $path or $screen->die("Config '$decoded': $!");
1454         my $mode = $stat[2];
1455         if (($mode & Fcntl::S_IWGRP) or ($mode & Fcntl::S_IWOTH)) {
1456             $screen->die("Config '$decoded' must not be writable by other users.");
1457         }
1458
1459         my $result = do $path;
1460         if (not $result) {
1461             $screen->die("Failed to parse '$decoded': $@") if $@;
1462             $screen->die("Failed to do '$decoded': $!") unless defined $result;
1463             $screen->die("Failed to run '$decoded'.");
1464         }
1465
1466         last; # success, don't load more files
1467     }
1468 }
1469 $screen->{debug} = $config{setting}{debug};
1470
1471
1472 # MAIN
1473
1474 eval {
1475     # Auto-detect current multiplexer.
1476     if (not defined $config{setting}{multiplexer}) {
1477         if (defined $ENV{STY} and defined $ENV{TMUX}) {
1478             die 'Found both $STY and $TMUX, set $config{setting}{multiplexer}.';
1479         } elsif (defined $ENV{STY}) {
1480             $config{setting}{multiplexer} = 'screen';
1481         } elsif (defined $ENV{TMUX}) {
1482             $config{setting}{multiplexer} = 'tmux';
1483         } else {
1484             die 'No multiplexer found.';
1485         }
1486     }
1487
1488     my $binmode = $encoding;
1489     # GNU screen stores the screen dump for unknown reasons as ISO-8859-1
1490     # instead of the currently active encoding.
1491     if ($config{setting}{multiplexer} eq 'screen') {
1492         $binmode = 'ISO-8859-1';
1493     }
1494
1495     my @input_lines;
1496     open my $fh, '<', $ARGV[0] or die $!;
1497     binmode $fh, ":encoding($binmode)" or die $!;
1498     while (<$fh>) {
1499         chomp;
1500         push @input_lines, $_;
1501     }
1502     close $fh or die $!;
1503
1504     my $input = prepare_input($screen, \@input_lines);
1505
1506     # Display original screen content.
1507     my $y = 0;
1508     foreach (@{$input->{lines}}) {
1509         $screen->draw_simple($y++, 0, undef, $_);
1510     }
1511     $screen->refresh;
1512
1513
1514     my $mapping = $config{setting}{initial_mode};
1515
1516     my $key;
1517     while (1) {
1518         if (not defined $mapping) {
1519             $key = $screen->getch unless defined $key;
1520             $screen->debug('input', "got key '$key'");
1521
1522             $mapping = $config{mapping}{mode}{$key};
1523             $mapping = $config{mapping}{simple}{$key} unless defined $mapping;
1524             if (not defined $mapping) { # ignore unknown mappings
1525                 $key = undef;
1526                 next;
1527             }
1528         }
1529
1530         $screen->debug('input', 'running mapping');
1531         my $result = $mapping->($key, $screen, \%config, $input);
1532         $mapping = undef;
1533
1534 RESULT:
1535         if (defined $result->{quit}) {
1536             $screen->debug('input', 'quitting');
1537             last;
1538         }
1539         if (defined $result->{key}) {
1540             $key = $result->{key}; # lookup another mapping
1541             $screen->debug('input', "processing new key: '$key'");
1542             next;
1543         }
1544         if (defined $result->{select}) {
1545             $screen->debug('input', 'selecting match');
1546             my $tmp = $result;
1547             $result = select_match($result->{select},
1548                                    $screen, \%config, $input,
1549                                    $result->{matches});
1550             $result->{handler} = $tmp->{handler};
1551             $result->{extend}  = $tmp->{extend};
1552             goto RESULT; # reprocess special entries in result
1553         }
1554         if (defined $result->{extend}) {
1555             $screen->debug('input', 'extending match');
1556             $result = extend_match($screen, \%config, $input,
1557                                    $result->{match});
1558             goto RESULT; # reprocess special entries in result
1559         }
1560         if (defined $result->{match}) {
1561             if (not defined $result->{match}{value}) {
1562                 $result->{match}{value} = $result->{match}{string};
1563             }
1564
1565             $screen->debug('input', 'running handler');
1566
1567             # Choose handler with falling priority.
1568             my @handlers = (
1569                 $config{state}{handler},     # set by user
1570                 $result->{match}{handler},   # set by match
1571                 $result->{handler},          # set by mapping
1572                 $config{handler}{yank},      # fallback
1573             );
1574             foreach my $handler (@handlers) {
1575                 next unless defined $handler;
1576
1577                 $handler->($screen, \%config, $result->{match});
1578                 last;
1579             }
1580             last;
1581         }
1582
1583         $key = undef; # get next key from user
1584     }
1585 };
1586 if ($@) {
1587     $screen->die("$@");
1588 }
1589
1590 $screen->deinit;
1591
1592 __END__
1593
1594 =head1 EXIT STATUS
1595
1596 =over 4
1597
1598 =item B<0>
1599
1600 Success.
1601
1602 =item B<1>
1603
1604 An error occurred.
1605
1606 =item B<2>
1607
1608 Invalid arguments/options.
1609
1610 =back
1611
1612 =head1 AUTHOR
1613
1614 Simon Ruderich E<lt>simon@ruderich.orgE<gt>
1615
1616 =head1 LICENSE AND COPYRIGHT
1617
1618 Copyright (C) 2013-2016 by Simon Ruderich
1619
1620 This program is free software: you can redistribute it and/or modify
1621 it under the terms of the GNU General Public License as published by
1622 the Free Software Foundation, either version 3 of the License, or
1623 (at your option) any later version.
1624
1625 This program is distributed in the hope that it will be useful,
1626 but WITHOUT ANY WARRANTY; without even the implied warranty of
1627 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1628 GNU General Public License for more details.
1629
1630 You should have received a copy of the GNU General Public License
1631 along with this program.  If not, see E<lt>http://www.gnu.org/licenses/E<gt>.
1632
1633 =head1 SEE ALSO
1634
1635 L<screen(1)>, L<tmux(1)>, L<urlview(1)>
1636
1637 =cut