vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Prevent editing as root as it may cause security problems. Use sudoedit
   7 " instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21).
   8 if $HOME == '/root' || exists('$SUDO_USER')
   9     echomsg 'Running as root is forbidden! Use sudoedit.'
  10     qa
  11 endif
  12
  13 " Make sure Vim (and not Vi) settings are used.
  14 set nocompatible
  15
  16 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  17 " runtime files).
  18 set runtimepath-=~/.vim
  19 set runtimepath^=~/.vim,~/.vim/runtime
  20
  21 " Disable modelines as they may cause security problems. Instead use
  22 " securemodelines (Vim script #1876).
  23 set nomodeline
  24
  25 " When completing paths first use the longest path then display a list of all
  26 " possible files.
  27 set wildmode=longest,list
  28
  29
  30 " EDIT SETTINGS
  31
  32 " Enable automatic file detection, plugin and indention support.
  33 if has('autocmd')
  34     filetype plugin indent on
  35 endif
  36
  37 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  38 " existing files.
  39 set fileencodings=utf-8,latin1
  40
  41 " Wrap text after 78 characters.
  42 set textwidth=78
  43
  44 " Set tabs to 4 spaces, use softtabs.
  45 set shiftwidth=4
  46 set softtabstop=4
  47 set expandtab
  48 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  49 set shiftround
  50 " Use the default value for real tabs.
  51 set tabstop=8
  52
  53 " Enable auto indention.
  54 set autoindent
  55
  56 " When joining lines only add one space after a sentence.
  57 set nojoinspaces
  58
  59 " Allow backspacing over autoindent and line breaks.
  60 set backspace=indent,eol
  61
  62 " Start a comment when hitting enter after a commented line (r) and when using
  63 " o or O around a commented line (o).
  64 set formatoptions+=ro
  65 " Don't break a line if was already longer then 'textwidth' when insert mode
  66 " started.
  67 set formatoptions+=l
  68
  69 " Allow virtual editing (cursor can be positioned anywhere, even when there is
  70 " no character) in visual block mode.
  71 set virtualedit=block
  72
  73 " Already display matches while typing the search command. This makes spotting
  74 " errors easy.
  75 set incsearch
  76
  77 " Activate syntax folding.
  78 if has('folding')
  79     set foldmethod=syntax
  80     set foldcolumn=2
  81     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
  82                      " folding which is not what I want
  83 endif
  84
  85 " Only check for case if the searched word contains a capital character.
  86 set ignorecase
  87 set smartcase
  88
  89 " Activate spell checking, use English as default. Don't use spell checking
  90 " when diffing.
  91 if v:version >= 700 && has('syntax') && !&diff
  92     set spell
  93     set spelllang=en_us
  94 endif
  95
  96 " Allow buffers with changes to be hidden. Very important for effective
  97 " editing with multiple buffers.
  98 set hidden
  99
 100
 101 " DISPLAY SETTINGS
 102
 103 " Use a dark background. Doesn't change the background color, only sets text
 104 " colors for a dark terminal.
 105 set background=dark
 106
 107 " Display line numbers.
 108 set number
 109 " Display the ruler with current line/file position.
 110 set ruler
 111 " Display partial commands in the status line.
 112 set showcmd
 113
 114 " Visualize the line the cursor is currently in.
 115 if v:version >= 700
 116     set cursorline
 117 endif
 118
 119 " Display tabs, trailing space, non breakable spaces and long lines (when
 120 " wrapping is enabled).
 121 set list
 122 set listchars=trail:-,extends:>
 123 if v:version >= 700
 124     set listchars+=nbsp:!
 125 endif
 126
 127 " Always display the status line even if there is only one window.
 128 if has('statusline')
 129     set laststatus=2
 130 endif
 131
 132
 133 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 134
 135 " Use <space> to move down a page and - to move up one like in mutt.
 136 nnoremap <Space> <C-f>
 137 nnoremap - <C-b>
 138
 139 " Fast access to buffers.
 140 nnoremap <Leader>1 :1b<CR>
 141 nnoremap <Leader>2 :2b<CR>
 142 nnoremap <Leader>3 :3b<CR>
 143 nnoremap <Leader>4 :4b<CR>
 144 nnoremap <Leader>5 :5b<CR>
 145 nnoremap <Leader>6 :6b<CR>
 146 nnoremap <Leader>7 :7b<CR>
 147 nnoremap <Leader>8 :8b<CR>
 148 nnoremap <Leader>9 :9b<CR>
 149 nnoremap <Leader>0 :10b<CR>
 150
 151 " Make last active window the only window. Similar to <C-w> o.
 152 nnoremap <C-w>O <C-w>p<C-w>o
 153
 154 " Maps to change spell language between English and German and disable spell
 155 " checking.
 156 if v:version >= 700
 157     map <Leader>sn :set nospell<CR>
 158     map <Leader>se :set spell spelllang=en_us<CR>
 159     map <Leader>sd :set spell spelllang=de_de<CR>
 160 endif
 161
 162 " Add semicolon to the end of the line. Thanks to
 163 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 164 " on Freenode for an improved version which doesn't clobber any marks.
 165 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 166
 167 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 168 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 169 " mailing list for the commands.
 170 if v:version < 700
 171     cnoreabbrev W w
 172     cnoreabbrev Wa wa
 173     cnoreabbrev Wq wq
 174     cnoreabbrev Wqa wqa
 175 else
 176     cnoreabbrev <expr> W
 177         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 178     cnoreabbrev <expr> Wa
 179         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 180     cnoreabbrev <expr> Wq
 181         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 182     cnoreabbrev <expr> Wqa
 183         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 184 endif
 185 " Also fix my typo with "Q".
 186 if v:version < 700
 187     cnoreabbrev Q q
 188     cnoreabbrev Qa qa
 189 else
 190     cnoreabbrev <expr> Q
 191         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 192     cnoreabbrev <expr> Qa
 193         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 194 endif
 195
 196 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 197 " if pressed accidentally while in insert mode (happens on Mac when alt
 198 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 199 " no longer set on the console.
 200 if has('mac') || filereadable('/Users/.localized')
 201     inoremap <Char-0xa0> <Space>
 202 endif
 203
 204 " Disable Apple style movements in MacVim.
 205 if has('gui_macvim') && has('eval')
 206     let macvim_skip_cmd_opt_movement = 1
 207 endif
 208
 209
 210 " SYNTAX SETTINGS
 211
 212 " Activate syntax coloring.
 213 if has('syntax')
 214     syntax enable
 215
 216 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 217 " <antoine.mechelynck@gmail.com> from the Vim mailing list.
 218 " It can easily be disabled if necessary with :2match (in Vim >= 700).
 219     if v:version >= 700
 220         2match Todo /\%>78v./
 221     else
 222         match Todo /\%>78v./
 223     endif
 224
 225 " Highlight TODO, FIXME, CHANGED and XXX in all documents.
 226     if v:version > 701 || (v:version == 701 && has('patch42'))
 227         call matchadd('Todo', '\(TODO\|FIXME\|CHANGED\|XXX\)')
 228     endif
 229 endif
 230
 231
 232 " PLUGIN SETTINGS
 233
 234 " Settings for the NERD commenter.
 235 " Don't create any mappings I don't want to use.
 236 if has('eval')
 237     let NERDCreateDefaultMappings = 0
 238 endif
 239 " Map toggle comment.
 240 map <Leader><Leader> <plug>NERDCommenterToggle
 241
 242
 243 " AUTO COMMANDS
 244
 245 " Use a custom auto group to prevent problems when the vimrc files is sourced
 246 " twice.
 247 if has('autocmd')
 248     augroup vimrc
 249         autocmd!
 250
 251 " Go to last position of opened files. Taken from :help last-position-jump.
 252         autocmd BufReadPost *
 253             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 254             \     execute "normal! g'\"" |
 255             \ endif
 256 " But not for Git commits, go to beginning of the file.
 257         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 258
 259 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 260 " when switching to a help buffer which is in the background with :buffer as
 261 " these options are local to windows (and not only to buffers). This happens
 262 " because I often want to use only one window and thus the help buffer is in
 263 " the background.
 264         autocmd BufWinEnter *.txt
 265             \ if &filetype == 'help' |
 266             \     setlocal nolist |
 267             \     setlocal nonumber |
 268             \ endif
 269
 270 " AFTER/FTPLUGIN AUTO COMMANDS
 271
 272 " Disable spell checking for files which don't need it.
 273         autocmd FileType deb  setlocal nospell
 274         autocmd FileType diff setlocal nospell
 275         autocmd FileType tar  setlocal nospell
 276 " Fix to allow Vim edit crontab files as crontab doesn't work with
 277 " backupcopy=auto.
 278         autocmd FileType crontab setlocal backupcopy=yes
 279 " Don't use the modeline in git commits as the diff created by `git commit -v`
 280 " may contain one which could change the filetype or other settings of the
 281 " commit buffer. Also make sure we use only 72 characters per line which is
 282 " the recommendation for git commit messages (http://tpope.net/node/106).
 283         autocmd FileType gitcommit setlocal nomodeline |
 284                                  \ let g:secure_modelines_allowed_items = [] |
 285                                  \ setlocal textwidth=72
 286 " Allow folding in perl.
 287         autocmd FileType perl let perl_fold = 1 |
 288                             \ let perl_fold_blocks = 1
 289 " Use the same comment string as for Vim files in Vimperator files.
 290         autocmd FileType vimperator setlocal commentstring=\"%s
 291
 292 " FTDETECT AUTO COMMANDS
 293
 294 " Recognize .md as markdown files (Vim default is .mkd).
 295         autocmd BufRead,BufNewFile *.md set filetype=mkd
 296 " Recognize .test as Tcl files.
 297         autocmd BufRead,BufNewFile *.test set filetype=tcl
 298
 299 " OTHER AUTO COMMANDS
 300
 301 " Use diff filetype for mercurial patches in patch queue.
 302         autocmd BufReadPost */.hg/patches/* set filetype=diff
 303
 304     augroup END
 305 endif