bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2013  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.04';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full = qr/
  42     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  43     $cc_regex
  44     /x;
  45 # Regex to check if a line contains a compiler command.
  46 my $cc_regex_normal = qr/
  47     \b$cc_regex(?:\s|\\)
  48     /x;
  49 # Regex to catch (GCC) compiler warnings.
  50 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  51 # Regex to catch libtool commands and not lines which show commands executed
  52 # by libtool (e.g. libtool: link: ...).
  53 my $libtool_regex = qr/\blibtool\s.*--mode=/;
  54
  55 # List of source file extensions which require preprocessing.
  56 my @source_preprocess_compile_cpp = (
  57     # C++
  58     qw( cc cp cxx cpp CPP c++ C ),
  59     # Objective-C++
  60     qw( mm M ),
  61 );
  62 my @source_preprocess_compile = (
  63     # C
  64     qw( c ),
  65     # Objective-C
  66     qw( m ),
  67     # (Objective-)C++
  68     @source_preprocess_compile_cpp,
  69     # Fortran
  70     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  71 );
  72 my @source_preprocess_no_compile = (
  73     # Assembly
  74     qw( S sx ),
  75 );
  76 my @source_preprocess = (
  77     @source_preprocess_compile,
  78     @source_preprocess_no_compile,
  79 );
  80 # List of source file extensions which don't require preprocessing.
  81 my @source_no_preprocess_compile_cpp = (
  82     # C++
  83     qw( ii ),
  84     # Objective-C++
  85     qw( mii ),
  86 );
  87 my @source_no_preprocess_compile_ada = (
  88     # Ada body
  89     qw( adb ),
  90     # If you add another file, fix use of @source_no_preprocess_compile_ada
  91     # below (search for $compile_ada).
  92 );
  93 my @source_no_preprocess_compile = (
  94     # C
  95     qw( i ),
  96     # (Objective-)C++
  97     @source_no_preprocess_compile_cpp,
  98     # Objective-C
  99     qw( mi ),
 100     # Fortran
 101     qw( f for ftn f90 f95 f03 f08 ),
 102     # Ada
 103     @source_no_preprocess_compile_ada,
 104 );
 105 my @source_no_preprocess_no_compile = (
 106     # Assembly
 107     qw( s ),
 108     # Ada specification
 109     qw( ads ),
 110 );
 111 my @source_no_preprocess = (
 112     @source_no_preprocess_compile,
 113     @source_no_preprocess_no_compile,
 114 );
 115 # List of header file extensions which require preprocessing.
 116 my @header_preprocess = (
 117     # C, C++, Objective-C, Objective-C++
 118     qw( h ),
 119     # C++
 120     qw( hh H hp hxx hpp HPP h++ tcc ),
 121 );
 122 # Object files.
 123 my @object = (
 124     # Normal object files.
 125     qw ( o ),
 126     # Libtool object files.
 127     qw ( lo la ),
 128     # Dynamic libraries. bzip2 uses .sho.
 129     qw ( so sho ),
 130     # Static libraries.
 131     qw ( a ),
 132 );
 133
 134 # Hashes for fast extensions lookup to check if a file falls in one of these
 135 # categories.
 136 my %extensions_no_preprocess = map { $_ => 1 } (
 137     # There's no @header_no_preprocess.
 138     @source_no_preprocess,
 139 );
 140 my %extensions_preprocess = map { $_ => 1 } (
 141     @header_preprocess,
 142     @source_preprocess,
 143 );
 144 my %extensions_compile_link = map { $_ => 1 } (
 145     @source_preprocess,
 146     @source_no_preprocess,
 147 );
 148 my %extensions_compile = map { $_ => 1 } (
 149     @source_preprocess_compile,
 150     @source_no_preprocess_compile,
 151 );
 152 my %extensions_no_compile = map { $_ => 1 } (
 153     @source_preprocess_no_compile,
 154     @source_no_preprocess_no_compile,
 155 );
 156 my %extensions_compile_cpp = map { $_ => 1 } (
 157     @source_preprocess_compile_cpp,
 158     @source_no_preprocess_compile_cpp,
 159 );
 160 my %extensions_object = map { $_ => 1 } (
 161     @object,
 162 );
 163 my %extension = map { $_ => 1 } (
 164     @source_no_preprocess,
 165     @header_preprocess,
 166     @source_preprocess,
 167     @object,
 168 );
 169
 170 # Regexp to match file extensions.
 171 my $file_extension_regex = qr/
 172     \s
 173     \S+             # Filename without extension.
 174     \.
 175     ([^\/\\.,;:\s]+)# File extension.
 176     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 177                     # word characters at the end and because \b matches double
 178                     # extensions (like .cpp.o). Works always as all lines are
 179                     # terminated with "\n".
 180     /x;
 181
 182 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 183 # real regexps below for better execution speed).
 184 my @def_cflags = (
 185     '-g',
 186     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
 187 );
 188 my @def_cflags_debug = (
 189     # These flags indicate a debug build which disables checks for -O2.
 190     '-O0',
 191     '-Og',
 192 );
 193 my @def_cflags_format = (
 194     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 195     '-Werror=format-security', # implies -Wformat-security
 196 );
 197 my @def_cflags_fortify = (
 198     # fortify needs at least -O1, but -O2 is recommended anyway
 199 );
 200 my @def_cflags_stack = (
 201     '-fstack-protector',
 202     '--param[= ]ssp-buffer-size=4',
 203 );
 204 my @def_cflags_stack_strong = (
 205     '-fstack-protector-strong',
 206 );
 207 my @def_cflags_pie = (
 208     '-fPIE',
 209 );
 210 my @def_cxxflags = (
 211     @def_cflags,
 212 );
 213 # @def_cxxflags_* is the same as @def_cflags_*.
 214 my @def_cppflags = ();
 215 my @def_cppflags_fortify = (
 216     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 217     # If you add another flag fix hack below (search for "Hack to fix") and
 218     # $def_cppflags_fortify[0].
 219 );
 220 my @def_cppflags_fortify_bad = (
 221     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 222     '-U_FORTIFY_SOURCE',
 223     '-D_FORTIFY_SOURCE=0',
 224     '-D_FORTIFY_SOURCE=1',
 225 );
 226 my @def_ldflags = ();
 227 my @def_ldflags_relro = (
 228     '-Wl,(?:-z,)?relro',
 229 );
 230 my @def_ldflags_bindnow = (
 231     '-Wl,(?:-z,)?now',
 232 );
 233 my @def_ldflags_pie = (
 234     '-fPIE',
 235     '-pie',
 236 );
 237 my @def_ldflags_pic = (
 238     '-fPIC',
 239     '-fpic',
 240     '-shared',
 241 );
 242 # References to all flags checked by the flag checker.
 243 my @flag_refs = (
 244     \@def_cflags,
 245     \@def_cflags_format,
 246     \@def_cflags_fortify,
 247     \@def_cflags_stack,
 248     \@def_cflags_stack_strong,
 249     \@def_cflags_pie,
 250     \@def_cxxflags,
 251     \@def_cppflags,
 252     \@def_cppflags_fortify,
 253     \@def_ldflags,
 254     \@def_ldflags_relro,
 255     \@def_ldflags_bindnow,
 256     \@def_ldflags_pie,
 257 );
 258 # References to all used flags.
 259 my @flag_refs_all = (
 260     @flag_refs,
 261     \@def_cflags_debug,
 262     \@def_cppflags_fortify_bad,
 263     \@def_ldflags_pic,
 264 );
 265 # Renaming rules for the output so the regex parts are not visible. Also
 266 # stores string values of flag regexps above, see compile_flag_regexp().
 267 my %flag_renames = (
 268     '-O(?:2|3)'                    => '-O2',
 269     '-Wformat(?:=2)?'              => '-Wformat',
 270     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 271     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 272     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 273 );
 274
 275 my %exit_code = (
 276     no_compiler_commands => 1 << 0,
 277     # used by POD::Usage => 1 << 1,
 278     non_verbose_build    => 1 << 2,
 279     flags_missing        => 1 << 3,
 280     hardening_wrapper    => 1 << 4,
 281     invalid_cmake        => 1 << 5,
 282 );
 283
 284 my %buildd_tag = (
 285     no_compiler_commands => 'I-no-compiler-commands',
 286     non_verbose_build    => 'W-compiler-flags-hidden',
 287     flags_missing        => 'W-dpkg-buildflags-missing',
 288     hardening_wrapper    => 'I-hardening-wrapper-used',
 289     invalid_cmake        => 'I-invalid-cmake-used',
 290 );
 291
 292 # Statistics of missing flags and non-verbose build commands. Used for
 293 # $option_buildd.
 294 my %statistics = (
 295     preprocess          => 0,
 296     preprocess_missing  => 0,
 297     compile             => 0,
 298     compile_missing     => 0,
 299     compile_cpp         => 0,
 300     compile_cpp_missing => 0,
 301     link                => 0,
 302     link_missing        => 0,
 303     commands            => 0,
 304     commands_nonverbose => 0,
 305 );
 306
 307 # Use colored (ANSI) output?
 308 my $option_color;
 309
 310
 311 # FUNCTIONS
 312
 313 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 314 sub array_equal {
 315     my ($first_ref, $second_ref) = @_;
 316
 317     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 318
 319     my $length = scalar @{$first_ref};
 320     for (my $i = 0; $i < $length; $i++) {
 321         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 322     }
 323
 324     return 1;
 325 }
 326
 327 sub error_flags {
 328     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 329
 330     # Get string value of qr//-escaped regexps and if requested rename them.
 331     my @missing_flags = map {
 332             $flag_renames_ref->{$_}
 333         } @{$missing_flags_ref};
 334
 335     my $flags = join ' ', @missing_flags;
 336     printf '%s (%s)%s %s',
 337            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 338            $line;
 339
 340     return;
 341 }
 342 sub error_non_verbose_build {
 343     my ($line) = @_;
 344
 345     printf '%s%s %s',
 346            error_color('NONVERBOSE BUILD', 'red'),
 347            error_color(':', 'yellow'),
 348            $line;
 349
 350     return;
 351 }
 352 sub error_invalid_cmake {
 353     my ($version) = @_;
 354
 355     printf "%s%s %s\n",
 356             error_color('INVALID CMAKE', 'red'),
 357             error_color(':', 'yellow'),
 358             $version;
 359
 360     return;
 361 }
 362 sub error_hardening_wrapper {
 363     printf "%s%s %s\n",
 364             error_color('HARDENING WRAPPER', 'red'),
 365             error_color(':', 'yellow'),
 366             'no checks possible, aborting';
 367
 368     return;
 369 }
 370 sub error_color {
 371     my ($message, $color) = @_;
 372
 373     if ($option_color) {
 374         return Term::ANSIColor::colored($message, $color);
 375     } else {
 376         return $message;
 377     }
 378 }
 379
 380 sub any_flags_used {
 381     my ($line, @flags) = @_;
 382
 383     foreach my $flag (@flags) {
 384         return 1 if $line =~ /$flag/;
 385     }
 386
 387     return 0;
 388 }
 389 sub all_flags_used {
 390     my ($line, $missing_flags_ref, @flags) = @_;
 391
 392     my @missing_flags = ();
 393     foreach my $flag (@flags) {
 394         if (not $line =~ /$flag/) {
 395             push @missing_flags, $flag;
 396         }
 397     }
 398
 399     return 1 if scalar @missing_flags == 0;
 400
 401     @{$missing_flags_ref} = @missing_flags;
 402     return 0;
 403 }
 404
 405 sub cppflags_fortify_broken {
 406     my ($line, $missing_flags) = @_;
 407
 408     # This doesn't take the position into account, but is a simple solution.
 409     # And if the build system tries to force -D_FORTIFY_SOURCE=0/1, something
 410     # is wrong anyway.
 411
 412     if (any_flags_used($line, @def_cppflags_fortify_bad)) {
 413         # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 414         push @{$missing_flags}, $def_cppflags_fortify[0];
 415         return 1;
 416     }
 417
 418     return 0;
 419 }
 420
 421 # Modifies $missing_flags_ref array.
 422 sub pic_pie_conflict {
 423     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 424
 425     return 0 if not $pie;
 426     return 0 if not any_flags_used($line, @def_ldflags_pic);
 427
 428     my %flags = map { $_ => 1 } @flags_pie;
 429
 430     # Remove all PIE flags from @missing_flags as they are not required with
 431     # -fPIC.
 432     my @result = grep {
 433         not exists $flags{$_}
 434     } @{$missing_flags_ref};
 435     @{$missing_flags_ref} = @result;
 436
 437     # We got a conflict when no flags are left, thus only PIE flags were
 438     # missing. If other flags were missing abort because the conflict is not
 439     # the problem.
 440     return scalar @result == 0;
 441 }
 442
 443 sub is_non_verbose_build {
 444     my ($line, $next_line, $skip_ref) = @_;
 445
 446     if ($line =~ /$libtool_regex/o) {
 447         # libtool's --silent hides the real compiler flags.
 448         if ($line =~ /\s--silent/) {
 449             return 1;
 450         # If --silent is not present, skip this line as some compiler flags
 451         # might be missing (e.g. -fPIE) which are handled correctly by libtool
 452         # internally. libtool displays the real compiler command on the next
 453         # line, so the flags are checked as usual.
 454         } else {
 455             ${$skip_ref} = 1;
 456             return 0;
 457         }
 458     }
 459
 460     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 461                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 462                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 463                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 464                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 465         return 0;
 466     }
 467
 468     # False positives.
 469     #
 470     # C++ compiler setting.
 471     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 472     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 473     # "Compiling" non binary files.
 474     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|el)['"]?\s*(?:\.\.\.)?$/;
 475     # "Compiling" with no file name.
 476     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 477         # $file_extension_regex may need spaces around the filename.
 478         return 0 if not " $1 " =~ /$file_extension_regex/o;
 479     }
 480
 481     my $file = $1;
 482
 483     # On the first pass we only check if this line is verbose or not.
 484     return 1 if not defined $next_line;
 485
 486     # Second pass, we have access to the next line.
 487     ${$skip_ref} = 0;
 488
 489     # CMake and other build systems print the non-verbose messages also when
 490     # building verbose. If a compiler and the file name occurs in the next
 491     # line, treat it as verbose build.
 492     if (defined $file) {
 493         # Get filename, we can't use the complete path as only parts of it are
 494         # used in the real compiler command.
 495         $file =~ m{/([^/\s]+)$};
 496         $file = $1;
 497
 498         if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 499             # Not a non-verbose line, but we still have to skip the current line
 500             # as it doesn't contain any compiler commands.
 501             ${$skip_ref} = 1;
 502             return 0;
 503         }
 504     }
 505
 506     return 1;
 507 }
 508
 509 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
 510 sub remove_flags {
 511     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 512
 513     my %removes = map { $_ => 1 } @flags;
 514     foreach my $flags (@{$flag_refs_ref}) {
 515         @{$flags} = grep {
 516             # Flag found as string.
 517             not exists $removes{$_}
 518             # Flag found as string representation of regexp.
 519                 and (not defined $flag_renames_ref->{$_}
 520                         or not exists $removes{$flag_renames_ref->{$_}})
 521         } @{$flags};
 522     }
 523
 524     return;
 525 }
 526
 527 # Modifies $flag_renames_ref hash.
 528 sub compile_flag_regexp {
 529     my ($flag_renames_ref, @flags) = @_;
 530
 531     my @result = ();
 532     foreach my $flag (@flags) {
 533         # Compile flag regexp for faster execution.
 534         my $regex = qr/\s$flag(?:\s|\\)/;
 535
 536         # Store flag name in replacement string for correct flags in messages
 537         # with qr//ed flag regexps.
 538         $flag_renames_ref->{$regex}
 539             = (exists $flag_renames_ref->{$flag})
 540                 ? $flag_renames_ref->{$flag}
 541                 : $flag;
 542
 543         push @result, $regex;
 544     }
 545     return @result;
 546 }
 547
 548 # Does any extension in @extensions exist in %{$extensions_ref}?
 549 sub extension_found {
 550     my ($extensions_ref, @extensions) = @_;
 551
 552     foreach my $extension (@extensions) {
 553         if (exists $extensions_ref->{$extension}) {
 554             return 1;
 555         }
 556     }
 557     return 0;
 558 }
 559
 560
 561 # MAIN
 562
 563 # Parse command line arguments.
 564 my $option_help             = 0;
 565 my $option_version          = 0;
 566 my $option_pie              = 0;
 567 my $option_bindnow          = 0;
 568 my @option_ignore_arch      = ();
 569 my @option_ignore_flag      = ();
 570 my @option_ignore_arch_flag = ();
 571 my @option_ignore_line      = ();
 572 my @option_ignore_arch_line = ();
 573 my $option_all              = 0;
 574 my $option_arch             = undef;
 575 my $option_buildd           = 0;
 576    $option_color            = 0;
 577 if (not Getopt::Long::GetOptions(
 578             'help|h|?'           => \$option_help,
 579             'version'            => \$option_version,
 580             # Hardening options.
 581             'pie'                => \$option_pie,
 582             'bindnow'            => \$option_bindnow,
 583             'all'                => \$option_all,
 584             # Ignore.
 585             'ignore-arch=s'      => \@option_ignore_arch,
 586             'ignore-flag=s'      => \@option_ignore_flag,
 587             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 588             'ignore-line=s'      => \@option_ignore_line,
 589             'ignore-arch-line=s' => \@option_ignore_arch_line,
 590             # Misc.
 591             'color'              => \$option_color,
 592             'arch=s'             => \$option_arch,
 593             'buildd'             => \$option_buildd,
 594         )) {
 595     require Pod::Usage;
 596     Pod::Usage::pod2usage(2);
 597 }
 598 if ($option_help) {
 599     require Pod::Usage;
 600     Pod::Usage::pod2usage(1);
 601 }
 602 if ($option_version) {
 603     print <<"EOF";
 604 blhc $VERSION  Copyright (C) 2012-2013  Simon Ruderich
 605
 606 This program is free software: you can redistribute it and/or modify
 607 it under the terms of the GNU General Public License as published by
 608 the Free Software Foundation, either version 3 of the License, or
 609 (at your option) any later version.
 610
 611 This program is distributed in the hope that it will be useful,
 612 but WITHOUT ANY WARRANTY; without even the implied warranty of
 613 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 614 GNU General Public License for more details.
 615
 616 You should have received a copy of the GNU General Public License
 617 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 618 EOF
 619     exit 0;
 620 }
 621
 622 # Arguments missing.
 623 if (scalar @ARGV == 0) {
 624     require Pod::Usage;
 625     Pod::Usage::pod2usage(2);
 626 }
 627
 628 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 629 # installed on Debian's buildds.
 630 if (not $option_buildd) {
 631     require Term::ANSIColor;
 632 }
 633
 634 if ($option_all) {
 635     $option_pie     = 1;
 636     $option_bindnow = 1;
 637 }
 638
 639 # Precompiled ignores for faster lookup.
 640 my %option_ignore_arch_flag = ();
 641 my %option_ignore_arch_line = ();
 642
 643 # Strip flags which should be ignored.
 644 if (scalar @option_ignore_flag > 0) {
 645     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 646 }
 647 # Same for arch specific ignore flags, but only prepare here.
 648 if (scalar @option_ignore_arch_flag > 0) {
 649     foreach my $ignore (@option_ignore_arch_flag) {
 650         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 651
 652         if (not $ignore_arch or not $ignore_flag) {
 653             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 654                         . '("arch:flag" expected)' . "\n", $ignore;
 655             require Pod::Usage;
 656             Pod::Usage::pod2usage(2);
 657         }
 658
 659         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 660     }
 661 }
 662
 663 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 664 # faster with this.
 665 foreach my $flags (@flag_refs_all) {
 666     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 667 }
 668
 669 # Precompile ignore line regexps, also anchor at beginning and end of line.
 670 foreach my $ignore (@option_ignore_line) {
 671     $ignore = qr/^$ignore$/;
 672 }
 673 # Same for arch specific ignore lines.
 674 if (scalar @option_ignore_arch_line > 0) {
 675     foreach my $ignore (@option_ignore_arch_line) {
 676         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 677
 678         if (not $ignore_arch or not $ignore_line) {
 679             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 680                         . '("arch:line" expected)' . "\n", $ignore;
 681             require Pod::Usage;
 682             Pod::Usage::pod2usage(2);
 683         }
 684
 685         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 686     }
 687 }
 688
 689 # Final exit code.
 690 my $exit = 0;
 691
 692 FILE:
 693 foreach my $file (@ARGV) {
 694     print "checking '$file'...\n" if scalar @ARGV > 1;
 695
 696     -f $file or die "No such file: $file";
 697
 698     open my $fh, '<', $file or die $!;
 699
 700     # Architecture of this file.
 701     my $arch = $option_arch;
 702
 703     # Hardening options. Not all architectures support all hardening options.
 704     my $harden_format  = 1;
 705     my $harden_fortify = 1;
 706     my $harden_stack   = 1;
 707     my $harden_stack_strong = 1;
 708     my $harden_relro   = 1;
 709     my $harden_bindnow = $option_bindnow; # defaults to 0
 710     my $harden_pie     = $option_pie;     # defaults to 0
 711
 712     # Does this build log use ada? Ada also uses gcc as compiler but uses
 713     # different CFLAGS. But only perform ada checks if an ada compiler used
 714     # for performance reasons.
 715     my $ada = 0;
 716
 717     while (my $line = <$fh>) {
 718         # Detect architecture automatically unless overridden. For buildd logs
 719         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 720         # build logs which aren't built (wrong architecture, build error,
 721         # etc.).
 722         if (not $arch) {
 723             if (index($line, 'Build Architecture: ') == 0) {
 724                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 725             # For old logs (sbuild << 0.63.0-1).
 726             } elsif (index($line, 'Architecture: ') == 0) {
 727                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 728             }
 729         }
 730
 731         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 732         # check for hardening flags in buildd mode if an older dpkg-dev is
 733         # used. Default flags (-g -O2) are still checked.
 734         #
 735         # Packages which were built before 1.16.1 but used their own hardening
 736         # flags are not checked.
 737         #
 738         # Strong stack protector is used since dpkg 1.17.11.
 739         if ($option_buildd
 740                 and index($line, 'Toolchain package versions: ') == 0) {
 741             require Dpkg::Version;
 742
 743             my $disable = 1;
 744             my $disable_strong = 1;
 745
 746             if ($line =~ /\bdpkg-dev_(\S+)/) {
 747                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
 748                     $disable = 0;
 749                 }
 750                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
 751                     $disable_strong = 0;
 752                 }
 753             }
 754
 755             if ($disable) {
 756                 $harden_format  = 0;
 757                 $harden_fortify = 0;
 758                 $harden_stack   = 0;
 759                 $harden_relro   = 0;
 760                 $harden_bindnow = 0;
 761                 $harden_pie     = 0;
 762             }
 763             if ($disable_strong) {
 764                 $harden_stack_strong = 0;
 765             }
 766         }
 767
 768         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 769         # this was later dropped because upstream rejected the patch. Thus
 770         # build logs with these versions will have fortify hardening flags
 771         # enabled, even though they may be not correctly set and are missing
 772         # when build with later CMake versions. Thanks to Aron Xu for letting
 773         # me know.
 774         if (index($line, 'Package versions: ') == 0
 775                 and $line =~ /\bcmake_(\S+)/
 776                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 777             if (not $option_buildd) {
 778                 error_invalid_cmake($1);
 779                 $exit |= $exit_code{invalid_cmake};
 780             } else {
 781                 print "$buildd_tag{invalid_cmake}|$1|\n";
 782             }
 783         }
 784
 785         # Debian's build daemons use "Filtered Build-Depends:" (or just
 786         # "Build-Depends:" in older versions) for the build dependencies, but
 787         # pbuilder uses "Depends:"; support both.
 788         if (index($line, 'Filtered Build-Depends: ') == 0
 789                 or index($line, 'Build-Depends: ') == 0
 790                 or index($line, 'Depends: ') == 0) {
 791             # If hardening wrapper is used (wraps calls to gcc and adds
 792             # hardening flags automatically) we can't perform any checks,
 793             # abort.
 794             if ($line =~ /\bhardening-wrapper\b/) {
 795                 if (not $option_buildd) {
 796                     error_hardening_wrapper();
 797                     $exit |= $exit_code{hardening_wrapper};
 798                 } else {
 799                     print "$buildd_tag{hardening_wrapper}||\n";
 800                 }
 801                 next FILE;
 802             }
 803
 804             # Ada compiler.
 805             if ($line =~ /\bgnat\b/) {
 806                 $ada = 1;
 807             }
 808         }
 809
 810         # We skip over unimportant lines at the beginning of the log to
 811         # prevent false positives.
 812         last if index($line, 'dpkg-buildpackage: ') == 0;
 813     }
 814
 815     # Input lines, contain only the lines with compiler commands.
 816     my @input = ();
 817     # Non-verbose lines in the input. Used to reduce calls to
 818     # is_non_verbose_build() (which is quite slow) in the second loop when
 819     # it's already clear if a line is non-verbose or not.
 820     my @input_nonverbose = ();
 821
 822     my $continuation = 0;
 823     my $complete_line = undef;
 824     my $non_verbose;
 825     while (my $line = <$fh>) {
 826         # And stop at the end of the build log. Package details (reported by
 827         # the buildd logs) are not important for us. This also prevents false
 828         # positives.
 829         last if index($line, 'Build finished at ') == 0
 830                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 831
 832         if (not $continuation) {
 833             $non_verbose = 0;
 834         }
 835
 836         # Detect architecture automatically unless overridden.
 837         if (not $arch
 838                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 839             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 840
 841             # Old buildd logs use e.g. "host architecture is alpha", remove
 842             # the "is", otherwise debarch_to_debtriplet() will not detect the
 843             # architecture.
 844             if (index($arch, 'is ') == 0) {
 845                 $arch = substr $arch, 3;
 846             }
 847         }
 848
 849         # Ignore compiler warnings for now.
 850         next if $line =~ /$warning_regex/o;
 851
 852         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 853             # Remove all ANSI color sequences which are sometimes used in
 854             # non-verbose builds.
 855             $line = Term::ANSIColor::colorstrip($line);
 856             # Also strip '\0xf' (delete previous character), used by Elinks'
 857             # build system.
 858             $line =~ s/\x0f//g;
 859             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 860             # what it does).
 861             $line =~ s/\033\(B//g;
 862         }
 863
 864         # Check if this line indicates a non verbose build.
 865         my $skip = 0;
 866         $non_verbose |= is_non_verbose_build($line, undef, \$skip);
 867         next if $skip;
 868
 869         # One line may contain multiple commands (";"). Treat each one as
 870         # single line. parse_line() is slow, only use it when necessary.
 871         my @line = (index($line, ';') == -1)
 872                  ? ($line)
 873                  : map {
 874                        # Ensure newline at the line end - necessary for
 875                        # correct parsing later.
 876                        $_ =~ s/\s+$//;
 877                        $_ .= "\n";
 878                    } Text::ParseWords::parse_line(';', 1, $line);
 879         foreach my $line (@line) {
 880             if ($continuation) {
 881                 $continuation = 0;
 882
 883                 # Join lines, but leave the "\" in place so it's clear where
 884                 # the original line break was.
 885                 chomp $complete_line;
 886                 $complete_line .= ' ' . $line;
 887             }
 888             # Line continuation, line ends with "\".
 889             if ($line =~ /\\$/) {
 890                 $continuation = 1;
 891                 # Start line continuation.
 892                 if (not defined $complete_line) {
 893                     $complete_line = $line;
 894                 }
 895                 next;
 896             }
 897
 898             # Use the complete line if a line continuation occurred.
 899             if (defined $complete_line) {
 900                 $line = $complete_line;
 901                 $complete_line = undef;
 902             }
 903
 904             # Ignore lines with no compiler commands.
 905             next if not $non_verbose
 906                     and not $line =~ /$cc_regex_normal/o;
 907             # Ignore lines with no filenames with extensions. May miss some
 908             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
 909             # a problem as the log will most likely contain other non-verbose
 910             # commands which are detected.
 911             next if not $non_verbose
 912                     and not $line =~ /$file_extension_regex/o;
 913
 914             # Ignore false positives.
 915             #
 916             # `./configure` output.
 917             next if not $non_verbose
 918                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
 919             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 920                                 [Cc]ompiler[\s.]*:?\s+
 921                                 /x;
 922             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
 923                                 \s*=\s*$cc_regex_full
 924                                 # optional compiler options, don't allow
 925                                 # "everything" here to prevent false negatives
 926                                 \s*(?:\s-\S+)*\s*$}xo;
 927             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
 928             # line (or similar for other architectures) which gets recognized
 929             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
 930             # C++ files. No hardening flags are relevant during this step,
 931             # thus ignore `moc-qt*` lines. The resulting files will be
 932             # compiled in a separate step (and therefore checked).
 933             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
 934                                \s.+\s
 935                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
 936                                \s}x;
 937             # Ignore false positives when the line contains only CC=gcc but no
 938             # other gcc command.
 939             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
 940                 my $before = $1;
 941                 my $after  = $2;
 942                 next if     not $before =~ /$cc_regex_normal/o
 943                         and not $after  =~ /$cc_regex_normal/o;
 944             }
 945
 946             # Check if additional hardening options were used. Used to ensure
 947             # they are used for the complete build.
 948             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
 949                                                          @def_ldflags_pie);
 950             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 951
 952             push @input, $line;
 953             push @input_nonverbose, $non_verbose;
 954         }
 955     }
 956
 957     close $fh or die $!;
 958
 959     # Ignore arch if requested.
 960     if (scalar @option_ignore_arch > 0 and $arch) {
 961         foreach my $ignore (@option_ignore_arch) {
 962             if ($arch eq $ignore) {
 963                 print "ignoring architecture '$arch'\n";
 964                 next FILE;
 965             }
 966         }
 967     }
 968
 969     if (scalar @input == 0) {
 970         if (not $option_buildd) {
 971             print "No compiler commands!\n";
 972             $exit |= $exit_code{no_compiler_commands};
 973         } else {
 974             print "$buildd_tag{no_compiler_commands}||\n";
 975         }
 976         next FILE;
 977     }
 978
 979     if ($option_buildd) {
 980         $statistics{commands} += scalar @input;
 981     }
 982
 983     # Option or auto detected.
 984     if ($arch) {
 985         # The following was partially copied from dpkg-dev 1.17.11
 986         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 987         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 988         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 989         # later. Keep it in sync.
 990
 991         require Dpkg::Arch;
 992         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
 993
 994         # Disable unsupported hardening options.
 995         if ($os !~ /^(?:linux|knetbsd|hurd)$/ or
 996                 $cpu =~ /^(?:hppa|mips|mipsel|avr32)$/) {
 997             $harden_pie = 0;
 998         }
 999         if ($cpu =~ /^(?:ia64|alpha|mips|mipsel|hppa)$/ or $arch eq 'arm') {
1000             $harden_stack = 0;
1001             $harden_stack_strong = 0;
1002         }
1003         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1004             $harden_relro   = 0;
1005             $harden_bindnow = 0;
1006         }
1007     }
1008
1009     # Default values.
1010     my @cflags   = @def_cflags;
1011     my @cxxflags = @def_cxxflags;
1012     my @cppflags = @def_cppflags;
1013     my @ldflags  = @def_ldflags;
1014     # Check the specified hardening options, same order as dpkg-buildflags.
1015     if ($harden_pie) {
1016         @cflags   = (@cflags,   @def_cflags_pie);
1017         @cxxflags = (@cxxflags, @def_cflags_pie);
1018         @ldflags  = (@ldflags,  @def_ldflags_pie);
1019     }
1020     if ($harden_stack_strong) {
1021         @cflags   = (@cflags,   @def_cflags_stack_strong);
1022         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1023     } elsif ($harden_stack) {
1024         @cflags   = (@cflags,   @def_cflags_stack);
1025         @cxxflags = (@cxxflags, @def_cflags_stack);
1026     }
1027     if ($harden_fortify) {
1028         @cflags   = (@cflags,   @def_cflags_fortify);
1029         @cxxflags = (@cxxflags, @def_cflags_fortify);
1030         @cppflags = (@cppflags, @def_cppflags_fortify);
1031     }
1032     if ($harden_format) {
1033         @cflags   = (@cflags,   @def_cflags_format);
1034         @cxxflags = (@cxxflags, @def_cflags_format);
1035     }
1036     if ($harden_relro) {
1037         @ldflags = (@ldflags, @def_ldflags_relro);
1038     }
1039     if ($harden_bindnow) {
1040         @ldflags = (@ldflags, @def_ldflags_bindnow);
1041     }
1042
1043     # Stores normal CFLAGS when @cflags_ada are temporarily used.
1044     my @cflags_backup;
1045     # Ada CFLAGS, only set if ada is used.
1046     my @cflags_ada;
1047     # Ada doesn't support format hardening flags, see #680117 for more
1048     # information. Filter them out if ada is used.
1049     if ($ada and $harden_format) {
1050         @cflags_ada = grep {
1051             my $ok = 1;
1052             foreach my $flag (@def_cflags_format) {
1053                 $ok = 0 if $_ eq $flag;
1054             }
1055             $ok;
1056         } @cflags;
1057     }
1058
1059     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1060     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1061     # as long as @def_cppflags_fortify contains only one variable.
1062     if (scalar @def_cppflags_fortify == 0) {
1063         $harden_fortify = 0;
1064     }
1065
1066     # Ignore flags for this arch if requested.
1067     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1068         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1069
1070         remove_flags(\@local_flag_refs,
1071                      \%flag_renames,
1072                      @{$option_ignore_arch_flag{$arch}});
1073     }
1074
1075     my @ignore_line = @option_ignore_line;
1076     # Ignore lines for this arch if requested.
1077     if ($arch and exists $option_ignore_arch_line{$arch}) {
1078         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1079     }
1080
1081 LINE:
1082     for (my $i = 0; $i < scalar @input; $i++) {
1083         my $line = $input[$i];
1084
1085         # Ignore line if requested.
1086         foreach my $ignore (@ignore_line) {
1087             next LINE if $line =~ /$ignore/;
1088         }
1089
1090         my $skip = 0;
1091         if ($input_nonverbose[$i]
1092                 and is_non_verbose_build($line, $input[$i + 1], \$skip)) {
1093             if (not $option_buildd) {
1094                 error_non_verbose_build($line);
1095                 $exit |= $exit_code{non_verbose_build};
1096             } else {
1097                 $statistics{commands_nonverbose}++;
1098             }
1099             next;
1100         }
1101         # Even if it's a verbose build, we might have to skip this line (see
1102         # is_non_verbose_build()).
1103         next if $skip;
1104
1105         # Remove everything until and including the compiler command. Makes
1106         # checks easier and faster.
1107         $line =~ s/^.*?$cc_regex//o;
1108         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1109         # the brace and similar characters at the line end.
1110         $line =~ s/['")]+$//;
1111
1112         # Skip unnecessary tests when only preprocessing.
1113         my $flag_preprocess = 0;
1114
1115         my $dependency = 0;
1116         my $preprocess = 0;
1117         my $compile    = 0;
1118         my $link       = 0;
1119
1120         # Preprocess, compile, assemble.
1121         if ($line =~ /\s(-E|-S|-c)\b/) {
1122             $preprocess      = 1;
1123             $flag_preprocess = 1 if $1 eq '-E';
1124             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1125         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1126         # -MT -MQ) are always used with -M/-MM.
1127         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1128             $dependency = 1;
1129         # Otherwise assume we are linking.
1130         } else {
1131             $link = 1;
1132         }
1133
1134         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1135         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1136             $dependency      = 0;
1137             $flag_preprocess = 0;
1138         }
1139
1140         # Dependency generation for Makefiles, no preprocessing or other flags
1141         # needed.
1142         next if $dependency;
1143
1144         # Get all file extensions on this line.
1145         my @extensions = $line =~ /$file_extension_regex/go;
1146         # Ignore all unknown extensions to speedup the search below.
1147         @extensions = grep { exists $extension{$_} } @extensions;
1148
1149         # These file types don't require preprocessing.
1150         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1151             $preprocess = 0;
1152         }
1153         # These file types require preprocessing.
1154         if (extension_found(\%extensions_preprocess, @extensions)) {
1155             $preprocess = 1;
1156         }
1157
1158         if (not $flag_preprocess) {
1159             # If there are source files then it's compiling/linking in one
1160             # step and we must check both. We only check for source files
1161             # here, because header files cause too many false positives.
1162             if (extension_found(\%extensions_compile_link, @extensions)) {
1163                 # Assembly files don't need CFLAGS.
1164                 if (not extension_found(\%extensions_compile, @extensions)
1165                         and extension_found(\%extensions_no_compile, @extensions)) {
1166                     $compile = 0;
1167                 # But the rest does.
1168                 } else {
1169                     $compile = 1;
1170                 }
1171             # No compilable extensions found, either linking or compiling
1172             # header flags.
1173             #
1174             # If there are also no object files we are just compiling headers
1175             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1176             # to our liberal checks for compiler lines, this also reduces the
1177             # number of false positives considerably.
1178             } elsif ($link
1179                     and not extension_found(\%extensions_object, @extensions)) {
1180                 $link = 0;
1181             }
1182         }
1183
1184         my $compile_cpp = 0;
1185         my $compile_ada = 0;
1186         # Assume CXXFLAGS are required when a C++ file is specified in the
1187         # compiler line.
1188         if ($compile
1189                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1190             $compile     = 0;
1191             $compile_cpp = 1;
1192         # Ada needs special CFLAGS, use them if only ada files are compiled.
1193         } elsif ($ada
1194                     and $compile
1195                     and array_equal(\@extensions,
1196                                     \@source_no_preprocess_compile_ada)) {
1197             $compile_ada = 1;
1198             @cflags_backup = @cflags;
1199             @cflags        = @cflags_ada;
1200         }
1201
1202         if ($option_buildd) {
1203             $statistics{preprocess}++  if $preprocess;
1204             $statistics{compile}++     if $compile;
1205             $statistics{compile_cpp}++ if $compile_cpp;
1206             $statistics{link}++        if $link;
1207         }
1208
1209         # Check if there are flags indicating a debug build. If that's true,
1210         # skip the check for -O2. This prevents fortification, but that's fine
1211         # for a debug build.
1212         if (any_flags_used($line, @def_cflags_debug)) {
1213             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1214             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1215         }
1216
1217         # Check hardening flags.
1218         my @missing;
1219         if ($compile and not all_flags_used($line, \@missing, @cflags)
1220                 # Libraries linked with -fPIC don't have to (and can't) be
1221                 # linked with -fPIE as well. It's no error if only PIE flags
1222                 # are missing.
1223                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1224                 # Assume dpkg-buildflags returns the correct flags.
1225                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1226             if (not $option_buildd) {
1227                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1228                 $exit |= $exit_code{flags_missing};
1229             } else {
1230                 $statistics{compile_missing}++;
1231             }
1232         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1233                 # Libraries linked with -fPIC don't have to (and can't) be
1234                 # linked with -fPIE as well. It's no error if only PIE flags
1235                 # are missing.
1236                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1237                 # Assume dpkg-buildflags returns the correct flags.
1238                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1239             if (not $option_buildd) {
1240                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1241                 $exit |= $exit_code{flags_missing};
1242             } else {
1243                 $statistics{compile_cpp_missing}++;
1244             }
1245         }
1246         if ($preprocess
1247                 and (not all_flags_used($line, \@missing, @cppflags)
1248                     # The fortify flag might be overwritten, detect that.
1249                      or ($harden_fortify
1250                          and cppflags_fortify_broken($line, \@missing)))
1251                 # Assume dpkg-buildflags returns the correct flags.
1252                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1253             if (not $option_buildd) {
1254                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1255                 $exit |= $exit_code{flags_missing};
1256             } else {
1257                 $statistics{preprocess_missing}++;
1258             }
1259         }
1260         if ($link and not all_flags_used($line, \@missing, @ldflags)
1261                 # Same here, -fPIC conflicts with -fPIE.
1262                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1263                 # Assume dpkg-buildflags returns the correct flags.
1264                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1265             if (not $option_buildd) {
1266                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1267                 $exit |= $exit_code{flags_missing};
1268             } else {
1269                 $statistics{link_missing}++;
1270             }
1271         }
1272
1273         # Restore normal CFLAGS.
1274         if ($compile_ada) {
1275             @cflags = @cflags_backup;
1276         }
1277     }
1278 }
1279
1280 # Print statistics for buildd mode, only output in this mode.
1281 if ($option_buildd) {
1282     my @warning;
1283
1284     if ($statistics{preprocess_missing}) {
1285         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1286                                $statistics{preprocess_missing},
1287                                $statistics{preprocess};
1288     }
1289     if ($statistics{compile_missing}) {
1290         push @warning, sprintf 'CFLAGS %d (of %d)',
1291                                $statistics{compile_missing},
1292                                $statistics{compile};
1293     }
1294     if ($statistics{compile_cpp_missing}) {
1295         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1296                                $statistics{compile_cpp_missing},
1297                                $statistics{compile_cpp};
1298     }
1299     if ($statistics{link_missing}) {
1300         push @warning, sprintf 'LDFLAGS %d (of %d)',
1301                                $statistics{link_missing},
1302                                $statistics{link};
1303     }
1304     if (scalar @warning) {
1305         local $" = ', '; # array join string
1306         print "$buildd_tag{flags_missing}|@warning missing|\n";
1307     }
1308
1309     if ($statistics{commands_nonverbose}) {
1310         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1311                $statistics{commands_nonverbose},
1312                $statistics{commands},
1313     }
1314 }
1315
1316
1317 exit $exit;
1318
1319
1320 __END__
1321
1322 =head1 NAME
1323
1324 blhc - build log hardening check, checks build logs for missing hardening flags
1325
1326 =head1 SYNOPSIS
1327
1328 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1329
1330 =head1 DESCRIPTION
1331
1332 blhc is a small tool which checks build logs for missing hardening flags. It's
1333 licensed under the GPL 3 or later.
1334
1335 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1336 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1337 official buildd build logs)) to help maintainers detect missing hardening
1338 flags in their packages.
1339
1340 Only gcc is detected as compiler at the moment. If other compilers support
1341 hardening flags as well, please report them.
1342
1343 If there's no output, no flags are missing and the build log is fine.
1344
1345 See F<README> for details about performed checks, auto-detection and
1346 limitations.
1347
1348 =head1 OPTIONS
1349
1350 =over 8
1351
1352 =item B<--all>
1353
1354 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1355 auto detected.
1356
1357 =item B<--arch> I<architecture>
1358
1359 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1360 disables hardening flags not available on this architecture. Is detected
1361 automatically if dpkg-buildpackage is used.
1362
1363 =item B<--bindnow>
1364
1365 Force check for all +bindnow hardening flags. By default it's auto detected.
1366
1367 =item B<--buildd>
1368
1369 Special mode for buildds when automatically parsing log files. The following
1370 changes are in effect:
1371
1372 =over 2
1373
1374 =item *
1375
1376 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1377 possible tags.
1378
1379 =item *
1380
1381 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1382 detected).
1383
1384 =item *
1385
1386 Don't require Term::ANSIColor.
1387
1388 =item *
1389
1390 Return exit code 0, unless there was a error (-I, -W messages don't count as
1391 error).
1392
1393 =back
1394
1395 =item B<--color>
1396
1397 Use colored (ANSI) output for warning messages.
1398
1399 =item B<--ignore-arch> I<arch>
1400
1401 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1402
1403 Used to prevent false positives. This option can be specified multiple times.
1404
1405 =item B<--ignore-arch-flag> I<arch>:I<flag>
1406
1407 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1408
1409 =item B<--ignore-arch-line> I<arch>:I<line>
1410
1411 Like B<--ignore-line>, but only ignore line on I<arch>.
1412
1413 =item B<--ignore-flag> I<flag>
1414
1415 Don't print an error when the specific flag is missing in a compiler line.
1416 I<flag> is a string.
1417
1418 Used to prevent false positives. This option can be specified multiple times.
1419
1420 =item B<--ignore-line> I<regex>
1421
1422 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1423 at the beginning and end of the line to prevent false negatives.
1424
1425 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1426 warnings (which have line continuation resolved).
1427
1428 Used to prevent false positives. This option can be specified multiple times.
1429
1430 =item B<--pie>
1431
1432 Force check for all +pie hardening flags. By default it's auto detected.
1433
1434 =item B<-h -? --help>
1435
1436 Print available options.
1437
1438 =item B<--version>
1439
1440 Print version number and license.
1441
1442 =back
1443
1444 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1445 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1446 all other commands as well.
1447
1448 =head1 EXAMPLES
1449
1450 Normal usage, parse a single log file.
1451
1452     blhc path/to/log/file
1453
1454 If there's no output, no flags are missing and the build log is fine.
1455
1456 Parse multiple log files. The exit code is ORed over all files.
1457
1458     blhc path/to/directory/with/log/files/*
1459
1460 Don't treat missing C<-g> as error:
1461
1462     blhc --ignore-flag -g path/to/log/file
1463
1464 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1465
1466     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1467
1468 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1469 false positive.
1470
1471     blhc --ignore-line '\./script gcc file' path/to/log/file
1472
1473 Ignore lines matching C<./script gcc file> somewhere in the line.
1474
1475     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1476
1477 Use blhc with pbuilder.
1478
1479     pbuilder path/to/package.dsc | tee path/log/file
1480     blhc path/to/file || echo flags missing
1481
1482 =head1 BUILDD TAGS
1483
1484 The following tags are used in I<--buildd> mode. In braces the additional data
1485 which is displayed.
1486
1487 =over 2
1488
1489 =item B<I-hardening-wrapper-used>
1490
1491 The package uses hardening-wrapper which intercepts calls to gcc and adds
1492 hardening flags. The build log doesn't contain any hardening flags and thus
1493 can't be checked by blhc.
1494
1495 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1496
1497 Build log contains lines which hide the real compiler flags. For example:
1498
1499     CC test-a.c
1500     CC test-b.c
1501     CC test-c.c
1502     LD test
1503
1504 Most of the time either C<export V=1> or C<export verbose=1> in
1505 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1506 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1507 patched to remove the C<@>s hiding the real compiler commands.
1508
1509 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1510
1511 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1512
1513 =item B<I-invalid-cmake-used> (version)
1514
1515 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1516 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1517 patch was rejected by upstream and later reverted in Debian. Thus those two
1518 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1519 handle them (for example by passing them to CFLAGS). To prevent false
1520 negatives just blacklist those two versions.
1521
1522 =item B<I-no-compiler-commands>
1523
1524 No compiler commands were detected. Either the log contains none or they were
1525 not correctly detected by blhc (please report the bug in this case).
1526
1527 =back
1528
1529 =head1 EXIT STATUS
1530
1531 The exit status is a "bit mask", each listed status is ORed when the error
1532 condition occurs to get the result.
1533
1534 =over 4
1535
1536 =item B<0>
1537
1538 Success.
1539
1540 =item B<1>
1541
1542 No compiler commands were found.
1543
1544 =item B<2>
1545
1546 Invalid arguments/options given to blhc.
1547
1548 =item B<4>
1549
1550 Non verbose build.
1551
1552 =item B<8>
1553
1554 Missing hardening flags.
1555
1556 =item B<16>
1557
1558 Hardening wrapper detected, no tests performed.
1559
1560 =item B<32>
1561
1562 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1563 TAGS"> for a detailed explanation.
1564
1565 =back
1566
1567 =head1 AUTHOR
1568
1569 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1570
1571 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1572 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1573
1574 =head1 LICENSE AND COPYRIGHT
1575
1576 Copyright (C) 2012-2013 by Simon Ruderich
1577
1578 This program is free software: you can redistribute it and/or modify
1579 it under the terms of the GNU General Public License as published by
1580 the Free Software Foundation, either version 3 of the License, or
1581 (at your option) any later version.
1582
1583 This program is distributed in the hope that it will be useful,
1584 but WITHOUT ANY WARRANTY; without even the implied warranty of
1585 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1586 GNU General Public License for more details.
1587
1588 You should have received a copy of the GNU General Public License
1589 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1590
1591 =head1 SEE ALSO
1592
1593 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1594
1595 =cut