+# Complete arguments and fix spelling mistakes when possible.
+zstyle ':completion:*' completer _complete _match _correct _approximate
+
+# Make sure the list of possible completions is displayed after pressing <TAB>
+# the first time.
+setopt nolistambiguous
+# Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
+# completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
+bindkey '^I' expand-or-complete-prefix
+# Try uppercase if the currently typed string doesn't match. This allows
+# typing in lowercase most of the time and completion fixes the case.
+zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
+
+# Use ls like colors for completions.
+zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
+
+# Make completion lists scrollable so "do you wish to see all n possibilities"
+# is no longer displayed.
+zstyle ':completion:*' list-prompt '%p'
+# Display group name (like 'external command', 'alias', etc.) when there are
+# multiple matches in bold.
+zstyle ':completion:*' format ' %B%d%b:'
+# Display different types of matches separately.
+zstyle ':completion:*' group-name ''
+
+# Ignore completion functions.
+zstyle ':completion:*:functions' ignored-patterns '_*'
+# Ignore parent directory.
+zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
+# Always complete one value (file name) only once in the current line. This
+# makes it easy to complete multiple values because I can just press tab to
+# get all possible values. Otherwise I would have to skip the first value
+# again and again.
+zstyle ':completion:*' ignore-line yes
+# Except for mv and cp, because I often want to use to similar names, so I
+# complete to the same and change it.
+zstyle ':completion:*:(mv|cp):*' ignore-line no
+
+
+# CUSTOM ALIASES AND FUNCTIONS
+
+# If ^C is pressed while typing a command, add it to the history so it can be
+# easily retrieved later and then abort like ^C normally does. This is useful
+# when I want to abort an command to do something in between and then finish
+# typing the command.
+#
+# Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
+# starting with - don't cause errors; and to Nadav Har'El
+# <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
+# correctly, both on the Zsh mailing list.
+TRAPINT() {
+ # Store the current buffer in the history.
+ zle && print -s -r -- $BUFFER
+
+ # Return the default exit code so Zsh aborts the current command.
+ return $1
+}
+
+# Colorize stderr. Very useful when looking for errors. Thanks to
+# http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
+# Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
+# perfect and doesn't work with su and git for example, but it can handle most
+# interactive output quite well (even with no trailing new line) and in those
+# cases the E alias can be used as workaround.
+exec 2>>(while read -r -k -u 0 line; do
+ printf '\e[91m%s\e[0m' "$line";
+ print -n $'\0';
+done &)
+
+# Load aliases and similar functions also used by other shells.
+if [[ -f ~/.shell/aliases ]]; then
+ . ~/.shell/aliases
+fi
+
+# Make sure aliases are expanded when using sudo.
+alias sudo='sudo '
+
+# Global aliases for often used commands in the command line.
+alias -g E='2>&1'
+alias -g L='E | less'
+alias -g D='E | colordiff L'
+alias -g G='| grep'
+alias -g S='| sort'
+alias -g U='| uniq'
+alias -g H='| head'
+alias -g T='| tail'
+
+# Make going up directories simple.
+alias -g ...='../..'
+alias -g ....='../../..'
+alias -g .....='../../../..'
+
+# If the window naming feature is used (see above) then use ".zsh" (leading
+# dot) as title name after running clear so it's clear to me that the window
+# is empty. I open so much windows that I don't know in which I have something
+# important. This helps me to remember which windows are empty (I run clear
+# after I finished my work in a window).
+if [[ -n $window_reset ]]; then
+ alias clear='clear; window_reset=yes; window_precmd reset'
+fi
+
+# Display all branches (except stash) in gitk but only 200 commits as this is
+# much faster. Also put in the background and disown. Thanks to sitaram in
+# #git on Freenode (2009-04-20 15:51).
+gitk() {
+ command gitk \
+ --max-count=200 \
+ $(git rev-parse --symbolic-full-name --remotes --branches) \
+ $@ &
+ disown %command
+}
+# Same for tig (except the disown part as it's no GUI program).
+tig() {
+ command tig \
+ --max-count=200 \
+ $(git rev-parse --symbolic-full-name --remotes --branches) \
+ $@
+}
+
+
+# OS SPECIFIC SETTINGS
+
+local uname=$(uname)
+
+if [[ $uname == Linux ]]; then
+ # Settings when creating Debian packages.
+ DEBEMAIL=simon@ruderich.org
+ export DEBEMAIL
+ DEBFULLNAME='Simon Ruderich'
+ export DEBFULLNAME
+
+elif [[ $uname == Darwin ]]; then # Mac OS X
+ # Store the current clipboard in CLIPBOARD before every command so it can
+ # be used in commands.
+ os_darwin_preexec() {
+ export CLIPBOARD="$(pbpaste)"
+ }
+ # Add the function as preexec hook.
+ add-zsh-hook preexec os_darwin_preexec
+
+ # Initialize CLIPBOARD so it's available for completion directly after
+ # startup.
+ CLIPBOARD=""
+ export CLIPBOARD
+
+ # Fetch current URL in clipboard with wget.
+ alias wnc='wget --no-proxy $CLIPBOARD'
+fi
+
+
+# LOAD ADDITIONAL CONFIGURATION FILES
+
+# Load rc file for current hostname (first part before a dot) or rc.local.
+source_config ~/.zsh host rc ${$(hostname)//.*/}
+
+
+# RUN COMMANDS
+
+# If not already in screen reattach to a running session or create a new one.
+# This also starts screen one a remote server when connecting through ssh.
+if [[ $TERM != dumb && -z $STY ]]; then
+ # Get running detached sessions.
+ session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
+
+ # As we exec later we have to set the title here.
+ window_preexec "screen"
+
+ # Create a new session if none is running.
+ if [[ -z $session ]]; then
+ exec screen
+ # Reattach to a running session.
+ else
+ exec screen -r $session
+ fi
+fi
+
+
+source_debug "finished sourcing ~/.zsh/rc"
+
+# vim: ft=zsh