+# Colorize stderr in bold red. Very useful when looking for errors. Thanks to
+# http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
+# Freenode (2010-03-07 04:03 CET) for some improvements (-r, printf). It's not
+# yet perfect and doesn't work with su and git for example, but it can handle
+# most interactive output quite well (even with no trailing new line) and in
+# cases it doesn't work, the E alias can be used as workaround.
+#
+# Moved in the "run commands" section to prevent one unnecessary zsh process
+# when starting GNU screen/tmux (see above).
+exec 2>>(while read -r -k -u 0 line; do
+ printf '\e[91m%s\e[0m' "$line"
+ print -n $'\0'
+done &)
+
+# Display possible log messages from ~/.xinitrc (if `xmessage` wasn't
+# installed). No race condition as xinitrc has finished before a shell is
+# executed and only one shell is started on login.
+if [[ -f ~/.xinitrc.errors ]]; then
+ echo "${fg_bold[red]}xinitrc failed!${fg_bold[default]}"
+ echo
+ cat ~/.xinitrc.errors
+ rm ~/.xinitrc.errors
+ echo
+fi
+
+# Run the following programs every 4 hours (and when zsh starts).
+PERIOD=14400
+periodic() {
+ # Display fortunes.
+ (( $+commands[fortune] )) && fortune -ac "${zshrc_fortune_arguments[@]}"
+ # Display reminders.
+ (( $+commands[rem] )) && [[ -f ~/.reminders ]] && rem -h
+}
+
+
+# RESTART SETTINGS
+
+zmodload -F zsh/stat b:zstat
+
+# Remember startup time. Used to perform automatic restarts when ~/.zshrc is
+# modified.
+zshrc_startup_time=$EPOCHSECONDS
+
+# Automatically restart Zsh if ~/.zshrc was modified.
+zshrc_restart_precmd() {
+ local stat
+ if ! zstat -A stat +mtime ~/.zshrc; then
+ return
+ fi
+
+ # ~/.zshrc wasn't modified, nothing to do.
+ if [[ $stat -le $zshrc_startup_time ]]; then
+ return
+ fi
+
+ local startup
+ strftime -s startup '%Y-%m-%d %H:%M:%S' "$zshrc_startup_time"
+
+ echo -n "${fg[magenta]}"
+ echo -n "~/.zshrc modified since startup ($startup) ... "
+ echo -n "${fg[default]}"
+
+ if [[ -n $zshrc_disable_restart ]]; then
+ echo 'automatic restart disabled.'
+ return
+ fi
+
+ # Don't exec if we have background processes because execing will let us
+ # lose control over them.
+ if [[ ${#${(k)jobstates}} -ne 0 ]]; then
+ echo 'active background jobs!'
+ return
+ fi
+
+ # Try to start a new interactive shell. If it fails, something is wrong.
+ # Don't kill our current session by execing it.
+ zsh -i -c 'exit 42'
+ if [[ $? -ne 42 ]]; then
+ echo -n "${fg_bold[red]}"
+ echo 'failed to start new zsh!'
+ echo -n "${fg_bold[default]}"
+ return
+ fi
+
+ echo 'restarting zsh.'
+ echo
+
+ exec zsh
+}
+precmd_functions+=(zshrc_restart_precmd)
+