vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Prevent editing as root as it may cause security problems. Use sudoedit
   7 " instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21).
   8 if $HOME == '/root' || exists('$SUDO_USER')
   9     echomsg 'Running as root is forbidden! Use sudoedit.'
  10     qa
  11 endif
  12
  13
  14 " Save 'runtimepath' in case it was changed by the system's configuration
  15 " files.
  16 if has('eval')
  17     let s:save_runtimepath = &runtimepath
  18 endif
  19 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  20 " system wide configuration file doesn't change default values.
  21 set all&
  22 " And restore it after all other options were reset.
  23 if has('eval')
  24     let &runtimepath = s:save_runtimepath
  25 endif
  26
  27 " Make sure Vim (and not Vi) settings are used.
  28 set nocompatible
  29
  30 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  31 " runtime files).
  32 set runtimepath-=~/.vim
  33 set runtimepath^=~/.vim,~/.vim/runtime
  34
  35 " Don't store swap files in the same directory as the edited file.
  36 set directory-=.
  37
  38 " Disable modelines as they may cause security problems. Instead use
  39 " securemodelines (Vim script #1876).
  40 set nomodeline
  41
  42 " When completing paths first use the longest path then display a list of all
  43 " possible files.
  44 set wildmode=longest,list
  45
  46 " Use strong encryption if possible, also used for swap/undo files.
  47 if v:version >= 703
  48     set cryptmethod=blowfish
  49 endif
  50
  51
  52 " EDIT SETTINGS
  53
  54 " Enable automatic file detection, plugin and indention support.
  55 if has('autocmd')
  56     filetype plugin indent on
  57 endif
  58
  59 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  60 " existing files.
  61 set fileencodings=utf-8,latin1
  62
  63 " Wrap text after 78 characters.
  64 set textwidth=78
  65
  66 " Set tabs to 4 spaces, use softtabs.
  67 set shiftwidth=4
  68 set softtabstop=4
  69 set expandtab
  70 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  71 set shiftround
  72 " Use the default value for real tabs.
  73 set tabstop=8
  74
  75 " Enable auto indention.
  76 set autoindent
  77
  78 " When joining lines only add one space after a sentence.
  79 set nojoinspaces
  80
  81 " Allow backspacing over autoindent and line breaks.
  82 set backspace=indent,eol
  83
  84 " Start a comment when hitting enter after a commented line (r) and when using
  85 " o or O around a commented line (o).
  86 set formatoptions+=ro
  87 " Don't break a line if was already longer then 'textwidth' when insert mode
  88 " started.
  89 set formatoptions+=l
  90
  91 " Allow virtual editing (cursor can be positioned anywhere, even when there is
  92 " no character) in visual block mode.
  93 set virtualedit=block
  94
  95 " Already display matches while typing the search command. This makes spotting
  96 " errors easy.
  97 set incsearch
  98
  99 " Activate syntax folding.
 100 if has('folding')
 101     set foldmethod=syntax
 102     set foldcolumn=2
 103     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 104                      " folding which is not what I want
 105 endif
 106
 107 " Only check for case if the searched word contains a capital character.
 108 set ignorecase
 109 set smartcase
 110
 111 " Activate spell checking, use English as default. Don't use spell checking
 112 " when diffing.
 113 if v:version >= 700 && has('syntax') && !&diff
 114     set spell
 115     set spelllang=en_us
 116 endif
 117
 118 " Allow buffers with changes to be hidden. Very important for effective
 119 " editing with multiple buffers.
 120 set hidden
 121
 122
 123 " DISPLAY SETTINGS
 124
 125 " Use a dark background. Doesn't change the background color, only sets text
 126 " colors for a dark terminal.
 127 set background=dark
 128
 129 " Display line numbers.
 130 set number
 131 " But use as little space as necessary for the numbers column. Thanks to James
 132 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 133 if v:version >= 700
 134     set numberwidth=1
 135 endif
 136 " Display the ruler with current line/file position. If 'statusline' is used
 137 " then this only affects <C-g>.
 138 set ruler
 139 " Display partial commands in the status line.
 140 set showcmd
 141
 142 " Don't redraw screen when executing macros; increases speed. Thanks to James
 143 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 144 set lazyredraw
 145
 146 " Visualize the line the cursor is currently in.
 147 if v:version >= 700
 148     set cursorline
 149 endif
 150
 151 " Display tabs, trailing space, non breakable spaces and long lines (when
 152 " wrapping is disabled).
 153 set list
 154 set listchars=trail:-,extends:>
 155 if v:version >= 700
 156     set listchars+=nbsp:!
 157 endif
 158
 159 if has('statusline')
 160     " Always display the status line even if there is only one window.
 161     set laststatus=2
 162
 163     set statusline=
 164     " on the left
 165     set statusline+=%02n: " buffer number
 166     set statusline+=%f\   " path to current file in buffer
 167     set statusline+=%h    " [help] if buffer is help file
 168     set statusline+=%w    " [Preview] if buffer is preview buffer
 169     set statusline+=%m    " [+] if buffer was modified,
 170                           " [-] if 'modifiable' is off
 171     set statusline+=%r    " [RO] if buffer is read only
 172
 173     " on the right
 174     set statusline+=%=                " right align
 175     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 176                                       " column number (%c),
 177                                       " virtual column number if different
 178                                       "                       than %c (%V)
 179     set statusline+=%P                " position in file in percent
 180 endif
 181
 182
 183 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 184
 185 " Easy way to exit insert mode.
 186 inoremap jj <Esc>
 187
 188 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 189 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 190 map <right> <nop>
 191 map <left>  <nop>
 192 map <up>    <nop>
 193 map <down>  <nop>
 194 imap <right> <nop>
 195 imap <left>  <nop>
 196 imap <up>    <nop>
 197 imap <down>  <nop>
 198 " Also disable up and down array in command mode, use <C-p>/<C-n> as
 199 " replacement (see below).
 200 cmap <up> <nop>
 201 cmap <down> <nop>
 202
 203 " Use Ctrl-P/Ctrl-N as replacement for <Up>/<Down> in command mode. Thanks to
 204 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20).
 205 cnoremap <C-p> <up>
 206 cnoremap <C-n> <down>
 207
 208 " Use <space> to move down a page and - to move up one like in mutt.
 209 nnoremap <Space> <C-f>
 210 nnoremap - <C-b>
 211
 212 " Fast access to buffers.
 213 nnoremap <Leader>1 :1b<CR>
 214 nnoremap <Leader>2 :2b<CR>
 215 nnoremap <Leader>3 :3b<CR>
 216 nnoremap <Leader>4 :4b<CR>
 217 nnoremap <Leader>5 :5b<CR>
 218 nnoremap <Leader>6 :6b<CR>
 219 nnoremap <Leader>7 :7b<CR>
 220 nnoremap <Leader>8 :8b<CR>
 221 nnoremap <Leader>9 :9b<CR>
 222 nnoremap <Leader>0 :10b<CR>
 223
 224 " Make last active window the only window. Similar to <C-w> o.
 225 nnoremap <C-w>O <C-w>p<C-w>o
 226
 227 " Maps to change spell language between English and German and disable spell
 228 " checking.
 229 if v:version >= 700
 230     map <Leader>sn :set nospell<CR>
 231     map <Leader>se :set spell spelllang=en_us<CR>
 232     map <Leader>sd :set spell spelllang=de_de<CR>
 233 endif
 234
 235 " Add semicolon to the end of the line. Thanks to
 236 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 237 " on Freenode for an improved version which doesn't clobber any marks.
 238 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 239
 240 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 241 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 242 " mailing list for the commands.
 243 if v:version < 700
 244     cnoreabbrev W w
 245     cnoreabbrev Wa wa
 246     cnoreabbrev Wq wq
 247     cnoreabbrev Wqa wqa
 248 else
 249     cnoreabbrev <expr> W
 250         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 251     cnoreabbrev <expr> Wa
 252         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 253     cnoreabbrev <expr> Wq
 254         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 255     cnoreabbrev <expr> Wqa
 256         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 257 endif
 258 " Also fix my typo with "Q".
 259 if v:version < 700
 260     cnoreabbrev Q q
 261     cnoreabbrev Qa qa
 262 else
 263     cnoreabbrev <expr> Q
 264         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 265     cnoreabbrev <expr> Qa
 266         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 267 endif
 268
 269 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 270 " if pressed accidentally while in insert mode (happens on Mac when alt
 271 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 272 " no longer set on the console.
 273 if has('mac') || filereadable('/Users/.localized')
 274     inoremap <Char-0xa0> <Space>
 275 endif
 276
 277 " Disable Apple style movements in MacVim.
 278 if has('gui_macvim') && has('eval')
 279     let macvim_skip_cmd_opt_movement = 1
 280 endif
 281
 282
 283 " SYNTAX SETTINGS
 284
 285 " Activate syntax coloring.
 286 if has('syntax')
 287     syntax enable
 288
 289 " Don't highlight more than 200 columns as I normally don't have that long
 290 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 291 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 292     set synmaxcol=200
 293
 294 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 295 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 296 " disabled when necessary with :2match (in Vim >= 700).
 297     if v:version >= 700
 298         2match Todo /\%>78v./
 299     else
 300         match Todo /\%>78v./
 301     endif
 302
 303 " Highlight TODO, FIXME, CHANGED and XXX in all documents.
 304     if v:version > 701 || (v:version == 701 && has('patch42'))
 305         call matchadd('Todo', '\(TODO\|FIXME\|CHANGED\|XXX\)')
 306     endif
 307 endif
 308
 309
 310 " PLUGIN SETTINGS
 311
 312 " Settings for the NERD commenter.
 313 " Don't create any mappings I don't want to use.
 314 if has('eval')
 315     let NERDCreateDefaultMappings = 0
 316 endif
 317 " Map toggle comment.
 318 map <Leader><Leader> <plug>NERDCommenterToggle
 319
 320 " XPTemplate settings.
 321 if has('eval')
 322     " Try to maintain snippet rendering even after editing outside of a
 323     " snippet.
 324     let g:xptemplate_strict = 0
 325     " Don't complete any braces automatically.
 326     let g:xptemplate_brace_complete = 0
 327     " Only highlight the current placeholder.
 328     let g:xptemplate_highlight = 'current'
 329 endif
 330
 331
 332 " AUTO COMMANDS
 333
 334 " Use a custom auto group to prevent problems when the vimrc files is sourced
 335 " twice.
 336 if has('autocmd')
 337     augroup vimrc
 338         autocmd!
 339
 340 " Go to last position of opened files. Taken from :help last-position-jump.
 341         autocmd BufReadPost *
 342             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 343             \     execute "normal! g'\"" |
 344             \ endif
 345 " But not for Git commits, go to beginning of the file.
 346         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 347
 348 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 349 " when switching to a help buffer which is in the background with :buffer as
 350 " these options are local to windows (and not only to buffers). This happens
 351 " because I often want to use only one window and thus the help buffer is in
 352 " the background.
 353         autocmd BufWinEnter *.txt
 354             \ if &filetype == 'help' |
 355             \     setlocal nolist |
 356             \     setlocal nonumber |
 357             \ endif
 358
 359 " AFTER/FTPLUGIN AUTO COMMANDS
 360
 361 " Disable spell checking for files which don't need it.
 362         autocmd FileType deb  setlocal nospell
 363         autocmd FileType diff setlocal nospell
 364         autocmd FileType tar  setlocal nospell
 365 " Fix to allow Vim edit crontab files as crontab doesn't work with
 366 " backupcopy=auto.
 367         autocmd FileType crontab setlocal backupcopy=yes
 368 " Don't use the modeline in git commits as the diff created by `git commit -v`
 369 " may contain one which could change the filetype or other settings of the
 370 " commit buffer. Also make sure we use only 72 characters per line which is
 371 " the recommendation for git commit messages (http://tpope.net/node/106).
 372         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 373                                  \ setlocal textwidth=72
 374 " Allow folding in perl.
 375         autocmd FileType perl let perl_fold = 1 |
 376                             \ let perl_fold_blocks = 1
 377 " Use the same comment string as for Vim files in Vimperator files.
 378         autocmd FileType vimperator setlocal commentstring=\"%s
 379
 380 " FTDETECT AUTO COMMANDS
 381
 382 " Recognize .md as markdown files (Vim default is .mkd).
 383         autocmd BufRead,BufNewFile *.md set filetype=mkd
 384 " Recognize .test as Tcl files.
 385         autocmd BufRead,BufNewFile *.test set filetype=tcl
 386
 387 " OTHER AUTO COMMANDS
 388
 389 " Use diff filetype for mercurial patches in patch queue.
 390         autocmd BufReadPost */.hg/patches/* set filetype=diff
 391
 392     augroup END
 393 endif