+++ /dev/null
-# Zsh configuration file.
-
-
-source_debug "sourcing ~/.zsh/rc"
-
-# MISCELLANEOUS SETTINGS
-
-# Use Vi(m) style key bindings.
-bindkey -v
-
-# Be paranoid, new files are readable/writable by me only.
-umask 077
-
-# Prevent overwriting existing files with '> filename', use '>| filename'
-# (or >!) instead.
-setopt noclobber
-
-# Entering the name of a directory (if it's not a command) will automatically
-# cd to that directory.
-setopt autocd
-
-# When entering a nonexistent command name automatically try to find a similar
-# one.
-setopt correct
-
-# Enable zsh's extended glob abilities.
-setopt extendedglob
-
-# Don't exit if <C-d> is pressed.
-setopt ignoreeof
-
-
-# FUNCTION SETTINGS
-
-# Set correct fpath to allow loading my functions (including completion
-# functions).
-fpath=(~/.zsh/functions $fpath)
-# Autoload my functions (except completion functions and hidden files). Thanks
-# to caphuso from the Zsh example files for this idea.
-autoload ${fpath[1]}/^_*(^/:t)
-
-# Simulate hooks using _functions arrays for Zsh versions older then 4.3.4. At
-# the moment only precmd() and preexec() are simulated.
-#
-# At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
-# so the compatibility version is used there too.
-if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
- # Provide add-zsh-hook which was added in 4.3.4.
- fpath=(~/.zsh/functions/compatibility $fpath)
-
- # Run all functions defined in the ${precmd,preexec}_functions arrays.
- function precmd() {
- for function in $precmd_functions; do
- $function $@
- done
- }
- function preexec() {
- for function in $preexec_functions; do
- $function $@
- done
- }
-fi
-
-# Autoload add-zsh-hook to add/remove zsh hook functions easily.
-autoload -Uz add-zsh-hook
-
-
-# HISTORY SETTINGS
-
-# Use history and store it in ~/.zsh/history.
-HISTSIZE=5000
-SAVEHIST=5000
-HISTFILE=~/.zsh/history
-# Append to the history file instead of overwriting it and do it immediately
-# when a command is executed.
-setopt appendhistory
-setopt incappendhistory
-# If the same command is run multiple times store it only once in the history.
-setopt histignoredups
-# Vim like completions of previous executed commands.
-bindkey "^P" history-beginning-search-backward
-bindkey "^N" history-beginning-search-forward
-
-
-# PROMPT SETTINGS
-
-# Use colorized output, necessary for prompts and completions.
-autoload -U colors && colors
-
-# Set the default prompt. The current host and working directory is displayed,
-# the exit code of the last command if it wasn't 0, the number of running jobs
-# if not 0 and a + if this shell is running inside another shell.
-# The prompt is in green and blue to make easily detectable, the error exit
-# code in red and bold and the job count in yellow.
-PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
-%{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
-%(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
-%(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
-
-# VCS_Info was added in 4.3.9.
-if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
- # Allow substitutions and expansions in the prompt, necessary for
- # vcs_info.
- setopt promptsubst
- # Load vcs_info to display information about version control repositories.
- autoload -Uz vcs_info
- # Only look for git and mercurial repositories; the only I use.
- zstyle ':vcs_info:*' enable git hg
- # Set style of vcs_info display. The current branch (green) and vcs (blue)
- # is displayed. If there is an special action going on (merge, rebase)
- # it's also displayed (red).
- zstyle ':vcs_info:*' formats \
- "(%{${fg[green]}%}%b%{${fg[default]}%}:\
-%{${fg[blue]}%}%s%{${fg[default]}%})"
- zstyle ':vcs_info:*' actionformats \
- "(%{${fg[green]}%}%b%{${fg[default]}%}/\
-%{${fg[red]}%}%a%{${fg[default]}%}:\
-%{${fg[blue]}%}%s%{${fg[default]}%})"
- # Call vcs_info as precmd before every prompt.
- prompt_precmd() {
- vcs_info
- }
- add-zsh-hook precmd prompt_precmd
-
- # Display the vcs information in the right prompt.
- RPROMPT='${vcs_info_msg_0_}'
-fi
-
-# When screen or xterm is used set the name of the window to the currently
-# running program.
-#
-# When a program is started preexec() sets the window's name to it; when it
-# stops precmd() resets the windows' name to 'zsh'.
-#
-# It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
-# and stumpwm is used (it's tested if stumpish is available) then the window
-# title is also set in stumpwm using stumpish.
-if [[ $TERM == screen* || $TERM == xterm* ]]; then
- # Set to a non empty value to reset the window name in the next precmd()
- # call.
- window_reset=yes
- # Set to a non empty value when the stump window manager is available.
- which stumpwm &> /dev/null
- if [[ $? -eq 0 ]]; then
- window_stumpwm=yes
- fi
-
- window_preexec() {
- # Get the program name with its arguments.
- local program_name=$1
-
- # When sudo is used use real program name instead, but with an
- # exclamation mark at the beginning.
- local program_sudo=
- if [[ $program_name == sudo* ]]; then
- program_name=${program_name#sudo }
- program_sudo=yes
- fi
- # Remove all arguments from the program name.
- program_name=${program_name%% *}
-
- # Ignore often used commands which are only running for a very short
- # time. This prevents a "blinking" name when it's changed to "cd" for
- # example and then some milliseconds later back to "zsh".
- [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
-
- # Change my shortcuts so the real name of the program is displayed.
- case $program_name in
- e)
- program_name=elinks
- ;;
- g)
- program_name=git
- ;;
- m)
- program_name=mutt
- ;;
- v|vi)
- program_name=vim
- ;;
- esac
-
- # Add an exclamation mark at the beginning if running with sudo.
- if [[ $program_sudo == yes ]]; then
- program_sudo=!$program_sudo
- fi
-
- # Add an at mark at the beginning if running ssh on a different
- # computer.
- if [[ -n $SSH_CONNECTION ]]; then
- program_name="@$program_name"
- fi
-
- # Set the window name to the currently running program.
- window_title "$program_name"
-
- # Tell precmd() to reset the window name when the program stops.
- window_reset=yes
- }
-
- window_precmd() {
- # Abort if no window name reset is necessary.
- [[ -z $window_reset ]] && return
-
- # Reset the window name to 'zsh'.
- if [[ -n $SSH_CONNECTION ]]; then
- window_title "@zsh"
- else
- window_title "zsh"
- fi
-
- # Just reset the name, so no screen reset necessary for the moment.
- window_reset=
- }
-
- # Sets the window title. Works with screen and xterm.
- window_title() {
- if [[ $TERM == screen* ]]; then
- print -n "\ek$1\e\\"
-
- # Update window name in stumpwm if running screen in X11 and when
- # stumpwm is used.
- if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
- echo "$1" | stumpish -e "title" > /dev/null
- fi
-
- elif [[ $TERM == xterm* ]]; then
- print -n "\e]2;$1\e\\"
- fi
- }
-
- # Add the preexec() and precmd() hooks.
- add-zsh-hook preexec window_preexec
- add-zsh-hook precmd window_precmd
-fi
-
-
-# COMPLETION SETTINGS
-
-# Load the complist module which provides additions to completion lists
-# (coloring, scrollable).
-zmodload zsh/complist
-# Use new completion system, store dumpfile in ~/.zsh/cache to prevent
-# cluttering of ~/.
-autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
-
-# Use cache to speed up completions.
-zstyle ':completion:*' use-cache on
-zstyle ':completion:*' cache-path ~/.zsh/cache
-
-# Complete arguments and fix spelling mistakes when possible.
-zstyle ':completion:*' completer _complete _match _correct _approximate
-
-# Make sure the list of possible completions is displayed after pressing <TAB>
-# the first time.
-setopt nolistambiguous
-# Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
-# completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
-bindkey "^I" expand-or-complete-prefix
-# Try uppercase if the currently typed string doesn't match. This allows
-# typing in lowercase most of the time and completion fixes the case.
-zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
-
-# Use ls like colors for completions.
-zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
-
-# Make completion lists scrollable so "do you wish to see all n possibilities"
-# is no longer displayed.
-zstyle ':completion:*' list-prompt '%p'
-# Display group name (like 'external command', 'alias', etc.) when there are
-# multiple matches in bold.
-zstyle ':completion:*' format ' %B%d%b:'
-# Display different types of matches separately.
-zstyle ':completion:*' group-name ''
-
-# Ignore completion functions.
-zstyle ':completion:*:functions' ignored-patterns '_*'
-# Ignore parent directory.
-zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
-# When unsetting variables make sure every variable name is only suggested
-# once.
-zstyle ':completion:*:unset:*' ignore-line yes
-# When working with Mercurial and Git don't complete the same file multiple
-# times. Very useful when completing file names.
-zstyle ':completion:*:(hg|git)*:*' ignore-line yes
-
-
-# CUSTOM ALIASES AND FUNCTIONS
-
-# Make sure aliases are expanded when using sudo.
-alias sudo='sudo '
-
-# Simplify calls to less, automatically redirects all output.
-alias -g L='2>&1 | less'
-# Simplify calls to colordiff, output is also piped through less.
-alias -g D='2>&1 | colordiff L'
-# Simplify calls to grep.
-alias -g G='| grep'
-
-# Automatically use unified diffs.
-alias diff='diff -u'
-
-# Display all files and use human readable sizes.
-alias du='du -sh'
-
-# Use human readable sizes.
-alias df='df -h'
-
-# Multiple files given to Vim are opened in tabs, supported since Vim 7.
-if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
- alias vim='vim -p'
-fi
-
-# Shortcuts for often used programs.
-alias e='elinks'
-alias g='git'
-alias m='mutt'
-alias v='vim'
-alias vi='vim'
-
-# I sometimes confuse editor and shell, print a warning to prevent I exit the
-# shell.
-alias :q='echo "This is not Vim!" >&2'
-
-# Edit the mercurial patch queue series file for the current mercurial
-# repository in Vim. Also change Vim's pwd to the patches directory so other
-# patches can easily be opened.
-alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
-
-# Make going up directories simple.
-alias -g ...='../..'
-alias -g ....='../../..'
-alias -g .....='../../../..'
-
-# Improved ls which displays the files in columns (-C), visualizes
-# directories, links and other special files (-F) and pages everything through
-# less (L).
-#
-# If available use GNU ls with colorized output. If it isn't available use
-# normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
-# pager.
-ls --color &> /dev/null
-if [[ $? -eq 0 ]]; then
- alias ls='ls --color'
-else
- alias ls='CLICOLOR_FORCE=1 ls -G'
-fi
-# Main ls function.
-function ls() {
- command ls -C -F $* L
-}
-# Helper function to list all files.
-function la() {
- ls -a $*
-}
-# Helper function to list all files in list format with access rights, etc.
-function ll() {
- la -l $*
-}
-
-# If ^C is pressed while typing a command, add it to the history so it can be
-# easily retrieved later and then abort like ^C normally does. This is useful
-# when I want to abort an command to do something in between and then finish
-# typing the command.
-TRAPINT() {
- # Store the current buffer in the history.
- zle && print -s $BUFFER
-
- # Return the default exit code so zsh aborts the current command.
- return $1
-}
-
-# Display TODOs stored in ~/.todo if this file exists.
-todo() {
- if [[ -f ~/.todo ]]; then
- cat ~/.todo | $PAGER
- fi
-}
-
-# Colorize stderr. Very useful when looking for errors. Thanks to
-# http://gentoo-wiki.com/wiki/Zsh
-exec 2>>(while read line; do
- print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
-
-
-# RUN COMMANDS
-
-# If not already in screen reattach to a running session or create a new one.
-#
-# screen* is necessary as `screen` uses screen.linux for example for a linux
-# console which would otherwise cause an infinite loop.
-if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
- # Create a new session if none is running.
- if [[ $(screen -list | grep "Detached" | wc -l) == 0 ]]; then
- screen
- # Reattach to a running session.
- else
- screen -r
- fi
-fi
-
-
-# Load rc file for current OS.
-source_config ~/.zsh os rc $(uname) nolocal
-# Load rc file for current hostname (first part before a dot) or rc.local.
-source_config ~/.zsh host rc ${$(hostname)//.*/}
-
-source_debug "finished sourcing ~/.zsh/rc"
-
-# vim: ft=zsh
ruderich.org/simon / config / dotfiles.git / blobdiff