zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Make sure core dumps are created.
  15 ulimit -c unlimited
  16
  17 # Prevent overwriting existing files with '> filename', use '>| filename'
  18 # (or >!) instead.
  19 setopt noclobber
  20
  21 # Entering the name of a directory (if it's not a command) will automatically
  22 # cd to that directory.
  23 setopt autocd
  24
  25 # When entering a nonexistent command name automatically try to find a similar
  26 # one.
  27 setopt correct
  28
  29 # Enable zsh's extended glob abilities.
  30 setopt extendedglob
  31
  32 # Don't exit if <C-d> is pressed.
  33 setopt ignoreeof
  34
  35
  36 # FUNCTION SETTINGS
  37
  38 # Set correct fpath to allow loading my functions (including completion
  39 # functions).
  40 fpath=(~/.zsh/functions $fpath)
  41 # Autoload my functions (except completion functions and hidden files). Thanks
  42 # to caphuso from the Zsh example files for this idea.
  43 autoload ${fpath[1]}/^_*(^/:t)
  44
  45 # Simulate hooks using _functions arrays for Zsh versions older then 4.3.4. At
  46 # the moment only precmd() and preexec() are simulated.
  47 if [[ $ZSH_VERSION != (4.3.<4->|4.<4->*|<5->*) ]]; then
  48     # Provide add-zsh-hook which was added in 4.3.4.
  49     fpath=($fpath ~/.zsh/functions/compatibility)
  50
  51     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  52     function precmd() {
  53         for function in $precmd_functions; do
  54             $function $@
  55         done
  56     }
  57     function preexec() {
  58         for function in $preexec_functions; do
  59             $function $@
  60         done
  61     }
  62 fi
  63
  64 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  65 autoload -Uz add-zsh-hook
  66
  67
  68 # HISTORY SETTINGS
  69
  70 # Use history and store it in ~/.zsh/history.
  71 HISTSIZE=5000
  72 SAVEHIST=5000
  73 HISTFILE=~/.zsh/history
  74 # Append to the history file instead of overwriting it and do it immediately
  75 # when a command is executed.
  76 setopt appendhistory
  77 setopt incappendhistory
  78 # If the same command is run multiple times store it only once in the history.
  79 setopt histignoredups
  80 # Vim like completions of previous executed commands.
  81 bindkey "^P" history-beginning-search-backward
  82 bindkey "^N" history-beginning-search-forward
  83
  84
  85 # PROMPT SETTINGS
  86
  87 # Use colorized output, necessary for prompts and completions.
  88 autoload -U colors && colors
  89
  90 # Set the default prompt. The current host and working directory is displayed,
  91 # the exit code of the last command if it wasn't 0, the number of running jobs
  92 # if not 0 and a + if this shell is running inside another shell.
  93 # The prompt is in green and blue to make easily detectable, the error exit
  94 # code in red and bold and the job count in yellow.
  95 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
  96 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
  97 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
  98 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
  99
 100 # VCS_Info was added in 4.3.9.
 101 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 102     # Allow substitutions and expansions in the prompt, necessary for
 103     # vcs_info.
 104     setopt promptsubst
 105     # Load vcs_info to display information about version control repositories.
 106     autoload -Uz vcs_info
 107     # Only look for git and mercurial repositories; the only I use.
 108     zstyle ':vcs_info:*' enable git hg
 109     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 110     # is displayed. If there is an special action going on (merge, rebase)
 111     # it's also displayed (red).
 112     zstyle ':vcs_info:*' formats \
 113     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 114 %{${fg[blue]}%}%s%{${fg[default]}%})"
 115     zstyle ':vcs_info:*' actionformats \
 116     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 117 %{${fg[red]}%}%a%{${fg[default]}%}:\
 118 %{${fg[blue]}%}%s%{${fg[default]}%})"
 119     # Call vcs_info as precmd before every prompt.
 120     prompt_precmd() {
 121         vcs_info
 122     }
 123     add-zsh-hook precmd prompt_precmd
 124
 125     # Display the vcs information in the right prompt.
 126     RPROMPT='${vcs_info_msg_0_}'
 127 fi
 128
 129 # When screen is used set the name of the window to the currently running
 130 # program.
 131 #
 132 # When a program is started preexec() sets the window's name to it; when it
 133 # stops precmd() resets the windows' name to 'zsh'.
 134 if [[ $TERM == screen ]]; then
 135     # Set to a non empty value to reset the window name in the next precmd()
 136     # call.
 137     screen_name_reset=yes
 138
 139     screen_preexec() {
 140         # Get the program name with its arguments.
 141         local program_name=$1
 142         # When sudo is used use real program name instead.
 143         if [[ $program_name == sudo* ]]; then
 144             program_name=${program_name#sudo }
 145         fi
 146         # Remove all arguments from the program name.
 147         program_name=${program_name%% *}
 148
 149         # Ignore often used commands which are only running for a very short
 150         # time. This prevents a "blinking" name when it's changed to "cd" for
 151         # example and then some milliseconds later back to "zsh".
 152         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 153
 154         # Change my shortcuts so the real name of the program is displayed.
 155         case $program_name in
 156             e)
 157                 program_name=elinks
 158                 ;;
 159             g)
 160                 program_name=git
 161                 ;;
 162             m)
 163                 program_name=mutt
 164                 ;;
 165             v|vi)
 166                 program_name=vim
 167                 ;;
 168         esac
 169
 170         # Set the window name to the currently running program.
 171         print -n "\ek$program_name\e\\"
 172
 173         # Tell precmd() to reset the window name when the program stops.
 174         screen_name_reset=yes
 175     }
 176
 177     screen_precmd() {
 178         # Abort if no window name reset is necessary.
 179         [[ -z $screen_name_reset ]] && return
 180
 181         # Reset the window name to 'zsh'.
 182         print -n "\ekzsh\e\\"
 183
 184         # Just reset the name, so no screen reset necessary for the moment.
 185         screen_name_reset=
 186     }
 187
 188     # Add the preexec() and precmd() hooks.
 189     add-zsh-hook preexec screen_preexec
 190     add-zsh-hook precmd screen_precmd
 191 fi
 192
 193
 194 # COMPLETION SETTINGS
 195
 196 # Load the complist module which provides additions to completion lists
 197 # (coloring, scrollable).
 198 zmodload zsh/complist
 199 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 200 # cluttering of ~/.
 201 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 202 # Make sure the list of possible completions is displayed after pressing <TAB>
 203 # the first time.
 204 setopt nolistambiguous
 205 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 206 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 207 bindkey "^I" expand-or-complete-prefix
 208 # Use cache to speed up completions.
 209 zstyle ':completion:*' use-cache on
 210 zstyle ':completion:*' cache-path ~/.zsh/cache
 211 # Try uppercase if the currently typed string doesn't match. This allows
 212 # typing in lowercase most of the time and completion fixes the case.
 213 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 214 # Ignore completion functions.
 215 zstyle ':completion:*:functions' ignored-patterns '_*'
 216 # Ignore parent directory.
 217 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 218 # Use ls like colors for completions.
 219 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 220 # Make completion lists scrollable so "do you wish to see all n possibilities"
 221 # is no longer displayed.
 222 zstyle ':completion:*' list-prompt '%p'
 223 # When unsetting variables make sure every variable name is only suggested
 224 # once.
 225 zstyle ':completion:*:unset:*' ignore-line yes
 226 # When working with Mercurial and Git don't complete the same file multiple
 227 # times. Very useful when completing file names.
 228 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 229
 230
 231 # CUSTOM ALIASES AND FUNCTIONS
 232
 233 # Simplify calls to less, automatically redirects all output.
 234 alias -g L='2>&1 | less'
 235 # Simplify calls to colordiff, output is also piped through less.
 236 alias -g D='2>&1 | colordiff L'
 237 # Simplify calls to grep.
 238 alias -g G='| grep'
 239
 240 # Automatically use unified diffs.
 241 alias diff='diff -u'
 242
 243 # Display all files and use human readable sizes.
 244 alias du='du -sh'
 245
 246 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
 247 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
 248     alias vim='vim -p'
 249 fi
 250
 251 # Shortcuts for often used programs.
 252 alias e='elinks'
 253 alias g='git'
 254 alias m='mutt'
 255 alias v='vim'
 256 alias vi='vim'
 257
 258 # Exit binding like in Vim; I sometimes confuse editor and shell.
 259 alias :q='exit'
 260
 261 # Edit the mercurial patch queue series file for the current mercurial
 262 # repository in Vim. Also change Vim's pwd to the patches directory so other
 263 # patches can easily be opened.
 264 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 265
 266 # Make going up directories simple.
 267 alias -g ...='../..'
 268 alias -g ....='../../..'
 269 alias -g .....='../../../..'
 270
 271 # Improved ls which displays the files in columns (-C), visualizes directories,
 272 # links and other special files (-F) and pages everything through less (L).
 273 #
 274 # If available use GNU ls with colorized output. If it isn't available use
 275 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 276 # pager.
 277 ls --color &> /dev/null
 278 if [[ $? -eq 0 ]]; then
 279     alias ls='ls --color'
 280 else
 281     alias ls='CLICOLOR_FORCE=1 ls -G'
 282 fi
 283 # Main ls function.
 284 function ls() {
 285     command ls -C -F $* L
 286 }
 287 # Helper function to list all files.
 288 function la() {
 289     ls -a $*
 290 }
 291 # Helper function to list all files in list format with access rights, etc.
 292 function ll() {
 293     la -l $*
 294 }
 295
 296 # If ^C is pressed while typing a command, add it to the history so it can be
 297 # easily retrieved later and then abort like ^C normally does. This is useful
 298 # when I want to abort an command to do something in between and then finish
 299 # typing the command.
 300 TRAPINT() {
 301     # Store the current buffer in the history.
 302     zle && print -s $BUFFER
 303
 304     # Return the default exit code so zsh aborts the current command.
 305     return $1
 306 }
 307
 308 # Display TODOs stored in ~/.todo if this file exists.
 309 todo() {
 310     if [[ -f ~/.todo ]]; then
 311         cat ~/.todo | $PAGER
 312     fi
 313 }
 314
 315
 316 # Load rc file for current OS.
 317 source_config ~/.zsh os rc $(uname) nolocal
 318 # Load rc file for current hostname (first part before a dot) or rc.local.
 319 source_config ~/.zsh host rc ${$(hostname)//.*/}
 320
 321 source_debug "finished sourcing ~/.zsh/rc"