bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2021  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.12';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+|gfortran|mpicc|mpicxx|mpifort)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full_prefix = qr/
  42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
  43     /x;
  44 my $cc_regex_full = qr/
  45     (?:$cc_regex_full_prefix-)?
  46     $cc_regex
  47     /x;
  48 # Regex to check if a line contains a compiler command.
  49 my $cc_regex_normal = qr/
  50     \b$cc_regex(?:\s|\\)
  51     /x;
  52 # Regex to catch (GCC) compiler warnings.
  53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  54 # Regex to catch libtool commands and not lines which show commands executed
  55 # by libtool (e.g. libtool: link: ...).
  56 my $libtool_regex = qr/\blibtool["']?\s.*--mode=/;
  57 my $libtool_link_regex = qr/\blibtool: link: /;
  58
  59 # List of source file extensions which require preprocessing.
  60 my @source_preprocess_compile_cpp = (
  61     # C++
  62     qw( cc cp cxx cpp CPP c++ C ),
  63     # Objective-C++
  64     qw( mm M ),
  65 );
  66 my @source_preprocess_compile_fortran = (
  67     # Fortran
  68     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  69 );
  70 my @source_preprocess_compile = (
  71     # C
  72     qw( c ),
  73     # Objective-C
  74     qw( m ),
  75     # (Objective-)C++
  76     @source_preprocess_compile_cpp,
  77     # Fortran
  78     @source_preprocess_compile_fortran,
  79 );
  80 my @source_preprocess_no_compile = (
  81     # Assembly
  82     qw( S sx ),
  83 );
  84 my @source_preprocess = (
  85     @source_preprocess_compile,
  86     @source_preprocess_no_compile,
  87 );
  88 # List of source file extensions which don't require preprocessing.
  89 my @source_no_preprocess_compile_cpp = (
  90     # C++
  91     qw( ii ),
  92     # Objective-C++
  93     qw( mii ),
  94 );
  95 my @source_no_preprocess_compile_ada = (
  96     # Ada source
  97     qw( ada ),
  98     # Ada body
  99     qw( adb ),
 100 );
 101 my @source_no_preprocess_compile_fortran = (
 102     # Fortran
 103     qw( f for ftn f90 f95 f03 f08 ),
 104 );
 105 my @source_no_preprocess_compile = (
 106     # C
 107     qw( i ),
 108     # (Objective-)C++
 109     @source_no_preprocess_compile_cpp,
 110     # Objective-C
 111     qw( mi ),
 112     # Fortran
 113     @source_no_preprocess_compile_fortran,
 114     # Ada
 115     @source_no_preprocess_compile_ada,
 116 );
 117 my @source_no_preprocess_no_compile_ada = (
 118     # Ada specification
 119     qw( ads ),
 120 );
 121 my @source_no_preprocess_no_compile = (
 122     # Assembly
 123     qw( s ),
 124     # Ada
 125     @source_no_preprocess_no_compile_ada,
 126 );
 127 my @source_no_preprocess = (
 128     @source_no_preprocess_compile,
 129     @source_no_preprocess_no_compile,
 130 );
 131 # List of header file extensions which require preprocessing.
 132 my @header_preprocess = (
 133     # C, C++, Objective-C, Objective-C++
 134     qw( h ),
 135     # C++
 136     qw( hh H hp hxx hpp HPP h++ tcc ),
 137 );
 138 # Object files.
 139 my @object = (
 140     # Normal object files.
 141     qw ( o ),
 142     # Libtool object files.
 143     qw ( lo la ),
 144     # Dynamic libraries. bzip2 uses .sho.
 145     qw ( so sho ),
 146     # Static libraries.
 147     qw ( a ),
 148 );
 149
 150 # Hashes for fast extensions lookup to check if a file falls in one of these
 151 # categories.
 152 my %extensions_no_preprocess = map { $_ => 1 } (
 153     # There's no @header_no_preprocess.
 154     @source_no_preprocess,
 155 );
 156 my %extensions_preprocess = map { $_ => 1 } (
 157     @header_preprocess,
 158     @source_preprocess,
 159 );
 160 my %extensions_compile_link = map { $_ => 1 } (
 161     @source_preprocess,
 162     @source_no_preprocess,
 163 );
 164 my %extensions_compile = map { $_ => 1 } (
 165     @source_preprocess_compile,
 166     @source_no_preprocess_compile,
 167 );
 168 my %extensions_no_compile = map { $_ => 1 } (
 169     @source_preprocess_no_compile,
 170     @source_no_preprocess_no_compile,
 171 );
 172 my %extensions_compile_cpp = map { $_ => 1 } (
 173     @source_preprocess_compile_cpp,
 174     @source_no_preprocess_compile_cpp,
 175 );
 176 my %extensions_ada = map { $_ => 1 } (
 177     @source_no_preprocess_compile_ada,
 178     @source_no_preprocess_no_compile_ada,
 179 );
 180 my %extensions_fortran = map { $_ => 1 } (
 181     @source_no_preprocess_compile_fortran,
 182     @source_preprocess_compile_fortran,
 183 );
 184 my %extensions_object = map { $_ => 1 } (
 185     @object,
 186 );
 187 my %extension = map { $_ => 1 } (
 188     @source_no_preprocess,
 189     @header_preprocess,
 190     @source_preprocess,
 191     @object,
 192 );
 193
 194 # Regexp to match file extensions.
 195 my $file_extension_regex = qr/
 196     \s
 197     \S+             # Filename without extension.
 198     \.
 199     ([^\/\\.,;:\s]+)# File extension.
 200     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 201                     # word characters at the end and because \b matches double
 202                     # extensions (like .cpp.o). Works always as all lines are
 203                     # terminated with "\n".
 204     /x;
 205
 206 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 207 # real regexps below for better execution speed).
 208 my @def_cflags = (
 209     '-g',
 210     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
 211 );
 212 my @def_cflags_debug = (
 213     # These flags indicate a debug build which disables checks for -O2.
 214     '-O0',
 215     '-Og',
 216 );
 217 my @def_cflags_format = (
 218     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 219     '-Werror=format-security', # implies -Wformat-security
 220 );
 221 my @def_cflags_fortify = (
 222     # fortify needs at least -O1, but -O2 is recommended anyway
 223 );
 224 my @def_cflags_stack = (
 225     '-fstack-protector', # keep first, used by cflags_stack_broken()
 226     '--param[= ]ssp-buffer-size=4',
 227 );
 228 my @def_cflags_stack_strong = (
 229     '-fstack-protector-strong', # keep first, used by cflags_stack_broken()
 230 );
 231 my @def_cflags_stack_bad = (
 232     # Blacklist all stack protector options for simplicity.
 233     '-fno-stack-protector',
 234     '-fno-stack-protector-all',
 235     '-fno-stack-protector-strong',
 236 );
 237 my @def_cflags_pie = (
 238     '-fPIE',
 239 );
 240 my @def_cxxflags = (
 241     @def_cflags,
 242 );
 243 # @def_cxxflags_* is the same as @def_cflags_*.
 244 my @def_cppflags = ();
 245 my @def_cppflags_fortify = (
 246     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 247     # If you add another flag fix hack below (search for "Hack to fix") and
 248     # $def_cppflags_fortify[0].
 249 );
 250 my @def_cppflags_fortify_bad = (
 251     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 252     '-U_FORTIFY_SOURCE',
 253     '-D_FORTIFY_SOURCE=0',
 254     '-D_FORTIFY_SOURCE=1',
 255 );
 256 my @def_ldflags = ();
 257 my @def_ldflags_relro = (
 258     '-Wl,(?:-z,)?relro',
 259 );
 260 my @def_ldflags_bindnow = (
 261     '-Wl,(?:-z,)?now',
 262 );
 263 my @def_ldflags_pie = (
 264     '-fPIE',
 265     '-pie',
 266 );
 267 my @def_ldflags_pic = (
 268     '-fPIC',
 269     '-fpic',
 270     '-shared',
 271 );
 272 # References to all flags checked by the flag checker.
 273 my @flag_refs = (
 274     \@def_cflags,
 275     \@def_cflags_format,
 276     \@def_cflags_fortify,
 277     \@def_cflags_stack,
 278     \@def_cflags_stack_strong,
 279     \@def_cflags_stack_bad,
 280     \@def_cflags_pie,
 281     \@def_cxxflags,
 282     \@def_cppflags,
 283     \@def_cppflags_fortify,
 284     \@def_ldflags,
 285     \@def_ldflags_relro,
 286     \@def_ldflags_bindnow,
 287     \@def_ldflags_pie,
 288 );
 289 # References to all used flags.
 290 my @flag_refs_all = (
 291     @flag_refs,
 292     \@def_cflags_debug,
 293     \@def_cppflags_fortify_bad,
 294     \@def_ldflags_pic,
 295 );
 296 # Renaming rules for the output so the regex parts are not visible. Also
 297 # stores string values of flag regexps above, see compile_flag_regexp().
 298 my %flag_renames = (
 299     '-O(?:2|3)'                    => '-O2',
 300     '-Wformat(?:=2)?'              => '-Wformat',
 301     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 302     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 303     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 304 );
 305
 306 my %exit_code = (
 307     no_compiler_commands => 1 << 0,
 308     # used by POD::Usage => 1 << 1,
 309     non_verbose_build    => 1 << 2,
 310     flags_missing        => 1 << 3,
 311     hardening_wrapper    => 1 << 4,
 312     invalid_cmake        => 1 << 5,
 313 );
 314
 315 my %buildd_tag = (
 316     no_compiler_commands => 'I-no-compiler-commands',
 317     non_verbose_build    => 'W-compiler-flags-hidden',
 318     flags_missing        => 'W-dpkg-buildflags-missing',
 319     hardening_wrapper    => 'I-hardening-wrapper-used',
 320     invalid_cmake        => 'I-invalid-cmake-used',
 321 );
 322
 323 # Statistics of missing flags and non-verbose build commands. Used for
 324 # $option_buildd.
 325 my %statistics = (
 326     preprocess          => 0,
 327     preprocess_missing  => 0,
 328     compile             => 0,
 329     compile_missing     => 0,
 330     compile_cpp         => 0,
 331     compile_cpp_missing => 0,
 332     link                => 0,
 333     link_missing        => 0,
 334     commands            => 0,
 335     commands_nonverbose => 0,
 336 );
 337
 338 # Use colored (ANSI) output?
 339 my $option_color;
 340
 341
 342 # FUNCTIONS
 343
 344 sub split_line {
 345     my ($line) = @_;
 346
 347     my @work = ($line);
 348     foreach my $delim (';', '&&', '||') {
 349         my @x;
 350         foreach (@work) {
 351             push @x, Text::ParseWords::parse_line(qr/\Q$delim\E/, 1, $_);
 352         }
 353         @work = @x;
 354     }
 355
 356     return map {
 357         # Ensure newline at the line end - necessary for
 358         # correct parsing later.
 359         $_ =~ s/\s+$//;
 360         $_ .= "\n";
 361     } @work;
 362 }
 363
 364 sub error_flags {
 365     my ($message, $missing_flags_ref, $flag_renames_ref, $line, $number) = @_;
 366
 367     # Get string value of qr//-escaped regexps and if requested rename them.
 368     my @missing_flags = map {
 369             $flag_renames_ref->{$_}
 370         } @{$missing_flags_ref};
 371
 372     my $flags = join ' ', @missing_flags;
 373     printf '%d:', $number if defined $number;
 374     printf '%s (%s)%s %s',
 375            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 376            $line;
 377
 378     return;
 379 }
 380 sub error_non_verbose_build {
 381     my ($line, $number) = @_;
 382
 383     printf '%d:', $number if defined $number;
 384     printf '%s%s %s',
 385            error_color('NONVERBOSE BUILD', 'red'),
 386            error_color(':', 'yellow'),
 387            $line;
 388
 389     return;
 390 }
 391 sub error_invalid_cmake {
 392     my ($version) = @_;
 393
 394     printf "%s%s %s\n",
 395             error_color('INVALID CMAKE', 'red'),
 396             error_color(':', 'yellow'),
 397             $version;
 398
 399     return;
 400 }
 401 sub error_hardening_wrapper {
 402     printf "%s%s %s\n",
 403             error_color('HARDENING WRAPPER', 'red'),
 404             error_color(':', 'yellow'),
 405             'no checks possible, aborting';
 406
 407     return;
 408 }
 409 sub error_color {
 410     my ($message, $color) = @_;
 411
 412     if ($option_color) {
 413         return Term::ANSIColor::colored($message, $color);
 414     } else {
 415         return $message;
 416     }
 417 }
 418
 419 sub any_flags_used {
 420     my ($line, @flags) = @_;
 421
 422     foreach my $flag (@flags) {
 423         return 1 if $line =~ /$flag/;
 424     }
 425
 426     return 0;
 427 }
 428 sub all_flags_used {
 429     my ($line, $missing_flags_ref, @flags) = @_;
 430
 431     my @missing_flags = ();
 432     foreach my $flag (@flags) {
 433         if (not $line =~ /$flag/) {
 434             push @missing_flags, $flag;
 435         }
 436     }
 437
 438     return 1 if scalar @missing_flags == 0;
 439
 440     @{$missing_flags_ref} = @missing_flags;
 441     return 0;
 442 }
 443 # Check if any of \@bad_flags occurs after $good_flag. Doesn't check if
 444 # $good_flag is present.
 445 sub flag_overwritten {
 446     my ($line, $good_flag, $bad_flags) = @_;
 447
 448     if (not any_flags_used($line, @{$bad_flags})) {
 449         return 0;
 450     }
 451
 452     my $bad_pos = 0;
 453     foreach my $flag (@{$bad_flags}) {
 454         while ($line =~ /$flag/g) {
 455             if ($bad_pos < $+[0]) {
 456                 $bad_pos = $+[0];
 457             }
 458         }
 459     }
 460     my $good_pos = 0;
 461     while ($line =~ /$good_flag/g) {
 462         $good_pos = $+[0];
 463     }
 464     if ($good_pos > $bad_pos) {
 465         return 0;
 466     }
 467     return 1;
 468 }
 469
 470 sub cppflags_fortify_broken {
 471     my ($line, $missing_flags) = @_;
 472
 473     # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 474     my $fortify_source = $def_cppflags_fortify[0];
 475
 476     # Some build systems enable/disable fortify source multiple times, check
 477     # the final result.
 478     if (not flag_overwritten($line,
 479                              $fortify_source,
 480                              \@def_cppflags_fortify_bad)) {
 481         return 0;
 482     }
 483     push @{$missing_flags}, $fortify_source;
 484     return 1;
 485 }
 486
 487 sub cflags_stack_broken {
 488     my ($line, $missing_flags, $strong) = @_;
 489
 490     my $flag = $strong ? $def_cflags_stack_strong[0]
 491                        : $def_cflags_stack[0];
 492
 493     if (not flag_overwritten($line, $flag, \@def_cflags_stack_bad)) {
 494         return 0;
 495     }
 496     push @{$missing_flags}, $flag;
 497     return 1;
 498 }
 499
 500 # Modifies $missing_flags_ref array.
 501 sub pic_pie_conflict {
 502     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 503
 504     return 0 if not $pie;
 505     return 0 if not any_flags_used($line, @def_ldflags_pic);
 506
 507     my %flags = map { $_ => 1 } @flags_pie;
 508
 509     # Remove all PIE flags from @missing_flags as they are not required with
 510     # -fPIC.
 511     my @result = grep {
 512         not exists $flags{$_}
 513     } @{$missing_flags_ref};
 514     @{$missing_flags_ref} = @result;
 515
 516     # We got a conflict when no flags are left, thus only PIE flags were
 517     # missing. If other flags were missing abort because the conflict is not
 518     # the problem.
 519     return scalar @result == 0;
 520 }
 521
 522 sub is_non_verbose_build {
 523     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
 524
 525     if ($line =~ /$libtool_regex/o) {
 526         # libtool's --silent hides the real compiler flags.
 527         if ($line =~ /\s--silent/) {
 528             return 1;
 529         # If --silent is not present, skip this line as some compiler flags
 530         # might be missing (e.g. -fPIE) which are handled correctly by libtool
 531         # internally. libtool displays the real compiler command on the next
 532         # line, so the flags are checked as usual.
 533         } else {
 534             ${$skip_ref} = 1;
 535             return 0;
 536         }
 537     }
 538
 539     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 540                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 541                 or $line =~ /^\s*[][\/0-9 ]*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 542                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 543                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 544         return 0;
 545     }
 546
 547     # False positives.
 548     #
 549     # C++ compiler setting.
 550     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 551     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 552     # "Compiling" non binary files.
 553     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|pyx|el)['"]?\s*(?:\.\.\.|because it changed\.)?$/;
 554     return 0 if $line =~ /^\s*[Cc]ompiling catalog \S+\.po\b/;
 555     # "Compiling" with no file name.
 556     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 557         # $file_extension_regex may need spaces around the filename.
 558         return 0 if not " $1 " =~ /$file_extension_regex/o;
 559     }
 560
 561     my $file = $1;
 562
 563     # On the first pass we only check if this line is verbose or not.
 564     return 1 if not defined $input_ref;
 565
 566     # Second pass, we have access to the next lines.
 567     ${$skip_ref} = 0;
 568
 569     # CMake and other build systems print the non-verbose messages also when
 570     # building verbose. If a compiler and the file name occurs in the next
 571     # lines, treat it as verbose build.
 572     if (defined $file) {
 573         # Get filename, we can't use the complete path as only parts of it are
 574         # used in the real compiler command.
 575         $file =~ m{/([^/\s]+)$};
 576         $file = $1;
 577
 578         for (my $i = 1; $i <= $line_count; $i++) {
 579             my $next_line = $input_ref->[$line_offset + $i];
 580             last unless defined $next_line;
 581
 582             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 583                 # Not a non-verbose line, but we still have to skip the
 584                 # current line as it doesn't contain any compiler commands.
 585                 ${$skip_ref} = 1;
 586                 return 0;
 587             }
 588         }
 589     }
 590
 591     return 1;
 592 }
 593
 594 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
 595 sub remove_flags {
 596     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 597
 598     my %removes = map { $_ => 1 } @flags;
 599     foreach my $flags (@{$flag_refs_ref}) {
 600         @{$flags} = grep {
 601             # Flag found as string.
 602             not exists $removes{$_}
 603             # Flag found as string representation of regexp.
 604                 and (not defined $flag_renames_ref->{$_}
 605                         or not exists $removes{$flag_renames_ref->{$_}})
 606         } @{$flags};
 607     }
 608
 609     return;
 610 }
 611
 612 # Modifies $flag_renames_ref hash.
 613 sub compile_flag_regexp {
 614     my ($flag_renames_ref, @flags) = @_;
 615
 616     my @result = ();
 617     foreach my $flag (@flags) {
 618         # Compile flag regexp for faster execution.
 619         my $regex = qr/\s$flag(?:\s|\\)/;
 620
 621         # Store flag name in replacement string for correct flags in messages
 622         # with qr//ed flag regexps.
 623         $flag_renames_ref->{$regex}
 624             = (exists $flag_renames_ref->{$flag})
 625                 ? $flag_renames_ref->{$flag}
 626                 : $flag;
 627
 628         push @result, $regex;
 629     }
 630     return @result;
 631 }
 632
 633 # Does any extension in @extensions exist in %{$extensions_ref}?
 634 sub extension_found {
 635     my ($extensions_ref, @extensions) = @_;
 636
 637     foreach my $extension (@extensions) {
 638         if (exists $extensions_ref->{$extension}) {
 639             return 1;
 640         }
 641     }
 642     return 0;
 643 }
 644
 645
 646 # MAIN
 647
 648 # Parse command line arguments.
 649 my $option_help             = 0;
 650 my $option_version          = 0;
 651 my $option_pie              = 0;
 652 my $option_bindnow          = 0;
 653 my @option_ignore_arch      = ();
 654 my @option_ignore_flag      = ();
 655 my @option_ignore_arch_flag = ();
 656 my @option_ignore_line      = ();
 657 my @option_ignore_arch_line = ();
 658 my $option_all              = 0;
 659 my $option_arch             = undef;
 660 my $option_buildd           = 0;
 661 my $option_debian           = 0;
 662    $option_color            = 0;
 663 my $option_line_numbers     = 0;
 664 if (not Getopt::Long::GetOptions(
 665             'help|h|?'           => \$option_help,
 666             'version'            => \$option_version,
 667             # Hardening options.
 668             'pie'                => \$option_pie,
 669             'bindnow'            => \$option_bindnow,
 670             'all'                => \$option_all,
 671             # Ignore.
 672             'ignore-arch=s'      => \@option_ignore_arch,
 673             'ignore-flag=s'      => \@option_ignore_flag,
 674             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 675             'ignore-line=s'      => \@option_ignore_line,
 676             'ignore-arch-line=s' => \@option_ignore_arch_line,
 677             # Misc.
 678             'color'              => \$option_color,
 679             'arch=s'             => \$option_arch,
 680             'buildd'             => \$option_buildd,
 681             'debian'             => \$option_debian,
 682             'line-numbers'       => \$option_line_numbers,
 683         )) {
 684     require Pod::Usage;
 685     Pod::Usage::pod2usage(2);
 686 }
 687 if ($option_help) {
 688     require Pod::Usage;
 689     Pod::Usage::pod2usage(1);
 690 }
 691 if ($option_version) {
 692     print <<"EOF";
 693 blhc $VERSION  Copyright (C) 2012-2021  Simon Ruderich
 694
 695 This program is free software: you can redistribute it and/or modify
 696 it under the terms of the GNU General Public License as published by
 697 the Free Software Foundation, either version 3 of the License, or
 698 (at your option) any later version.
 699
 700 This program is distributed in the hope that it will be useful,
 701 but WITHOUT ANY WARRANTY; without even the implied warranty of
 702 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 703 GNU General Public License for more details.
 704
 705 You should have received a copy of the GNU General Public License
 706 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 707 EOF
 708     exit 0;
 709 }
 710
 711 # Arguments missing.
 712 if (scalar @ARGV == 0) {
 713     require Pod::Usage;
 714     Pod::Usage::pod2usage(2);
 715 }
 716
 717 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 718 # installed on Debian's buildds.
 719 if (not $option_buildd) {
 720     require Term::ANSIColor;
 721 }
 722
 723 if ($option_all) {
 724     $option_pie     = 1;
 725     $option_bindnow = 1;
 726 }
 727
 728 # Precompiled ignores for faster lookup.
 729 my %option_ignore_arch_flag = ();
 730 my %option_ignore_arch_line = ();
 731
 732 # Strip flags which should be ignored.
 733 if (scalar @option_ignore_flag > 0) {
 734     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 735 }
 736 # Same for arch specific ignore flags, but only prepare here.
 737 if (scalar @option_ignore_arch_flag > 0) {
 738     foreach my $ignore (@option_ignore_arch_flag) {
 739         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 740
 741         if (not $ignore_arch or not $ignore_flag) {
 742             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 743                         . '("arch:flag" expected)' . "\n", $ignore;
 744             require Pod::Usage;
 745             Pod::Usage::pod2usage(2);
 746         }
 747
 748         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 749     }
 750 }
 751
 752 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 753 # faster with this.
 754 foreach my $flags (@flag_refs_all) {
 755     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 756 }
 757
 758 # Precompile ignore line regexps, also anchor at beginning and end of line.
 759 # Additional entries are also extracted from the build log, see below.
 760 foreach my $ignore (@option_ignore_line) {
 761     $ignore = qr/^$ignore$/;
 762 }
 763 # Same for arch specific ignore lines.
 764 if (scalar @option_ignore_arch_line > 0) {
 765     foreach my $ignore (@option_ignore_arch_line) {
 766         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 767
 768         if (not $ignore_arch or not $ignore_line) {
 769             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 770                         . '("arch:line" expected)' . "\n", $ignore;
 771             require Pod::Usage;
 772             Pod::Usage::pod2usage(2);
 773         }
 774
 775         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 776     }
 777 }
 778
 779 # Final exit code.
 780 my $exit = 0;
 781
 782 FILE:
 783 foreach my $file (@ARGV) {
 784     print "checking '$file'...\n" if scalar @ARGV > 1;
 785
 786     -f $file or die "No such file: $file";
 787
 788     open my $fh, '<', $file or die $!;
 789
 790     # Architecture of this file.
 791     my $arch = $option_arch;
 792
 793     # Hardening options. Not all architectures support all hardening options.
 794     my $harden_format  = 1;
 795     my $harden_fortify = 1;
 796     my $harden_stack   = 1;
 797     my $harden_stack_strong = 1;
 798     my $harden_relro   = 1;
 799     my $harden_bindnow = $option_bindnow; # defaults to 0
 800     my $harden_pie     = $option_pie;     # defaults to 0
 801
 802     # Number of parallel jobs to prevent false positives when detecting
 803     # non-verbose builds. As not all jobs declare the number of parallel jobs
 804     # use a large enough default.
 805     my $parallel = 10;
 806
 807     # Don't check for PIE flags if automatically applied by the compiler. Only
 808     # used in buildd and Debian mode.
 809     my $disable_harden_pie = 0;
 810     if ($option_debian) {
 811         $disable_harden_pie = 1;
 812     }
 813
 814     my $number = 0;
 815     while (my $line = <$fh>) {
 816         $number++;
 817
 818         # Detect architecture automatically unless overridden. For buildd logs
 819         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 820         # build logs which aren't built (wrong architecture, build error,
 821         # etc.).
 822         if (not $arch) {
 823             if (index($line, 'Build Architecture: ') == 0) {
 824                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 825             # For old logs (sbuild << 0.63.0-1).
 826             } elsif (index($line, 'Architecture: ') == 0) {
 827                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 828             }
 829         }
 830
 831         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 832         # check for hardening flags in buildd mode if an older dpkg-dev is
 833         # used. Default flags (-g -O2) are still checked.
 834         #
 835         # Packages which were built before 1.16.1 but used their own hardening
 836         # flags are not checked.
 837         #
 838         # Strong stack protector is used since dpkg 1.17.11.
 839         #
 840         # Recent GCC versions automatically use PIE (only on supported
 841         # architectures) and dpkg respects this properly since 1.18.15 and
 842         # doesn't pass PIE flags manually.
 843         if ($option_buildd
 844                 and index($line, 'Toolchain package versions: ') == 0) {
 845             require Dpkg::Version;
 846
 847             my $disable = 1;
 848             my $disable_strong = 1;
 849
 850             if ($line =~ /\bdpkg-dev_(\S+)/) {
 851                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
 852                     $disable = 0;
 853                 }
 854                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
 855                     $disable_strong = 0;
 856                 }
 857                 if (Dpkg::Version::version_compare($1, '1.18.15') >= 0) {
 858                     $disable_harden_pie = 1;
 859                 }
 860             }
 861
 862             if ($disable) {
 863                 $harden_format  = 0;
 864                 $harden_fortify = 0;
 865                 $harden_stack   = 0;
 866                 $harden_relro   = 0;
 867                 $harden_bindnow = 0;
 868                 $harden_pie     = 0;
 869             }
 870             if ($disable_strong) {
 871                 $harden_stack_strong = 0;
 872             }
 873         }
 874
 875         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 876         # this was later dropped because upstream rejected the patch. Thus
 877         # build logs with these versions will have fortify hardening flags
 878         # enabled, even though they may be not correctly set and are missing
 879         # when build with later CMake versions. Thanks to Aron Xu for letting
 880         # me know.
 881         if (index($line, 'Package versions: ') == 0
 882                 and $line =~ /\bcmake_(\S+)/
 883                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 884             if (not $option_buildd) {
 885                 error_invalid_cmake($1);
 886                 $exit |= $exit_code{invalid_cmake};
 887             } else {
 888                 print "$buildd_tag{invalid_cmake}|$1|\n";
 889             }
 890         }
 891
 892         # Debian's build daemons use "Filtered Build-Depends:" (or just
 893         # "Build-Depends:" in older versions) for the build dependencies, but
 894         # pbuilder uses "Depends:"; support both.
 895         if (index($line, 'Filtered Build-Depends: ') == 0
 896                 or index($line, 'Build-Depends: ') == 0
 897                 or index($line, 'Depends: ') == 0) {
 898             # If hardening wrapper is used (wraps calls to gcc and adds
 899             # hardening flags automatically) we can't perform any checks,
 900             # abort.
 901             if ($line =~ /\bhardening-wrapper\b/) {
 902                 if (not $option_buildd) {
 903                     error_hardening_wrapper();
 904                     $exit |= $exit_code{hardening_wrapper};
 905                 } else {
 906                     print "$buildd_tag{hardening_wrapper}||\n";
 907                 }
 908                 next FILE;
 909             }
 910         }
 911
 912         # This flags is not always available, but if it is use it.
 913         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
 914             $parallel = $1 * 2;
 915         }
 916
 917         # We skip over unimportant lines at the beginning of the log to
 918         # prevent false positives.
 919         last if index($line, 'dpkg-buildpackage: ') == 0;
 920     }
 921
 922     # Input lines, contain only the lines with compiler commands.
 923     my @input = ();
 924     # Non-verbose lines in the input. Used to reduce calls to
 925     # is_non_verbose_build() (which is quite slow) in the second loop when
 926     # it's already clear if a line is non-verbose or not.
 927     my @input_nonverbose = ();
 928     # Input line number.
 929     my @input_number = ();
 930
 931     my $continuation = 0;
 932     my $complete_line = undef;
 933     my $non_verbose;
 934     while (my $line = <$fh>) {
 935         $number++;
 936
 937         # And stop at the end of the build log. Package details (reported by
 938         # the buildd logs) are not important for us. This also prevents false
 939         # positives.
 940         last if index($line, 'Build finished at ') == 0
 941                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 942
 943         if (not $continuation) {
 944             $non_verbose = 0;
 945         }
 946
 947         # Detect architecture automatically unless overridden.
 948         if (not $arch
 949                 and index($line, 'dpkg-buildpackage: info: host architecture ') == 0) {
 950             $arch = substr $line, 43, -1; # -1 to ignore '\n' at the end
 951         # Older versions of dpkg-buildpackage
 952         } elsif (not $arch
 953                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 954             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 955
 956             # Old buildd logs use e.g. "host architecture is alpha", remove
 957             # the "is", otherwise debarch_to_debtriplet() will not detect the
 958             # architecture.
 959             if (index($arch, 'is ') == 0) {
 960                 $arch = substr $arch, 3;
 961             }
 962         }
 963
 964         # Permit dynamic excludes from within the build log to ignore false
 965         # positives. Cannot use a separate config file as we often only have
 966         # the build log itself.
 967         if (index($line, 'blhc: ignore-line-regexp: ') == 0) {
 968             my $ignore = substr $line, 26, -1; # -1 to ignore '\n' at the end
 969             push @option_ignore_line, qr/^$ignore$/;
 970             next;
 971         }
 972
 973         next if $line =~ /^\s*#/;
 974         # Ignore compiler warnings for now.
 975         next if $line =~ /$warning_regex/o;
 976
 977         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 978             # Remove all ANSI color sequences which are sometimes used in
 979             # non-verbose builds.
 980             $line = Term::ANSIColor::colorstrip($line);
 981             # Also strip '\0xf' (delete previous character), used by Elinks'
 982             # build system.
 983             $line =~ s/\x0f//g;
 984             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 985             # what it does).
 986             $line =~ s/\033\(B//g;
 987         }
 988
 989         # Check if this line indicates a non verbose build.
 990         my $skip = 0;
 991         $non_verbose |= is_non_verbose_build($line, \$skip);
 992         next if $skip;
 993
 994         # Treat each command as a single line so we don't ignore valid
 995         # commands when handling false positives. split_line() is slow, only
 996         # use it when necessary.
 997         my @line = ($line !~ /(?:;|&&|\|\|)/)
 998                  ? ($line)
 999                  : split_line($line);
1000         foreach my $line (@line) {
1001             if ($continuation) {
1002                 $continuation = 0;
1003
1004                 # Join lines, but leave the "\" in place so it's clear where
1005                 # the original line break was.
1006                 chomp $complete_line;
1007                 $complete_line .= ' ' . $line;
1008             }
1009             # Line continuation, line ends with "\".
1010             if ($line =~ /\\$/) {
1011                 $continuation = 1;
1012                 # Start line continuation.
1013                 if (not defined $complete_line) {
1014                     $complete_line = $line;
1015                 }
1016                 next;
1017             }
1018
1019             # Use the complete line if a line continuation occurred.
1020             if (defined $complete_line) {
1021                 $line = $complete_line;
1022                 $complete_line = undef;
1023             }
1024
1025             # Ignore lines with no compiler commands.
1026             next if not $non_verbose
1027                     and not $line =~ /$cc_regex_normal/o;
1028             # Ignore lines with no filenames with extensions. May miss some
1029             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
1030             # a problem as the log will most likely contain other non-verbose
1031             # commands which are detected.
1032             next if not $non_verbose
1033                     and not $line =~ /$file_extension_regex/o;
1034
1035             # Ignore false positives.
1036             #
1037             # `./configure` output.
1038             next if not $non_verbose
1039                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
1040             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
1041                                 [Cc]ompiler[\s.]*:?\s+
1042                                 /x;
1043             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
1044                                 \s*=\s*$cc_regex_full
1045                                 # optional compiler options, don't allow
1046                                 # "everything" here to prevent false negatives
1047                                 \s*(?:\s-\S+)*\s*$}xo;
1048             # `echo` is never a compiler command
1049             next if $line =~ /^\s*echo\s/;
1050             # Ignore calls to `make` because they can contain environment
1051             # variables which look like compiler commands, e.g. CC=).
1052             next if $line =~ /^\s*make\s/;
1053             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
1054             # line (or similar for other architectures) which gets recognized
1055             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
1056             # C++ files. No hardening flags are relevant during this step,
1057             # thus ignore `moc-qt*` lines. The resulting files will be
1058             # compiled in a separate step (and therefore checked).
1059             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
1060                                \s.+\s
1061                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
1062                                \s}x;
1063             # Ignore false positives when the line contains only CC=gcc but no
1064             # other gcc command.
1065             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
1066                 my $before = $1;
1067                 my $after  = $2;
1068                 next if     not $before =~ /$cc_regex_normal/o
1069                         and not $after  =~ /$cc_regex_normal/o;
1070             }
1071             # Ignore false positives caused by gcc -v. It outputs a line
1072             # looking like a normal compiler line but which is sometimes
1073             # missing hardening flags, although the normal compiler line
1074             # contains them.
1075             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
1076                                    [0-9.]+/cc1(?:plus)?}xo;
1077             # Ignore false positive with `rm` which may remove files which
1078             # look like a compiler executable thus causing the line to be
1079             # treated as a normal compiler line.
1080             next if $line =~ m{^\s*rm\s+};
1081             next if $line =~ m{^\s*dwz\s+};
1082             # Some build systems emit "gcc > file".
1083             next if $line =~ m{$cc_regex_normal\s*>\s*\S+}o;
1084             # Hex output may contain "cc".
1085             next if $line =~ m#(?:\b[0-9a-fA-F]{2,}\b\s*){5}#;
1086             # Meson build output
1087             next if $line =~ /^C\+\+ linker for the host machine: /;
1088             # Embedded `gcc -print-*` commands
1089             next if $line =~ /`$cc_regex_normal\s*[^`]*-print-\S+`/;
1090
1091             # Check if additional hardening options were used. Used to ensure
1092             # they are used for the complete build.
1093             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
1094                                                          @def_ldflags_pie);
1095             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
1096
1097             push @input, $line;
1098             push @input_nonverbose, $non_verbose;
1099             push @input_number, $number if $option_line_numbers;
1100         }
1101     }
1102
1103     close $fh or die $!;
1104
1105     # Ignore arch if requested.
1106     if (scalar @option_ignore_arch > 0 and $arch) {
1107         foreach my $ignore (@option_ignore_arch) {
1108             if ($arch eq $ignore) {
1109                 print "ignoring architecture '$arch'\n";
1110                 next FILE;
1111             }
1112         }
1113     }
1114
1115     if (scalar @input == 0) {
1116         if (not $option_buildd) {
1117             print "No compiler commands!\n";
1118             $exit |= $exit_code{no_compiler_commands};
1119         } else {
1120             print "$buildd_tag{no_compiler_commands}||\n";
1121         }
1122         next FILE;
1123     }
1124
1125     if ($option_buildd) {
1126         $statistics{commands} += scalar @input;
1127     }
1128
1129     # Option or auto detected.
1130     if ($arch) {
1131         # The following was partially copied from dpkg-dev 1.20.5
1132         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, _add_build_flags()),
1133         # copyright Raphaël Hertzog <hertzog@debian.org>, Guillem Jover
1134         # <guillem@debian.org>, Kees Cook <kees@debian.org>, Canonical, Ltd.
1135         # licensed under GPL version 2 or later. Keep it in sync.
1136
1137         require Dpkg::Arch;
1138         my ($os, $cpu);
1139         # Recent dpkg versions use a quadruplet for arch. Support both.
1140         eval {
1141             (undef, undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtuple($arch);
1142         };
1143         if ($@) {
1144             (undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1145         }
1146
1147         my %builtin_pie_arch = map { $_ => 1 } qw(
1148             amd64
1149             arm64
1150             armel
1151             armhf
1152             hurd-i386
1153             i386
1154             kfreebsd-amd64
1155             kfreebsd-i386
1156             mips
1157             mipsel
1158             mips64el
1159             powerpc
1160             ppc64
1161             ppc64el
1162             riscv64
1163             s390x
1164             sparc
1165             sparc64
1166         );
1167
1168         # Disable unsupported hardening options.
1169         if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/
1170                 or $cpu =~ /^(?:hppa|avr32)$/) {
1171             $harden_pie = 0;
1172         }
1173         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1174             $harden_stack = 0;
1175             $harden_stack_strong = 0;
1176         }
1177         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1178             $harden_relro   = 0;
1179             $harden_bindnow = 0;
1180         }
1181
1182         if ($disable_harden_pie and exists $builtin_pie_arch{$arch}) {
1183             $harden_pie = 0;
1184         }
1185     }
1186
1187     # Default values.
1188     my @cflags   = @def_cflags;
1189     my @cxxflags = @def_cxxflags;
1190     my @cppflags = @def_cppflags;
1191     my @ldflags  = @def_ldflags;
1192     # Check the specified hardening options, same order as dpkg-buildflags.
1193     if ($harden_pie) {
1194         @cflags   = (@cflags,   @def_cflags_pie);
1195         @cxxflags = (@cxxflags, @def_cflags_pie);
1196         @ldflags  = (@ldflags,  @def_ldflags_pie);
1197     }
1198     if ($harden_stack_strong) {
1199         @cflags   = (@cflags,   @def_cflags_stack_strong);
1200         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1201     } elsif ($harden_stack) {
1202         @cflags   = (@cflags,   @def_cflags_stack);
1203         @cxxflags = (@cxxflags, @def_cflags_stack);
1204     }
1205     if ($harden_fortify) {
1206         @cflags   = (@cflags,   @def_cflags_fortify);
1207         @cxxflags = (@cxxflags, @def_cflags_fortify);
1208         @cppflags = (@cppflags, @def_cppflags_fortify);
1209     }
1210     if ($harden_format) {
1211         @cflags   = (@cflags,   @def_cflags_format);
1212         @cxxflags = (@cxxflags, @def_cflags_format);
1213     }
1214     if ($harden_relro) {
1215         @ldflags = (@ldflags, @def_ldflags_relro);
1216     }
1217     if ($harden_bindnow) {
1218         @ldflags = (@ldflags, @def_ldflags_bindnow);
1219     }
1220
1221     # Ada doesn't support format hardening flags, see #680117 for more
1222     # information. Same for fortran.
1223     my @cflags_backup;
1224     my @cflags_noformat = grep {
1225         my $ok = 1;
1226         foreach my $flag (@def_cflags_format) {
1227             $ok = 0 if $_ eq $flag;
1228         }
1229         $ok;
1230     } @cflags;
1231
1232     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1233     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1234     # as long as @def_cppflags_fortify contains only one variable.
1235     if (scalar @def_cppflags_fortify == 0) {
1236         $harden_fortify = 0;
1237     }
1238
1239     # Ignore flags for this arch if requested.
1240     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1241         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1242
1243         remove_flags(\@local_flag_refs,
1244                      \%flag_renames,
1245                      @{$option_ignore_arch_flag{$arch}});
1246     }
1247
1248     my @ignore_line = @option_ignore_line;
1249     # Ignore lines for this arch if requested.
1250     if ($arch and exists $option_ignore_arch_line{$arch}) {
1251         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1252     }
1253
1254 LINE:
1255     for (my $i = 0; $i < scalar @input; $i++) {
1256         my $line = $input[$i];
1257
1258         # Ignore line if requested.
1259         foreach my $ignore (@ignore_line) {
1260             next LINE if $line =~ /$ignore/;
1261         }
1262
1263         my $skip = 0;
1264         if ($input_nonverbose[$i]
1265                 and is_non_verbose_build($line, \$skip,
1266                                          \@input, $i, $parallel)) {
1267             if (not $option_buildd) {
1268                 error_non_verbose_build($line, $input_number[$i]);
1269                 $exit |= $exit_code{non_verbose_build};
1270             } else {
1271                 $statistics{commands_nonverbose}++;
1272             }
1273             next;
1274         }
1275         # Even if it's a verbose build, we might have to skip this line (see
1276         # is_non_verbose_build()).
1277         next if $skip;
1278
1279         my $orig_line = $line;
1280
1281         # Remove everything until and including the compiler command. Makes
1282         # checks easier and faster.
1283         $line =~ s/^.*?$cc_regex//o;
1284         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1285         # the brace and similar characters at the line end.
1286         $line =~ s/['")]+$//;
1287
1288         # Skip unnecessary tests when only preprocessing.
1289         my $flag_preprocess = 0;
1290
1291         my $dependency = 0;
1292         my $preprocess = 0;
1293         my $compile    = 0;
1294         my $link       = 0;
1295
1296         # Preprocess, compile, assemble.
1297         if ($line =~ /\s(-E|-S|-c)\b/) {
1298             $preprocess      = 1;
1299             $flag_preprocess = 1 if $1 eq '-E';
1300             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1301         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1302         # -MT -MQ) are always used with -M/-MM.
1303         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1304             $dependency = 1;
1305         # Otherwise assume we are linking.
1306         } else {
1307             $link = 1;
1308         }
1309
1310         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1311         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1312             $dependency      = 0;
1313             $flag_preprocess = 0;
1314         }
1315
1316         # Dependency generation for Makefiles, no preprocessing or other flags
1317         # needed.
1318         next if $dependency;
1319
1320         # Get all file extensions on this line.
1321         my @extensions = $line =~ /$file_extension_regex/go;
1322         # Ignore all unknown extensions to speedup the search below.
1323         @extensions = grep { exists $extension{$_} } @extensions;
1324
1325         # These file types don't require preprocessing.
1326         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1327             $preprocess = 0;
1328         }
1329         # These file types require preprocessing.
1330         if (extension_found(\%extensions_preprocess, @extensions)) {
1331             # Prevent false positives with "libtool: link: g++ -include test.h
1332             # .." compiler lines.
1333             if ($orig_line !~ /$libtool_link_regex/o) {
1334                 $preprocess = 1;
1335             }
1336         }
1337
1338         if (not $flag_preprocess) {
1339             # If there are source files then it's compiling/linking in one
1340             # step and we must check both. We only check for source files
1341             # here, because header files cause too many false positives.
1342             if (extension_found(\%extensions_compile_link, @extensions)) {
1343                 # Assembly files don't need CFLAGS.
1344                 if (not extension_found(\%extensions_compile, @extensions)
1345                         and extension_found(\%extensions_no_compile, @extensions)) {
1346                     $compile = 0;
1347                 # But the rest does.
1348                 } else {
1349                     $compile = 1;
1350                 }
1351             # No compilable extensions found, either linking or compiling
1352             # header flags.
1353             #
1354             # If there are also no object files we are just compiling headers
1355             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1356             # to our liberal checks for compiler lines, this also reduces the
1357             # number of false positives considerably.
1358             } elsif ($link
1359                     and not extension_found(\%extensions_object, @extensions)) {
1360                 $link = 0;
1361             }
1362         }
1363
1364         my $compile_cpp = 0;
1365         my $restore_cflags = 0;
1366         # Assume CXXFLAGS are required when a C++ file is specified in the
1367         # compiler line.
1368         if ($compile
1369                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1370             $compile     = 0;
1371             $compile_cpp = 1;
1372         # Ada needs special CFLAGS
1373         } elsif (extension_found(\%extensions_ada, @extensions)) {
1374             $restore_cflags = 1;
1375             $preprocess = 0; # Ada uses no CPPFLAGS
1376             @cflags_backup = @cflags;
1377             @cflags        = @cflags_noformat;
1378         # Same for fortran
1379         } elsif (extension_found(\%extensions_fortran, @extensions)) {
1380             $restore_cflags = 1;
1381             @cflags_backup = @cflags;
1382             @cflags        = @cflags_noformat;
1383         }
1384
1385         if ($option_buildd) {
1386             $statistics{preprocess}++  if $preprocess;
1387             $statistics{compile}++     if $compile;
1388             $statistics{compile_cpp}++ if $compile_cpp;
1389             $statistics{link}++        if $link;
1390         }
1391
1392         # Check if there are flags indicating a debug build. If that's true,
1393         # skip the check for -O2. This prevents fortification, but that's fine
1394         # for a debug build.
1395         if (any_flags_used($line, @def_cflags_debug)) {
1396             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1397             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1398         }
1399
1400         # Check hardening flags.
1401         my @missing;
1402         if ($compile and (not all_flags_used($line, \@missing, @cflags)
1403                     or (($harden_stack or $harden_stack_strong)
1404                         and cflags_stack_broken($line, \@missing,
1405                                                 $harden_stack_strong)))
1406                 # Libraries linked with -fPIC don't have to (and can't) be
1407                 # linked with -fPIE as well. It's no error if only PIE flags
1408                 # are missing.
1409                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1410                 # Assume dpkg-buildflags returns the correct flags.
1411                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1412             if (not $option_buildd) {
1413                 error_flags('CFLAGS missing', \@missing, \%flag_renames,
1414                             $input[$i], $input_number[$i]);
1415                 $exit |= $exit_code{flags_missing};
1416             } else {
1417                 $statistics{compile_missing}++;
1418             }
1419         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1420                 # Libraries linked with -fPIC don't have to (and can't) be
1421                 # linked with -fPIE as well. It's no error if only PIE flags
1422                 # are missing.
1423                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1424                 # Assume dpkg-buildflags returns the correct flags.
1425                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1426             if (not $option_buildd) {
1427                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames,
1428                             $input[$i], $input_number[$i]);
1429                 $exit |= $exit_code{flags_missing};
1430             } else {
1431                 $statistics{compile_cpp_missing}++;
1432             }
1433         }
1434         if ($preprocess
1435                 and (not all_flags_used($line, \@missing, @cppflags)
1436                     # The fortify flag might be overwritten, detect that.
1437                      or ($harden_fortify
1438                          and cppflags_fortify_broken($line, \@missing)))
1439                 # Assume dpkg-buildflags returns the correct flags.
1440                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1441             if (not $option_buildd) {
1442                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames,
1443                             $input[$i], $input_number[$i]);
1444                 $exit |= $exit_code{flags_missing};
1445             } else {
1446                 $statistics{preprocess_missing}++;
1447             }
1448         }
1449         if ($link and not all_flags_used($line, \@missing, @ldflags)
1450                 # Same here, -fPIC conflicts with -fPIE.
1451                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1452                 # Assume dpkg-buildflags returns the correct flags.
1453                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1454             if (not $option_buildd) {
1455                 error_flags('LDFLAGS missing', \@missing, \%flag_renames,
1456                             $input[$i], $input_number[$i]);
1457                 $exit |= $exit_code{flags_missing};
1458             } else {
1459                 $statistics{link_missing}++;
1460             }
1461         }
1462
1463         # Restore normal CFLAGS.
1464         if ($restore_cflags) {
1465             @cflags = @cflags_backup;
1466         }
1467     }
1468 }
1469
1470 # Print statistics for buildd mode, only output in this mode.
1471 if ($option_buildd) {
1472     my @warning;
1473
1474     if ($statistics{preprocess_missing}) {
1475         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1476                                $statistics{preprocess_missing},
1477                                $statistics{preprocess};
1478     }
1479     if ($statistics{compile_missing}) {
1480         push @warning, sprintf 'CFLAGS %d (of %d)',
1481                                $statistics{compile_missing},
1482                                $statistics{compile};
1483     }
1484     if ($statistics{compile_cpp_missing}) {
1485         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1486                                $statistics{compile_cpp_missing},
1487                                $statistics{compile_cpp};
1488     }
1489     if ($statistics{link_missing}) {
1490         push @warning, sprintf 'LDFLAGS %d (of %d)',
1491                                $statistics{link_missing},
1492                                $statistics{link};
1493     }
1494     if (scalar @warning) {
1495         local $" = ', '; # array join string
1496         print "$buildd_tag{flags_missing}|@warning missing|\n";
1497     }
1498
1499     if ($statistics{commands_nonverbose}) {
1500         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1501                $statistics{commands_nonverbose},
1502                $statistics{commands},
1503     }
1504 }
1505
1506
1507 exit $exit;
1508
1509
1510 __END__
1511
1512 =head1 NAME
1513
1514 blhc - build log hardening check, checks build logs for missing hardening flags
1515
1516 =head1 SYNOPSIS
1517
1518 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1519
1520 =head1 DESCRIPTION
1521
1522 blhc is a small tool which checks build logs for missing hardening flags. It's
1523 licensed under the GPL 3 or later.
1524
1525 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1526 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1527 official buildd build logs)) to help maintainers detect missing hardening
1528 flags in their packages.
1529
1530 Only gcc is detected as compiler at the moment. If other compilers support
1531 hardening flags as well, please report them.
1532
1533 If there's no output, no flags are missing and the build log is fine.
1534
1535 See F<README> for details about performed checks, auto-detection and
1536 limitations.
1537
1538 =head1 FALSE POSITIVES
1539
1540 To suppress false positives you can embed the following string in the build
1541 log:
1542
1543     blhc: ignore-line-regexp: REGEXP
1544
1545 All lines fully matching REGEXP (see B<--ignore-line> for details) will be
1546 ignored.
1547
1548 Please use this feature sparingly so that missing flags are not overlooked. If
1549 you find false positives which affect more packages please report a bug.
1550
1551 To generate this string simply use echo in C<debian/rules>; make sure to use @
1552 to suppress the echo command itself as it could also trigger a false positive.
1553 If the build process takes a long time edit the C<.build> file in place and
1554 tweak the ignore string until B<blhc --all --debian package.build> no longer
1555 reports any false positives.
1556
1557 =head1 OPTIONS
1558
1559 =over 8
1560
1561 =item B<--all>
1562
1563 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1564 auto detected.
1565
1566 =item B<--arch> I<architecture>
1567
1568 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1569 disables hardening flags not available on this architecture. Is detected
1570 automatically if dpkg-buildpackage is used.
1571
1572 =item B<--bindnow>
1573
1574 Force check for all +bindnow hardening flags. By default it's auto detected.
1575
1576 =item B<--buildd>
1577
1578 Special mode for buildds when automatically parsing log files. The following
1579 changes are in effect:
1580
1581 =over 2
1582
1583 =item *
1584
1585 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1586 possible tags.
1587
1588 =item *
1589
1590 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1591 detected).
1592
1593 =item *
1594
1595 Don't require Term::ANSIColor.
1596
1597 =item *
1598
1599 Return exit code 0, unless there was a error (-I, -W messages don't count as
1600 error).
1601
1602 =back
1603
1604 =item B<--debian>
1605
1606 Apply Debian-specific settings. At the moment this only disables checking for
1607 PIE which is automatically applied by Debian's GCC and no longer requires a
1608 compiler command line argument.
1609
1610 =item B<--color>
1611
1612 Use colored (ANSI) output for warning messages.
1613
1614 =item B<--line-numbers>
1615
1616 Display line numbers.
1617
1618 =item B<--ignore-arch> I<arch>
1619
1620 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1621
1622 Used to prevent false positives. This option can be specified multiple times.
1623
1624 =item B<--ignore-arch-flag> I<arch>:I<flag>
1625
1626 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1627
1628 =item B<--ignore-arch-line> I<arch>:I<line>
1629
1630 Like B<--ignore-line>, but only ignore line on I<arch>.
1631
1632 =item B<--ignore-flag> I<flag>
1633
1634 Don't print an error when the specific flag is missing in a compiler line.
1635 I<flag> is a string.
1636
1637 Used to prevent false positives. This option can be specified multiple times.
1638
1639 =item B<--ignore-line> I<regex>
1640
1641 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1642 at the beginning and end of the line to prevent false negatives.
1643
1644 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1645 warnings (which have line continuation resolved).
1646
1647 Used to prevent false positives. This option can be specified multiple times.
1648
1649 =item B<--pie>
1650
1651 Force check for all +pie hardening flags. By default it's auto detected.
1652
1653 =item B<-h -? --help>
1654
1655 Print available options.
1656
1657 =item B<--version>
1658
1659 Print version number and license.
1660
1661 =back
1662
1663 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1664 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1665 all other commands as well.
1666
1667 =head1 EXAMPLES
1668
1669 Normal usage, parse a single log file.
1670
1671     blhc path/to/log/file
1672
1673 If there's no output, no flags are missing and the build log is fine.
1674
1675 Parse multiple log files. The exit code is ORed over all files.
1676
1677     blhc path/to/directory/with/log/files/*
1678
1679 Don't treat missing C<-g> as error:
1680
1681     blhc --ignore-flag -g path/to/log/file
1682
1683 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1684
1685     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1686
1687 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1688 false positive.
1689
1690     blhc --ignore-line '\./script gcc file' path/to/log/file
1691
1692 Ignore lines matching C<./script gcc file> somewhere in the line.
1693
1694     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1695
1696 Use blhc with pbuilder.
1697
1698     pbuilder path/to/package.dsc | tee path/log/file
1699     blhc path/to/file || echo flags missing
1700
1701 Assume this build log was created on a Debian system and thus don't warn about
1702 missing PIE flags if the current architecture injects them automatically (this
1703 is enabled in buildd mode per default). C<--arch> is necessary if the build
1704 log contains no architecture information as written by dpkg-buildpackage.
1705
1706     blhc --debian --all --arch=amd64 path/to/log/file
1707
1708 =head1 BUILDD TAGS
1709
1710 The following tags are used in I<--buildd> mode. In braces the additional data
1711 which is displayed.
1712
1713 =over 2
1714
1715 =item B<I-hardening-wrapper-used>
1716
1717 The package uses hardening-wrapper which intercepts calls to gcc and adds
1718 hardening flags. The build log doesn't contain any hardening flags and thus
1719 can't be checked by blhc.
1720
1721 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1722
1723 Build log contains lines which hide the real compiler flags. For example:
1724
1725     CC test-a.c
1726     CC test-b.c
1727     CC test-c.c
1728     LD test
1729
1730 Most of the time either C<export V=1> or C<export verbose=1> in
1731 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1732 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1733 patched to remove the C<@>s hiding the real compiler commands.
1734
1735 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1736
1737 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1738
1739 =item B<I-invalid-cmake-used> (version)
1740
1741 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1742 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1743 patch was rejected by upstream and later reverted in Debian. Thus those two
1744 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1745 handle them (for example by passing them to CFLAGS). To prevent false
1746 negatives just blacklist those two versions.
1747
1748 =item B<I-no-compiler-commands>
1749
1750 No compiler commands were detected. Either the log contains none or they were
1751 not correctly detected by blhc (please report the bug in this case).
1752
1753 =back
1754
1755 =head1 EXIT STATUS
1756
1757 The exit status is a "bit mask", each listed status is ORed when the error
1758 condition occurs to get the result.
1759
1760 =over 4
1761
1762 =item B<0>
1763
1764 Success.
1765
1766 =item B<1>
1767
1768 No compiler commands were found.
1769
1770 =item B<2>
1771
1772 Invalid arguments/options given to blhc.
1773
1774 =item B<4>
1775
1776 Non verbose build.
1777
1778 =item B<8>
1779
1780 Missing hardening flags.
1781
1782 =item B<16>
1783
1784 Hardening wrapper detected, no tests performed.
1785
1786 =item B<32>
1787
1788 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1789 TAGS"> for a detailed explanation.
1790
1791 =back
1792
1793 =head1 AUTHOR
1794
1795 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1796
1797 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1798 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1799
1800 =head1 LICENSE AND COPYRIGHT
1801
1802 Copyright (C) 2012-2020 by Simon Ruderich
1803
1804 This program is free software: you can redistribute it and/or modify
1805 it under the terms of the GNU General Public License as published by
1806 the Free Software Foundation, either version 3 of the License, or
1807 (at your option) any later version.
1808
1809 This program is distributed in the hope that it will be useful,
1810 but WITHOUT ANY WARRANTY; without even the implied warranty of
1811 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1812 GNU General Public License for more details.
1813
1814 You should have received a copy of the GNU General Public License
1815 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1816
1817 =head1 SEE ALSO
1818
1819 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1820
1821 =cut