zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # FUNCTION SETTINGS
  34
  35 # Set correct fpath to allow loading my functions (including completion
  36 # functions).
  37 fpath=(~/.zsh/functions $fpath)
  38 # Autoload my functions (except completion functions and hidden files). Thanks
  39 # to caphuso from the Zsh example files for this idea.
  40 autoload ${fpath[1]}/^_*(^/:t)
  41
  42 # Simulate hooks using _functions arrays for Zsh versions older then 4.3.4. At
  43 # the moment only precmd() and preexec() are simulated.
  44 #
  45 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  46 # so the compatibility version is used there too.
  47 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  48     # Provide add-zsh-hook which was added in 4.3.4.
  49     fpath=(~/.zsh/functions/compatibility $fpath)
  50
  51     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  52     function precmd() {
  53         for function in $precmd_functions; do
  54             $function $@
  55         done
  56     }
  57     function preexec() {
  58         for function in $preexec_functions; do
  59             $function $@
  60         done
  61     }
  62 fi
  63
  64 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  65 autoload -Uz add-zsh-hook
  66
  67
  68 # HISTORY SETTINGS
  69
  70 # Use history and store it in ~/.zsh/history.
  71 HISTSIZE=5000
  72 SAVEHIST=5000
  73 HISTFILE=~/.zsh/history
  74 # Append to the history file instead of overwriting it and do it immediately
  75 # when a command is executed.
  76 setopt appendhistory
  77 setopt incappendhistory
  78 # If the same command is run multiple times store it only once in the history.
  79 setopt histignoredups
  80 # Vim like completions of previous executed commands.
  81 bindkey "^P" history-beginning-search-backward
  82 bindkey "^N" history-beginning-search-forward
  83
  84
  85 # PROMPT SETTINGS
  86
  87 # Use colorized output, necessary for prompts and completions.
  88 autoload -U colors && colors
  89
  90 # Set the default prompt. The current host and working directory is displayed,
  91 # the exit code of the last command if it wasn't 0, the number of running jobs
  92 # if not 0 and a + if this shell is running inside another shell.
  93 # The prompt is in green and blue to make easily detectable, the error exit
  94 # code in red and bold and the job count in yellow.
  95 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
  96 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
  97 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
  98 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
  99
 100 # VCS_Info was added in 4.3.9.
 101 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 102     # Allow substitutions and expansions in the prompt, necessary for
 103     # vcs_info.
 104     setopt promptsubst
 105     # Load vcs_info to display information about version control repositories.
 106     autoload -Uz vcs_info
 107     # Only look for git and mercurial repositories; the only I use.
 108     zstyle ':vcs_info:*' enable git hg
 109     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 110     # is displayed. If there is an special action going on (merge, rebase)
 111     # it's also displayed (red).
 112     zstyle ':vcs_info:*' formats \
 113     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 114 %{${fg[blue]}%}%s%{${fg[default]}%})"
 115     zstyle ':vcs_info:*' actionformats \
 116     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 117 %{${fg[red]}%}%a%{${fg[default]}%}:\
 118 %{${fg[blue]}%}%s%{${fg[default]}%})"
 119     # Call vcs_info as precmd before every prompt.
 120     prompt_precmd() {
 121         vcs_info
 122     }
 123     add-zsh-hook precmd prompt_precmd
 124
 125     # Display the vcs information in the right prompt.
 126     RPROMPT='${vcs_info_msg_0_}'
 127 fi
 128
 129 # When screen or xterm is used set the name of the window to the currently
 130 # running program.
 131 #
 132 # When a program is started preexec() sets the window's name to it; when it
 133 # stops precmd() resets the windows' name to 'zsh'.
 134 #
 135 # It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
 136 # and stumpwm is used (it's tested if stumpish is available) then the window
 137 # title is also set in stumpwm using stumpish.
 138 if [[ $TERM == screen* || $TERM == xterm* ]]; then
 139     # Set to a non empty value to reset the window name in the next precmd()
 140     # call.
 141     window_reset=yes
 142     # Set to a non empty value when the stump window manager is available.
 143     which stumpwm &> /dev/null
 144     if [[ $? -eq 0 ]]; then
 145         window_stumpwm=yes
 146     fi
 147     # Set to a non empty value when the shell is running as root.
 148     if [[ $(id -u) -eq 0 ]]; then
 149         window_root=yes
 150     fi
 151
 152     window_preexec() {
 153         # Get the program name with its arguments.
 154         local program_name=$1
 155
 156         # When sudo is used use real program name instead, but with an
 157         # exclamation mark at the beginning.
 158         local program_sudo=
 159         if [[ $program_name == sudo* ]]; then
 160             program_name=${program_name#sudo }
 161             program_sudo=yes
 162         fi
 163         # Remove all arguments from the program name.
 164         program_name=${program_name%% *}
 165
 166         # Ignore often used commands which are only running for a very short
 167         # time. This prevents a "blinking" name when it's changed to "cd" for
 168         # example and then some milliseconds later back to "zsh".
 169         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 170
 171         # Change my shortcuts so the real name of the program is displayed.
 172         case $program_name in
 173             e)
 174                 program_name=elinks
 175                 ;;
 176             g)
 177                 program_name=git
 178                 ;;
 179             m)
 180                 program_name=mutt
 181                 ;;
 182             v|vi)
 183                 program_name=vim
 184                 ;;
 185         esac
 186
 187         # Add an exclamation mark at the beginning if running with sudo or if
 188         # running zsh as root.
 189         if [[ $program_sudo == yes || $window_root == yes ]]; then
 190             program_name=!$program_name
 191         fi
 192
 193         # Add an at mark at the beginning if running ssh on a different
 194         # computer.
 195         if [[ -n $SSH_CONNECTION ]]; then
 196             program_name="@$program_name"
 197         fi
 198
 199         # Set the window name to the currently running program.
 200         window_title "$program_name"
 201
 202         # Tell precmd() to reset the window name when the program stops.
 203         window_reset=yes
 204     }
 205
 206     window_precmd() {
 207         # Abort if no window name reset is necessary.
 208         [[ -z $window_reset ]] && return
 209
 210         # Reset the window name to 'zsh'.
 211         if [[ -n $SSH_CONNECTION ]]; then
 212             window_title "@zsh"
 213         elif [[ $window_root == yes ]]; then
 214             window_title "!zsh"
 215         else
 216             window_title "zsh"
 217         fi
 218
 219         # Just reset the name, so no screen reset necessary for the moment.
 220         window_reset=
 221     }
 222
 223     # Sets the window title. Works with screen and xterm.
 224     window_title() {
 225         if [[ $TERM == screen* ]]; then
 226             print -n "\ek$1\e\\"
 227
 228             # Update window name in stumpwm if running screen in X11 and when
 229             # stumpwm is used.
 230             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
 231                 echo "$1" | stumpish -e "title" > /dev/null
 232             fi
 233
 234         elif [[ $TERM == xterm* ]]; then
 235             print -n "\e]2;$1\e\\"
 236         fi
 237     }
 238
 239     # Add the preexec() and precmd() hooks.
 240     add-zsh-hook preexec window_preexec
 241     add-zsh-hook precmd window_precmd
 242 fi
 243
 244
 245 # COMPLETION SETTINGS
 246
 247 # Load the complist module which provides additions to completion lists
 248 # (coloring, scrollable).
 249 zmodload zsh/complist
 250 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 251 # cluttering of ~/.
 252 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 253
 254 # Use cache to speed up completions.
 255 zstyle ':completion:*' use-cache on
 256 zstyle ':completion:*' cache-path ~/.zsh/cache
 257
 258 # Complete arguments and fix spelling mistakes when possible.
 259 zstyle ':completion:*' completer _complete _match _correct _approximate
 260
 261 # Make sure the list of possible completions is displayed after pressing <TAB>
 262 # the first time.
 263 setopt nolistambiguous
 264 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 265 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 266 bindkey "^I" expand-or-complete-prefix
 267 # Try uppercase if the currently typed string doesn't match. This allows
 268 # typing in lowercase most of the time and completion fixes the case.
 269 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 270
 271 # Use ls like colors for completions.
 272 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 273
 274 # Make completion lists scrollable so "do you wish to see all n possibilities"
 275 # is no longer displayed.
 276 zstyle ':completion:*' list-prompt '%p'
 277 # Display group name (like 'external command', 'alias', etc.) when there are
 278 # multiple matches in bold.
 279 zstyle ':completion:*' format '    %B%d%b:'
 280 # Display different types of matches separately.
 281 zstyle ':completion:*' group-name ''
 282
 283 # Ignore completion functions.
 284 zstyle ':completion:*:functions' ignored-patterns '_*'
 285 # Ignore parent directory.
 286 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 287 # When unsetting variables make sure every variable name is only suggested
 288 # once.
 289 zstyle ':completion:*:unset:*' ignore-line yes
 290 # When working with Mercurial and Git don't complete the same file multiple
 291 # times. Very useful when completing file names.
 292 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 293
 294
 295 # CUSTOM ALIASES AND FUNCTIONS
 296
 297 # Make sure aliases are expanded when using sudo.
 298 alias sudo='sudo '
 299
 300 # Simplify calls to less, automatically redirects all output.
 301 alias -g L='2>&1 | less'
 302 # Simplify calls to colordiff, output is also piped through less.
 303 alias -g D='2>&1 | colordiff L'
 304 # Simplify calls to grep.
 305 alias -g G='| grep'
 306
 307 # Automatically use unified diffs.
 308 alias diff='diff -u'
 309
 310 # Display all files and use human readable sizes.
 311 alias du='du -sh'
 312
 313 # Use human readable sizes.
 314 alias df='df -h'
 315
 316 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
 317 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
 318     alias vim='vim -p'
 319 fi
 320
 321 # Shortcuts for often used programs.
 322 alias e='elinks'
 323 alias g='git'
 324 alias m='mutt'
 325 alias v='vim'
 326 alias vi='vim'
 327
 328 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 329 # shell.
 330 alias :q='echo "This is not Vim!" >&2'
 331
 332 # Edit the mercurial patch queue series file for the current mercurial
 333 # repository in Vim. Also change Vim's pwd to the patches directory so other
 334 # patches can easily be opened.
 335 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 336
 337 # Make going up directories simple.
 338 alias -g ...='../..'
 339 alias -g ....='../../..'
 340 alias -g .....='../../../..'
 341
 342 # Improved ls which displays the files in columns (-C), visualizes
 343 # directories, links and other special files (-F) and pages everything through
 344 # less (L).
 345 #
 346 # If available use GNU ls with colorized output. If it isn't available use
 347 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 348 # pager.
 349 ls --color &> /dev/null
 350 if [[ $? -eq 0 ]]; then
 351     alias ls='ls --color'
 352 else
 353     alias ls='CLICOLOR_FORCE=1 ls -G'
 354 fi
 355 # Main ls function.
 356 function ls() {
 357     command ls -C -F $* L
 358 }
 359 # Helper function to list all files.
 360 function la() {
 361     ls -a $*
 362 }
 363 # Helper function to list all files in list format with access rights, etc.
 364 function ll() {
 365     la -l $*
 366 }
 367
 368 # If ^C is pressed while typing a command, add it to the history so it can be
 369 # easily retrieved later and then abort like ^C normally does. This is useful
 370 # when I want to abort an command to do something in between and then finish
 371 # typing the command.
 372 TRAPINT() {
 373     # Store the current buffer in the history.
 374     zle && print -s $BUFFER
 375
 376     # Return the default exit code so zsh aborts the current command.
 377     return $1
 378 }
 379
 380 # Display TODOs stored in ~/.todo if this file exists.
 381 todo() {
 382     if [[ -f ~/.todo ]]; then
 383         cat ~/.todo | $PAGER
 384     fi
 385 }
 386
 387 # Colorize stderr. Very useful when looking for errors. Thanks to
 388 # http://gentoo-wiki.com/wiki/Zsh
 389 exec 2>>(while read line; do
 390     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
 391
 392
 393 # RUN COMMANDS
 394
 395 # If not already in screen reattach to a running session or create a new one.
 396 #
 397 # screen* is necessary as `screen` uses screen.linux for example for a linux
 398 # console which would otherwise cause an infinite loop.
 399 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 400     # Create a new session if none is running.
 401     if [[ $(screen -list | grep "Detached" | wc -l) == 0 ]]; then
 402         screen
 403     # Reattach to a running session.
 404     else
 405         screen -r
 406     fi
 407 fi
 408
 409
 410 # Load rc file for current OS.
 411 source_config ~/.zsh os rc $(uname) nolocal
 412 # Load rc file for current hostname (first part before a dot) or rc.local.
 413 source_config ~/.zsh host rc ${$(hostname)//.*/}
 414
 415 source_debug "finished sourcing ~/.zsh/rc"
 416
 417 # vim: ft=zsh