zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Disable beeps.
  15 setopt nobeep
  16
  17 # Prevent overwriting existing files with '> filename', use '>| filename'
  18 # (or >!) instead.
  19 setopt noclobber
  20
  21 # Entering the name of a directory (if it's not a command) will automatically
  22 # cd to that directory.
  23 setopt autocd
  24
  25 # When entering a nonexistent command name automatically try to find a similar
  26 # one.
  27 setopt correct
  28
  29 # Enable zsh's extended glob abilities.
  30 setopt extendedglob
  31
  32 # Don't exit if <C-d> is pressed.
  33 setopt ignoreeof
  34
  35
  36 # FUNCTION SETTINGS
  37
  38 # Make sure every entry in $fpath is unique.
  39 typeset -U fpath
  40 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  41 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  42 if [[ -d ~/.zsh/functions/completion ]]; then
  43     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  44 fi
  45 # Set correct fpath to allow loading my functions (including completion
  46 # functions).
  47 fpath=(~/.zsh/functions $fpath)
  48 # Autoload my functions (except completion functions and hidden files). Thanks
  49 # to caphuso from the Zsh example files for this idea.
  50 if [[ -d ~/.zsh/functions ]]; then
  51     autoload ${fpath[1]}/^_*(^/:t)
  52 fi
  53
  54 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  55 # the moment only precmd() and preexec() are simulated.
  56 #
  57 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  58 # so the compatibility version is used there too.
  59 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  60     # Provide add-zsh-hook which was added in 4.3.4.
  61     fpath=(~/.zsh/functions/compatibility $fpath)
  62
  63     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  64     function precmd() {
  65         for function in $precmd_functions; do
  66             $function $@
  67         done
  68     }
  69     function preexec() {
  70         for function in $preexec_functions; do
  71             $function $@
  72         done
  73     }
  74 fi
  75
  76 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  77 autoload -Uz add-zsh-hook
  78
  79 # Load zmv (zsh move) which is powerful to rename files.
  80 autoload zmv
  81
  82 # HISTORY SETTINGS
  83
  84 # Use history and store it in ~/.zsh/history.
  85 HISTSIZE=50000
  86 SAVEHIST=50000
  87 HISTFILE=~/.zsh/history
  88 # Append to the history file instead of overwriting it and do it immediately
  89 # when a command is executed.
  90 setopt appendhistory
  91 setopt incappendhistory
  92 # If the same command is run multiple times store it only once in the history.
  93 setopt histignoredups
  94 # Vim like completions of previous executed commands (also enter Vi-mode). If
  95 # called at the beginning it just recalls old commands (like cursor up), if
  96 # called after typing something only likes starting with the typed are
  97 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
  98 # on Freenode (2010-01-17 12:47) for the information how to a function with
  99 # bindkey.
 100 zle -N my-vi-history-beginning-search-backward
 101 my-vi-history-beginning-search-backward() {
 102     local not_at_beginning_of_line
 103     if [[ $CURSOR -ne 0 ]]; then
 104         not_at_beginning_of_line=yes
 105     fi
 106
 107     zle history-beginning-search-backward
 108
 109     # Start Vi-mode and stay at the same position (Vi-mode modes one left,
 110     # this counters it).
 111     zle vi-cmd-mode
 112     if [[ -n $not_at_beginning_of_line ]]; then
 113         zle vi-forward-char
 114     fi
 115 }
 116 bindkey "^P" my-vi-history-beginning-search-backward
 117 bindkey -a "^P" history-beginning-search-backward # binding for Vi-mode
 118 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 119 # after calling ^P.
 120 bindkey -a "^N" history-beginning-search-forward
 121
 122
 123 # PROMPT SETTINGS
 124
 125 # Use colorized output, necessary for prompts and completions.
 126 autoload -U colors && colors
 127
 128 # Set the default prompt. The current host and working directory is displayed,
 129 # the exit code of the last command if it wasn't 0, the number of running jobs
 130 # if not 0 and a + if this shell is running inside another shell.
 131 # The prompt is in green and blue to make easily detectable, the error exit
 132 # code in red and bold and the job count in yellow.
 133 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
 134 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
 135 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
 136 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
 137
 138 # VCS_Info was added in 4.3.9 but it works in earlier versions too. So load it
 139 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 140 # symbolic link to current checkout of Zsh's sources).
 141 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 142       -d ~/.zsh/functions/vcs_info ]]; then
 143     # Update fpath to allow loading the VCS_Info functions.
 144     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 145        fpath=(~/.zsh/functions/vcs_info/
 146               ~/.zsh/functions/vcs_info/Backends
 147               $fpath)
 148     fi
 149
 150     # Allow substitutions and expansions in the prompt, necessary for
 151     # vcs_info.
 152     setopt promptsubst
 153     # Load vcs_info to display information about version control repositories.
 154     autoload -Uz vcs_info
 155     # Only look for git and mercurial repositories; the only I use.
 156     zstyle ':vcs_info:*' enable git hg
 157     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 158     # is displayed. If there is an special action going on (merge, rebase)
 159     # it's also displayed (red).
 160     zstyle ':vcs_info:*' formats \
 161     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 162 %{${fg[blue]}%}%s%{${fg[default]}%})"
 163     zstyle ':vcs_info:*' actionformats \
 164     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 165 %{${fg[red]}%}%a%{${fg[default]}%}:\
 166 %{${fg[blue]}%}%s%{${fg[default]}%})"
 167     # Call vcs_info as precmd before every prompt.
 168     prompt_precmd() {
 169         vcs_info
 170     }
 171     add-zsh-hook precmd prompt_precmd
 172
 173     # Display the vcs information in the right prompt.
 174     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 175         RPROMPT='${vcs_info_msg_0_}'
 176     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 177     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 178     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 179     else
 180         RPROMPT='${vcs_info_msg_0_:- }'
 181     fi
 182 fi
 183
 184 # When screen, xterm or rxvt is used set the name of the window to the
 185 # currently running program.
 186 #
 187 # When a program is started preexec() sets the window's name to it; when it
 188 # stops precmd() resets the window's name to 'zsh'.
 189 #
 190 # It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
 191 # and stumpwm is running then the window title is also set in stumpwm using
 192 # stumpish.
 193 #
 194 # If a command is run with sudo or if the shell is running as root then a ! is
 195 # added at the beginning of the command to make this clear. If a command is
 196 # running on a different computer with ssh a @ is added at the beginning. This
 197 # only works if the .zshrc on the server also uses this command.
 198 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 199     # Is set to a non empty value to reset the window name in the next
 200     # precmd() call.
 201     window_reset=yes
 202     # Is set to a non empty value when the stump window manager is running.
 203     ps aux | grep -q stumpwm | grep -v grep
 204     if [[ $? -eq 0 ]]; then
 205         window_stumpwm=yes
 206     fi
 207     # Is set to a non empty value when the shell is running as root.
 208     if [[ $(id -u) -eq 0 ]]; then
 209         window_root=yes
 210     fi
 211
 212     window_preexec() {
 213         # Get the program name with its arguments.
 214         local program_name=$1
 215
 216         # When sudo is used use real program name instead, but with an
 217         # exclamation mark at the beginning.
 218         local program_sudo=
 219         if [[ $program_name == sudo* ]]; then
 220             program_name=${program_name#sudo }
 221             program_sudo=yes
 222         fi
 223         # Remove all arguments from the program name.
 224         program_name=${program_name%% *}
 225
 226         # Ignore often used commands which are only running for a very short
 227         # time. This prevents a "blinking" name when it's changed to "cd" for
 228         # example and then some milliseconds later back to "zsh".
 229         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 230
 231         # Change my shortcuts so the real name of the program is displayed.
 232         case $program_name in
 233             e)
 234                 program_name=elinks
 235                 ;;
 236             g)
 237                 program_name=git
 238                 ;;
 239             m)
 240                 program_name=mutt
 241                 ;;
 242             v|vi)
 243                 program_name=vim
 244                 ;;
 245         esac
 246
 247         # Add an exclamation mark at the beginning if running with sudo or if
 248         # running zsh as root.
 249         if [[ -n $program_sudo || -n $window_root ]]; then
 250             program_name=!$program_name
 251         fi
 252
 253         # Add an at mark at the beginning if running through ssh on a
 254         # different computer.
 255         if [[ -n $SSH_CONNECTION ]]; then
 256             program_name="@$program_name"
 257         fi
 258
 259         # Set the window name to the currently running program.
 260         window_title "$program_name"
 261
 262         # Tell precmd() to reset the window name when the program stops.
 263         window_reset=yes
 264     }
 265
 266     window_precmd() {
 267         # Abort if no window name reset is necessary.
 268         [[ -z $window_reset ]] && return
 269
 270         # Reset the window name to 'zsh'.
 271         local name="zsh"
 272         # If the function was called with an argument then reset the window
 273         # name to '.zsh' (used by clear alias).
 274         if [[ -n $1 ]]; then
 275             name=".zsh"
 276         fi
 277
 278         # Prepend prefixes like in window_preexec().
 279         if [[ -n $SSH_CONNECTION ]]; then
 280             window_title "@$name"
 281         elif [[ -n $window_root ]]; then
 282             window_title "!$name"
 283         else
 284             window_title $name
 285         fi
 286
 287         # Just reset the name, so no screen reset necessary for the moment.
 288         window_reset=
 289     }
 290
 291     # Sets the window title. Works with screen, xterm and rxvt.
 292     window_title() {
 293         if [[ $TERM == screen* ]]; then
 294             print -n "\ek$1\e\\"
 295
 296             # Update window name in stumpwm if running screen in X11 and when
 297             # stumpwm is used.
 298             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
 299                 echo "$1" | stumpish -e "title" > /dev/null
 300             fi
 301
 302         elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 303             print -n "\e]2;$1\e\\"
 304         fi
 305     }
 306
 307     # Add the preexec() and precmd() hooks.
 308     add-zsh-hook preexec window_preexec
 309     add-zsh-hook precmd window_precmd
 310 fi
 311
 312
 313 # COMPLETION SETTINGS
 314
 315 # Load the complist module which provides additions to completion lists
 316 # (coloring, scrollable).
 317 zmodload zsh/complist
 318 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 319 # cluttering of ~/.
 320 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 321
 322 # Use cache to speed up completions.
 323 zstyle ':completion:*' use-cache on
 324 zstyle ':completion:*' cache-path ~/.zsh/cache
 325
 326 # Complete arguments and fix spelling mistakes when possible.
 327 zstyle ':completion:*' completer _complete _match _correct _approximate
 328
 329 # Make sure the list of possible completions is displayed after pressing <TAB>
 330 # the first time.
 331 setopt nolistambiguous
 332 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 333 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 334 bindkey "^I" expand-or-complete-prefix
 335 # Try uppercase if the currently typed string doesn't match. This allows
 336 # typing in lowercase most of the time and completion fixes the case.
 337 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 338
 339 # Use ls like colors for completions.
 340 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 341
 342 # Make completion lists scrollable so "do you wish to see all n possibilities"
 343 # is no longer displayed.
 344 zstyle ':completion:*' list-prompt '%p'
 345 # Display group name (like 'external command', 'alias', etc.) when there are
 346 # multiple matches in bold.
 347 zstyle ':completion:*' format '    %B%d%b:'
 348 # Display different types of matches separately.
 349 zstyle ':completion:*' group-name ''
 350
 351 # Ignore completion functions.
 352 zstyle ':completion:*:functions' ignored-patterns '_*'
 353 # Ignore parent directory.
 354 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 355 # When unsetting variables make sure every variable name is only suggested
 356 # once.
 357 zstyle ':completion:*:unset:*' ignore-line yes
 358 # When working with Mercurial and Git don't complete the same file multiple
 359 # times. Very useful when completing file names.
 360 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 361
 362
 363 # CUSTOM ALIASES AND FUNCTIONS
 364
 365 # If ^C is pressed while typing a command, add it to the history so it can be
 366 # easily retrieved later and then abort like ^C normally does. This is useful
 367 # when I want to abort an command to do something in between and then finish
 368 # typing the command.
 369 #
 370 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 371 # starting with - don't cause errors.
 372 TRAPINT() {
 373     # Store the current buffer in the history.
 374     zle && print -s -- $BUFFER
 375
 376     # Return the default exit code so zsh aborts the current command.
 377     return $1
 378 }
 379
 380 # Colorize stderr. Very useful when looking for errors. Thanks to
 381 # http://gentoo-wiki.com/wiki/Zsh
 382 exec 2>>(while read line; do
 383     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
 384
 385 # Make sure aliases are expanded when using sudo.
 386 alias sudo='sudo '
 387
 388 # Global aliases for often used commands used in the command line.
 389 alias -g E='2>&1'
 390 alias -g L='E | less'
 391 alias -g D='E | colordiff L'
 392 alias -g G='| grep'
 393 alias -g S='| sort'
 394 alias -g U='| uniq'
 395
 396 # Make going up directories simple.
 397 alias -g ...='../..'
 398 alias -g ....='../../..'
 399 alias -g .....='../../../..'
 400
 401 # Shortcuts for often used programs.
 402 alias c='clear'
 403 alias e='elinks'
 404 alias g='git'
 405 alias m='mutt'
 406 alias v='vim'
 407 alias vi='vim'
 408
 409 # Improved ls which displays the files in columns (-C), visualizes
 410 # directories, links and other special files (-F) and pages everything through
 411 # less (L).
 412 #
 413 # If available use GNU ls with colorized output. If it isn't available use
 414 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 415 # pager.
 416 ls --color &> /dev/null
 417 if [[ $? -eq 0 ]]; then
 418     alias ls='ls --color'
 419 else
 420     alias ls='CLICOLOR_FORCE=1 ls -G'
 421 fi
 422 # Main ls function.
 423 function ls() {
 424     command ls -C -F $* L
 425 }
 426 # Helper function to list all files.
 427 function la() {
 428     ls -a $*
 429 }
 430 # Helper function to list all files in list format with access rights, etc.
 431 function ll() {
 432     la -l $*
 433 }
 434
 435 # If the window naming feature is used (see above) then use ".zsh" (leading
 436 # dot) as title name after running clear so it's clear to me that the window
 437 # is empty. I open so much windows that I don't know in which I have something
 438 # important. This helps me to remember which windows are empty (I run clear
 439 # after I finished my work in a window).
 440 if [[ -n $window_reset ]]; then
 441     alias clear='clear; window_reset=yes; window_precmd reset'
 442 fi
 443
 444 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 445 # shell.
 446 alias :q='echo "This is not Vim!" >&2'
 447
 448 # Automatically use unified diffs.
 449 alias diff='diff -u'
 450
 451 # Display all files and use human readable sizes.
 452 alias du='du -sh'
 453
 454 # Use human readable sizes.
 455 alias df='df -h'
 456
 457 # Edit the mercurial patch queue series file for the current mercurial
 458 # repository in Vim. Also change Vim's pwd to the patches directory so other
 459 # patches can easily be opened.
 460 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 461
 462 # Display all branches (except stash) in gitk but only 200 commits as this is
 463 # much faster. Also put in the background and disown. Thanks to sitaram in
 464 # #git on Freenode (2009-04-20 15:51).
 465 gitk() {
 466     command gitk \
 467         --max-count=200 \
 468         $(git rev-parse --symbolic-full-name --remotes --branches) \
 469         $@ &
 470     disown %command
 471 }
 472 # Same for tig (except the disown part as it's no GUI program).
 473 tig() {
 474     command tig \
 475         --max-count=200 \
 476         $(git rev-parse --symbolic-full-name --remotes --branches) \
 477         $@
 478 }
 479
 480
 481 # RUN COMMANDS
 482
 483 # If not already in screen reattach to a running session or create a new one.
 484 #
 485 # screen* is necessary as `screen` uses screen.linux for example for a linux
 486 # console which would otherwise cause an infinite loop.
 487 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 488     # Get running detached sessions.
 489     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 490     # Create a new session if none is running.
 491     if [[ -z $session ]]; then
 492         screen
 493     # Reattach to a running session.
 494     else
 495         screen -r $session
 496     fi
 497 fi
 498
 499
 500 # OS SPECIFIC SETTINGS
 501
 502 if [[ $(uname) == Linux ]]; then
 503     # Settings to create Debian packages.
 504     DEBEMAIL=simon@ruderich.org
 505     export DEBEMAIL
 506     DEBFULLNAME="Simon Ruderich"
 507     export DEBFULLNAME
 508
 509 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 510     # Store the current clipboard in CLIPBOARD before every command so it can
 511     # be used in commands.
 512     os_darwin_preexec() {
 513         export CLIPBOARD="$(pbpaste)"
 514     }
 515     # Add the function as preexec hook.
 516     add-zsh-hook preexec os_darwin_preexec
 517
 518     # Initialize CLIPBOARD so it's available for completion directly after
 519     # startup.
 520     CLIPBOARD=""
 521     export CLIPBOARD
 522
 523     # Fetch current URL in clipboard with wget.
 524     alias wnc='wget --no-proxy $CLIPBOARD'
 525 fi
 526
 527
 528 # Load rc file for current hostname (first part before a dot) or rc.local.
 529 source_config ~/.zsh host rc ${$(hostname)//.*/}
 530
 531 source_debug "finished sourcing ~/.zsh/rc"
 532
 533 # vim: ft=zsh