X-Git-Url: https://ruderich.org/simon/gitweb/?a=blobdiff_plain;f=zsh%2Frc;h=5cad9c8e77c39aa65f46fa446c34c55f0ca3dba8;hb=2c96f7708cecf5f7eebf8e3349eb8f2a8eee1694;hp=f696a34f16efa20fe5bbf7d4c5c708e41ed498c5;hpb=7462c890fb0ddcd28654e06ff8f8d378854a4f12;p=config%2Fdotfiles.git

diff --git a/zsh/rc b/zsh/rc
index f696a34..5cad9c8 100644
--- a/zsh/rc
+++ b/zsh/rc
@@ -16,12 +16,39 @@
 # along with this file.  If not, see <http://www.gnu.org/licenses/>.
 
 
-source_debug ". ~/.zsh/rc"
+source_debug '. ~/.zsh/rc'
+
+
+# HELPER FUNCTIONS
+
+# Return the name of the program which is called in the foreground with `fg`.
+# $1 is the name of the program (optional). If it's not 'fg' or 'fg *' it's
+# returned unchanged.
+resolve_fg_to_resumed_job_name() {
+    # $REPLY is used by convention for scalars ($reply for arrays) to return
+    # values from functions. unset it here to prevent problems when REPLY is
+    # bound to an integer or similar. Thanks to Mikachu in #zsh on Freenode
+    # (2012-09-27 17:14 CEST) for this hint.
+    unset REPLY
+
+    # Replace fg with the resumed job name.
+    if [[ $1 == fg ]]; then
+        REPLY="${jobtexts[%+]}"
+    elif [[ $1 == fg\ * ]]; then
+        REPLY="${jobtexts[${1#fg }]}"
+    # Normal program, return as is.
+    else
+        REPLY="$1"
+    fi
+}
+
 
 # MISCELLANEOUS SETTINGS
 
-# Be paranoid, new files are readable/writable by me only.
-umask 077
+# Be paranoid, new files are readable/writable by me only, but not as root.
+if [[ $UID -ne 0 ]]; then
+    umask 077
+fi
 
 # Disable beeps.
 setopt nobeep
@@ -41,7 +68,8 @@ setopt correct
 # Enable zsh's extended glob abilities.
 setopt extendedglob
 
-# Don't exit if <C-d> is pressed.
+# Don't exit if <C-D> is pressed. Prevents exiting the shell by accident (e.g.
+# pressing <C-D> twice).
 setopt ignoreeof
 
 
@@ -67,7 +95,7 @@ bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
 # Make sure every entry in $fpath is unique.
 typeset -U fpath
 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
-# of a Zsh CVS checkout. Use it to get the newest completions if available.
+# of a Zsh Git checkout. Use it to get the newest completions if available.
 if [[ -d ~/.zsh/functions/completion ]]; then
     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
 fi
@@ -265,6 +293,53 @@ else
     RUN_VCS_INFO=
 fi
 
+typeset -a longrun_data
+longrun_data=()
+# Display runtime in seconds for long running programs (> 60 seconds) and send
+# a bell to notify me.
+longrun_preexec() {
+    local program="$3"
+
+    # Handle fg.
+    local REPLY
+    resolve_fg_to_resumed_job_name "$program"
+    program="$REPLY"
+
+    # Don't track the time for certain (possible) long running processes which
+    # need no automatic notification.
+    for ignore in elinks man mutt vim; do
+        case $program in
+            $ignore | $ignore\ *)
+                longrun_data=()
+                return
+                ;;
+        esac
+    done
+
+    longrun_data=("$program" $EPOCHSECONDS)
+}
+longrun_precmd() {
+    # No previous timestamp available or disabled for this command, ignore.
+    if [[ -z $longrun_data ]]; then
+        return
+    fi
+
+    local difference=$(( EPOCHSECONDS - longrun_data[2] ))
+    if [[ $difference -gt 60 ]]; then
+        echo
+        echo -n "${fg[yellow]}"
+        echo -n "~> ${(V)longrun_data[1]} took $difference seconds."
+        echo -n "${fg[default]}"
+        echo    "\a" # send bell
+    fi
+
+    # Clear status. Prevents displaying old status information when pressing
+    # enter with an empty command line.
+    longrun_data=()
+}
+preexec_functions+=(longrun_preexec)
+precmd_functions+=(longrun_precmd)
+
 # Set the prompt. A two line prompt is used. On the top left the current
 # working directory is displayed, on the right vcs_info (if available) and the
 # current time in hex. On the bottom left current user name and host is shown,
