+# Arguments missing.
+if (scalar @ARGV == 0) {
+ require Pod::Usage;
+ Pod::Usage::pod2usage(2);
+}
+
+# Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
+# installed on Debian's buildds.
+if (not $option_buildd) {
+ require Term::ANSIColor;
+}
+
+if ($option_all) {
+ $option_pie = 1;
+ $option_bindnow = 1;
+}
+
+# Precompiled ignores for faster lookup.
+my %option_ignore_arch_flag = ();
+my %option_ignore_arch_line = ();
+
+# Strip flags which should be ignored.
+if (scalar @option_ignore_flag > 0) {
+ remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
+}
+# Same for arch specific ignore flags, but only prepare here.
+if (scalar @option_ignore_arch_flag > 0) {
+ foreach my $ignore (@option_ignore_arch_flag) {
+ my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
+
+ if (not $ignore_arch or not $ignore_flag) {
+ printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
+ . '("arch:flag" expected)' . "\n", $ignore;
+ require Pod::Usage;
+ Pod::Usage::pod2usage(2);
+ }
+
+ push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
+ }
+}
+
+# Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
+# faster with this.
+foreach my $flags (@flag_refs_all) {
+ @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
+}
+
+# Precompile ignore line regexps, also anchor at beginning and end of line.
+foreach my $ignore (@option_ignore_line) {
+ $ignore = qr/^$ignore$/;
+}
+# Same for arch specific ignore lines.
+if (scalar @option_ignore_arch_line > 0) {
+ foreach my $ignore (@option_ignore_arch_line) {
+ my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
+
+ if (not $ignore_arch or not $ignore_line) {
+ printf STDERR 'Value "%s" invalid for option ignore-arch-line '
+ . '("arch:line" expected)' . "\n", $ignore;
+ require Pod::Usage;
+ Pod::Usage::pod2usage(2);
+ }
+
+ push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
+ }
+}
+
+# Final exit code.
+my $exit = 0;
+
+FILE:
+foreach my $file (@ARGV) {
+ print "checking '$file'...\n" if scalar @ARGV > 1;
+
+ -f $file or die "No such file: $file";
+
+ open my $fh, '<', $file or die $!;
+
+ # Architecture of this file.
+ my $arch = $option_arch;
+
+ # Hardening options. Not all architectures support all hardening options.
+ my $harden_format = 1;
+ my $harden_fortify = 1;
+ my $harden_stack = 1;
+ my $harden_stack_strong = 1;
+ my $harden_relro = 1;
+ my $harden_bindnow = $option_bindnow; # defaults to 0
+ my $harden_pie = $option_pie; # defaults to 0
+
+ # Does this build log use ada? Ada also uses gcc as compiler but uses
+ # different CFLAGS. But only perform ada checks if an ada compiler is used
+ # for performance reasons.
+ my $ada = 0;
+
+ # Number of parallel jobs to prevent false positives when detecting
+ # non-verbose builds. As not all jobs declare the number of parallel jobs
+ # use a large enough default.
+ my $parallel = 10;
+
+ while (my $line = <$fh>) {
+ # Detect architecture automatically unless overridden. For buildd logs
+ # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
+ # build logs which aren't built (wrong architecture, build error,
+ # etc.).
+ if (not $arch) {
+ if (index($line, 'Build Architecture: ') == 0) {
+ $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
+ # For old logs (sbuild << 0.63.0-1).
+ } elsif (index($line, 'Architecture: ') == 0) {
+ $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
+ }
+ }
+
+ # dpkg-buildflags only provides hardening flags since 1.16.1, don't
+ # check for hardening flags in buildd mode if an older dpkg-dev is
+ # used. Default flags (-g -O2) are still checked.
+ #
+ # Packages which were built before 1.16.1 but used their own hardening
+ # flags are not checked.
+ #
+ # Strong stack protector is used since dpkg 1.17.11.
+ if ($option_buildd
+ and index($line, 'Toolchain package versions: ') == 0) {
+ require Dpkg::Version;
+
+ my $disable = 1;
+ my $disable_strong = 1;
+
+ if ($line =~ /\bdpkg-dev_(\S+)/) {
+ if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
+ $disable = 0;
+ }
+ if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
+ $disable_strong = 0;
+ }
+ }
+
+ if ($disable) {
+ $harden_format = 0;
+ $harden_fortify = 0;
+ $harden_stack = 0;
+ $harden_relro = 0;
+ $harden_bindnow = 0;
+ $harden_pie = 0;
+ }
+ if ($disable_strong) {
+ $harden_stack_strong = 0;
+ }
+ }
+
+ # The following two versions of CMake in Debian obeyed CPPFLAGS, but
+ # this was later dropped because upstream rejected the patch. Thus
+ # build logs with these versions will have fortify hardening flags
+ # enabled, even though they may be not correctly set and are missing
+ # when build with later CMake versions. Thanks to Aron Xu for letting
+ # me know.
+ if (index($line, 'Package versions: ') == 0
+ and $line =~ /\bcmake_(\S+)/
+ and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
+ if (not $option_buildd) {
+ error_invalid_cmake($1);
+ $exit |= $exit_code{invalid_cmake};
+ } else {
+ print "$buildd_tag{invalid_cmake}|$1|\n";
+ }
+ }
+
+ # Debian's build daemons use "Filtered Build-Depends:" (or just
+ # "Build-Depends:" in older versions) for the build dependencies, but
+ # pbuilder uses "Depends:"; support both.
+ if (index($line, 'Filtered Build-Depends: ') == 0
+ or index($line, 'Build-Depends: ') == 0
+ or index($line, 'Depends: ') == 0) {
+ # If hardening wrapper is used (wraps calls to gcc and adds
+ # hardening flags automatically) we can't perform any checks,
+ # abort.
+ if ($line =~ /\bhardening-wrapper\b/) {
+ if (not $option_buildd) {
+ error_hardening_wrapper();
+ $exit |= $exit_code{hardening_wrapper};
+ } else {
+ print "$buildd_tag{hardening_wrapper}||\n";
+ }
+ next FILE;
+ }
+
+ # Ada compiler.
+ if ($line =~ /\bgnat\b/) {
+ $ada = 1;
+ }
+ }
+
+ # This flags is not always available, but if it is use it.
+ if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
+ $parallel = $1;
+ }
+
+ # We skip over unimportant lines at the beginning of the log to
+ # prevent false positives.
+ last if index($line, 'dpkg-buildpackage: ') == 0;
+ }
+
+ # Input lines, contain only the lines with compiler commands.
+ my @input = ();
+ # Non-verbose lines in the input. Used to reduce calls to
+ # is_non_verbose_build() (which is quite slow) in the second loop when
+ # it's already clear if a line is non-verbose or not.
+ my @input_nonverbose = ();
+
+ my $continuation = 0;
+ my $complete_line = undef;
+ my $non_verbose;
+ while (my $line = <$fh>) {
+ # And stop at the end of the build log. Package details (reported by
+ # the buildd logs) are not important for us. This also prevents false
+ # positives.
+ last if index($line, 'Build finished at ') == 0
+ and $line =~ /^Build finished at \d{8}-\d{4}$/;
+
+ if (not $continuation) {
+ $non_verbose = 0;
+ }
+
+ # Detect architecture automatically unless overridden.
+ if (not $arch
+ and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
+ $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
+
+ # Old buildd logs use e.g. "host architecture is alpha", remove
+ # the "is", otherwise debarch_to_debtriplet() will not detect the
+ # architecture.
+ if (index($arch, 'is ') == 0) {
+ $arch = substr $arch, 3;
+ }
+ }
+
+ next if $line =~ /^\s*#/;
+ # Ignore compiler warnings for now.
+ next if $line =~ /$warning_regex/o;
+
+ if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
+ # Remove all ANSI color sequences which are sometimes used in
+ # non-verbose builds.
+ $line = Term::ANSIColor::colorstrip($line);
+ # Also strip '\0xf' (delete previous character), used by Elinks'
+ # build system.
+ $line =~ s/\x0f//g;
+ # And "ESC(B" which seems to be used on armhf and hurd (not sure
+ # what it does).
+ $line =~ s/\033\(B//g;
+ }
+
+ # Check if this line indicates a non verbose build.
+ my $skip = 0;
+ $non_verbose |= is_non_verbose_build($line, \$skip);
+ next if $skip;
+
+ # One line may contain multiple commands (";"). Treat each one as
+ # single line. parse_line() is slow, only use it when necessary.
+ my @line = (index($line, ';') == -1)
+ ? ($line)
+ : map {
+ # Ensure newline at the line end - necessary for
+ # correct parsing later.
+ $_ =~ s/\s+$//;
+ $_ .= "\n";
+ } Text::ParseWords::parse_line(';', 1, $line);
+ foreach my $line (@line) {
+ if ($continuation) {
+ $continuation = 0;
+
+ # Join lines, but leave the "\" in place so it's clear where
+ # the original line break was.
+ chomp $complete_line;
+ $complete_line .= ' ' . $line;
+ }
+ # Line continuation, line ends with "\".
+ if ($line =~ /\\$/) {
+ $continuation = 1;
+ # Start line continuation.
+ if (not defined $complete_line) {
+ $complete_line = $line;
+ }
+ next;
+ }
+
+ # Use the complete line if a line continuation occurred.
+ if (defined $complete_line) {
+ $line = $complete_line;
+ $complete_line = undef;
+ }
+
+ # Ignore lines with no compiler commands.
+ next if not $non_verbose
+ and not $line =~ /$cc_regex_normal/o;
+ # Ignore lines with no filenames with extensions. May miss some
+ # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
+ # a problem as the log will most likely contain other non-verbose
+ # commands which are detected.
+ next if not $non_verbose
+ and not $line =~ /$file_extension_regex/o;
+
+ # Ignore false positives.
+ #
+ # `./configure` output.
+ next if not $non_verbose
+ and $line =~ /^(?:checking|[Cc]onfigure:) /;
+ next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
+ [Cc]ompiler[\s.]*:?\s+
+ /x;
+ next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
+ \s*=\s*$cc_regex_full
+ # optional compiler options, don't allow
+ # "everything" here to prevent false negatives
+ \s*(?:\s-\S+)*\s*$}xo;
+ # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
+ # line (or similar for other architectures) which gets recognized
+ # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
+ # C++ files. No hardening flags are relevant during this step,
+ # thus ignore `moc-qt*` lines. The resulting files will be
+ # compiled in a separate step (and therefore checked).
+ next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
+ \s.+\s
+ -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
+ \s}x;
+ # Ignore false positives when the line contains only CC=gcc but no
+ # other gcc command.
+ if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
+ my $before = $1;
+ my $after = $2;
+ next if not $before =~ /$cc_regex_normal/o
+ and not $after =~ /$cc_regex_normal/o;
+ }
+ # Ignore false positives caused by gcc -v. It outputs a line
+ # looking like a normal compiler line but which is sometimes
+ # missing hardening flags, although the normal compiler line
+ # contains them.
+ next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
+ [0-9.]+/cc1(?:plus)?}xo;
+ # Ignore false positive with `rm` which may remove files which
+ # look like a compiler executable thus causing the line to be
+ # treated as a normal compiler line.
+ next if $line =~ m{^\s*rm\s+};
+ # Some build systems emit "gcc > file".
+ next if $line =~ m{$cc_regex_normal\s*>\s*\S+};
+
+ # Check if additional hardening options were used. Used to ensure
+ # they are used for the complete build.
+ $harden_pie = 1 if any_flags_used($line, @def_cflags_pie,
+ @def_ldflags_pie);
+ $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
+
+ push @input, $line;
+ push @input_nonverbose, $non_verbose;
+ }
+ }
+
+ close $fh or die $!;
+
+ # Ignore arch if requested.
+ if (scalar @option_ignore_arch > 0 and $arch) {
+ foreach my $ignore (@option_ignore_arch) {
+ if ($arch eq $ignore) {
+ print "ignoring architecture '$arch'\n";
+ next FILE;
+ }
+ }
+ }
+
+ if (scalar @input == 0) {
+ if (not $option_buildd) {
+ print "No compiler commands!\n";
+ $exit |= $exit_code{no_compiler_commands};
+ } else {
+ print "$buildd_tag{no_compiler_commands}||\n";
+ }
+ next FILE;
+ }
+
+ if ($option_buildd) {
+ $statistics{commands} += scalar @input;
+ }
+
+ # Option or auto detected.
+ if ($arch) {
+ # The following was partially copied from dpkg-dev 1.18.15
+ # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, _add_hardening_flags()),
+ # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
+ # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
+ # later. Keep it in sync.
+
+ require Dpkg::Arch;
+ my ($os, $cpu);
+ # Recent dpkg versions use a quadruplet for arch. Support both.
+ eval {
+ (undef, undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtuple($arch);
+ };
+ if ($@) {
+ (undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
+ }
+
+ # Disable unsupported hardening options.
+ if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/
+ or $cpu =~ /^(?:hppa|avr32)$/) {
+ $harden_pie = 0;
+ }
+ if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
+ $harden_stack = 0;
+ $harden_stack_strong = 0;
+ }
+ if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
+ $harden_relro = 0;
+ $harden_bindnow = 0;
+ }
+ }
+
+ # Default values.
+ my @cflags = @def_cflags;
+ my @cxxflags = @def_cxxflags;
+ my @cppflags = @def_cppflags;
+ my @ldflags = @def_ldflags;
+ # Check the specified hardening options, same order as dpkg-buildflags.
+ if ($harden_pie) {
+ @cflags = (@cflags, @def_cflags_pie);
+ @cxxflags = (@cxxflags, @def_cflags_pie);
+ @ldflags = (@ldflags, @def_ldflags_pie);
+ }
+ if ($harden_stack_strong) {
+ @cflags = (@cflags, @def_cflags_stack_strong);
+ @cxxflags = (@cxxflags, @def_cflags_stack_strong);
+ } elsif ($harden_stack) {
+ @cflags = (@cflags, @def_cflags_stack);
+ @cxxflags = (@cxxflags, @def_cflags_stack);
+ }
+ if ($harden_fortify) {
+ @cflags = (@cflags, @def_cflags_fortify);
+ @cxxflags = (@cxxflags, @def_cflags_fortify);
+ @cppflags = (@cppflags, @def_cppflags_fortify);
+ }
+ if ($harden_format) {
+ @cflags = (@cflags, @def_cflags_format);
+ @cxxflags = (@cxxflags, @def_cflags_format);
+ }
+ if ($harden_relro) {
+ @ldflags = (@ldflags, @def_ldflags_relro);
+ }
+ if ($harden_bindnow) {
+ @ldflags = (@ldflags, @def_ldflags_bindnow);
+ }
+
+ # Stores normal CFLAGS when @cflags_ada are temporarily used.
+ my @cflags_backup;
+ # Ada CFLAGS, only set if ada is used.
+ my @cflags_ada;
+ # Ada doesn't support format hardening flags, see #680117 for more
+ # information. Filter them out if ada is used.
+ if ($ada and $harden_format) {
+ @cflags_ada = grep {
+ my $ok = 1;
+ foreach my $flag (@def_cflags_format) {
+ $ok = 0 if $_ eq $flag;
+ }
+ $ok;
+ } @cflags;
+ }
+
+ # Hack to fix cppflags_fortify_broken() if --ignore-flag
+ # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
+ # as long as @def_cppflags_fortify contains only one variable.
+ if (scalar @def_cppflags_fortify == 0) {
+ $harden_fortify = 0;
+ }
+
+ # Ignore flags for this arch if requested.
+ if ($arch and exists $option_ignore_arch_flag{$arch}) {
+ my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
+
+ remove_flags(\@local_flag_refs,
+ \%flag_renames,
+ @{$option_ignore_arch_flag{$arch}});
+ }
+
+ my @ignore_line = @option_ignore_line;
+ # Ignore lines for this arch if requested.
+ if ($arch and exists $option_ignore_arch_line{$arch}) {
+ @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
+ }
+
+LINE:
+ for (my $i = 0; $i < scalar @input; $i++) {
+ my $line = $input[$i];
+
+ # Ignore line if requested.
+ foreach my $ignore (@ignore_line) {
+ next LINE if $line =~ /$ignore/;
+ }
+
+ my $skip = 0;
+ if ($input_nonverbose[$i]
+ and is_non_verbose_build($line, \$skip,
+ \@input, $i, $parallel)) {
+ if (not $option_buildd) {
+ error_non_verbose_build($line);
+ $exit |= $exit_code{non_verbose_build};
+ } else {
+ $statistics{commands_nonverbose}++;
+ }
+ next;
+ }
+ # Even if it's a verbose build, we might have to skip this line (see
+ # is_non_verbose_build()).
+ next if $skip;
+
+ my $orig_line = $line;
+
+ # Remove everything until and including the compiler command. Makes
+ # checks easier and faster.
+ $line =~ s/^.*?$cc_regex//o;
+ # "([...] test.c)" is not detected as 'test.c' - fix this by removing
+ # the brace and similar characters at the line end.
+ $line =~ s/['")]+$//;
+
+ # Skip unnecessary tests when only preprocessing.
+ my $flag_preprocess = 0;
+
+ my $dependency = 0;
+ my $preprocess = 0;
+ my $compile = 0;
+ my $link = 0;
+
+ # Preprocess, compile, assemble.
+ if ($line =~ /\s(-E|-S|-c)\b/) {
+ $preprocess = 1;
+ $flag_preprocess = 1 if $1 eq '-E';
+ $compile = 1 if $1 eq '-S' or $1 eq '-c';
+ # Dependency generation for Makefiles. The other flags (-MF -MG -MP
+ # -MT -MQ) are always used with -M/-MM.
+ } elsif ($line =~ /\s(?:-M|-MM)\b/) {
+ $dependency = 1;
+ # Otherwise assume we are linking.
+ } else {
+ $link = 1;
+ }
+
+ # -MD/-MMD also cause dependency generation, but they don't imply -E!
+ if ($line =~ /\s(?:-MD|-MMD)\b/) {
+ $dependency = 0;
+ $flag_preprocess = 0;
+ }
+
+ # Dependency generation for Makefiles, no preprocessing or other flags
+ # needed.
+ next if $dependency;
+
+ # Get all file extensions on this line.
+ my @extensions = $line =~ /$file_extension_regex/go;
+ # Ignore all unknown extensions to speedup the search below.
+ @extensions = grep { exists $extension{$_} } @extensions;
+
+ # These file types don't require preprocessing.
+ if (extension_found(\%extensions_no_preprocess, @extensions)) {
+ $preprocess = 0;
+ }
+ # These file types require preprocessing.
+ if (extension_found(\%extensions_preprocess, @extensions)) {
+ # Prevent false positives with "libtool: link: g++ -include test.h
+ # .." compiler lines.
+ if ($orig_line !~ /$libtool_link_regex/o) {
+ $preprocess = 1;
+ }
+ }
+
+ if (not $flag_preprocess) {
+ # If there are source files then it's compiling/linking in one
+ # step and we must check both. We only check for source files
+ # here, because header files cause too many false positives.
+ if (extension_found(\%extensions_compile_link, @extensions)) {
+ # Assembly files don't need CFLAGS.
+ if (not extension_found(\%extensions_compile, @extensions)
+ and extension_found(\%extensions_no_compile, @extensions)) {
+ $compile = 0;
+ # But the rest does.
+ } else {
+ $compile = 1;
+ }
+ # No compilable extensions found, either linking or compiling
+ # header flags.
+ #
+ # If there are also no object files we are just compiling headers
+ # (.h -> .h.gch). Don't check for linker flags in this case. Due
+ # to our liberal checks for compiler lines, this also reduces the
+ # number of false positives considerably.
+ } elsif ($link
+ and not extension_found(\%extensions_object, @extensions)) {
+ $link = 0;
+ }
+ }
+
+ my $compile_cpp = 0;
+ my $compile_ada = 0;
+ # Assume CXXFLAGS are required when a C++ file is specified in the
+ # compiler line.
+ if ($compile
+ and extension_found(\%extensions_compile_cpp, @extensions)) {
+ $compile = 0;
+ $compile_cpp = 1;
+ # Ada needs special CFLAGS, use them if only ada files are compiled.
+ } elsif ($ada
+ and extension_found(\%extensions_ada, @extensions)) {
+ $compile_ada = 1;
+ $preprocess = 0; # Ada uses no CPPFLAGS
+ @cflags_backup = @cflags;
+ @cflags = @cflags_ada;
+ }
+
+ if ($option_buildd) {
+ $statistics{preprocess}++ if $preprocess;
+ $statistics{compile}++ if $compile;
+ $statistics{compile_cpp}++ if $compile_cpp;
+ $statistics{link}++ if $link;
+ }
+
+ # Check if there are flags indicating a debug build. If that's true,
+ # skip the check for -O2. This prevents fortification, but that's fine
+ # for a debug build.
+ if (any_flags_used($line, @def_cflags_debug)) {
+ remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
+ remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
+ }
+
+ # Check hardening flags.
+ my @missing;
+ if ($compile and not all_flags_used($line, \@missing, @cflags)
+ # Libraries linked with -fPIC don't have to (and can't) be
+ # linked with -fPIE as well. It's no error if only PIE flags
+ # are missing.
+ and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
+ # Assume dpkg-buildflags returns the correct flags.
+ and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
+ if (not $option_buildd) {
+ error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
+ $exit |= $exit_code{flags_missing};
+ } else {
+ $statistics{compile_missing}++;
+ }
+ } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
+ # Libraries linked with -fPIC don't have to (and can't) be
+ # linked with -fPIE as well. It's no error if only PIE flags
+ # are missing.
+ and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
+ # Assume dpkg-buildflags returns the correct flags.
+ and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
+ if (not $option_buildd) {
+ error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
+ $exit |= $exit_code{flags_missing};
+ } else {
+ $statistics{compile_cpp_missing}++;
+ }
+ }
+ if ($preprocess
+ and (not all_flags_used($line, \@missing, @cppflags)
+ # The fortify flag might be overwritten, detect that.
+ or ($harden_fortify
+ and cppflags_fortify_broken($line, \@missing)))
+ # Assume dpkg-buildflags returns the correct flags.
+ and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
+ if (not $option_buildd) {
+ error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
+ $exit |= $exit_code{flags_missing};
+ } else {
+ $statistics{preprocess_missing}++;
+ }
+ }
+ if ($link and not all_flags_used($line, \@missing, @ldflags)
+ # Same here, -fPIC conflicts with -fPIE.
+ and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
+ # Assume dpkg-buildflags returns the correct flags.
+ and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
+ if (not $option_buildd) {
+ error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
+ $exit |= $exit_code{flags_missing};
+ } else {
+ $statistics{link_missing}++;
+ }
+ }
+
+ # Restore normal CFLAGS.
+ if ($compile_ada) {
+ @cflags = @cflags_backup;
+ }
+ }
+}
+
+# Print statistics for buildd mode, only output in this mode.
+if ($option_buildd) {
+ my @warning;
+
+ if ($statistics{preprocess_missing}) {
+ push @warning, sprintf 'CPPFLAGS %d (of %d)',
+ $statistics{preprocess_missing},
+ $statistics{preprocess};
+ }
+ if ($statistics{compile_missing}) {
+ push @warning, sprintf 'CFLAGS %d (of %d)',
+ $statistics{compile_missing},
+ $statistics{compile};
+ }
+ if ($statistics{compile_cpp_missing}) {
+ push @warning, sprintf 'CXXFLAGS %d (of %d)',
+ $statistics{compile_cpp_missing},
+ $statistics{compile_cpp};
+ }
+ if ($statistics{link_missing}) {
+ push @warning, sprintf 'LDFLAGS %d (of %d)',
+ $statistics{link_missing},
+ $statistics{link};
+ }
+ if (scalar @warning) {
+ local $" = ', '; # array join string
+ print "$buildd_tag{flags_missing}|@warning missing|\n";
+ }
+
+ if ($statistics{commands_nonverbose}) {
+ printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
+ $statistics{commands_nonverbose},
+ $statistics{commands},
+ }
+}
+
+
+exit $exit;
+