vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Save 'runtimepath' in case it was changed by the system's configuration
   7 " files. Also save 'diff' as set all& resets it; but somehow later (after
   8 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
   9 " automagically restored to the correct value.
  10 if has('eval')
  11     let s:save_runtimepath = &runtimepath
  12     let s:save_diff = &diff
  13 endif
  14 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  15 " system wide configuration file doesn't change default values.
  16 set all&
  17 " And restore it after all other options were reset.
  18 if has('eval')
  19     let &runtimepath = s:save_runtimepath
  20     let &diff = s:save_diff
  21     unlet s:save_runtimepath
  22     unlet s:save_diff
  23 endif
  24
  25 " Make sure Vim (and not Vi) settings are used.
  26 set nocompatible
  27
  28 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  29 " runtime files) if available.
  30 set runtimepath-=~/.vim
  31 set runtimepath^=~/.vim,~/.vim/runtime
  32
  33 " Don't store swap files in the same directory as the edited file.
  34 set directory-=.
  35 " But store them in ~/.tmp if available.
  36 set directory^=~/.tmp
  37
  38 " Disable modelines as they may cause security problems. Instead use
  39 " securemodelines (Vim script #1876).
  40 set nomodeline
  41
  42 " Complete to longest common string (list:longest) and then complete all full
  43 " matches after another (full). Thanks to pbrisbin
  44 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  45 set wildmode=list:longest,full
  46
  47 " Increase history of executed commands (:).
  48 set history=1000
  49
  50 " Increase number of possible undos.
  51 set undolevels=1000
  52
  53 " Use strong encryption if possible, also used for swap/undo files.
  54 if exists('+cryptmethod')
  55     set cryptmethod=blowfish
  56 endif
  57
  58
  59 " EDIT SETTINGS
  60
  61 " Enable automatic file detection, plugin and indention support.
  62 if has('autocmd')
  63     filetype off " necessary for pathogen to force a reload of ftplugins
  64     filetype plugin indent on
  65 endif
  66
  67 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  68 " existing files.
  69 set fileencodings=utf-8,latin1
  70
  71 " Wrap text after 78 characters.
  72 set textwidth=78
  73
  74 " Set tabs to 4 spaces, use softtabs.
  75 set shiftwidth=4
  76 set softtabstop=4
  77 set expandtab
  78 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  79 set shiftround
  80 " Use the default value for real tabs.
  81 set tabstop=8
  82
  83 " Enable auto indention.
  84 set autoindent
  85
  86 " When joining lines only add one space after a sentence.
  87 set nojoinspaces
  88
  89 " Allow backspacing over autoindent and line breaks.
  90 set backspace=indent,eol
  91
  92 " Start a comment when hitting enter after a commented line (r) and when using
  93 " o or O around a commented line (o).
  94 set formatoptions+=ro
  95 " Don't break a line if was already longer then 'textwidth' when insert mode
  96 " started.
  97 set formatoptions+=l
  98
  99 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 100 " no character) in visual block mode.
 101 set virtualedit=block
 102
 103 " Already display matches while typing the search command. This makes spotting
 104 " errors easy.
 105 set incsearch
 106
 107 " Activate syntax folding.
 108 if has('folding')
 109     set foldmethod=syntax
 110     set foldcolumn=2
 111     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 112                      " folding which is not what I want
 113 endif
 114
 115 " Only check for case if the searched word contains a capital character.
 116 set ignorecase
 117 set smartcase
 118
 119 " Activate spell checking, use English as default.
 120 if exists('+spell') && has('syntax')
 121     " But not when diffing as spell checking is distracting in this case.
 122     if !&diff
 123         set spell
 124     endif
 125     set spelllang=en_us
 126 endif
 127
 128 " Allow buffers with changes to be hidden. Very important for effective
 129 " editing with multiple buffers.
 130 set hidden
 131
 132
 133 " DISPLAY SETTINGS
 134
 135 " Use a dark background. Doesn't change the background color, only sets text
 136 " colors for a dark terminal.
 137 set background=dark
 138
 139 " Display line numbers.
 140 set number
 141 " But use as little space as necessary for the numbers column. Thanks to James
 142 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 143 if exists('+numberwidth')
 144     set numberwidth=1
 145 endif
 146 " Display the ruler with current line/file position. If 'statusline' is used
 147 " then this only affects <C-G>.
 148 set ruler
 149 " Display partial commands in the status line.
 150 set showcmd
 151
 152 " Don't redraw screen when executing macros; increases speed. Thanks to James
 153 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 154 set lazyredraw
 155
 156 " Visualize the line the cursor is currently in.
 157 if exists('+cursorline')
 158     set cursorline
 159 endif
 160
 161 " Display tabs, trailing space, non breakable spaces and long lines (when
 162 " wrapping is disabled).
 163 set list
 164 set listchars=trail:-,extends:>
 165 if v:version >= 700
 166     set listchars+=nbsp:!
 167 endif
 168
 169 if has('statusline')
 170     " Always display the status line even if there is only one window.
 171     set laststatus=2
 172
 173     set statusline=
 174     " on the left
 175     set statusline+=%02n: " buffer number
 176     set statusline+=%f\   " path to current file in buffer
 177     set statusline+=%h    " [help] if buffer is help file
 178     set statusline+=%w    " [Preview] if buffer is preview buffer
 179     set statusline+=%m    " [+] if buffer was modified,
 180                           " [-] if 'modifiable' is off
 181     set statusline+=%r    " [RO] if buffer is read only
 182
 183     " on the right
 184     set statusline+=%=                " right align
 185     set statusline+=0x%-8B\           " current character under cursor as hex
 186     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 187                                       " column number (%c),
 188                                       " virtual column number if different
 189                                       "                       than %c (%V)
 190     set statusline+=%P                " position in file in percent
 191 endif
 192
 193
 194 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 195
 196 " Easy way to exit insert mode.
 197 inoremap jj <Esc>
 198 inoremap jk <Esc>
 199 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 200 " (2010-10-15).
 201 cnoremap jj <C-C>
 202 cnoremap jk <C-C>
 203
 204 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 205 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 206 map <Right>  <Nop>
 207 map <Left>   <Nop>
 208 map <Up>     <Nop>
 209 map <Down>   <Nop>
 210 imap <Right> <Nop>
 211 imap <Left>  <Nop>
 212 imap <Up>    <Nop>
 213 imap <Down>  <Nop>
 214 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 215 " below).
 216 cmap <Up>    <Nop>
 217 cmap <Down>  <Nop>
 218 cmap <Right> <Nop>
 219 cmap <Left>  <Nop>
 220
 221 " Use Ctrl-P/Ctrl-N as replacement for <Up>/<Down> in command mode. Thanks to
 222 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 223 cnoremap <C-P> <Up>
 224 cnoremap <C-N> <Down>
 225
 226 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 227 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 228 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 229
 230 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 231 " in #vim on Freenode (2011-08-15 00:17 CEST).
 232 nnoremap <C-G> 2<C-G>
 233
 234 " Use <Space> to move down a page and - to move up one like in mutt.
 235 nnoremap <Space> <C-F>
 236 nnoremap - <C-B>
 237
 238 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 239 " (2010-05-16 18:38 CEST) for this idea.
 240 nnoremap <silent> gb :bnext<CR>
 241 nnoremap <silent> gB :bprev<CR>
 242
 243 " Fast access to buffers.
 244 nnoremap <silent> <Leader>1 :1b<CR>
 245 nnoremap <silent> <Leader>2 :2b<CR>
 246 nnoremap <silent> <Leader>3 :3b<CR>
 247 nnoremap <silent> <Leader>4 :4b<CR>
 248 nnoremap <silent> <Leader>5 :5b<CR>
 249 nnoremap <silent> <Leader>6 :6b<CR>
 250 nnoremap <silent> <Leader>7 :7b<CR>
 251 nnoremap <silent> <Leader>8 :8b<CR>
 252 nnoremap <silent> <Leader>9 :9b<CR>
 253 nnoremap <silent> <Leader>0 :10b<CR>
 254
 255 " Make last active window the only window. Similar to <C-W> o.
 256 nnoremap <C-W>O <C-W>p<C-W>o
 257
 258 " Maps to change spell language between English and German and disable spell
 259 " checking.
 260 if exists('+spell')
 261     noremap <silent> <Leader>sn :set nospell<CR>
 262     noremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 263     noremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 264 endif
 265
 266 " Add semicolon to the end of the line. Thanks to
 267 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 268 " on Freenode for an improved version which doesn't clobber any marks.
 269 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 270
 271 " * and # for selections in visual mode. Thanks to
 272 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 273 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 274 if has('eval')
 275     function! s:VSetSearch()
 276         let temp = @@
 277         normal! gvy
 278         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 279         let @@ = temp
 280     endfunction
 281     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 282     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 283 endif
 284
 285 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 286 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 287 " mailing list for the commands.
 288 if v:version < 700
 289     cnoreabbrev W w
 290     cnoreabbrev Wa wa
 291     cnoreabbrev Wq wq
 292     cnoreabbrev Wqa wqa
 293 else
 294     cnoreabbrev <expr> W
 295         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 296     cnoreabbrev <expr> Wa
 297         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 298     cnoreabbrev <expr> Wq
 299         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 300     cnoreabbrev <expr> Wqa
 301         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 302 endif
 303 " Also fix my typo with "Q".
 304 if v:version < 700
 305     cnoreabbrev Q q
 306     cnoreabbrev Qa qa
 307 else
 308     cnoreabbrev <expr> Q
 309         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 310     cnoreabbrev <expr> Qa
 311         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 312 endif
 313
 314 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 315 " if pressed accidentally while in insert mode (happens on Mac when alt
 316 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 317 " no longer set on the console.
 318 if has('mac') || filereadable('/Users/.localized')
 319     inoremap <Char-0xa0> <Space>
 320 endif
 321
 322 " Disable Apple style movements in MacVim.
 323 if has('gui_macvim')
 324     let g:macvim_skip_cmd_opt_movement = 1
 325 endif
 326
 327 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 328 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 329 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 330
 331 " Ctrl-U in insert mode deletes a lot, break undo sequence before deleting the
 332 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 333 " Vim's source.
 334 inoremap <C-U> <C-G>u<C-U>
 335 " Same for <C-@> (insert previously inserted text and leave insert mode).
 336 inoremap <C-@> <C-G>u<C-@>
 337 " And for <C-A> (insert previously inserted text).
 338 inoremap <C-A> <C-G>u<C-A>
 339 " And for <C-W> (delete word before cursor).
 340 inoremap <C-W> <C-G>u<C-W>
 341
 342 if has('eval')
 343 " New text-objects ii and ai to work on text with the same indentation. Thanks
 344 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 345 " (visited on 2011-11-19).
 346     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 347     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 348     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 349     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 350
 351     function! s:IndTxtObj(inner)
 352         let curline = line(".")
 353         let lastline = line("$")
 354         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 355         let i = i < 0 ? 0 : i
 356         if getline(".") !~ "^\\s*$"
 357             let p = line(".") - 1
 358             let nextblank = getline(p) =~ "^\\s*$"
 359             while p > 0
 360                     \ && ((i == 0 && !nextblank)
 361                         \ || (i > 0 && ((indent(p) >= i
 362                             \ && !(nextblank && a:inner))
 363                             \ || (nextblank && !a:inner))))
 364                 -
 365                 let p = line(".") - 1
 366                 let nextblank = getline(p) =~ "^\\s*$"
 367             endwhile
 368             normal! 0V
 369             call cursor(curline, 0)
 370             let p = line(".") + 1
 371             let nextblank = getline(p) =~ "^\\s*$"
 372             while p <= lastline
 373                     \ && ((i == 0 && !nextblank)
 374                         \ || (i > 0 && ((indent(p) >= i
 375                             \ && !(nextblank && a:inner))
 376                             \ || (nextblank && !a:inner))))
 377                 +
 378                 let p = line(".") + 1
 379                 let nextblank = getline(p) =~ "^\\s*$"
 380             endwhile
 381             normal! $
 382         endif
 383     endfunction
 384 endif
 385
 386
 387 " ABBREVIATIONS
 388
 389 " Fix some of my spelling mistakes.
 390 iabbrev relle reelle
 391 iabbrev reele reelle
 392
 393
 394 " SYNTAX SETTINGS
 395
 396 " Activate syntax coloring.
 397 if has('syntax')
 398     syntax enable
 399
 400 " Don't highlight more than 500 columns as I normally don't have that long
 401 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 402 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 403     if exists('+synmaxcol')
 404         set synmaxcol=500
 405     endif
 406
 407 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 408 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 409 " disabled when necessary with :2match (in Vim >= 700).
 410     if exists(':2match')
 411         2match Todo /\%>78v./
 412     else
 413         match Todo /\%>78v./
 414     endif
 415
 416     if exists('*matchadd')
 417 " Highlight some important keywords in all documents.
 418         for x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
 419             call matchadd('Todo', x)
 420         endfor
 421
 422 " Highlight unicode whitespace which is no normal whitespace (0x20).
 423         for x in ['00a0', '1680', '180e', '2000', '2001', '2002', '2003',
 424                 \ '2004', '2005', '2006', '2007', '2008', '2009', '200a',
 425                 \ '200b', '200c', '200d', '202f', '205f', '2060', '3000',
 426                 \ 'feff']
 427             call matchadd('Error', '\%u' . x)
 428         endfor
 429     endif
 430
 431 " Settings for specific filetypes.
 432
 433     " Haskell.
 434     let g:hs_highlight_boolean = 1
 435     let g:hs_highlight_types = 1
 436     let g:hs_highlight_more_types = 1
 437
 438     " Perl.
 439     let g:perl_fold = 1
 440     let g:perl_fold_blocks = 1
 441     let g:perl_nofold_packages = 1
 442     let g:perl_include_pod = 1 " syntax coloring for PODs
 443 endif
 444
 445
 446 " PLUGIN SETTINGS
 447
 448 if has('eval')
 449 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 450 " installing/removing/updating plugins simple. (Used for plugins with more
 451 " than one file.)
 452     if v:version >= 700
 453         execute 'call pathogen#runtime_append_all_bundles()'
 454     endif
 455
 456 " Settings for the NERD commenter.
 457     " Don't create any mappings I don't want to use.
 458     let NERDCreateDefaultMappings = 0
 459     " Map toggle comment.
 460     map <Leader><Leader> <Plug>NERDCommenterToggle
 461
 462 " XPTemplate settings.
 463     " Try to maintain snippet rendering even after editing outside of a
 464     " snippet.
 465     let g:xptemplate_strict = 0
 466     " Don't complete any braces automatically.
 467     let g:xptemplate_brace_complete = 0
 468     " Only highlight the current placeholder.
 469     let g:xptemplate_highlight = 'current'
 470 endif
 471
 472
 473 " AUTO COMMANDS
 474
 475 " Use a custom auto group to prevent problems when the vimrc files is sourced
 476 " twice.
 477 if has('autocmd')
 478     augroup vimrc
 479 " Remove all autocmds from the current group.
 480         autocmd!
 481
 482 " Go to last position of opened files. Taken from :help last-position-jump.
 483         autocmd BufReadPost *
 484             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 485             \     execute "normal! g'\"" |
 486             \ endif
 487 " But not for Git commits, go to beginning of the file.
 488         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 489
 490 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 491 " when switching to a help buffer which is in the background with :buffer as
 492 " these options are local to windows (and not only to buffers). This happens
 493 " because I often want to use only one window and thus the help buffer is in
 494 " the background.
 495         autocmd BufWinEnter *.txt
 496             \ if &filetype == 'help' |
 497             \     setlocal nolist |
 498             \     setlocal nonumber |
 499             \ endif
 500
 501 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 502 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 503 " want to paste once and then 'paste' gets automatically unset.
 504         if exists('##InsertLeave')
 505             autocmd InsertLeave * set nopaste
 506         endif
 507
 508 " Write file when running :mak[e] before 'makeprg' is called.
 509         autocmd QuickFixCmdPre * write
 510
 511 " AFTER/FTPLUGIN AUTO COMMANDS
 512
 513 " Disable spell checking for files which don't need it.
 514         autocmd FileType deb  setlocal nospell
 515         autocmd FileType diff setlocal nospell
 516         autocmd FileType tar  setlocal nospell
 517 " Fix to allow Vim edit crontab files as crontab doesn't work with
 518 " backupcopy=auto.
 519         autocmd FileType crontab setlocal backupcopy=yes
 520 " Don't use the modeline in git commits as the diff created by `git commit -v`
 521 " may contain one which could change the filetype or other settings of the
 522 " commit buffer. Also make sure we use only 72 characters per line which is
 523 " the recommendation for git commit messages (http://tpope.net/node/106).
 524         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 525                                  \ setlocal textwidth=72
 526 " Use the same comment string as for Vim files in Vimperator files.
 527         autocmd FileType vimperator setlocal commentstring=\"%s
 528 " Use tex compiler for (La)TeX files.
 529         autocmd FileType tex compiler tex
 530
 531 " FTDETECT AUTO COMMANDS
 532
 533 " Recognize .md as markdown files (Vim default is .mkd).
 534         autocmd BufRead,BufNewFile *.md set filetype=mkd
 535 " Recognize .test as Tcl files.
 536         autocmd BufRead,BufNewFile *.test set filetype=tcl
 537
 538 " OTHER AUTO COMMANDS
 539
 540 " Disable spell checking, displaying of list characters and long lines when
 541 " viewing documentation.
 542         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 543
 544 " Use diff filetype for mercurial patches in patch queue.
 545         autocmd BufReadPost */.hg/patches/* set filetype=diff
 546
 547     augroup END
 548 endif
 549
 550
 551 " CUSTOM FUNCTIONS AND COMMANDS
 552
 553 if has('eval')
 554 " Convenient command to see the difference between the current buffer and the
 555 " file it was loaded from, thus the changes you made. Thanks to the
 556 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 557 " for the diffed file than the filetype for the original file.
 558     if !exists(":DiffOrig")
 559         command DiffOrig
 560             \ let s:diff_orig_filetype = &filetype
 561             \ | vertical new
 562             \ | let &filetype = s:diff_orig_filetype
 563             \ | unlet s:diff_orig_filetype
 564             \ | set buftype=nofile
 565             \ | read ++edit #
 566             \ | 0d_
 567             \ | diffthis
 568             \ | wincmd p
 569             \ | diffthis
 570     endif
 571 endif