vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2011-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 if has('viminfo')
  73     " Remember marks (including the last cursor position) for more files.
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  83 " is used multiple times.
  84 if has('autocmd')
  85     augroup vimrc
  86         autocmd!
  87     augroup END
  88 endif
  89
  90
  91 " EDIT SETTINGS
  92
  93 " Enable automatic file detection, plugin and indention support.
  94 if has('autocmd')
  95     filetype off " necessary for pathogen to force a reload of ftplugins
  96     filetype plugin indent on
  97 endif
  98
  99 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 100 " existing files.
 101 set fileencodings=utf-8,latin1
 102
 103 " Wrap text after 78 characters.
 104 set textwidth=78
 105
 106 " Set tabs to 4 spaces, use softtabs.
 107 set shiftwidth=4
 108 set softtabstop=4
 109 set expandtab
 110 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 111 set shiftround
 112 " Use the default value for real tabs.
 113 set tabstop=8
 114
 115 " Enable auto indention.
 116 set autoindent
 117
 118 " When joining lines only add one space after a sentence.
 119 set nojoinspaces
 120
 121 " Allow backspacing over autoindent and line breaks.
 122 set backspace=indent,eol
 123
 124 " Start a comment when hitting enter after a commented line (r) and when using
 125 " o or O around a commented line (o).
 126 set formatoptions+=ro
 127 " Don't break a line if was already longer then 'textwidth' when insert mode
 128 " started.
 129 set formatoptions+=l
 130
 131 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 132 " no character) in visual block mode.
 133 set virtualedit=block
 134
 135 " Already display matches while typing the search command. This makes spotting
 136 " errors easy.
 137 set incsearch
 138
 139 " Activate syntax folding.
 140 if has('folding')
 141     set foldmethod=syntax
 142     set foldcolumn=2
 143     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 144                      " folding which is not what I want
 145 endif
 146
 147 " Only check for case if the searched word contains a capital character.
 148 set ignorecase
 149 set smartcase
 150
 151 " Activate spell checking, use English as default.
 152 if exists('+spell') && has('syntax')
 153     " But not when diffing as spell checking is distracting in this case.
 154     if !&diff
 155         set spell
 156     endif
 157     set spelllang=en_us
 158 endif
 159
 160 " Allow buffers with changes to be hidden. Very important for effective
 161 " editing with multiple buffers.
 162 set hidden
 163
 164
 165 " DISPLAY SETTINGS
 166
 167 " Use a dark background. Doesn't change the background color, only sets text
 168 " colors for a dark terminal.
 169 set background=dark
 170
 171 " Display line numbers.
 172 set number
 173 " But use as little space as necessary for the numbers column. Thanks to James
 174 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 175 if exists('+numberwidth')
 176     set numberwidth=1
 177 endif
 178 " Display the ruler with current line/file position. If 'statusline' is used
 179 " then this only affects <C-G>.
 180 set ruler
 181 " Display partial commands in the status line.
 182 set showcmd
 183
 184 " Don't redraw screen when executing macros; increases speed. Thanks to James
 185 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 186 set lazyredraw
 187
 188 " Visualize the line the cursor is currently in.
 189 if exists('+cursorline')
 190     set cursorline
 191 endif
 192
 193 " Display tabs, trailing space, non breakable spaces and long lines (when
 194 " wrapping is disabled).
 195 set list
 196 set listchars=trail:-,extends:>
 197 if v:version >= 700
 198     set listchars+=nbsp:!
 199 endif
 200
 201 if has('statusline')
 202     " Always display the status line even if there is only one window.
 203     set laststatus=2
 204
 205     set statusline=
 206     " on the left
 207     set statusline+=%02n: " buffer number
 208     set statusline+=%f\   " path to current file in buffer
 209     set statusline+=%h    " [help] if buffer is help file
 210     set statusline+=%w    " [Preview] if buffer is preview buffer
 211     set statusline+=%m    " [+] if buffer was modified,
 212                           " [-] if 'modifiable' is off
 213     set statusline+=%r    " [RO] if buffer is read only
 214
 215     " on the right
 216     set statusline+=%=                " right align
 217     set statusline+=0x%-8B\           " current character under cursor as hex
 218     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 219                                       " column number (%c),
 220                                       " virtual column number if different
 221                                       "                       than %c (%V)
 222     set statusline+=%P                " position in file in percent
 223 endif
 224
 225
 226 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 227
 228 " noremap is used to make sure the right side is executed as is and can't be
 229 " modified by a plugin or other settings. Except for <Nop> which isn't
 230 " affected by mappings.
 231
 232 " Easy way to exit insert mode.
 233 inoremap jj <Esc>
 234 inoremap jk <Esc>
 235 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 236 " (2010-10-15).
 237 cnoremap jj <C-C>
 238 cnoremap jk <C-C>
 239
 240 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 241 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 242 map <Right>  <Nop>
 243 map <Left>   <Nop>
 244 map <Up>     <Nop>
 245 map <Down>   <Nop>
 246 imap <Right> <Nop>
 247 imap <Left>  <Nop>
 248 imap <Up>    <Nop>
 249 imap <Down>  <Nop>
 250 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 251 " below).
 252 cmap <Up>    <Nop>
 253 cmap <Down>  <Nop>
 254 cmap <Right> <Nop>
 255 cmap <Left>  <Nop>
 256
 257 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 258 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 259 cnoremap <C-P> <Up>
 260 cnoremap <C-N> <Down>
 261
 262 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 263 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 264 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 265
 266 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 267 " in #vim on Freenode (2011-08-15 00:17 CEST).
 268 nnoremap <C-G> 2<C-G>
 269
 270 " Use <Space> to move down a page and - to move up one like in mutt.
 271 nnoremap <Space> <C-F>
 272 nnoremap - <C-B>
 273
 274 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 275 " (2010-05-16 18:38 CEST) for this idea.
 276 nnoremap <silent> gb :bnext<CR>
 277 nnoremap <silent> gB :bprev<CR>
 278
 279 " Fast access to buffers.
 280 nnoremap <silent> <Leader>1 :1buffer<CR>
 281 nnoremap <silent> <Leader>2 :2buffer<CR>
 282 nnoremap <silent> <Leader>3 :3buffer<CR>
 283 nnoremap <silent> <Leader>4 :4buffer<CR>
 284 nnoremap <silent> <Leader>5 :5buffer<CR>
 285 nnoremap <silent> <Leader>6 :6buffer<CR>
 286 nnoremap <silent> <Leader>7 :7buffer<CR>
 287 nnoremap <silent> <Leader>8 :8buffer<CR>
 288 nnoremap <silent> <Leader>9 :9buffer<CR>
 289 nnoremap <silent> <Leader>0 :10buffer<CR>
 290
 291 " Make last active window the only window. Similar to <C-W> o.
 292 nnoremap <C-W>O <C-W>p<C-W>o
 293
 294 " Maps to change spell language between English and German and disable spell
 295 " checking.
 296 if exists('+spell')
 297     noremap <silent> <Leader>sn :set nospell<CR>
 298     noremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 299     noremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 300 endif
 301
 302 " Add semicolon to the end of the line. Thanks to
 303 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 304 " on Freenode for an improved version which doesn't clobber any marks.
 305 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 306
 307 " * and # for selections in visual mode. Thanks to
 308 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 309 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 310 if has('eval')
 311     function! s:VSetSearch()
 312         let l:temp = @@
 313         normal! gvy
 314         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 315         let @@ = l:temp
 316     endfunction
 317     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 318     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 319 endif
 320
 321 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 322 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 323 " mailing list for the commands.
 324 if v:version < 700
 325     cnoreabbrev W w
 326     cnoreabbrev Wa wa
 327     cnoreabbrev Wq wq
 328     cnoreabbrev Wqa wqa
 329 else
 330     cnoreabbrev <expr> W
 331         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 332     cnoreabbrev <expr> Wa
 333         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 334     cnoreabbrev <expr> Wq
 335         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 336     cnoreabbrev <expr> Wqa
 337         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 338 endif
 339 " Also fix my typo with "Q".
 340 if v:version < 700
 341     cnoreabbrev Q q
 342     cnoreabbrev Qa qa
 343 else
 344     cnoreabbrev <expr> Q
 345         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 346     cnoreabbrev <expr> Qa
 347         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 348 endif
 349
 350 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 351 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 352 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 353
 354 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 355 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 356 " Vim's source.
 357 inoremap <C-U> <C-G>u<C-U>
 358 " Same for <C-@> (insert previously inserted text and leave insert mode).
 359 inoremap <C-@> <C-G>u<C-@>
 360 " And for <C-A> (insert previously inserted text).
 361 inoremap <C-A> <C-G>u<C-A>
 362 " And for <C-W> (delete word before cursor).
 363 inoremap <C-W> <C-G>u<C-W>
 364
 365 if has('eval')
 366 " New text-objects ii and ai to work on text with the same indentation. Thanks
 367 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 368 " (visited on 2011-11-19).
 369     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 370     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 371     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 372     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 373
 374     function! s:IndTxtObj(inner)
 375         let curline = line(".")
 376         let lastline = line("$")
 377         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 378         let i = i < 0 ? 0 : i
 379         if getline(".") !~ "^\\s*$"
 380             let p = line(".") - 1
 381             let nextblank = getline(p) =~ "^\\s*$"
 382             while p > 0
 383                     \ && ((i == 0 && !nextblank)
 384                         \ || (i > 0 && ((indent(p) >= i
 385                             \ && !(nextblank && a:inner))
 386                             \ || (nextblank && !a:inner))))
 387                 -
 388                 let p = line(".") - 1
 389                 let nextblank = getline(p) =~ "^\\s*$"
 390             endwhile
 391             normal! 0V
 392             call cursor(curline, 0)
 393             let p = line(".") + 1
 394             let nextblank = getline(p) =~ "^\\s*$"
 395             while p <= lastline
 396                     \ && ((i == 0 && !nextblank)
 397                         \ || (i > 0 && ((indent(p) >= i
 398                             \ && !(nextblank && a:inner))
 399                             \ || (nextblank && !a:inner))))
 400                 +
 401                 let p = line(".") + 1
 402                 let nextblank = getline(p) =~ "^\\s*$"
 403             endwhile
 404             normal! $
 405         endif
 406     endfunction
 407 endif
 408
 409
 410 " ABBREVIATIONS
 411
 412 " Fix some of my spelling mistakes.
 413 iabbrev relle reelle
 414 iabbrev reele reelle
 415
 416
 417 " SYNTAX SETTINGS
 418
 419 " Activate syntax coloring.
 420 if has('syntax')
 421     syntax enable
 422
 423 " Don't highlight more than 500 columns as I normally don't have that long
 424 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 425 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 426     if exists('+synmaxcol')
 427         set synmaxcol=500
 428     endif
 429
 430 " Use (limited) syntax based omni completion if no other omni completion is
 431 " available. Taken from :help ft-syntax-omni.
 432     if has('autocmd') && exists('+omnifunc')
 433         augroup vimrc
 434             autocmd FileType *
 435                 \ if &omnifunc == '' |
 436                 \     setlocal omnifunc=syntaxcomplete#Complete |
 437                 \ endif
 438         augroup END
 439     endif
 440
 441 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 442 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 443 " disabled when necessary with :2match (in Vim >= 700).
 444     if exists(':2match')
 445         2match Todo /\%>78v./
 446     else
 447         match Todo /\%>78v./
 448     endif
 449
 450     if exists('*matchadd')
 451 " Highlight some important keywords in all documents.
 452         for s:x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
 453             call matchadd('Todo', s:x)
 454         endfor
 455
 456 " Highlight unicode whitespace which is no normal whitespace (0x20).
 457         for s:x in ['00a0', '1680', '180e', '2000', '2001', '2002', '2003',
 458                 \ '2004', '2005', '2006', '2007', '2008', '2009', '200a',
 459                 \ '200b', '200c', '200d', '202f', '205f', '2060', '3000',
 460                 \ 'feff']
 461             call matchadd('Error', '\%u' . s:x)
 462         endfor
 463     endif
 464
 465 " Settings for specific filetypes.
 466
 467     " Haskell.
 468     let g:hs_highlight_delimiters = 1
 469     let g:hs_highlight_boolean = 1
 470     let g:hs_highlight_types = 1
 471     let g:hs_highlight_more_types = 1
 472     " Perl.
 473     let g:perl_fold = 1
 474     let g:perl_fold_blocks = 1
 475     let g:perl_nofold_packages = 1
 476     let g:perl_include_pod = 1 " syntax coloring for PODs
 477     " Python.
 478     let g:python_highlight_all = 1
 479     " Vim.
 480     let g:vimsyn_embed = 0      " don't highlight embedded languages
 481     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 482     " XML.
 483     let g:xml_syntax_folding = 1
 484 endif
 485
 486
 487 " PLUGIN SETTINGS
 488
 489 if has('eval')
 490 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 491 " installing/removing/updating plugins simple. (Used for plugins with more
 492 " than one file.)
 493     if v:version >= 700
 494         execute 'call pathogen#runtime_append_all_bundles()'
 495     endif
 496
 497 " Settings for the NERD commenter.
 498     " Don't create any mappings I don't want to use.
 499     let g:NERDCreateDefaultMappings = 0
 500     " Map toggle comment.
 501     map <Leader><Leader> <Plug>NERDCommenterToggle
 502
 503 " XPTemplate settings.
 504     " Try to maintain snippet rendering even after editing outside of a
 505     " snippet.
 506     let g:xptemplate_strict = 0
 507     " Don't complete any braces automatically.
 508     let g:xptemplate_brace_complete = 0
 509     " Only highlight the current placeholder.
 510     let g:xptemplate_highlight = 'current'
 511 endif
 512
 513
 514 " AUTO COMMANDS
 515
 516 " Use a custom auto group to prevent problems when the vimrc files is sourced
 517 " twice.
 518 if has('autocmd')
 519     augroup vimrc
 520
 521 " Go to last position of opened files. Taken from :help last-position-jump.
 522         autocmd BufReadPost *
 523             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 524             \     execute "normal! g'\"" |
 525             \ endif
 526 " But not for Git commits, go to beginning of the file.
 527         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 528
 529 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 530 " when switching to a help buffer which is in the background with :buffer as
 531 " these options are local to windows (and not only to buffers). This happens
 532 " because I often want to use only one window and thus the help buffer is in
 533 " the background.
 534         autocmd BufWinEnter *.txt
 535             \ if &filetype == 'help' |
 536             \     setlocal nolist |
 537             \     setlocal nonumber |
 538             \ endif
 539
 540 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 541 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 542 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 543 " doesn't exist in older Vims.
 544         if exists('##InsertLeave')
 545             autocmd InsertLeave * set nopaste
 546         endif
 547
 548 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 549 " doesn't exist in older Vims.
 550         if exists('##QuickFixCmdPre')
 551             autocmd QuickFixCmdPre * write
 552         endif
 553
 554 " AFTER/FTPLUGIN AUTO COMMANDS
 555
 556 " Disable spell checking for files which don't need it.
 557         autocmd FileType deb  setlocal nospell
 558         autocmd FileType diff setlocal nospell
 559         autocmd FileType tar  setlocal nospell
 560 " Fix to allow Vim edit crontab files as crontab doesn't work with
 561 " backupcopy=auto.
 562         autocmd FileType crontab setlocal backupcopy=yes
 563 " Don't use the modeline in git commits as the diff created by `git commit -v`
 564 " may contain one which could change the filetype or other settings of the
 565 " commit buffer. Also make sure we use only 72 characters per line which is
 566 " the recommendation for git commit messages (http://tpope.net/node/106).
 567         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 568                                  \ setlocal textwidth=72
 569 " Use the same comment string as for Vim files in Vimperator files.
 570         autocmd FileType vimperator setlocal commentstring=\"%s
 571 " Use tex compiler for (La)TeX files.
 572         autocmd FileType tex compiler tex
 573
 574 " FTDETECT AUTO COMMANDS
 575
 576 " Recognize .md as markdown files (Vim default is .mkd).
 577         autocmd BufRead,BufNewFile *.md set filetype=mkd
 578 " Recognize .test as Tcl files.
 579         autocmd BufRead,BufNewFile *.test set filetype=tcl
 580
 581 " OTHER AUTO COMMANDS
 582
 583 " Disable spell checking, displaying of list characters and long lines when
 584 " viewing documentation.
 585         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 586
 587 " Use diff filetype for mercurial patches in patch queue.
 588         autocmd BufReadPost */.hg/patches/* set filetype=diff
 589
 590     augroup END
 591 endif
 592
 593
 594 " CUSTOM FUNCTIONS AND COMMANDS
 595
 596 if has('eval')
 597 " Convenient command to see the difference between the current buffer and the
 598 " file it was loaded from, thus the changes you made. Thanks to the
 599 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 600 " for the diffed file than the filetype for the original file.
 601     if !exists(':DiffOrig')
 602         command DiffOrig
 603             \ let s:diff_orig_filetype = &filetype
 604             \ | vertical new
 605             \ | let &filetype = s:diff_orig_filetype
 606             \ | unlet s:diff_orig_filetype
 607             \ | set buftype=nofile
 608             \ | read ++edit #
 609             \ | 0d_
 610             \ | diffthis
 611             \ | wincmd p
 612             \ | diffthis
 613     endif
 614 endif