zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Disable beeps.
  15 setopt nobeep
  16
  17 # Prevent overwriting existing files with '> filename', use '>| filename'
  18 # (or >!) instead.
  19 setopt noclobber
  20
  21 # Entering the name of a directory (if it's not a command) will automatically
  22 # cd to that directory.
  23 setopt autocd
  24
  25 # When entering a nonexistent command name automatically try to find a similar
  26 # one.
  27 setopt correct
  28
  29 # Enable zsh's extended glob abilities.
  30 setopt extendedglob
  31
  32 # Don't exit if <C-d> is pressed.
  33 setopt ignoreeof
  34
  35
  36 # FUNCTION SETTINGS
  37
  38 # Make sure every entry in $fpath is unique.
  39 typeset -U fpath
  40 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  41 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  42 if [[ -d ~/.zsh/functions/completion ]]; then
  43     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  44 fi
  45 # Set correct fpath to allow loading my functions (including completion
  46 # functions).
  47 fpath=(~/.zsh/functions $fpath)
  48 # Autoload my functions (except completion functions and hidden files). Thanks
  49 # to caphuso from the Zsh example files for this idea.
  50 if [[ -d ~/.zsh/functions ]]; then
  51     autoload ${fpath[1]}/^_*(^/:t)
  52 fi
  53
  54 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  55 # the moment only precmd() and preexec() are simulated.
  56 #
  57 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  58 # so the compatibility version is used there too.
  59 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  60     # Provide add-zsh-hook which was added in 4.3.4.
  61     fpath=(~/.zsh/functions/compatibility $fpath)
  62
  63     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  64     function precmd() {
  65         for function in $precmd_functions; do
  66             $function $@
  67         done
  68     }
  69     function preexec() {
  70         for function in $preexec_functions; do
  71             $function $@
  72         done
  73     }
  74 fi
  75
  76 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  77 autoload -Uz add-zsh-hook
  78
  79 # Load zmv (zsh move) which is powerful to rename files.
  80 autoload zmv
  81
  82 # HISTORY SETTINGS
  83
  84 # Use history and store it in ~/.zsh/history.
  85 HISTSIZE=50000
  86 SAVEHIST=50000
  87 HISTFILE=~/.zsh/history
  88 # Append to the history file instead of overwriting it and do it immediately
  89 # when a command is executed.
  90 setopt appendhistory
  91 setopt incappendhistory
  92 # If the same command is run multiple times store it only once in the history.
  93 setopt histignoredups
  94 # Vim like completions of previous executed commands (also enter Vi-mode). If
  95 # called at the beginning it just recalls old commands (like cursor up), if
  96 # called after typing something only lines starting with the typed are
  97 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
  98 # on Freenode (2010-01-17 12:47) for the information how to a use function
  99 # with bindkey.
 100 zle -N my-vi-history-beginning-search-backward
 101 my-vi-history-beginning-search-backward() {
 102     local not_at_beginning_of_line
 103     if [[ $CURSOR -ne 0 ]]; then
 104         not_at_beginning_of_line=yes
 105     fi
 106
 107     zle history-beginning-search-backward
 108
 109     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 110     # this counters it).
 111     zle vi-cmd-mode
 112     if [[ -n $not_at_beginning_of_line ]]; then
 113         zle vi-forward-char
 114     fi
 115 }
 116 bindkey "^P" my-vi-history-beginning-search-backward
 117 bindkey -a "^P" history-beginning-search-backward # binding for Vi-mode
 118 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 119 # after calling ^P.
 120 bindkey -a "^N" history-beginning-search-forward
 121
 122
 123 # PROMPT SETTINGS
 124
 125 # Use colorized output, necessary for prompts and completions.
 126 autoload -U colors && colors
 127
 128 # Some shortcuts for colors.
 129 local red="%{${fg[red]}%}"
 130 local blue="%{${fg[blue]}%}"
 131 local green="%{${fg[green]}%}"
 132 local yellow="%{${fg[yellow]}%}"
 133 local default="%{${fg[default]}%}"
 134
 135 # Set the default prompt. The current host and working directory is displayed,
 136 # the exit code of the last command if it wasn't 0, the number of running jobs
 137 # if not 0 and a + if this shell is running inside another shell.
 138 # The prompt is in green and blue to make easily detectable, the error exit
 139 # code in red and bold and the job count in yellow.
 140 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 141 %(1j.$yellow%j$default.)%(2L.+.)%# \
 142 %(?..($red%B%?%b$default%) )"
 143
 144 # VCS_Info was added in 4.3.9 but it works in earlier versions too. So load it
 145 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 146 # symbolic link to current checkout of Zsh's sources).
 147 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 148       -d ~/.zsh/functions/vcs_info ]]; then
 149     # Update fpath to allow loading the VCS_Info functions.
 150     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 151        fpath=(~/.zsh/functions/vcs_info/
 152               ~/.zsh/functions/vcs_info/Backends
 153               $fpath)
 154     fi
 155
 156     # Allow substitutions and expansions in the prompt, necessary for
 157     # VCS_info.
 158     setopt promptsubst
 159     # Load VCS_info to display information about version control repositories.
 160     autoload -Uz vcs_info
 161     # Only look for git and mercurial repositories; the only I use.
 162     zstyle ':vcs_info:*' enable git hg
 163     # Set style of VCS_info display. The current branch (green) and VCS (blue)
 164     # is displayed. If there is an special action going on (merge, rebase)
 165     # it's also displayed (red).
 166     zstyle ':vcs_info:*' formats \
 167         "($green%b$default:$blue%s$default)"
 168     zstyle ':vcs_info:*' actionformats \
 169         "($green%b$default/$red%a$default:$blue%s$default)"
 170     # Call VCS_info as precmd before every prompt.
 171     prompt_precmd() {
 172         vcs_info
 173     }
 174     add-zsh-hook precmd prompt_precmd
 175
 176     # Display the VCS information in the right prompt.
 177     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 178         RPROMPT='${vcs_info_msg_0_}'
 179     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 180     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 181     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 182     else
 183         RPROMPT='${vcs_info_msg_0_:- }'
 184     fi
 185 fi
 186
 187 unset red blue green yellow default
 188
 189 # When screen, xterm or rxvt is used set the name of the window to the
 190 # currently running program.
 191 #
 192 # When a program is started preexec() sets the window's name to it; when it
 193 # stops precmd() resets the window's name to 'zsh'.
 194 #
 195 # It works with screen, xterm and rxvt.
 196 #
 197 # If a command is run with sudo or if the shell is running as root then a ! is
 198 # added at the beginning of the command to make this clear. If a command is
 199 # running on a different computer with ssh a @ is added at the beginning. This
 200 # only works if the .zshrc on the server also uses this command.
 201 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 202     # Is set to a non empty value to reset the window name in the next
 203     # precmd() call.
 204     window_reset=yes
 205     # Is set to a non empty value when the shell is running as root.
 206     if [[ $(id -u) -eq 0 ]]; then
 207         window_root=yes
 208     fi
 209
 210     window_preexec() {
 211         # Get the program name with its arguments.
 212         local program_name=$1
 213
 214         # When sudo is used use real program name instead, but with an
 215         # exclamation mark at the beginning (handled below).
 216         local program_sudo=
 217         if [[ $program_name == sudo* ]]; then
 218             program_name=${program_name#sudo }
 219             program_sudo=yes
 220         fi
 221         # Remove all arguments from the program name.
 222         program_name=${program_name%% *}
 223
 224         # Ignore often used commands which are only running for a very short
 225         # time. This prevents a "blinking" name when it's changed to "cd" for
 226         # example and then some milliseconds later back to "zsh".
 227         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 228
 229         # Change my shortcuts so the real name of the program is displayed.
 230         case $program_name in
 231             e)
 232                 program_name=elinks
 233                 ;;
 234             g)
 235                 program_name=git
 236                 ;;
 237             m)
 238                 program_name=mutt
 239                 ;;
 240             v|vi)
 241                 program_name=vim
 242                 ;;
 243         esac
 244
 245         # Add an exclamation mark at the beginning if running with sudo or if
 246         # running zsh as root.
 247         if [[ -n $program_sudo || -n $window_root ]]; then
 248             program_name=!$program_name
 249         fi
 250
 251         # Add an at mark at the beginning if running through ssh on a
 252         # different computer.
 253         if [[ -n $SSH_CONNECTION ]]; then
 254             program_name="@$program_name"
 255         fi
 256
 257         # Set the window name to the currently running program.
 258         window_title "$program_name"
 259
 260         # Tell precmd() to reset the window name when the program stops.
 261         window_reset=yes
 262     }
 263
 264     window_precmd() {
 265         # Abort if no window name reset is necessary.
 266         [[ -z $window_reset ]] && return
 267
 268         # Reset the window name to 'zsh'.
 269         local name="zsh"
 270         # If the function was called with an argument then reset the window
 271         # name to '.zsh' (used by clear alias).
 272         if [[ -n $1 ]]; then
 273             name=".zsh"
 274         fi
 275
 276         # Prepend prefixes like in window_preexec().
 277         if [[ -n $SSH_CONNECTION ]]; then
 278             window_title "@$name"
 279         elif [[ -n $window_root ]]; then
 280             window_title "!$name"
 281         else
 282             window_title $name
 283         fi
 284
 285         # Just reset the name, so no screen reset necessary for the moment.
 286         window_reset=
 287     }
 288
 289     # Sets the window title. Works with screen, xterm and rxvt.
 290     window_title() {
 291         if [[ $TERM == screen* ]]; then
 292             print -n "\ek$1\e\\"
 293
 294         elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 295             print -n "\e]2;$1\e\\"
 296         fi
 297     }
 298
 299     # Add the preexec() and precmd() hooks.
 300     add-zsh-hook preexec window_preexec
 301     add-zsh-hook precmd window_precmd
 302 fi
 303
 304
 305 # COMPLETION SETTINGS
 306
 307 # Load the complist module which provides additions to completion lists
 308 # (coloring, scrollable).
 309 zmodload zsh/complist
 310 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 311 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 312 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 313 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 314
 315 # Use cache to speed up completions.
 316 zstyle ':completion:*' use-cache on
 317 zstyle ':completion:*' cache-path ~/.zsh/cache
 318
 319 # Complete arguments and fix spelling mistakes when possible.
 320 zstyle ':completion:*' completer _complete _match _correct _approximate
 321
 322 # Make sure the list of possible completions is displayed after pressing <TAB>
 323 # the first time.
 324 setopt nolistambiguous
 325 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 326 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 327 bindkey "^I" expand-or-complete-prefix
 328 # Try uppercase if the currently typed string doesn't match. This allows
 329 # typing in lowercase most of the time and completion fixes the case.
 330 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 331
 332 # Use ls like colors for completions.
 333 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 334
 335 # Make completion lists scrollable so "do you wish to see all n possibilities"
 336 # is no longer displayed.
 337 zstyle ':completion:*' list-prompt '%p'
 338 # Display group name (like 'external command', 'alias', etc.) when there are
 339 # multiple matches in bold.
 340 zstyle ':completion:*' format '    %B%d%b:'
 341 # Display different types of matches separately.
 342 zstyle ':completion:*' group-name ''
 343
 344 # Ignore completion functions.
 345 zstyle ':completion:*:functions' ignored-patterns '_*'
 346 # Ignore parent directory.
 347 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 348 # When unsetting variables make sure every variable name is only suggested
 349 # once.
 350 zstyle ':completion:*:unset:*' ignore-line yes
 351 # When working with Mercurial and Git don't complete the same file multiple
 352 # times. Very useful when completing file names.
 353 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 354
 355
 356 # CUSTOM ALIASES AND FUNCTIONS
 357
 358 # If ^C is pressed while typing a command, add it to the history so it can be
 359 # easily retrieved later and then abort like ^C normally does. This is useful
 360 # when I want to abort an command to do something in between and then finish
 361 # typing the command.
 362 #
 363 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 364 # starting with - don't cause errors.
 365 TRAPINT() {
 366     # Store the current buffer in the history.
 367     zle && print -s -- $BUFFER
 368
 369     # Return the default exit code so zsh aborts the current command.
 370     return $1
 371 }
 372
 373 # Colorize stderr. Very useful when looking for errors. Thanks to
 374 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 375 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 376 # perfect and doesn't work with some interactive stderr output, but in those
 377 # cases the E alias can be used as workaround.
 378 exec 2>>(while read -r line; do
 379     printf '\e[91m%s\e[0m\n' "$line"
 380     print -n $'\0';
 381 done &)
 382
 383 # Load aliases and similar functions also used by other shells.
 384 if [[ -f ~/.shell/aliases ]]; then
 385     . ~/.shell/aliases
 386 fi
 387
 388 # Make sure aliases are expanded when using sudo.
 389 alias sudo='sudo '
 390
 391 # Global aliases for often used commands in the command line.
 392 alias -g E='2>&1'
 393 alias -g L='E | less'
 394 alias -g D='E | colordiff L'
 395 alias -g G='| grep'
 396 alias -g S='| sort'
 397 alias -g U='| uniq'
 398
 399 # Make going up directories simple.
 400 alias -g ...='../..'
 401 alias -g ....='../../..'
 402 alias -g .....='../../../..'
 403
 404 # If the window naming feature is used (see above) then use ".zsh" (leading
 405 # dot) as title name after running clear so it's clear to me that the window
 406 # is empty. I open so much windows that I don't know in which I have something
 407 # important. This helps me to remember which windows are empty (I run clear
 408 # after I finished my work in a window).
 409 if [[ -n $window_reset ]]; then
 410     alias clear='clear; window_reset=yes; window_precmd reset'
 411 fi
 412
 413 # Display all branches (except stash) in gitk but only 200 commits as this is
 414 # much faster. Also put in the background and disown. Thanks to sitaram in
 415 # #git on Freenode (2009-04-20 15:51).
 416 gitk() {
 417     command gitk \
 418         --max-count=200 \
 419         $(git rev-parse --symbolic-full-name --remotes --branches) \
 420         $@ &
 421     disown %command
 422 }
 423 # Same for tig (except the disown part as it's no GUI program).
 424 tig() {
 425     command tig \
 426         --max-count=200 \
 427         $(git rev-parse --symbolic-full-name --remotes --branches) \
 428         $@
 429 }
 430
 431
 432 # RUN COMMANDS
 433
 434 # If not already in screen reattach to a running session or create a new one.
 435 #
 436 # screen* is necessary as `screen` uses screen.linux for example for a linux
 437 # console which would otherwise cause an infinite loop.
 438 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 439     # Get running detached sessions.
 440     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 441     # Create a new session if none is running.
 442     if [[ -z $session ]]; then
 443         screen
 444     # Reattach to a running session.
 445     else
 446         screen -r $session
 447     fi
 448 fi
 449
 450
 451 # OS SPECIFIC SETTINGS
 452
 453 if [[ $(uname) == Linux ]]; then
 454     # Settings when creating Debian packages.
 455     DEBEMAIL=simon@ruderich.org
 456     export DEBEMAIL
 457     DEBFULLNAME="Simon Ruderich"
 458     export DEBFULLNAME
 459
 460 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 461     # Store the current clipboard in CLIPBOARD before every command so it can
 462     # be used in commands.
 463     os_darwin_preexec() {
 464         export CLIPBOARD="$(pbpaste)"
 465     }
 466     # Add the function as preexec hook.
 467     add-zsh-hook preexec os_darwin_preexec
 468
 469     # Initialize CLIPBOARD so it's available for completion directly after
 470     # startup.
 471     CLIPBOARD=""
 472     export CLIPBOARD
 473
 474     # Fetch current URL in clipboard with wget.
 475     alias wnc='wget --no-proxy $CLIPBOARD'
 476 fi
 477
 478
 479 # Load rc file for current hostname (first part before a dot) or rc.local.
 480 source_config ~/.zsh host rc ${$(hostname)//.*/}
 481
 482 source_debug "finished sourcing ~/.zsh/rc"
 483
 484 # vim: ft=zsh