+# code in red and bold and the job count in yellow.
+PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
+%(1j.$yellow%j$default.)%# \
+%(?..($red%B%?%b$default%) )"
+
+unset red blue green yellow default
+
+# When screen, xterm or rxvt is used set the name of the window to the
+# currently running program.
+#
+# When a program is started preexec() sets the window's name to it; when it
+# stops precmd() resets the window's name to 'zsh'.
+#
+# It works with screen, xterm and rxvt.
+#
+# If a command is run with sudo or if the shell is running as root then a ! is
+# added at the beginning of the command to make this clear. If a command is
+# running on a different computer with ssh a @ is added at the beginning. If
+# screen is running on the remote machine instead of @screen @:hostname
+# (hostname replaced by the machine's hostname) is displayed. This only works
+# if the .zshrc on the server also uses this command.
+#
+# screen* is necessary as `screen` uses screen.linux for example for a linux
+# console.
+if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
+ # Is set to a non empty value to reset the window name in the next
+ # precmd() call.
+ window_reset=yes
+ # Is set to a non empty value when the shell is running as root.
+ if [[ $(id -u) -eq 0 ]]; then
+ window_root=yes
+ fi
+
+ window_preexec() {
+ # Get the program name with its arguments.
+ local program_name=$1
+
+ # When sudo is used use real program name instead, but with an
+ # exclamation mark at the beginning (handled below).
+ local program_sudo=
+ if [[ $program_name == sudo* ]]; then
+ program_name=${program_name#sudo }
+ program_sudo=yes
+ fi
+ # Remove all arguments from the program name.
+ program_name=${program_name%% *}
+
+ # Ignore often used commands which are only running for a very short
+ # time. This prevents a "blinking" name when it's changed to "cd" for
+ # example and then some milliseconds later back to "zsh".
+ [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
+
+ # Change my shortcuts so the real name of the program is displayed.
+ case $program_name in
+ e)
+ program_name=elinks
+ ;;
+ g)
+ program_name=git
+ ;;
+ m)
+ program_name=mutt
+ ;;
+ v)
+ program_name=vim
+ ;;
+ esac
+
+ # Add an exclamation mark at the beginning if running with sudo or if
+ # running zsh as root.
+ if [[ -n $program_sudo || -n $window_root ]]; then
+ program_name=!$program_name
+ fi
+
+ # Add an at mark at the beginning if running through ssh on a
+ # different computer.
+ if [[ -n $SSH_CONNECTION ]]; then
+ program_name="@$program_name"
+
+ # If screen is running in SSH then display "@:hostname" as title
+ # in the term/outer screen.
+ if [[ $program_name == @screen ]]; then
+ program_name="@:${$(hostname)//.*/}"
+ fi
+ fi
+
+ # Set the window name to the currently running program.
+ window_title "$program_name"
+
+ # Tell precmd() to reset the window name when the program stops.
+ window_reset=yes
+ }
+
+ window_precmd() {
+ # Abort if no window name reset is necessary.
+ [[ -z $window_reset ]] && return
+
+ # Reset the window name to 'zsh'.
+ local name=zsh
+ # If the function was called with an argument then reset the window
+ # name to '.zsh' (used by clear alias).
+ if [[ -n $1 ]]; then
+ name=.zsh
+ fi
+
+ # Prepend prefixes like in window_preexec().
+ if [[ -n $window_root ]]; then
+ name="!$name"
+ fi
+ if [[ -n $SSH_CONNECTION ]]; then
+ name="@$name"
+ fi
+ window_title $name
+
+ # Just reset the name, so no screen reset necessary for the moment.
+ window_reset=
+ }
+
+ # Sets the window title. Works with screen, xterm and rxvt.
+ if [[ $TERM == screen* ]]; then
+ window_title() {
+ print -n "\ek$1\e\\"
+ }
+ elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
+ window_title() {
+ print -n "\e]2;$1\e\\"
+ }
+ else
+ # Fallback if another TERM is used.
+ window_title() { }
+ fi
+
+ # Add the preexec() and precmd() hooks.
+ add-zsh-hook preexec window_preexec
+ add-zsh-hook precmd window_precmd
+fi
+
+
+# COMPLETION SETTINGS
+
+# Load the complist module which provides additions to completion lists
+# (coloring, scrollable).
+zmodload zsh/complist
+# Use new completion system, store dumpfile in ~/.zsh/cache to prevent
+# cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
+# #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
+autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump