vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Prevent editing as root as it may cause security problems. Use sudoedit
   7 " instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21).
   8 if $HOME == '/root' || exists('$SUDO_USER')
   9     echomsg 'Running as root is forbidden! Use sudoedit.'
  10     qa
  11 endif
  12
  13
  14 " Reset all options (except 'term, 'lines' and 'columns'). This makes sure a
  15 " system wide configuration file doesn't change default values.
  16 set all&
  17
  18 " Make sure Vim (and not Vi) settings are used.
  19 set nocompatible
  20
  21 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  22 " runtime files).
  23 set runtimepath-=~/.vim
  24 set runtimepath^=~/.vim,~/.vim/runtime
  25
  26 " Don't store swap files in the same directory as the edited file.
  27 set directory-=.
  28
  29 " Disable modelines as they may cause security problems. Instead use
  30 " securemodelines (Vim script #1876).
  31 set nomodeline
  32
  33 " When completing paths first use the longest path then display a list of all
  34 " possible files.
  35 set wildmode=longest,list
  36
  37
  38 " EDIT SETTINGS
  39
  40 " Enable automatic file detection, plugin and indention support.
  41 if has('autocmd')
  42     filetype plugin indent on
  43 endif
  44
  45 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  46 " existing files.
  47 set fileencodings=utf-8,latin1
  48
  49 " Wrap text after 78 characters.
  50 set textwidth=78
  51
  52 " Set tabs to 4 spaces, use softtabs.
  53 set shiftwidth=4
  54 set softtabstop=4
  55 set expandtab
  56 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  57 set shiftround
  58 " Use the default value for real tabs.
  59 set tabstop=8
  60
  61 " Enable auto indention.
  62 set autoindent
  63
  64 " When joining lines only add one space after a sentence.
  65 set nojoinspaces
  66
  67 " Allow backspacing over autoindent and line breaks.
  68 set backspace=indent,eol
  69
  70 " Start a comment when hitting enter after a commented line (r) and when using
  71 " o or O around a commented line (o).
  72 set formatoptions+=ro
  73 " Don't break a line if was already longer then 'textwidth' when insert mode
  74 " started.
  75 set formatoptions+=l
  76
  77 " Allow virtual editing (cursor can be positioned anywhere, even when there is
  78 " no character) in visual block mode.
  79 set virtualedit=block
  80
  81 " Already display matches while typing the search command. This makes spotting
  82 " errors easy.
  83 set incsearch
  84
  85 " Activate syntax folding.
  86 if has('folding')
  87     set foldmethod=syntax
  88     set foldcolumn=2
  89     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
  90                      " folding which is not what I want
  91 endif
  92
  93 " Only check for case if the searched word contains a capital character.
  94 set ignorecase
  95 set smartcase
  96
  97 " Activate spell checking, use English as default. Don't use spell checking
  98 " when diffing.
  99 if v:version >= 700 && has('syntax') && !&diff
 100     set spell
 101     set spelllang=en_us
 102 endif
 103
 104 " Allow buffers with changes to be hidden. Very important for effective
 105 " editing with multiple buffers.
 106 set hidden
 107
 108
 109 " DISPLAY SETTINGS
 110
 111 " Use a dark background. Doesn't change the background color, only sets text
 112 " colors for a dark terminal.
 113 set background=dark
 114
 115 " Display line numbers.
 116 set number
 117 " But use as little space as necessary for the numbers column. Thanks to James
 118 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 119 if v:version >= 700
 120     set numberwidth=1
 121 endif
 122 " Display the ruler with current line/file position. If 'statusline' is used
 123 " then this only affects <C-g>.
 124 set ruler
 125 " Display partial commands in the status line.
 126 set showcmd
 127
 128 " Don't redraw screen when executing macros; increases speed. Thanks to James
 129 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 130 set lazyredraw
 131
 132 " Visualize the line the cursor is currently in.
 133 if v:version >= 700
 134     set cursorline
 135 endif
 136
 137 " Display tabs, trailing space, non breakable spaces and long lines (when
 138 " wrapping is disabled).
 139 set list
 140 set listchars=trail:-,extends:>
 141 if v:version >= 700
 142     set listchars+=nbsp:!
 143 endif
 144
 145 if has('statusline')
 146     " Always display the status line even if there is only one window.
 147     set laststatus=2
 148
 149     set statusline=
 150     " on the left
 151     set statusline+=%02n: " buffer number
 152     set statusline+=%f\   " path to current file in buffer
 153     set statusline+=%h    " [help] if buffer is help file
 154     set statusline+=%w    " [Preview] if buffer is preview buffer
 155     set statusline+=%m    " [+] if buffer was modified,
 156                           " [-] if 'modifiable' is off
 157     set statusline+=%r    " [RO] if buffer is read only
 158
 159     " on the right
 160     set statusline+=%=                " right align
 161     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 162                                       " column number (%c),
 163                                       " virtual column number if different
 164                                       "                       than %c (%V)
 165     set statusline+=%P                " position in file in percent
 166 endif
 167
 168
 169 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 170
 171 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 172 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 173 map <right> <nop>
 174 map <left>  <nop>
 175 map <up>    <nop>
 176 map <down>  <nop>
 177 imap <right> <nop>
 178 imap <left>  <nop>
 179 imap <up>    <nop>
 180 imap <down>  <nop>
 181
 182 " Use <space> to move down a page and - to move up one like in mutt.
 183 nnoremap <Space> <C-f>
 184 nnoremap - <C-b>
 185
 186 " Fast access to buffers.
 187 nnoremap <Leader>1 :1b<CR>
 188 nnoremap <Leader>2 :2b<CR>
 189 nnoremap <Leader>3 :3b<CR>
 190 nnoremap <Leader>4 :4b<CR>
 191 nnoremap <Leader>5 :5b<CR>
 192 nnoremap <Leader>6 :6b<CR>
 193 nnoremap <Leader>7 :7b<CR>
 194 nnoremap <Leader>8 :8b<CR>
 195 nnoremap <Leader>9 :9b<CR>
 196 nnoremap <Leader>0 :10b<CR>
 197
 198 " Make last active window the only window. Similar to <C-w> o.
 199 nnoremap <C-w>O <C-w>p<C-w>o
 200
 201 " Maps to change spell language between English and German and disable spell
 202 " checking.
 203 if v:version >= 700
 204     map <Leader>sn :set nospell<CR>
 205     map <Leader>se :set spell spelllang=en_us<CR>
 206     map <Leader>sd :set spell spelllang=de_de<CR>
 207 endif
 208
 209 " Add semicolon to the end of the line. Thanks to
 210 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 211 " on Freenode for an improved version which doesn't clobber any marks.
 212 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 213
 214 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 215 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 216 " mailing list for the commands.
 217 if v:version < 700
 218     cnoreabbrev W w
 219     cnoreabbrev Wa wa
 220     cnoreabbrev Wq wq
 221     cnoreabbrev Wqa wqa
 222 else
 223     cnoreabbrev <expr> W
 224         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 225     cnoreabbrev <expr> Wa
 226         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 227     cnoreabbrev <expr> Wq
 228         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 229     cnoreabbrev <expr> Wqa
 230         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 231 endif
 232 " Also fix my typo with "Q".
 233 if v:version < 700
 234     cnoreabbrev Q q
 235     cnoreabbrev Qa qa
 236 else
 237     cnoreabbrev <expr> Q
 238         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 239     cnoreabbrev <expr> Qa
 240         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 241 endif
 242
 243 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 244 " if pressed accidentally while in insert mode (happens on Mac when alt
 245 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 246 " no longer set on the console.
 247 if has('mac') || filereadable('/Users/.localized')
 248     inoremap <Char-0xa0> <Space>
 249 endif
 250
 251 " Disable Apple style movements in MacVim.
 252 if has('gui_macvim') && has('eval')
 253     let macvim_skip_cmd_opt_movement = 1
 254 endif
 255
 256
 257 " SYNTAX SETTINGS
 258
 259 " Activate syntax coloring.
 260 if has('syntax')
 261     syntax enable
 262
 263 " Don't highlight more than 200 columns as I normally don't have that long
 264 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 265 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 266     set synmaxcol=200
 267
 268 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 269 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 270 " disabled when necessary with :2match (in Vim >= 700).
 271     if v:version >= 700
 272         2match Todo /\%>78v./
 273     else
 274         match Todo /\%>78v./
 275     endif
 276
 277 " Highlight TODO, FIXME, CHANGED and XXX in all documents.
 278     if v:version > 701 || (v:version == 701 && has('patch42'))
 279         call matchadd('Todo', '\(TODO\|FIXME\|CHANGED\|XXX\)')
 280     endif
 281 endif
 282
 283
 284 " PLUGIN SETTINGS
 285
 286 " Settings for the NERD commenter.
 287 " Don't create any mappings I don't want to use.
 288 if has('eval')
 289     let NERDCreateDefaultMappings = 0
 290 endif
 291 " Map toggle comment.
 292 map <Leader><Leader> <plug>NERDCommenterToggle
 293
 294
 295 " AUTO COMMANDS
 296
 297 " Use a custom auto group to prevent problems when the vimrc files is sourced
 298 " twice.
 299 if has('autocmd')
 300     augroup vimrc
 301         autocmd!
 302
 303 " Go to last position of opened files. Taken from :help last-position-jump.
 304         autocmd BufReadPost *
 305             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 306             \     execute "normal! g'\"" |
 307             \ endif
 308 " But not for Git commits, go to beginning of the file.
 309         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 310
 311 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 312 " when switching to a help buffer which is in the background with :buffer as
 313 " these options are local to windows (and not only to buffers). This happens
 314 " because I often want to use only one window and thus the help buffer is in
 315 " the background.
 316         autocmd BufWinEnter *.txt
 317             \ if &filetype == 'help' |
 318             \     setlocal nolist |
 319             \     setlocal nonumber |
 320             \ endif
 321
 322 " AFTER/FTPLUGIN AUTO COMMANDS
 323
 324 " Disable spell checking for files which don't need it.
 325         autocmd FileType deb  setlocal nospell
 326         autocmd FileType diff setlocal nospell
 327         autocmd FileType tar  setlocal nospell
 328 " Fix to allow Vim edit crontab files as crontab doesn't work with
 329 " backupcopy=auto.
 330         autocmd FileType crontab setlocal backupcopy=yes
 331 " Don't use the modeline in git commits as the diff created by `git commit -v`
 332 " may contain one which could change the filetype or other settings of the
 333 " commit buffer. Also make sure we use only 72 characters per line which is
 334 " the recommendation for git commit messages (http://tpope.net/node/106).
 335         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 336                                  \ setlocal textwidth=72
 337 " Allow folding in perl.
 338         autocmd FileType perl let perl_fold = 1 |
 339                             \ let perl_fold_blocks = 1
 340 " Use the same comment string as for Vim files in Vimperator files.
 341         autocmd FileType vimperator setlocal commentstring=\"%s
 342
 343 " FTDETECT AUTO COMMANDS
 344
 345 " Recognize .md as markdown files (Vim default is .mkd).
 346         autocmd BufRead,BufNewFile *.md set filetype=mkd
 347 " Recognize .test as Tcl files.
 348         autocmd BufRead,BufNewFile *.test set filetype=tcl
 349
 350 " OTHER AUTO COMMANDS
 351
 352 " Use diff filetype for mercurial patches in patch queue.
 353         autocmd BufReadPost */.hg/patches/* set filetype=diff
 354
 355     augroup END
 356 endif