vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file. But only if
  53 " we have a "safe" writable directory available.
  54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  55     set directory-=.
  56 endif
  57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  58 set directory^=~/.tmp
  59
  60 " Disable modelines as they may cause security problems. Instead use
  61 " securemodelines (Vim script #1876).
  62 set nomodeline
  63
  64 " Complete to longest common string (list:longest) and then complete all full
  65 " matches after another (full). Thanks to pbrisbin
  66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  67 set wildmode=list:longest,full
  68 " Ignore case when completing files/directories.
  69 if exists('+wildignorecase')
  70     set wildignorecase
  71 endif
  72
  73 " Ignore files with the following extensions because I almost never want to
  74 " edit them in Vim (specifying them manually still works of course).
  75 set wildignore=
  76 " C
  77 set wildignore+=*.o,*.d,*.so
  78 " Java
  79 set wildignore+=*.class
  80 " LaTeX
  81 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  82 " Python
  83 set wildignore+=*.pyc
  84
  85 " Show completion menu even if only one entry matches.
  86 if exists('+completeopt')
  87     set completeopt+=menuone
  88 endif
  89
  90 " Increase history of executed commands (:) and search patterns (/).
  91 set history=1000
  92
  93 " Increase number of possible undos.
  94 set undolevels=1000
  95
  96 " Remember marks (including the last cursor position) for more files. ^= is
  97 " necessary because 'viminfo' is parsed from the beginning and the first match
  98 " is used.
  99 if has('viminfo')
 100     set viminfo^='1000
 101 endif
 102
 103 " Use strong encryption if possible, also used for swap/undo files.
 104 if exists('+cryptmethod')
 105     set cryptmethod=blowfish
 106 endif
 107
 108 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 109 " is used multiple times. Necessary to support reloading the vimrc.
 110 if has('autocmd')
 111     augroup vimrc
 112         autocmd!
 113     augroup END
 114 endif
 115
 116
 117 " HELPER FUNCTIONS
 118
 119 if has('eval')
 120 " Check if the given syntax group is available. Thanks to bairui in #vim on
 121 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 122     function! s:HasSyntaxGroup(group)
 123         try
 124             execute 'silent highlight ' . a:group
 125         " \a = [A-Za-z]
 126         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 127             return 0
 128         endtry
 129         return 1
 130     endfunction
 131
 132 " Check if the given Vim version and patch is available.
 133     function! s:HasVersionAndPatch(version, patch)
 134         return v:version > a:version
 135             \ || (v:version == a:version && has('patch' . a:patch))
 136     endfunction
 137 endif
 138
 139
 140 " TERMINAL SETTINGS
 141
 142 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
 143 " connections.
 144 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
 145     set ttyfast
 146 endif
 147
 148
 149 " EDIT SETTINGS
 150
 151 " Enable automatic file detection, plugin and indention support.
 152 if has('autocmd')
 153     filetype off " necessary for pathogen to force a reload of ftplugins
 154     filetype plugin indent on
 155 endif
 156
 157 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 158 " existing files.
 159 set fileencodings=utf-8,latin1
 160
 161 " Always use unix line-endings for new files.
 162 set fileformats=unix,dos
 163
 164 " Wrap text after 78 characters.
 165 set textwidth=78
 166
 167 " Set tabs to 4 spaces, use softtabs.
 168 set shiftwidth=4
 169 set softtabstop=4
 170 set expandtab
 171 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 172 set shiftround
 173 " Use the default value for real tabs.
 174 set tabstop=8
 175
 176 " Enable auto indention.
 177 set autoindent
 178
 179 " When joining lines only add one space after a sentence.
 180 set nojoinspaces
 181
 182 " Allow backspacing over autoindent and line breaks.
 183 set backspace=indent,eol
 184
 185 " Start a comment when hitting enter after a commented line (r) and when using
 186 " o or O around a commented line (o).
 187 set formatoptions+=ro
 188 " Don't break a line if was already longer then 'textwidth' when insert mode
 189 " started.
 190 set formatoptions+=l
 191 " Remove comment leader when joining lines where it makes sense.
 192 if <SID>HasVersionAndPatch(703, 541)
 193     set formatoptions+=j
 194 endif
 195
 196 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 197 " no character) in visual block mode.
 198 set virtualedit=block
 199
 200 " Already display matches while typing the search command. This makes spotting
 201 " typos easy and searching faster.
 202 set incsearch
 203
 204 " Activate syntax folding.
 205 if has('folding')
 206     set foldmethod=syntax
 207     " Only use fold column if we have enough space (for example not in a
 208     " (virtual) terminal which has only 80 columns).
 209     if &columns > 80
 210         set foldcolumn=2
 211     endif
 212     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 213                      " folding which is not what I want
 214     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 215     set foldopen-=block
 216 endif
 217
 218 " Only check case if the searched word contains a capital character.
 219 set ignorecase
 220 set smartcase
 221
 222 " Activate spell checking, use English as default.
 223 if exists('+spell') && has('syntax')
 224     " But not when diffing because spell checking is distracting in this case.
 225     if !&diff
 226         set spell
 227     endif
 228     set spelllang=en_us
 229 endif
 230
 231 " Allow buffers with changes to be hidden. Very important for effective
 232 " editing with multiple buffers. Prevents the "E37: No write since last change
 233 " (add ! to override)" warning when switching buffers.
 234 set hidden
 235
 236 " When splitting vertically put the new window right of the current one.
 237 if has('vertsplit')
 238     set splitright
 239 endif
 240
 241
 242 " DISPLAY SETTINGS
 243
 244 " Use a dark background. Doesn't change the background color, only sets text
 245 " colors for a dark terminal.
 246 set background=dark
 247
 248 " Use my color scheme if 256 colors are available.
 249 if &t_Co == 256 || has('gui_running')
 250     colorscheme simon
 251 endif
 252
 253 " Display line numbers.
 254 set number
 255 " But use as little space as possible for the numbers column. Thanks to James
 256 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 257 if exists('+numberwidth')
 258     set numberwidth=1
 259 endif
 260 " Display the ruler with current line/file position. If 'statusline' is used
 261 " then this only affects <C-G>.
 262 set ruler
 263 " Display partial commands in the status line.
 264 set showcmd
 265
 266 " Don't redraw screen when executing macros; increases speed. Thanks to James
 267 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 268 set lazyredraw
 269
 270 " Visualize the line the cursor is currently in.
 271 if exists('+cursorline')
 272     set cursorline
 273 endif
 274
 275 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 276 " remove the highlighting until the next search.
 277 set hlsearch
 278
 279 " Display some special characters.
 280 set list
 281 set listchars=
 282 " Display tabs as ">--------".
 283 set listchars+=tab:>-
 284 " Display trailing whitespace as "-".
 285 set listchars+=trail:-
 286 " Display markers for long lines when wrapping is disabled.
 287 set listchars+=extends:>,precedes:<
 288 " Display non-breakable space as "!".
 289 if v:version >= 700
 290     set listchars+=nbsp:!
 291 endif
 292
 293 " Don't draw the vertical split separator by using space as character. Thanks
 294 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 295 " non-breakable space. But a simple space works as well, as long as the
 296 " current color scheme is not reset.
 297 if has('windows') && has('folding')
 298     set fillchars+=vert:\  " comment to prevent trailing whitespace
 299 endif
 300
 301 if has('statusline')
 302     " Always display the status line even if there is only one window.
 303     set laststatus=2
 304
 305     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 306     " is the highest buffer number, otherwise return nothing. Used in
 307     " 'statusline' to get an overview of available buffer numbers.
 308     function! s:StatuslineBufferCount()
 309         let l:bufnr = bufnr('$')
 310         if l:bufnr > 1
 311             let l:result = '/'
 312             if exists('*printf')
 313                 let l:result .= printf('%02d', l:bufnr)
 314             else
 315                 " Older Vims don't have printf() (and no .= either). Emulate
 316                 " "%02d".
 317                 if l:bufnr < 10
 318                     let l:result = l:result . '0'
 319                 endif
 320                 let l:result = l:result . l:bufnr
 321             endif
 322             return l:result
 323         else
 324             return ''
 325         endif
 326     endfunction
 327
 328     " Like %f but use relative filename if it's shorter than the absolute path
 329     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 330     " not enough because it doesn't create '../'s.
 331     function! s:StatuslineRelativeFilename()
 332         " Display only filename for help files.
 333         if &buftype == 'help'
 334             return expand('%:t')
 335         endif
 336         " Special case for scratch files.
 337         if &buftype == 'nofile'
 338             return '[Scratch]'
 339         endif
 340
 341         let l:path = expand('%')
 342         " No file.
 343         if l:path == ''
 344             return '[No Name]'
 345         endif
 346         " Path is already relative, nothing to do.
 347         if stridx(l:path, '/') != 0
 348             return l:path
 349         endif
 350
 351         " Absolute path to this file.
 352         let l:path = expand('%:p')
 353         " Shortened path to this file, thanks to bairui in #vim on Freenode
 354         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 355         " Vim normally uses as %f (minus some exceptions).
 356         let l:original_path = fnamemodify(l:path, ':~')
 357         " Absolute path to the current working directory.
 358         let l:cwd = getcwd()
 359
 360         " Working directory completely contained in path, replace it with a
 361         " relative path. Happens for example when opening a file with netrw.
 362         " %f displays this as absolute path, but we want a relative path of
 363         " course.
 364         if stridx(l:path, l:cwd) == 0
 365             return strpart(l:path, strlen(l:cwd) + 1)
 366         endif
 367
 368         let l:path_list = split(l:path, '/')
 369         let l:cwd_list  = split(l:cwd,  '/')
 370
 371         " Remove the common path.
 372         while l:path_list[0] == l:cwd_list[0]
 373             call remove(l:path_list, 0)
 374             call remove(l:cwd_list,  0)
 375         endwhile
 376
 377         " Add as many '..' as necessary for the relative path and join the
 378         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 379         " the hint to use repeat() instead of a loop.
 380         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 381
 382         " Use the shorter path, either relative or absolute.
 383         if strlen(l:path) < strlen(l:original_path)
 384             return l:path
 385         else
 386             return l:original_path
 387         endif
 388     endfunction
 389
 390     " Display unexpected 'fileformat' and 'fileencoding' settings.
 391     function! s:StatuslineFileFormat()
 392         if &fileformat != 'unix'
 393             return '[' . &fileformat . ']'
 394         else
 395             return ''
 396         endif
 397     endfunction
 398     function! s:StatuslineFileEncoding()
 399         if &fileencoding != '' && &fileencoding != 'utf-8'
 400                 \ && &filetype != 'help'
 401             return '[' . &fileencoding . ']'
 402         else
 403             return ''
 404         endif
 405     endfunction
 406
 407     " Return current syntax group in brackets or nothing if there's none.
 408     function! s:StatuslineSyntaxGroup()
 409         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 410         if l:group != ''
 411             return '[' . l:group . '] '
 412         else
 413             return ''
 414         endif
 415     endfunction
 416
 417     " Short function names to make 'statusline' more readable.
 418     function! SBC()
 419         return <SID>StatuslineBufferCount()
 420     endfunction
 421     function! SRF()
 422         return <SID>StatuslineRelativeFilename()
 423     endfunction
 424     function! SFF()
 425         return <SID>StatuslineFileFormat()
 426     endfunction
 427     function! SFE()
 428         return <SID>StatuslineFileEncoding()
 429     endfunction
 430     function! SSG()
 431         return <SID>StatuslineSyntaxGroup()
 432     endfunction
 433
 434     set statusline=
 435     " on the left
 436     set statusline+=%02n              " buffer number
 437     set statusline+=%{SBC()}          " highest buffer number
 438     set statusline+=:
 439     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 440         set statusline+=%{SRF()}      " path to current file
 441         set statusline+=\             " space after path
 442     else
 443         set statusline+=%f\           " path to current file in buffer
 444     endif
 445     set statusline+=%h                " [help] if buffer is help file
 446     set statusline+=%w                " [Preview] if buffer is preview buffer
 447     set statusline+=%m                " [+] if buffer was modified,
 448                                       " [-] if 'modifiable' is off
 449     set statusline+=%r                " [RO] if buffer is read only
 450     set statusline+=%#Error#          " display warnings
 451     set statusline+=%{SFF()}          "   - unexpected file format
 452     set statusline+=%{SFE()}          "   - unexpected file encoding
 453     set statusline+=%##               " continue with normal colors
 454
 455     " on the right
 456     set statusline+=%=                " right align
 457     set statusline+=0x%-8B\           " current character under cursor as hex
 458     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 459                                       " column number (%c),
 460                                       " virtual column number if different
 461                                       "                       than %c (%V)
 462     set statusline+=%P                " position in file in percent
 463 endif
 464
 465
 466 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 467
 468 " noremap is used to make sure the right side is executed as is and can't be
 469 " modified by a plugin or other settings. Except for <Nop> which isn't
 470 " affected by mappings.
 471
 472 " Easy way to exit insert mode. jk is preferred because it's faster.
 473 inoremap jj <Esc>
 474 inoremap jk <Esc>
 475 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 476 " (2010-10-15).
 477 cnoremap jj <C-C>
 478 cnoremap jk <C-C>
 479
 480 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 481 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 482 map <Right>  <Nop>
 483 map <Left>   <Nop>
 484 map <Up>     <Nop>
 485 map <Down>   <Nop>
 486 imap <Right> <Nop>
 487 imap <Left>  <Nop>
 488 imap <Up>    <Nop>
 489 imap <Down>  <Nop>
 490 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 491 " below).
 492 cmap <Up>    <Nop>
 493 cmap <Down>  <Nop>
 494 cmap <Right> <Nop>
 495 cmap <Left>  <Nop>
 496
 497 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 498 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 499 cnoremap <C-P> <Up>
 500 cnoremap <C-N> <Down>
 501
 502 if has('eval')
 503 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 504 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 505 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 506 " directly because it also enables that feature for other commands which I
 507 " don't want.
 508
 509     " Set 'nostartofline' for a single movement.
 510     function! s:TemporaryNostartofline(movement)
 511         let l:startofline = &startofline
 512         set nostartofline
 513         execute 'normal! ' . a:movement
 514         let &startofline = l:startofline
 515     endfunction
 516
 517     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 518     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 519     nnoremap <silent> <C-F>
 520         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 521     nnoremap <silent> <C-B>
 522         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 523     nnoremap <silent> <C-D>
 524         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 525     nnoremap <silent> <C-U>
 526         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 527 endif
 528
 529 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 530 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 531 " Only the current buffer is written, thus switching to another buffer works
 532 " too.
 533 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 534
 535 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 536 " in #vim on Freenode (2011-08-15 00:17 CEST).
 537 nnoremap <C-G> 2<C-G>
 538
 539 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 540 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 541 nmap <Space> <C-F>
 542 nmap - <C-B>
 543
 544 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 545 " (2010-05-16 18:38 CEST) for this idea.
 546 nnoremap <silent> gb :bnext<CR>
 547 nnoremap <silent> gB :bprevious<CR>
 548 if has('eval')
 549     " But when starting again at the first buffer, print a warning which
 550     " reminds me that I've already seen that buffer.
 551     function! s:NextBuffer()
 552         " Are we currently on the last buffer and moving to the first?
 553         let l:last_buffer = 0
 554         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 555             let l:last_buffer = 1
 556         endif
 557
 558         " Go to the next buffer.
 559         if !l:last_buffer
 560             bnext
 561
 562         " Go to the first buffer, silent is necessary or the following message
 563         " won't be displayed because it's overwritten by the status message
 564         " displayed when entering a buffer.
 565         else
 566             silent bnext
 567
 568             echohl WarningMsg
 569             echo 'Starting again at first buffer.'
 570             echohl None
 571         endif
 572     endfunction
 573     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 574 endif
 575
 576 " Fast access to buffers.
 577 nnoremap <silent> <Leader>1 :1buffer<CR>
 578 nnoremap <silent> <Leader>2 :2buffer<CR>
 579 nnoremap <silent> <Leader>3 :3buffer<CR>
 580 nnoremap <silent> <Leader>4 :4buffer<CR>
 581 nnoremap <silent> <Leader>5 :5buffer<CR>
 582 nnoremap <silent> <Leader>6 :6buffer<CR>
 583 nnoremap <silent> <Leader>7 :7buffer<CR>
 584 nnoremap <silent> <Leader>8 :8buffer<CR>
 585 nnoremap <silent> <Leader>9 :9buffer<CR>
 586 nnoremap <silent> <Leader>0 :10buffer<CR>
 587
 588 " Make last active window the only window. Similar to <C-W> o.
 589 nnoremap <C-W>O <C-W>p<C-W>o
 590
 591 " Maps to change spell language between English and German and disable spell
 592 " checking.
 593 if exists('+spell')
 594     nnoremap <silent> <Leader>sn :set nospell<CR>
 595     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 596     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 597 " If no spell support is available, these mappings do nothing.
 598 else
 599     nmap <Leader>sn <Nop>
 600     nmap <Leader>se <Nop>
 601     nmap <Leader>sd <Nop>
 602 endif
 603
 604 " Add semicolon to the end of the line. Thanks to
 605 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 606 " on Freenode for an improved version which doesn't clobber any marks.
 607 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 608
 609 " * and # for selections in visual mode. Thanks to
 610 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 611 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 612 if has('eval')
 613     function! s:VSetSearch()
 614         let l:temp = @@ " unnamed register
 615         normal! gvy
 616         " Added \C to force 'noignorecase' while searching the current visual
 617         " selection. I want to search for the exact string in this case.
 618         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 619         let @@ = l:temp
 620     endfunction
 621     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 622     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 623 endif
 624
 625 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 626 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 627 " mailing list for the commands.
 628 if v:version < 700
 629     cnoreabbrev W w
 630     cnoreabbrev Wa wa
 631     cnoreabbrev Wq wq
 632     cnoreabbrev Wqa wqa
 633 else
 634     cnoreabbrev <expr> W
 635         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 636     cnoreabbrev <expr> Wa
 637         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 638     cnoreabbrev <expr> Wq
 639         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 640     cnoreabbrev <expr> Wqa
 641         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 642 endif
 643 " Also fix my typo with "Q".
 644 if v:version < 700
 645     cnoreabbrev Q q
 646     cnoreabbrev Qa qa
 647 else
 648     cnoreabbrev <expr> Q
 649         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 650     cnoreabbrev <expr> Qa
 651         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 652 endif
 653
 654 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 655 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 656 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 657
 658 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 659 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 660 " Vim's source.
 661 inoremap <C-U> <C-G>u<C-U>
 662 " Same for <C-@> (insert previously inserted text and leave insert mode).
 663 inoremap <C-@> <C-G>u<C-@>
 664 " And for <C-A> (insert previously inserted text).
 665 inoremap <C-A> <C-G>u<C-A>
 666 " And for <C-W> (delete word before cursor).
 667 inoremap <C-W> <C-G>u<C-W>
 668
 669 if has('eval')
 670 " New text-objects ii and ai to work on text with the same indentation. Thanks
 671 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 672 " (visited on 2011-11-19).
 673     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 674     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 675     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 676     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 677
 678     function! s:IndTxtObj(inner)
 679         let curline = line(".")
 680         let lastline = line("$")
 681         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 682         let i = i < 0 ? 0 : i
 683         if getline(".") !~ "^\\s*$"
 684             let p = line(".") - 1
 685             let nextblank = getline(p) =~ "^\\s*$"
 686             while p > 0
 687                     \ && ((i == 0 && !nextblank)
 688                         \ || (i > 0 && ((indent(p) >= i
 689                             \ && !(nextblank && a:inner))
 690                             \ || (nextblank && !a:inner))))
 691                 -
 692                 let p = line(".") - 1
 693                 let nextblank = getline(p) =~ "^\\s*$"
 694             endwhile
 695             normal! 0V
 696             call cursor(curline, 0)
 697             let p = line(".") + 1
 698             let nextblank = getline(p) =~ "^\\s*$"
 699             while p <= lastline
 700                     \ && ((i == 0 && !nextblank)
 701                         \ || (i > 0 && ((indent(p) >= i
 702                             \ && !(nextblank && a:inner))
 703                             \ || (nextblank && !a:inner))))
 704                 +
 705                 let p = line(".") + 1
 706                 let nextblank = getline(p) =~ "^\\s*$"
 707             endwhile
 708             normal! $
 709         endif
 710     endfunction
 711 endif
 712
 713
 714 " ABBREVIATIONS
 715
 716 " Fix some of my spelling mistakes (German).
 717 inoreabbrev relle reelle
 718 inoreabbrev reele reelle
 719 " Fix some of my spelling mistakes (English).
 720 inoreabbrev completly completely
 721
 722
 723 " SYNTAX SETTINGS
 724
 725 " Activate syntax coloring.
 726 if has('syntax')
 727     syntax enable
 728
 729 " Don't highlight more than 500 columns as I normally don't have that long
 730 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 731 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 732     if exists('+synmaxcol')
 733         set synmaxcol=500
 734     endif
 735
 736 " Use (limited) syntax based omni completion if no other omni completion is
 737 " available. Taken from :help ft-syntax-omni.
 738     if has('autocmd') && exists('+omnifunc')
 739         augroup vimrc
 740             autocmd FileType *
 741                 \ if &omnifunc == '' |
 742                 \     setlocal omnifunc=syntaxcomplete#Complete |
 743                 \ endif
 744         augroup END
 745     endif
 746
 747 " Function to enable all custom highlights. Necessary as highlights are
 748 " window-local and thus must be set for each new window.
 749     function! s:CustomSyntaxHighlights()
 750         " Not the first time called, nothing to do.
 751         if exists('w:vimrc_syntax_run')
 752             return
 753         endif
 754         let w:vimrc_syntax_run = 1
 755
 756 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 757 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 758 " disabled when necessary with :2match (in Vim >= 700).
 759         if !&diff && exists(':2match')
 760             " Use ColorColumn for overlong lines if available and my color
 761             " scheme is used.
 762             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 763                 2match ColorColumn /\%>78v./
 764             else
 765                 2match Todo /\%>78v./
 766             endif
 767         elseif !&diff
 768             match Todo /\%>78v./
 769         endif
 770
 771         if exists('*matchadd')
 772 " Highlight some important keywords in all documents.
 773             let l:todos = ['TODO', 'XXX', 'FIXME',
 774                          \ 'CHANGED', 'REMOVED', 'DELETED']
 775             " Compatibility fix for Vim 6.4 which can't handle for in function
 776             " (without function it's ignored).
 777             execute '  for l:x in l:todos'
 778                   \ '|     call matchadd("Todo", l:x)'
 779                   \ '| endfor'
 780
 781 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 782             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 783                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 784                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 785                           \ '205f', '2060', '3000', 'feff']
 786             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 787             " it won't work!
 788             execute '  for l:x in l:spaces'
 789                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 790                   \ '| endfor'
 791
 792 " Special highlight for tabs to reduce their visibility in contrast to other
 793 " SpecialKey characters (e.g. ^L).
 794             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 795                 call matchadd('specialKeyTab', '\t')
 796             endif
 797         endif
 798     endfunction
 799 " Enable highlights for the current and all new windows. Thanks to bairui in
 800 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 801     call <SID>CustomSyntaxHighlights()
 802     if has('autocmd')
 803         augroup vimrc
 804             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 805         augroup END
 806     endif
 807
 808 " Settings for specific filetypes.
 809
 810     " C
 811     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 812     " Haskell.
 813     let g:hs_highlight_delimiters = 1
 814     let g:hs_highlight_boolean = 1
 815     let g:hs_highlight_types = 1
 816     let g:hs_highlight_more_types = 1
 817     " Java.
 818     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 819     " Perl.
 820     let g:perl_fold = 1
 821     let g:perl_fold_blocks = 1
 822     let g:perl_nofold_packages = 1
 823     let g:perl_include_pod = 1 " syntax coloring for PODs
 824     " PHP.
 825     let g:php_folding = 3    " fold functions
 826     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 827     let g:php_sql_query = 1  " highlight SQL queries in strings
 828     " Python.
 829     let g:python_highlight_all = 1
 830     " Shell.
 831     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 832     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 833     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 834     " Vim.
 835     let g:vimsyn_embed = 0      " don't highlight embedded languages
 836     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 837     " XML.
 838     let g:xml_syntax_folding = 1
 839 endif
 840
 841
 842 " PLUGIN SETTINGS
 843
 844 if has('eval')
 845 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 846 " installing/removing/updating plugins simple. (Used for plugins with more
 847 " than one file.) Ignore errors in case pathogen is not installed.
 848     if v:version >= 700
 849         silent! execute 'call pathogen#infect()'
 850     endif
 851
 852 " Settings for securemodelines.
 853     " Only allow items I need (also includes spl which is not enabled by
 854     " default).
 855     if v:version >= 700 " need lists
 856         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 857                                               \ 'sw', 'sts', 'noet']
 858     endif
 859
 860 " Settings for the NERD commenter.
 861     " Don't create any mappings I don't want to use.
 862     let g:NERDCreateDefaultMappings = 0
 863     " Map toggle comment.
 864     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 865
 866 " XPTemplate settings.
 867     " Try to maintain snippet rendering even after editing outside of a
 868     " snippet.
 869     let g:xptemplate_strict = 0
 870     " Don't complete any braces automatically.
 871     let g:xptemplate_brace_complete = 0
 872     " Only highlight the current placeholder.
 873     let g:xptemplate_highlight = 'current'
 874
 875 " CtrlP settings.
 876     " Don't manage the working directory (the default setting is too slow for
 877     " me).
 878     let g:ctrlp_working_path_mode = 0
 879     " Path to cache directory. I prefer to keep generated files as local as
 880     " possible.
 881     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 882     " Permanent cache, cleared by a crontab entry.
 883     let g:ctrlp_clear_cache_on_exit = 0
 884
 885 " FSWitch settings.
 886     " Default don't work well for my projects.
 887     augroup vimrc
 888         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 889                           \ | let b:fswitchlocs = './'
 890         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 891                           \ | let b:fswitchlocs = './'
 892     augroup END
 893
 894     " Switch to corresponding header/source file.
 895     nnoremap <silent> <Leader>h :FSHere<CR>
 896 endif
 897
 898
 899 " AUTO COMMANDS
 900
 901 " Use a custom auto group to prevent problems when the vimrc files is sourced
 902 " twice.
 903 if has('autocmd')
 904     augroup vimrc
 905
 906 " Go to last position of opened files. Taken from :help last-position-jump.
 907         autocmd BufReadPost *
 908             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 909             \     execute "normal! g'\"" |
 910             \ endif
 911 " But not for Git commits, go to beginning of the file.
 912         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 913
 914 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 915 " when switching to a help buffer which is in the background with :buffer as
 916 " these options are local to windows (and not only to buffers). This happens
 917 " because I often want to use only one window and thus the help buffer is in
 918 " the background.
 919         autocmd BufWinEnter *.txt
 920             \ if &filetype == 'help' |
 921             \     setlocal nolist |
 922             \     setlocal nonumber |
 923             \ endif
 924
 925 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 926 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 927 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 928 " doesn't exist in older Vims.
 929         if exists('##InsertLeave')
 930             autocmd InsertLeave * set nopaste
 931         endif
 932
 933 " Write all files when running :mak[e] before 'makeprg' is called.
 934 " QuickFixCmdPre doesn't exist in older Vims.
 935         if exists('##QuickFixCmdPre')
 936             autocmd QuickFixCmdPre * wall
 937         endif
 938
 939 " Don't ignore case while in insert mode, but ignore case in all other modes.
 940 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 941 " capitalization. But while searching (/) 'ignorecase' is used.
 942 " InsertEnter/InsertLeave doesn't exist in older Vims.
 943         if exists('##InsertEnter') && exists('##InsertLeave')
 944             autocmd InsertEnter * set noignorecase
 945             autocmd InsertLeave * set   ignorecase
 946         endif
 947
 948 " Display a warning when editing a file which contains "do not edit" (ignoring
 949 " the case, \c), for example template files which were preprocessed or
 950 " auto-generated files. Especially useful when the header is not displayed on
 951 " the first screen, e.g. when the old position is restored. Not for vimrc
 952 " though.
 953         function! s:SearchForDoNotEditHeader()
 954             if search('\cdo not edit', 'n') == 0
 955                     \ || expand('<afile>:t') =~# '^.\?vimrc$'
 956                 return
 957             endif
 958
 959             echoerr 'Do not edit this file! (Maybe a template file.)'
 960         endfunction
 961         autocmd BufRead * call <SID>SearchForDoNotEditHeader()
 962
 963 " AFTER/FTPLUGIN AUTO COMMANDS
 964
 965 " Disable spell checking for files which don't need it.
 966         autocmd FileType deb  setlocal nospell
 967         autocmd FileType diff setlocal nospell
 968         autocmd FileType tar  setlocal nospell
 969 " Fix to allow Vim edit crontab files as crontab doesn't work with
 970 " backupcopy=auto.
 971         autocmd FileType crontab setlocal backupcopy=yes
 972 " Don't use the modeline in git commits as the diff created by `git commit -v`
 973 " may contain one which could change the filetype or other settings of the
 974 " commit buffer. Also make sure we use only 72 characters per line which is
 975 " the recommendation for git commit messages (http://tpope.net/node/106).
 976         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 977                                  \ setlocal textwidth=72
 978 " Use the same comment string as for Vim files in Vimperator files.
 979         autocmd FileType vimperator setlocal commentstring=\"%s
 980 " Use TeX compiler for (La)TeX files.
 981         autocmd FileType tex compiler tex
 982
 983 " FTDETECT AUTO COMMANDS
 984
 985 " Recognize .md as markdown files (Vim default is .mkd).
 986         autocmd BufRead,BufNewFile *.md set filetype=mkd
 987 " Recognize .test as Tcl files.
 988         autocmd BufRead,BufNewFile *.test set filetype=tcl
 989
 990 " OTHER AUTO COMMANDS
 991
 992 " Disable spell checking, displaying of list characters and long lines when
 993 " viewing documentation.
 994         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 995
 996 " Use diff filetype for mercurial patches in patch queue.
 997         autocmd BufReadPost */.hg/patches/* set filetype=diff
 998
 999     augroup END
1000 endif
1001
1002
1003 " CUSTOM FUNCTIONS AND COMMANDS
1004
1005 if has('eval')
1006 " Convenient command to see the difference between the current buffer and the
1007 " file it was loaded from, thus the changes you made. Thanks to the
1008 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
1009 " for the diffed file than the filetype for the original file.
1010     if !exists(':DiffOrig')
1011         command DiffOrig
1012             \ let s:diff_orig_filetype = &filetype
1013             \ | vertical new
1014             \ | let &filetype = s:diff_orig_filetype
1015             \ | unlet s:diff_orig_filetype
1016             \ | set buftype=nofile
1017             \ | read ++edit #
1018             \ | 0d_
1019             \ | diffthis
1020             \ | wincmd p
1021             \ | diffthis
1022     endif
1023 endif