+# When screen is used set the name of the window to the currently running
+# program.
+#
+# When a program is started preexec() sets the window's name to it; when it
+# stops precmd() resets the windows' name to 'zsh'.
+if [[ $TERM == screen ]]; then
+ # Set to a non empty value to reset the window name in the next precmd()
+ # call.
+ screen_name_reset=yes
+
+ screen_preexec() {
+ # Get the program name with its arguments.
+ local program_name=$1
+ # When sudo is used use real program name instead.
+ if [[ $program_name == sudo* ]]; then
+ program_name=${program_name#sudo }
+ fi
+ # Remove all arguments from the program name.
+ program_name=${program_name%% *}
+
+ # Ignore often used commands which are only running for a very short
+ # time. This prevents a "blinking" name when it's changed to "cd" for
+ # example and then some milliseconds later back to "zsh".
+ [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
+
+ # Change my shortcuts so the real name of the program is displayed.
+ case $program_name in
+ e)
+ program_name=elinks
+ ;;
+ g)
+ program_name=git
+ ;;
+ m)
+ program_name=mutt
+ ;;
+ v|vi)
+ program_name=vim
+ ;;
+ esac
+
+ # Set the window name to the currently running program.
+ print -n "\ek$program_name\e\\"
+
+ # Tell precmd() to reset the window name when the program stops.
+ screen_name_reset=yes
+ }
+
+ screen_precmd() {
+ # Abort if no window name reset is necessary.
+ [[ -z $screen_name_reset ]] && return
+
+ # Reset the window name to 'zsh'.
+ print -n "\ekzsh\e\\"
+
+ # Just reset the name, so no screen reset necessary for the moment.
+ screen_name_reset=
+ }
+
+ # Add the preexec() and precmd() hooks.
+ add-zsh-hook preexec screen_preexec
+ add-zsh-hook precmd screen_precmd
+fi