@@ -272,7 +347,8 @@ fi
 # if not 0.
 #
 # The prompt is in green and blue to make easily detectable, the error exit
-# code in red and bold and the job count in yellow.
+# code in red and bold and the job count in yellow. Designed for dark
+# terminals.
 #
 # Thanks to Adam's prompt for the basic idea of this prompt.
 prompt_precmd() {
@@ -288,45 +364,72 @@ prompt_precmd() {
         vcs_info_msg_0_=
     fi
 
-    local width width_left width_right
-    local top_left top_right
-
-    # Display the current time in HEX in bright blue and vcs_info (if used) on
-    # the right in the top prompt.
-    top_right="$vcs_info_msg_0_($blue%B0x$(([##16] EPOCHSECONDS))%b$default)"
-    width_right=${#${(S%%)top_right//$~zero/}}
-    # Remove it if it would get too long.
-    if [[ $(( COLUMNS - 4 - 1 - width_right )) -lt 0 ]]; then
-        top_right=
-        width_right=0
+    # Setup. Create variables holding the formatted content.
+
+    # Current directory in yellow, truncated if necessary (WIDTH is replaced
+    # below).
+    local directory="${yellow}%WIDTH<..<%~%<<${default}"
+
+    # Information about the VCS in this directory.
+    local vcs="${vcs_info_msg_0_}"
+    # Current time (seconds since epoch) in Hex in bright blue.
+    local seconds="${blue}%B0x$(([##16] EPOCHSECONDS))%b${default}"
+
+    # User name (%n) in bright green.
+    local user="${green}%B%n%b${default}"
+    # Host name (%m) in bright green; underlined if running on a remote system
+    # through SSH.
+    local host="${green}%B%m%b${default}"
+    if [[ -n $SSH_CONNECTION ]]; then
+        host="%U${host}%u"
     fi
 
-    # Display current directory on the left in the top prompt. Truncate the
-    # directory if necessary.
-    width=$(( COLUMNS - 4 - 1 - width_right ))
-    top_left=".-$default%b($yellow%$width<..<%~%<<$default)%B$blue"
+    # Number of background processes in yellow if not zero.
+    local background="%(1j.${yellow}%j${default}.)"
+    # Exit code in bright red in parentheses if not zero.
+    local exitcode="%(?..(${red}%B%?%b${default}%) )"
+
+    # Prefix characters in first and second line.
+    local top_prefix="${blue}%B.-%b${default}"
+    local bottom_prefix="${blue}%B'%b${default}"
+
+    # Combine them to create the prompt.
+
+    local top_right="${vcs}(${seconds})"
+
+    local width_top_prefix=${#${(S%%)top_prefix//$~zero/}}
+    local width_top_right=${#${(S%%)top_right//$~zero/}}
+
+    # Calculate the maximum width of ${top_left}. -2 are the braces of
+    # ${top_left}, -1 is one separator from ${top_separator} (we want at least
+    # one between left and right parts).
+    local top_left_width_max=$((
+        COLUMNS - $width_top_prefix - 2 - 1 - $width_top_right
+    ))
+    # Truncate directory if necessary.
+    local top_left="(${directory/WIDTH/${top_left_width_max}})"
+    local width_top_left=${#${(S%%)top_left//$~zero/}}
 
     # Calculate the width of the top prompt to fill the middle with "-".
-    width_left=${#${(S%%)top_left//$~zero/}}
-    width_right=${#${(S%%)top_right//$~zero/}}
-    width=$(( COLUMNS - width_left - width_right ))
-
-    PROMPT="$blue%B$top_left${(l:$width::-:)}%b$default$top_right
-$blue%B'%b$default\
-$green%B%n%b$default@$green%B%m%b$default %(1j.$yellow%j$default.)%# \
-%(?..($red%B%?%b$default%) )"
+    local width=$((
+        COLUMNS - width_top_prefix - width_top_left - width_top_right
+    ))
+    local top_separator="%B${blue}${(l:${width}::-:)}%b${default}"
+
+    PROMPT="${top_prefix}${top_left}${top_separator}${top_right}
+${bottom_prefix}${user}@${host} ${background}%# ${exitcode}"
 }
 precmd_functions+=(prompt_precmd)
 
 
-# When screen, tmux, xterm or rxvt is used set the name of the window to the
-# currently running program.
+# When GNU screen, tmux, xterm or rxvt is used set the name of the window to
+# the currently running program.
 #
 # When a program is started preexec() sets the window's name to it; when it
 # stops precmd() resets the window's name to 'zsh'. 'fg' is supported and sets
 # the window's name to the resumed job.
 #
-# It works with screen, tmux, xterm and rxvt.
+# It works with GNU screen, tmux, xterm and rxvt.
 #
 # If a command is run with sudo or if the shell is running as root then a ! is
 # added at the beginning of the command to make this clear. If a command is
@@ -350,7 +453,7 @@ if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
         # Get the program name with its arguments.
         local program_name=$1
 
-        # When sudo is used use real program name instead, but with an
+        # When sudo is used, use real program name instead, but with an
         # exclamation mark at the beginning (handled below).
         local program_sudo=
         if [[ $program_name == sudo* ]]; then
@@ -358,12 +461,10 @@ if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
             program_sudo=yes
         fi
 
-        # Replace fg with the resumed job name.
-        if [[ $program_name == fg ]]; then
-            program_name=${jobtexts[%+]}
-        elif [[ $program_name == fg\ * ]]; then
-            program_name=${jobtexts[${program_name#fg }]}
-        fi
+        # Handle fg.
+        local REPLY
+        resolve_fg_to_resumed_job_name "$program_name"
+        program_name="$REPLY"
 
         # Remove all arguments from the program name.
         program_name=${program_name%% *}
@@ -442,8 +543,8 @@ if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
         window_reset=
     }
 
-    # Sets the window title. Works with screen, tmux (which uses screen as
-    # TERM), xterm and rxvt. (V) escapes all non-printable characters. Thanks
+    # Sets the window title. Works with GNU screen, tmux (which uses screen as
+    # TERM), xterm and rxvt. (V) escapes all non-printable characters, thanks
     # to Mikachu in #zsh on Freenode (2010-08-07 17:09 CEST).
     if [[ $TERM == screen* ]]; then
         window_title() {
@@ -629,7 +730,7 @@ alias -g EN='2>/dev/null'
 alias -g L='2>&1 | less'
 alias -g LS='2>&1 | less -S' # -S prevents wrapping of long lines
 alias -g D='2>&1 | colordiff | less'
-# Global aliases for often used commands in the command line.
+# Global aliases for often used commands.
 alias -g A='| awk'
 alias -g G='| grep'
 alias -g H='| head'
@@ -672,20 +773,22 @@ fi
     command tree -C "$@" | less
 }
 
-# Choose the "best" PDF viewer available: zathura, then xpdf. Also setup
-# completion for `pdf`.
-if (( $+commands[zathura] )); then
+# Choose the "best" PDF viewer available: xpdf, then zathura (in the past
+# zathura was preferred, but recent versions are completely broken: still no
+# working search and no page-wise scrolling anymore). Also setup completion
+# for `pdf`.
+if (( $+commands[xpdf] )); then
     pdf() {
-        command zathura "$@" 2>/dev/null &
+        command xpdf "$@" 2>/dev/null &
         disown %command
     }
-    # No completion for zathura yet.
     compdef _xpdf pdf
-elif (( $+commands[xpdf] )); then
+elif (( $+commands[zathura] )); then
     pdf() {
-        command xpdf "$@" 2>/dev/null &
+        command zathura "$@" 2>/dev/null &
         disown %command
     }
+    # No completion for zathura yet.
     compdef _xpdf pdf
 fi
 
@@ -703,17 +806,16 @@ fi
 
 if [[ $OSTYPE == linux* ]]; then
     # Settings when creating Debian packages.
-    DEBEMAIL=simon@ruderich.org
-    export DEBEMAIL
-    DEBFULLNAME='Simon Ruderich'
-    export DEBFULLNAME
+    export DEBEMAIL=simon@ruderich.org
+    export DEBFULLNAME='Simon Ruderich'
 fi
 
 
 # LOAD ADDITIONAL CONFIGURATION FILES
 
-# Configuration option for rc.local to use tmux. By default screen is used.
-use_tmux=
+# Configuration option for rc.local to use GNU screen/tmux. By default GNU
+# screen is used. Possible values: screen, tmux and empty (no value).
+use_multiplexer=screen
 
 source_config ~/.zsh/rc.local
 
@@ -725,32 +827,32 @@ source_config ~/.zsh/rc.local
 # through ssh.
 if [[ $TERM != dumb && $TERM != linux && -z $STY && -z $TMUX ]]; then
     # Get running detached sessions.
-    if [[ -z $use_tmux ]]; then
+    if [[ $use_multiplexer = screen ]]; then
         session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
-    else
+    elif [[ $use_multiplexer = tmux ]]; then
         session=$(tmux list-sessions 2>/dev/null \
                   | sed '/(attached)$/ d; s/^\([0-9]\{1,\}\).*$/\1/; q')
     fi
 
     # As we exec later we have to set the title here.
-    if [[ -z $use_tmux ]]; then
-        window_preexec "screen"
-    else
-        window_preexec "tmux"
+    if [[ $use_multiplexer = screen ]]; then
+        window_preexec screen
+    elif [[ $use_multiplexer = tmux ]]; then
+        window_preexec tmux
     fi
 
     # Create a new session if none is running.
     if [[ -z $session ]]; then
-        if [[ -z $use_tmux ]]; then
+        if [[ $use_multiplexer = screen ]]; then
             exec screen
-        else
+        elif [[ $use_multiplexer = tmux ]]; then
             exec tmux
         fi
     # Reattach to a running session.
     else
-        if [[ -z $use_tmux ]]; then
+        if [[ $use_multiplexer = screen ]]; then
             exec screen -r $session
-        else
+        elif [[ $use_multiplexer = tmux ]]; then
             exec tmux attach-session -t $session
         fi
     fi
@@ -764,19 +866,22 @@ fi
 # cases it doesn't work, the E alias can be used as workaround.
 #
 # Moved in the "run commands" section to prevent one unnecessary zsh process
-# when starting screen/tmux (see above).
+# when starting GNU screen/tmux (see above).
 exec 2>>(while read -r -k -u 0 line; do
-    printf '\e[91m%s\e[0m' "$line";
-    print -n $'\0';
+    printf '\e[91m%s\e[0m' "$line"
+    print -n $'\0'
 done &)
 
-# Run reminder and redisplay it every four hours (if it's available).
+# Run the following programs every 4 hours (and when zsh starts).
 PERIOD=14400
 periodic() {
-    (( $+commands[rem] )) && [ -f ~/.reminders ] && rem -h
+    # Display fortunes.
+    (( $+commands[fortune] )) && fortune -ac
+    # Display reminders.
+    (( $+commands[rem] )) && [[ -f ~/.reminders ]] && rem -h
 }
 
 
-source_debug ". ~/.zsh/rc (done)"
+source_debug '. ~/.zsh/rc (done)'
 
 # vim: ft=zsh