zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Disable beeps.
  15 setopt nobeep
  16
  17 # Prevent overwriting existing files with '> filename', use '>| filename'
  18 # (or >!) instead.
  19 setopt noclobber
  20
  21 # Entering the name of a directory (if it's not a command) will automatically
  22 # cd to that directory.
  23 setopt autocd
  24
  25 # When entering a nonexistent command name automatically try to find a similar
  26 # one.
  27 setopt correct
  28
  29 # Enable zsh's extended glob abilities.
  30 setopt extendedglob
  31
  32 # Don't exit if <C-d> is pressed.
  33 setopt ignoreeof
  34
  35
  36 # FUNCTION SETTINGS
  37
  38 # Make sure every entry in $fpath is unique.
  39 typeset -U fpath
  40 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  41 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  42 if [[ -d ~/.zsh/functions/completion ]]; then
  43     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  44 fi
  45 # Set correct fpath to allow loading my functions (including completion
  46 # functions).
  47 fpath=(~/.zsh/functions $fpath)
  48 # Autoload my functions (except completion functions and hidden files). Thanks
  49 # to caphuso from the Zsh example files for this idea.
  50 if [[ -d ~/.zsh/functions ]]; then
  51     autoload ${fpath[1]}/^_*(^/:t)
  52 fi
  53
  54 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  55 # the moment only precmd(), preexec() and chpwd() are simulated.
  56 #
  57 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  58 # so the compatibility version is used there too.
  59 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  60     # Provide add-zsh-hook which was added in 4.3.4.
  61     fpath=(~/.zsh/functions/compatibility $fpath)
  62
  63     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  64     # arrays.
  65     function precmd() {
  66         for function in $precmd_functions; do
  67             $function $@
  68         done
  69     }
  70     function preexec() {
  71         for function in $preexec_functions; do
  72             $function $@
  73         done
  74     }
  75     function chpwd() {
  76         for function in $chpwd_functions; do
  77             $function $@
  78         done
  79     }
  80 fi
  81
  82 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  83 autoload -Uz add-zsh-hook
  84
  85 # Load zmv (zsh move) which is powerful to rename files.
  86 autoload zmv
  87
  88 # HISTORY SETTINGS
  89
  90 # Use history and store it in ~/.zsh/history.
  91 HISTSIZE=50000
  92 SAVEHIST=50000
  93 HISTFILE=~/.zsh/history
  94 # Append to the history file instead of overwriting it and do it immediately
  95 # when a command is executed.
  96 setopt appendhistory
  97 setopt incappendhistory
  98 # If the same command is run multiple times store it only once in the history.
  99 setopt histignoredups
 100 # Vim like completions of previous executed commands (also enter Vi-mode). If
 101 # called at the beginning it just recalls old commands (like cursor up), if
 102 # called after typing something only lines starting with the typed are
 103 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 104 # on Freenode (2010-01-17 12:47) for the information how to a use function
 105 # with bindkey.
 106 zle -N my-vi-history-beginning-search-backward
 107 my-vi-history-beginning-search-backward() {
 108     local not_at_beginning_of_line
 109     if [[ $CURSOR -ne 0 ]]; then
 110         not_at_beginning_of_line=yes
 111     fi
 112
 113     zle history-beginning-search-backward
 114
 115     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 116     # this counters it).
 117     zle vi-cmd-mode
 118     if [[ -n $not_at_beginning_of_line ]]; then
 119         zle vi-forward-char
 120     fi
 121 }
 122 bindkey "^P" my-vi-history-beginning-search-backward
 123 bindkey -a "^P" history-beginning-search-backward # binding for Vi-mode
 124 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 125 # after calling ^P.
 126 bindkey -a "^N" history-beginning-search-forward
 127
 128
 129 # PROMPT SETTINGS
 130
 131 # Use colorized output, necessary for prompts and completions.
 132 autoload -U colors && colors
 133
 134 # Some shortcuts for colors.
 135 local red="%{${fg[red]}%}"
 136 local blue="%{${fg[blue]}%}"
 137 local green="%{${fg[green]}%}"
 138 local yellow="%{${fg[yellow]}%}"
 139 local default="%{${fg[default]}%}"
 140
 141 # Set the default prompt. The current host and working directory is displayed,
 142 # the exit code of the last command if it wasn't 0, the number of running jobs
 143 # if not 0 and a + if this shell is running inside another shell.
 144 # The prompt is in green and blue to make easily detectable, the error exit
 145 # code in red and bold and the job count in yellow.
 146 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 147 %(1j.$yellow%j$default.)%# \
 148 %(?..($red%B%?%b$default%) )"
 149
 150 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 151 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 152 # symbolic link to current checkout of Zsh's sources).
 153 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 154       -d ~/.zsh/functions/vcs_info ]]; then
 155     # Update fpath to allow loading the vcs_info functions.
 156     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 157        fpath=(~/.zsh/functions/vcs_info/
 158               ~/.zsh/functions/vcs_info/Backends
 159               $fpath)
 160     fi
 161
 162     # Allow substitutions and expansions in the prompt, necessary for
 163     # vcs_info.
 164     setopt promptsubst
 165     # Load vcs_info to display information about version control repositories.
 166     autoload -Uz vcs_info
 167     # Only look for git and mercurial repositories; the only I use.
 168     zstyle ':vcs_info:*' enable git hg
 169     # Check the repository for changes so they can be used in %u/%c (see
 170     # below). This comes with a speed penalty for bigger repositories.
 171     zstyle ':vcs_info:*' check-for-changes true
 172
 173     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 174     # is displayed. If there is an special action going on (merge, rebase)
 175     # it's also displayed (red). Also display if there are unstaged or staged
 176     # (%u/%c) changes.
 177     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 178           -d ~/.zsh/functions/vcs_info ]]; then
 179         zstyle ':vcs_info:*' formats \
 180             "($green%b%u%c$default:$blue%s$default)"
 181         zstyle ':vcs_info:*' actionformats \
 182             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 183     else
 184         # In older versions %u and %c are not defined yet and are not
 185         # correctly expanded.
 186         zstyle ':vcs_info:*' formats \
 187             "($green%b$default:$blue%s$default)"
 188         zstyle ':vcs_info:*' actionformats \
 189             "($green%b$default/$red%a$default:$blue%s$default)"
 190     fi
 191     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 192     # changes are detected in the repository; check-for-changes must be set to
 193     # true for this to work. Thanks to Bart Trojanowski
 194     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 195     # (2010-03-11 00:20).
 196     zstyle ':vcs_info:*' unstagedstr '¹'
 197     zstyle ':vcs_info:*' stagedstr   '²'
 198
 199     # Call vcs_info as precmd before every prompt.
 200     prompt_precmd() {
 201         vcs_info
 202     }
 203     add-zsh-hook precmd prompt_precmd
 204
 205     # Display the VCS information in the right prompt.
 206     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 207         RPROMPT='${vcs_info_msg_0_}'
 208     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 209     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 210     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 211     else
 212         RPROMPT='${vcs_info_msg_0_:- }'
 213     fi
 214 fi
 215
 216 unset red blue green yellow default
 217
 218 # When screen, xterm or rxvt is used set the name of the window to the
 219 # currently running program.
 220 #
 221 # When a program is started preexec() sets the window's name to it; when it
 222 # stops precmd() resets the window's name to 'zsh'.
 223 #
 224 # It works with screen, xterm and rxvt.
 225 #
 226 # If a command is run with sudo or if the shell is running as root then a ! is
 227 # added at the beginning of the command to make this clear. If a command is
 228 # running on a different computer with ssh a @ is added at the beginning. This
 229 # only works if the .zshrc on the server also uses this command.
 230 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 231     # Is set to a non empty value to reset the window name in the next
 232     # precmd() call.
 233     window_reset=yes
 234     # Is set to a non empty value when the shell is running as root.
 235     if [[ $(id -u) -eq 0 ]]; then
 236         window_root=yes
 237     fi
 238
 239     window_preexec() {
 240         # Get the program name with its arguments.
 241         local program_name=$1
 242
 243         # When sudo is used use real program name instead, but with an
 244         # exclamation mark at the beginning (handled below).
 245         local program_sudo=
 246         if [[ $program_name == sudo* ]]; then
 247             program_name=${program_name#sudo }
 248             program_sudo=yes
 249         fi
 250         # Remove all arguments from the program name.
 251         program_name=${program_name%% *}
 252
 253         # Ignore often used commands which are only running for a very short
 254         # time. This prevents a "blinking" name when it's changed to "cd" for
 255         # example and then some milliseconds later back to "zsh".
 256         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 257
 258         # Change my shortcuts so the real name of the program is displayed.
 259         case $program_name in
 260             e)
 261                 program_name=elinks
 262                 ;;
 263             g)
 264                 program_name=git
 265                 ;;
 266             m)
 267                 program_name=mutt
 268                 ;;
 269             v|vi)
 270                 program_name=vim
 271                 ;;
 272         esac
 273
 274         # Add an exclamation mark at the beginning if running with sudo or if
 275         # running zsh as root.
 276         if [[ -n $program_sudo || -n $window_root ]]; then
 277             program_name=!$program_name
 278         fi
 279
 280         # Add an at mark at the beginning if running through ssh on a
 281         # different computer.
 282         if [[ -n $SSH_CONNECTION ]]; then
 283             program_name="@$program_name"
 284         fi
 285
 286         # Set the window name to the currently running program.
 287         window_title "$program_name"
 288
 289         # Tell precmd() to reset the window name when the program stops.
 290         window_reset=yes
 291     }
 292
 293     window_precmd() {
 294         # Abort if no window name reset is necessary.
 295         [[ -z $window_reset ]] && return
 296
 297         # Reset the window name to 'zsh'.
 298         local name="zsh"
 299         # If the function was called with an argument then reset the window
 300         # name to '.zsh' (used by clear alias).
 301         if [[ -n $1 ]]; then
 302             name=".zsh"
 303         fi
 304
 305         # Prepend prefixes like in window_preexec().
 306         if [[ -n $SSH_CONNECTION ]]; then
 307             window_title "@$name"
 308         elif [[ -n $window_root ]]; then
 309             window_title "!$name"
 310         else
 311             window_title $name
 312         fi
 313
 314         # Just reset the name, so no screen reset necessary for the moment.
 315         window_reset=
 316     }
 317
 318     # Sets the window title. Works with screen, xterm and rxvt.
 319     window_title() {
 320         if [[ $TERM == screen* ]]; then
 321             print -n "\ek$1\e\\"
 322
 323         elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 324             print -n "\e]2;$1\e\\"
 325         fi
 326     }
 327
 328     # Add the preexec() and precmd() hooks.
 329     add-zsh-hook preexec window_preexec
 330     add-zsh-hook precmd window_precmd
 331 fi
 332
 333
 334 # COMPLETION SETTINGS
 335
 336 # Load the complist module which provides additions to completion lists
 337 # (coloring, scrollable).
 338 zmodload zsh/complist
 339 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 340 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 341 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 342 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 343
 344 # Use cache to speed up completions.
 345 zstyle ':completion:*' use-cache on
 346 zstyle ':completion:*' cache-path ~/.zsh/cache
 347
 348 # Complete arguments and fix spelling mistakes when possible.
 349 zstyle ':completion:*' completer _complete _match _correct _approximate
 350
 351 # Make sure the list of possible completions is displayed after pressing <TAB>
 352 # the first time.
 353 setopt nolistambiguous
 354 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 355 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 356 bindkey "^I" expand-or-complete-prefix
 357 # Try uppercase if the currently typed string doesn't match. This allows
 358 # typing in lowercase most of the time and completion fixes the case.
 359 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 360
 361 # Use ls like colors for completions.
 362 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 363
 364 # Make completion lists scrollable so "do you wish to see all n possibilities"
 365 # is no longer displayed.
 366 zstyle ':completion:*' list-prompt '%p'
 367 # Display group name (like 'external command', 'alias', etc.) when there are
 368 # multiple matches in bold.
 369 zstyle ':completion:*' format '    %B%d%b:'
 370 # Display different types of matches separately.
 371 zstyle ':completion:*' group-name ''
 372
 373 # Ignore completion functions.
 374 zstyle ':completion:*:functions' ignored-patterns '_*'
 375 # Ignore parent directory.
 376 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 377 # When unsetting variables make sure every variable name is only suggested
 378 # once.
 379 zstyle ':completion:*:unset:*' ignore-line yes
 380 # When working with Mercurial and Git don't complete the same file multiple
 381 # times. Very useful when completing file names.
 382 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 383
 384
 385 # CUSTOM ALIASES AND FUNCTIONS
 386
 387 # If ^C is pressed while typing a command, add it to the history so it can be
 388 # easily retrieved later and then abort like ^C normally does. This is useful
 389 # when I want to abort an command to do something in between and then finish
 390 # typing the command.
 391 #
 392 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 393 # starting with - don't cause errors.
 394 TRAPINT() {
 395     # Store the current buffer in the history.
 396     zle && print -s -- $BUFFER
 397
 398     # Return the default exit code so zsh aborts the current command.
 399     return $1
 400 }
 401
 402 # Colorize stderr. Very useful when looking for errors. Thanks to
 403 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 404 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 405 # perfect and doesn't work with some interactive stderr output, but in those
 406 # cases the E alias can be used as workaround.
 407 exec 2>>(while read -r line; do
 408     printf '\e[91m%s\e[0m\n' "$line"
 409     print -n $'\0';
 410 done &)
 411
 412 # Load aliases and similar functions also used by other shells.
 413 if [[ -f ~/.shell/aliases ]]; then
 414     . ~/.shell/aliases
 415 fi
 416
 417 # Make sure aliases are expanded when using sudo.
 418 alias sudo='sudo '
 419
 420 # Global aliases for often used commands in the command line.
 421 alias -g E='2>&1'
 422 alias -g L='E | less'
 423 alias -g D='E | colordiff L'
 424 alias -g G='| grep'
 425 alias -g S='| sort'
 426 alias -g U='| uniq'
 427
 428 # Make going up directories simple.
 429 alias -g ...='../..'
 430 alias -g ....='../../..'
 431 alias -g .....='../../../..'
 432
 433 # If the window naming feature is used (see above) then use ".zsh" (leading
 434 # dot) as title name after running clear so it's clear to me that the window
 435 # is empty. I open so much windows that I don't know in which I have something
 436 # important. This helps me to remember which windows are empty (I run clear
 437 # after I finished my work in a window).
 438 if [[ -n $window_reset ]]; then
 439     alias clear='clear; window_reset=yes; window_precmd reset'
 440 fi
 441
 442 # Display all branches (except stash) in gitk but only 200 commits as this is
 443 # much faster. Also put in the background and disown. Thanks to sitaram in
 444 # #git on Freenode (2009-04-20 15:51).
 445 gitk() {
 446     command gitk \
 447         --max-count=200 \
 448         $(git rev-parse --symbolic-full-name --remotes --branches) \
 449         $@ &
 450     disown %command
 451 }
 452 # Same for tig (except the disown part as it's no GUI program).
 453 tig() {
 454     command tig \
 455         --max-count=200 \
 456         $(git rev-parse --symbolic-full-name --remotes --branches) \
 457         $@
 458 }
 459
 460
 461 # OS SPECIFIC SETTINGS
 462
 463 if [[ $(uname) == Linux ]]; then
 464     # Settings when creating Debian packages.
 465     DEBEMAIL=simon@ruderich.org
 466     export DEBEMAIL
 467     DEBFULLNAME="Simon Ruderich"
 468     export DEBFULLNAME
 469
 470 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 471     # Store the current clipboard in CLIPBOARD before every command so it can
 472     # be used in commands.
 473     os_darwin_preexec() {
 474         export CLIPBOARD="$(pbpaste)"
 475     }
 476     # Add the function as preexec hook.
 477     add-zsh-hook preexec os_darwin_preexec
 478
 479     # Initialize CLIPBOARD so it's available for completion directly after
 480     # startup.
 481     CLIPBOARD=""
 482     export CLIPBOARD
 483
 484     # Fetch current URL in clipboard with wget.
 485     alias wnc='wget --no-proxy $CLIPBOARD'
 486 fi
 487
 488
 489 # LOAD ADDITIONAL CONFIGURATION FILES
 490
 491 # Load rc file for current hostname (first part before a dot) or rc.local.
 492 source_config ~/.zsh host rc ${$(hostname)//.*/}
 493
 494
 495 # RUN COMMANDS
 496
 497 # If not already in screen reattach to a running session or create a new one.
 498 #
 499 # screen* is necessary as `screen` uses screen.linux for example for a linux
 500 # console which would otherwise cause an infinite loop.
 501 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 502     # Get running detached sessions.
 503     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 504     # Create a new session if none is running.
 505     if [[ -z $session ]]; then
 506         screen
 507     # Reattach to a running session.
 508     else
 509         screen -r $session
 510     fi
 511 fi
 512
 513
 514 source_debug "finished sourcing ~/.zsh/rc"
 515
 516 # vim: ft=zsh