vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Prevent editing as root as it may cause security problems. Use sudoedit
   7 " instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21).
   8 if $HOME == '/root' || exists('$SUDO_USER')
   9     echomsg 'Running as root is forbidden! Use sudoedit.'
  10     qa
  11 endif
  12
  13
  14 " Save 'runtimepath' in case it was changed by the system's configuration
  15 " files.
  16 if has('eval')
  17     let s:save_runtimepath = &runtimepath
  18 endif
  19 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  20 " system wide configuration file doesn't change default values.
  21 set all&
  22 " And restore it after all other options were reset.
  23 if has('eval')
  24     let &runtimepath = s:save_runtimepath
  25 endif
  26
  27 " Make sure Vim (and not Vi) settings are used.
  28 set nocompatible
  29
  30 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  31 " runtime files).
  32 set runtimepath-=~/.vim
  33 set runtimepath^=~/.vim,~/.vim/runtime
  34
  35 " Don't store swap files in the same directory as the edited file.
  36 set directory-=.
  37
  38 " Disable modelines as they may cause security problems. Instead use
  39 " securemodelines (Vim script #1876).
  40 set nomodeline
  41
  42 " When completing paths first use the longest path then display a list of all
  43 " possible files.
  44 set wildmode=longest,list
  45
  46
  47 " EDIT SETTINGS
  48
  49 " Enable automatic file detection, plugin and indention support.
  50 if has('autocmd')
  51     filetype plugin indent on
  52 endif
  53
  54 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  55 " existing files.
  56 set fileencodings=utf-8,latin1
  57
  58 " Wrap text after 78 characters.
  59 set textwidth=78
  60
  61 " Set tabs to 4 spaces, use softtabs.
  62 set shiftwidth=4
  63 set softtabstop=4
  64 set expandtab
  65 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  66 set shiftround
  67 " Use the default value for real tabs.
  68 set tabstop=8
  69
  70 " Enable auto indention.
  71 set autoindent
  72
  73 " When joining lines only add one space after a sentence.
  74 set nojoinspaces
  75
  76 " Allow backspacing over autoindent and line breaks.
  77 set backspace=indent,eol
  78
  79 " Start a comment when hitting enter after a commented line (r) and when using
  80 " o or O around a commented line (o).
  81 set formatoptions+=ro
  82 " Don't break a line if was already longer then 'textwidth' when insert mode
  83 " started.
  84 set formatoptions+=l
  85
  86 " Allow virtual editing (cursor can be positioned anywhere, even when there is
  87 " no character) in visual block mode.
  88 set virtualedit=block
  89
  90 " Already display matches while typing the search command. This makes spotting
  91 " errors easy.
  92 set incsearch
  93
  94 " Activate syntax folding.
  95 if has('folding')
  96     set foldmethod=syntax
  97     set foldcolumn=2
  98     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
  99                      " folding which is not what I want
 100 endif
 101
 102 " Only check for case if the searched word contains a capital character.
 103 set ignorecase
 104 set smartcase
 105
 106 " Activate spell checking, use English as default. Don't use spell checking
 107 " when diffing.
 108 if v:version >= 700 && has('syntax') && !&diff
 109     set spell
 110     set spelllang=en_us
 111 endif
 112
 113 " Allow buffers with changes to be hidden. Very important for effective
 114 " editing with multiple buffers.
 115 set hidden
 116
 117
 118 " DISPLAY SETTINGS
 119
 120 " Use a dark background. Doesn't change the background color, only sets text
 121 " colors for a dark terminal.
 122 set background=dark
 123
 124 " Display line numbers.
 125 set number
 126 " But use as little space as necessary for the numbers column. Thanks to James
 127 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 128 if v:version >= 700
 129     set numberwidth=1
 130 endif
 131 " Display the ruler with current line/file position. If 'statusline' is used
 132 " then this only affects <C-g>.
 133 set ruler
 134 " Display partial commands in the status line.
 135 set showcmd
 136
 137 " Don't redraw screen when executing macros; increases speed. Thanks to James
 138 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 139 set lazyredraw
 140
 141 " Visualize the line the cursor is currently in.
 142 if v:version >= 700
 143     set cursorline
 144 endif
 145
 146 " Display tabs, trailing space, non breakable spaces and long lines (when
 147 " wrapping is disabled).
 148 set list
 149 set listchars=trail:-,extends:>
 150 if v:version >= 700
 151     set listchars+=nbsp:!
 152 endif
 153
 154 if has('statusline')
 155     " Always display the status line even if there is only one window.
 156     set laststatus=2
 157
 158     set statusline=
 159     " on the left
 160     set statusline+=%02n: " buffer number
 161     set statusline+=%f\   " path to current file in buffer
 162     set statusline+=%h    " [help] if buffer is help file
 163     set statusline+=%w    " [Preview] if buffer is preview buffer
 164     set statusline+=%m    " [+] if buffer was modified,
 165                           " [-] if 'modifiable' is off
 166     set statusline+=%r    " [RO] if buffer is read only
 167
 168     " on the right
 169     set statusline+=%=                " right align
 170     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 171                                       " column number (%c),
 172                                       " virtual column number if different
 173                                       "                       than %c (%V)
 174     set statusline+=%P                " position in file in percent
 175 endif
 176
 177
 178 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 179
 180 " Easy way to exit insert mode.
 181 inoremap jj <Esc>
 182
 183 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 184 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 185 map <right> <nop>
 186 map <left>  <nop>
 187 map <up>    <nop>
 188 map <down>  <nop>
 189 imap <right> <nop>
 190 imap <left>  <nop>
 191 imap <up>    <nop>
 192 imap <down>  <nop>
 193 " Also disable up and down array in command mode, use <C-p>/<C-n> as
 194 " replacement (see below).
 195 cmap <up> <nop>
 196 cmap <down> <nop>
 197
 198 " Use Ctrl-P/Ctrl-N as replacement for <Up>/<Down> in command mode. Thanks to
 199 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20).
 200 cnoremap <C-p> <up>
 201 cnoremap <C-n> <down>
 202
 203 " Use <space> to move down a page and - to move up one like in mutt.
 204 nnoremap <Space> <C-f>
 205 nnoremap - <C-b>
 206
 207 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 208 " (2010-05-16 18:38) for this idea.
 209 nnoremap <silent> gb :bnext<CR>
 210 nnoremap <silent> gB :bprev<CR>
 211
 212 " Fast access to buffers.
 213 nnoremap <Leader>1 :1b<CR>
 214 nnoremap <Leader>2 :2b<CR>
 215 nnoremap <Leader>3 :3b<CR>
 216 nnoremap <Leader>4 :4b<CR>
 217 nnoremap <Leader>5 :5b<CR>
 218 nnoremap <Leader>6 :6b<CR>
 219 nnoremap <Leader>7 :7b<CR>
 220 nnoremap <Leader>8 :8b<CR>
 221 nnoremap <Leader>9 :9b<CR>
 222 nnoremap <Leader>0 :10b<CR>
 223
 224 " Make last active window the only window. Similar to <C-w> o.
 225 nnoremap <C-w>O <C-w>p<C-w>o
 226
 227 " Maps to change spell language between English and German and disable spell
 228 " checking.
 229 if v:version >= 700
 230     map <Leader>sn :set nospell<CR>
 231     map <Leader>se :set spell spelllang=en_us<CR>
 232     map <Leader>sd :set spell spelllang=de_de<CR>
 233 endif
 234
 235 " Add semicolon to the end of the line. Thanks to
 236 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 237 " on Freenode for an improved version which doesn't clobber any marks.
 238 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 239
 240 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 241 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 242 " mailing list for the commands.
 243 if v:version < 700
 244     cnoreabbrev W w
 245     cnoreabbrev Wa wa
 246     cnoreabbrev Wq wq
 247     cnoreabbrev Wqa wqa
 248 else
 249     cnoreabbrev <expr> W
 250         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 251     cnoreabbrev <expr> Wa
 252         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 253     cnoreabbrev <expr> Wq
 254         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 255     cnoreabbrev <expr> Wqa
 256         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 257 endif
 258 " Also fix my typo with "Q".
 259 if v:version < 700
 260     cnoreabbrev Q q
 261     cnoreabbrev Qa qa
 262 else
 263     cnoreabbrev <expr> Q
 264         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 265     cnoreabbrev <expr> Qa
 266         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 267 endif
 268
 269 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 270 " if pressed accidentally while in insert mode (happens on Mac when alt
 271 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 272 " no longer set on the console.
 273 if has('mac') || filereadable('/Users/.localized')
 274     inoremap <Char-0xa0> <Space>
 275 endif
 276
 277 " Disable Apple style movements in MacVim.
 278 if has('gui_macvim') && has('eval')
 279     let macvim_skip_cmd_opt_movement = 1
 280 endif
 281
 282
 283 " SYNTAX SETTINGS
 284
 285 " Activate syntax coloring.
 286 if has('syntax')
 287     syntax enable
 288
 289 " Don't highlight more than 200 columns as I normally don't have that long
 290 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 291 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 292     set synmaxcol=200
 293
 294 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 295 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 296 " disabled when necessary with :2match (in Vim >= 700).
 297     if v:version >= 700
 298         2match Todo /\%>78v./
 299     else
 300         match Todo /\%>78v./
 301     endif
 302
 303 " Highlight TODO, FIXME, CHANGED and XXX in all documents.
 304     if v:version > 701 || (v:version == 701 && has('patch42'))
 305         call matchadd('Todo', '\(TODO\|FIXME\|CHANGED\|XXX\)')
 306     endif
 307 endif
 308
 309
 310 " PLUGIN SETTINGS
 311
 312 " Settings for the NERD commenter.
 313 " Don't create any mappings I don't want to use.
 314 if has('eval')
 315     let NERDCreateDefaultMappings = 0
 316 endif
 317 " Map toggle comment.
 318 map <Leader><Leader> <plug>NERDCommenterToggle
 319
 320 " XPTemplate settings.
 321 if has('eval')
 322     " Try to maintain snippet rendering even after editing outside of a
 323     " snippet.
 324     let g:xptemplate_strict = 0
 325     " Don't complete any braces automatically.
 326     let g:xptemplate_brace_complete = 0
 327     " Only highlight the current placeholder.
 328     let g:xptemplate_highlight = 'current'
 329 endif
 330
 331
 332 " AUTO COMMANDS
 333
 334 " Use a custom auto group to prevent problems when the vimrc files is sourced
 335 " twice.
 336 if has('autocmd')
 337     augroup vimrc
 338         autocmd!
 339
 340 " Go to last position of opened files. Taken from :help last-position-jump.
 341         autocmd BufReadPost *
 342             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 343             \     execute "normal! g'\"" |
 344             \ endif
 345 " But not for Git commits, go to beginning of the file.
 346         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 347
 348 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 349 " when switching to a help buffer which is in the background with :buffer as
 350 " these options are local to windows (and not only to buffers). This happens
 351 " because I often want to use only one window and thus the help buffer is in
 352 " the background.
 353         autocmd BufWinEnter *.txt
 354             \ if &filetype == 'help' |
 355             \     setlocal nolist |
 356             \     setlocal nonumber |
 357             \ endif
 358
 359 " AFTER/FTPLUGIN AUTO COMMANDS
 360
 361 " Disable spell checking for files which don't need it.
 362         autocmd FileType deb  setlocal nospell
 363         autocmd FileType diff setlocal nospell
 364         autocmd FileType tar  setlocal nospell
 365 " Fix to allow Vim edit crontab files as crontab doesn't work with
 366 " backupcopy=auto.
 367         autocmd FileType crontab setlocal backupcopy=yes
 368 " Don't use the modeline in git commits as the diff created by `git commit -v`
 369 " may contain one which could change the filetype or other settings of the
 370 " commit buffer. Also make sure we use only 72 characters per line which is
 371 " the recommendation for git commit messages (http://tpope.net/node/106).
 372         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 373                                  \ setlocal textwidth=72
 374 " Allow folding in perl.
 375         autocmd FileType perl let perl_fold = 1 |
 376                             \ let perl_fold_blocks = 1
 377 " Use the same comment string as for Vim files in Vimperator files.
 378         autocmd FileType vimperator setlocal commentstring=\"%s
 379
 380 " FTDETECT AUTO COMMANDS
 381
 382 " Recognize .md as markdown files (Vim default is .mkd).
 383         autocmd BufRead,BufNewFile *.md set filetype=mkd
 384 " Recognize .test as Tcl files.
 385         autocmd BufRead,BufNewFile *.test set filetype=tcl
 386
 387 " OTHER AUTO COMMANDS
 388
 389 " Use diff filetype for mercurial patches in patch queue.
 390         autocmd BufReadPost */.hg/patches/* set filetype=diff
 391
 392     augroup END
 393 endif