--- /dev/null
+" Vim syntax file
+" Language: msmtp rc files
+" Maintainer: Simon Ruderich <simon@ruderich.org>
+" Last Change: 2008-08-23
+" Filenames: msmtprc
+" Version: 0.1
+
+
+if version < 600
+ syntax clear
+elseif exists("b:current_syntax")
+ finish
+endif
+
+
+" Comments.
+syn match msmtpComment /#.*$/ contains=@Spell
+
+" General commands.
+syntax match msmtpOption /\<\(defaults\|account\|host\|port\|timeout\|protocol\|domain\)\>/
+" Authentication commands.
+syntax match msmtpOption /\<\(auth\|user\|password\|ntlmdomain\)\>/
+" TLS commands.
+syntax match msmtpOption /\<\(tls\|tls_trust_file\|tls_crl_file\|tls_key_file\|tls_cert_file\|tls_certcheck\|tls_starttls\|tls_force_sslv3\|tls_min_dh_prime_bits\|tls_priorities\)\>/
+" Sendmail mode specific commands.
+syntax match msmtpOption /\<\(auto_from\|from\|maildomain\|dsn_notify\|dsn_return\|keepbcc\|logfile\|syslog\)\>/
+
+
+" Options which accept only an on/off value.
+syn match msmtpWrongOption /\<\(tls\|tls_certcheck\|tls_starttls\|tls_force_sslv3\|auto_from\|keepbcc\) \(on$\|off$\)\@!.*$/
+" Option port accepts numeric values.
+syn match msmtpWrongOption /\<port \(\d\+$\)\@!.*$/
+" Option timeout accepts off and numeric values.
+syn match msmtpWrongOption /\<timeout \(off$\|\d\+$\)\@!.*$/
+" Option protocol accepts smtp and lmtp.
+syn match msmtpWrongOption /\<protocol \(smtp$\|lmtp$\)\@!.*$/
+" Option auth accepts on, off and the method.
+syn match msmtpWrongOption /\<auth \(on$\|off$\|plain$\|cram-md5$\|digest-md5$\|gssapi$\|external$\|login$\|ntlm$\)\@!.*$/
+" Option auth accepts on, off and the facility.
+syn match msmtpWrongOption /\<syslog \(on$\|off$\|LOG_USER$\|LOG_MAIL$\|LOG_LOCAL\d$\)\@!.*$/
+
+" Marks all wrong option values as errors.
+syn match msmtpWrongOptionValue /\S* \zs.*$/ contained containedin=msmtpWrongOption
+
+" Mark the option part as a normal option.
+highlight default link msmtpWrongOption msmtpOption
+
+highlight default link msmtpComment Comment
+highlight default link msmtpOption Type
+highlight default link msmtpWrongOptionValue Error
+
+let b:current_syntax = "msmtp"
--- /dev/null
+" Vim main configuration file.
+
+
+" EDITOR SETTINGS
+
+" Make sure Vim (and not Vi) settings are used.
+set nocompatible
+
+" Load my scripts from ~/.vim (my scripts), ~/.vim/plugins (plugins) and
+" ~/.vim/runtime (checkout of Vim runtime files).
+set runtimepath-=~/.vim
+set runtimepath^=~/.vim,~/.vim/plugins,~/.vim/runtime
+
+" Disable modelines as they may cause security problems. Instead use
+" securemodelines (Vim script #1876).
+set nomodeline
+
+" When completing paths first use the longest path then display a list of all
+" possible files.
+set wildmode=longest,list
+
+" Increase number of tabs which can be opened with the -p option.
+if v:version >= 700
+ set tabpagemax=50
+endif
+
+
+" EDIT SETTINGS
+
+" Enable automatic file detection, plugin and indention.
+if has('autocmd')
+ filetype plugin indent on
+endif
+
+" Use UTF-8 file encoding for all files. Automatically recognize latin1 in
+" existing files.
+set fileencodings=utf-8,latin1
+
+" Wrap text after 78 characters.
+set textwidth=78
+
+" Set tabs to 4 spaces, use softtabs.
+set shiftwidth=4
+set softtabstop=4
+set expandtab
+" When < and > is used indent/deindent to the next shiftwidth boundary.
+set shiftround
+" Use the default value for real tabs.
+set tabstop=8
+
+" Enable auto indention.
+set autoindent
+
+" When joining lines only add one space after a sentence.
+set nojoinspaces
+
+" Allow backspacing over autoindent and line breaks.
+set backspace=indent,eol
+
+" Start a comment when hitting enter after a commented line (r) and when using
+" o or O around a commented line (o).
+set formatoptions+=ro
+" Don't break a line if was already longer then 'textwidth' when insert mode
+" started.
+set formatoptions+=l
+
+" Allow virtual editing (cursor can be positioned anywhere, even when there is
+" no character) in visual block mode.
+set virtualedit=block
+
+" Already display matches while typing the search command. This makes spotting
+" errors easy.
+set incsearch
+
+" Activate syntax folding.
+if has('folding')
+ set foldmethod=syntax
+ set foldcolumn=2
+ set foldlevel=99 " no closed folds at default, 'foldenable' would disable
+ " folding which is not what I want
+endif
+
+" Only check for case if the searched word contains a capital character.
+set ignorecase
+set smartcase
+
+" Activate spell checking, use English as default. Don't use spell checking
+" when diffing.
+if v:version >= 700 && !&diff
+ set spell
+ set spelllang=en_us
+endif
+
+" Allow buffers with changes to be hidden.
+set hidden
+
+
+" DISPLAY SETTINGS
+
+" Use a dark background.
+set background=dark
+
+" Activate lines display.
+set number
+" Display the ruler with current line/file position.
+set ruler
+" Display partial commands in the status line.
+set showcmd
+
+" Visualize the line the cursor is currently in.
+if v:version >= 700
+ set cursorline
+endif
+
+" Display tabs, trailing space, non breakable spaces and long lines (when
+" wrapping is enabled).
+set list
+set listchars=trail:-,nbsp:!,extends:>
+
+
+" MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
+
+" Use <space> to move down a page and - to move up one like in mutt.
+nnoremap <Space> <C-f>
+nnoremap - <C-b>
+
+" Fast access to buffers.
+nnoremap <Leader>1 :1b<CR>
+nnoremap <Leader>2 :2b<CR>
+nnoremap <Leader>3 :3b<CR>
+nnoremap <Leader>4 :4b<CR>
+nnoremap <Leader>5 :5b<CR>
+nnoremap <Leader>6 :6b<CR>
+nnoremap <Leader>7 :7b<CR>
+nnoremap <Leader>8 :8b<CR>
+nnoremap <Leader>9 :9b<CR>
+nnoremap <Leader>0 :10b<CR>
+
+" Maps to change spell language between English and German and disable it.
+if v:version >= 700
+ map <Leader>sn :set nospell<CR>
+ map <Leader>se :set spell spelllang=en_us<CR>
+ map <Leader>sd :set spell spelllang=de_de<CR>
+endif
+
+" Add semicolon to the end of the line. Thanks to
+" http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
+" on Freenode for an improved version which doesn't clobber any marks.
+nnoremap <silent> ; :call setline(line('.'), getline('.') . ';')<CR>
+
+" I often type "W" instead of "w" when trying to save a file. Fix my mistake.
+" Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
+" mailing list for the commands.
+if v:version < 700
+ cnoreabbrev W w
+ cnoreabbrev Wq wq
+ cnoreabbrev Wqa wqa
+else
+ cnoreabbrev <expr> W
+ \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
+ cnoreabbrev <expr> Wq
+ \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
+ cnoreabbrev <expr> Wqa
+ \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
+endif
+" Also fix my typo with "Q".
+if v:version < 700
+ cnoreabbrev Q q
+ cnoreabbrev Qa qa
+else
+ cnoreabbrev <expr> Q
+ \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
+ cnoreabbrev <expr> Qa
+ \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
+endif
+
+" Make sure xa0 (alt + space) is automatically changed to a normal whitespace
+" if pressed accidentally while in insert mode (happens on Mac when alt
+" doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
+" no longer set on the console.
+if has('mac') || filereadable('/Users/.localized')
+ imap <Char-0xa0> <Space>
+endif
+
+" Disable Apple style movements in MacVim.
+if has('gui_macvim') && has('eval')
+ let macvim_skip_cmd_opt_movement = 1
+endif
+
+
+" SYNTAX SETTINGS
+
+" Activate syntax coloring.
+if has('syntax')
+ syntax enable
+
+" Highlight text longer then 78 characters. Thanks to Tony Mechelynck
+" <antoine.mechelynck@gmail.com> from the Vim mailing list.
+ if v:version >= 700
+ 2match Todo /\%>78v./
+ else
+ match Todo /\%>78v./
+ endif
+
+" Highlight TODO, FIXME, CHANGED and XXX in all documents.
+ if v:version >= 701 && has('patch40')
+ call matchadd('Todo', '\(TODO\|FIXME\|CHANGED\|XXX\)')
+ endif
+endif
+
+
+" PLUGIN SETTINGS
+
+" Settings for the NERD commenter.
+" Don't create any mappings I don't want to use.
+if has('eval')
+ let NERDCreateDefaultMappings = 0
+endif
+" Map toggle comment.
+map <Leader><Leader> <plug>NERDCommenterToggle
+
+
+" AUTO COMMANDS
+
+" Use a custom auto group to prevent problems when the vimrc files is sourced
+" twice.
+if has('autocmd')
+ augroup vimrc
+ autocmd!
+
+" Use diff filetype for mercurial patches in patch queue.
+ autocmd BufReadPost */.hg/patches/* set filetype=diff
+
+ augroup END
+endif