zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Disable beeps.
  15 setopt nobeep
  16
  17 # Prevent overwriting existing files with '> filename', use '>| filename'
  18 # (or >!) instead.
  19 setopt noclobber
  20
  21 # Entering the name of a directory (if it's not a command) will automatically
  22 # cd to that directory.
  23 setopt autocd
  24
  25 # When entering a nonexistent command name automatically try to find a similar
  26 # one.
  27 setopt correct
  28
  29 # Enable zsh's extended glob abilities.
  30 setopt extendedglob
  31
  32 # Don't exit if <C-d> is pressed.
  33 setopt ignoreeof
  34
  35
  36 # FUNCTION SETTINGS
  37
  38 # Make sure every entry in $fpath is unique.
  39 typeset -U fpath
  40 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  41 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  42 if [[ -d ~/.zsh/functions/completion ]]; then
  43     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  44 fi
  45 # Set correct fpath to allow loading my functions (including completion
  46 # functions).
  47 fpath=(~/.zsh/functions $fpath)
  48 # Autoload my functions (except completion functions and hidden files). Thanks
  49 # to caphuso from the Zsh example files for this idea.
  50 autoload ${fpath[1]}/^_*(^/:t)
  51
  52 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  53 # the moment only precmd() and preexec() are simulated.
  54 #
  55 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  56 # so the compatibility version is used there too.
  57 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  58     # Provide add-zsh-hook which was added in 4.3.4.
  59     fpath=(~/.zsh/functions/compatibility $fpath)
  60
  61     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  62     function precmd() {
  63         for function in $precmd_functions; do
  64             $function $@
  65         done
  66     }
  67     function preexec() {
  68         for function in $preexec_functions; do
  69             $function $@
  70         done
  71     }
  72 fi
  73
  74 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  75 autoload -Uz add-zsh-hook
  76
  77
  78 # HISTORY SETTINGS
  79
  80 # Use history and store it in ~/.zsh/history.
  81 HISTSIZE=50000
  82 SAVEHIST=50000
  83 HISTFILE=~/.zsh/history
  84 # Append to the history file instead of overwriting it and do it immediately
  85 # when a command is executed.
  86 setopt appendhistory
  87 setopt incappendhistory
  88 # If the same command is run multiple times store it only once in the history.
  89 setopt histignoredups
  90 # Vim like completions of previous executed commands.
  91 bindkey "^P" history-beginning-search-backward
  92 bindkey "^N" history-beginning-search-forward
  93
  94
  95 # PROMPT SETTINGS
  96
  97 # Use colorized output, necessary for prompts and completions.
  98 autoload -U colors && colors
  99
 100 # Set the default prompt. The current host and working directory is displayed,
 101 # the exit code of the last command if it wasn't 0, the number of running jobs
 102 # if not 0 and a + if this shell is running inside another shell.
 103 # The prompt is in green and blue to make easily detectable, the error exit
 104 # code in red and bold and the job count in yellow.
 105 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
 106 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
 107 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
 108 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
 109
 110 # VCS_Info was added in 4.3.9 but it works in earlier versions too. So load it
 111 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 112 # symbolic link to current checkout of Zsh's sources).
 113 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 114       -d ~/.zsh/functions/vcs_info ]]; then
 115     # Update fpath to allow loading the VCS_Info functions.
 116     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 117        fpath=(~/.zsh/functions/vcs_info/
 118               ~/.zsh/functions/vcs_info/Backends
 119               $fpath)
 120     fi
 121
 122     # Allow substitutions and expansions in the prompt, necessary for
 123     # vcs_info.
 124     setopt promptsubst
 125     # Load vcs_info to display information about version control repositories.
 126     autoload -Uz vcs_info
 127     # Only look for git and mercurial repositories; the only I use.
 128     zstyle ':vcs_info:*' enable git hg
 129     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 130     # is displayed. If there is an special action going on (merge, rebase)
 131     # it's also displayed (red).
 132     zstyle ':vcs_info:*' formats \
 133     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 134 %{${fg[blue]}%}%s%{${fg[default]}%})"
 135     zstyle ':vcs_info:*' actionformats \
 136     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 137 %{${fg[red]}%}%a%{${fg[default]}%}:\
 138 %{${fg[blue]}%}%s%{${fg[default]}%})"
 139     # Call vcs_info as precmd before every prompt.
 140     prompt_precmd() {
 141         vcs_info
 142     }
 143     add-zsh-hook precmd prompt_precmd
 144
 145     # Display the vcs information in the right prompt.
 146     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 147         RPROMPT='${vcs_info_msg_0_}'
 148     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 149     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 150     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 151     else
 152         RPROMPT='${vcs_info_msg_0_:- }'
 153     fi
 154 fi
 155
 156 # When screen, xterm or rxvt is used set the name of the window to the
 157 # currently running program.
 158 #
 159 # When a program is started preexec() sets the window's name to it; when it
 160 # stops precmd() resets the window's name to 'zsh'.
 161 #
 162 # It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
 163 # and stumpwm is running then the window title is also set in stumpwm using
 164 # stumpish.
 165 #
 166 # If a command is run with sudo or if the shell is running as root then a ! is
 167 # added at the beginning of the command to make this clear. If a command is
 168 # running on a different computer with ssh a @ is added at the beginning. This
 169 # only works if the .zshrc on the server also uses this command.
 170 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 171     # Is set to a non empty value to reset the window name in the next
 172     # precmd() call.
 173     window_reset=yes
 174     # Is set to a non empty value when the stump window manager is running.
 175     ps aux | grep -q stumpwm | grep -v grep
 176     if [[ $? -eq 0 ]]; then
 177         window_stumpwm=yes
 178     fi
 179     # Is set to a non empty value when the shell is running as root.
 180     if [[ $(id -u) -eq 0 ]]; then
 181         window_root=yes
 182     fi
 183
 184     window_preexec() {
 185         # Get the program name with its arguments.
 186         local program_name=$1
 187
 188         # When sudo is used use real program name instead, but with an
 189         # exclamation mark at the beginning.
 190         local program_sudo=
 191         if [[ $program_name == sudo* ]]; then
 192             program_name=${program_name#sudo }
 193             program_sudo=yes
 194         fi
 195         # Remove all arguments from the program name.
 196         program_name=${program_name%% *}
 197
 198         # Ignore often used commands which are only running for a very short
 199         # time. This prevents a "blinking" name when it's changed to "cd" for
 200         # example and then some milliseconds later back to "zsh".
 201         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 202
 203         # Change my shortcuts so the real name of the program is displayed.
 204         case $program_name in
 205             e)
 206                 program_name=elinks
 207                 ;;
 208             g)
 209                 program_name=git
 210                 ;;
 211             m)
 212                 program_name=mutt
 213                 ;;
 214             v|vi)
 215                 program_name=vim
 216                 ;;
 217         esac
 218
 219         # Add an exclamation mark at the beginning if running with sudo or if
 220         # running zsh as root.
 221         if [[ -n $program_sudo || -n $window_root ]]; then
 222             program_name=!$program_name
 223         fi
 224
 225         # Add an at mark at the beginning if running through ssh on a
 226         # different computer.
 227         if [[ -n $SSH_CONNECTION ]]; then
 228             program_name="@$program_name"
 229         fi
 230
 231         # Set the window name to the currently running program.
 232         window_title "$program_name"
 233
 234         # Tell precmd() to reset the window name when the program stops.
 235         window_reset=yes
 236     }
 237
 238     window_precmd() {
 239         # Abort if no window name reset is necessary.
 240         [[ -z $window_reset ]] && return
 241
 242         # Reset the window name to 'zsh'.
 243         local name="zsh"
 244         # If the function was called with an argument then reset the window
 245         # name to '.zsh' (used by clear alias).
 246         if [[ -n $1 ]]; then
 247             name=".zsh"
 248         fi
 249
 250         # Prepend prefixes like in window_preexec().
 251         if [[ -n $SSH_CONNECTION ]]; then
 252             window_title "@$name"
 253         elif [[ -n $window_root ]]; then
 254             window_title "!$name"
 255         else
 256             window_title $name
 257         fi
 258
 259         # Just reset the name, so no screen reset necessary for the moment.
 260         window_reset=
 261     }
 262
 263     # Sets the window title. Works with screen, xterm and rxvt.
 264     window_title() {
 265         if [[ $TERM == screen* ]]; then
 266             print -n "\ek$1\e\\"
 267
 268             # Update window name in stumpwm if running screen in X11 and when
 269             # stumpwm is used.
 270             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
 271                 echo "$1" | stumpish -e "title" > /dev/null
 272             fi
 273
 274         elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 275             print -n "\e]2;$1\e\\"
 276         fi
 277     }
 278
 279     # Add the preexec() and precmd() hooks.
 280     add-zsh-hook preexec window_preexec
 281     add-zsh-hook precmd window_precmd
 282 fi
 283
 284
 285 # COMPLETION SETTINGS
 286
 287 # Load the complist module which provides additions to completion lists
 288 # (coloring, scrollable).
 289 zmodload zsh/complist
 290 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 291 # cluttering of ~/.
 292 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 293
 294 # Use cache to speed up completions.
 295 zstyle ':completion:*' use-cache on
 296 zstyle ':completion:*' cache-path ~/.zsh/cache
 297
 298 # Complete arguments and fix spelling mistakes when possible.
 299 zstyle ':completion:*' completer _complete _match _correct _approximate
 300
 301 # Make sure the list of possible completions is displayed after pressing <TAB>
 302 # the first time.
 303 setopt nolistambiguous
 304 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 305 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 306 bindkey "^I" expand-or-complete-prefix
 307 # Try uppercase if the currently typed string doesn't match. This allows
 308 # typing in lowercase most of the time and completion fixes the case.
 309 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 310
 311 # Use ls like colors for completions.
 312 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 313
 314 # Make completion lists scrollable so "do you wish to see all n possibilities"
 315 # is no longer displayed.
 316 zstyle ':completion:*' list-prompt '%p'
 317 # Display group name (like 'external command', 'alias', etc.) when there are
 318 # multiple matches in bold.
 319 zstyle ':completion:*' format '    %B%d%b:'
 320 # Display different types of matches separately.
 321 zstyle ':completion:*' group-name ''
 322
 323 # Ignore completion functions.
 324 zstyle ':completion:*:functions' ignored-patterns '_*'
 325 # Ignore parent directory.
 326 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 327 # When unsetting variables make sure every variable name is only suggested
 328 # once.
 329 zstyle ':completion:*:unset:*' ignore-line yes
 330 # When working with Mercurial and Git don't complete the same file multiple
 331 # times. Very useful when completing file names.
 332 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 333
 334
 335 # CUSTOM ALIASES AND FUNCTIONS
 336
 337 # If ^C is pressed while typing a command, add it to the history so it can be
 338 # easily retrieved later and then abort like ^C normally does. This is useful
 339 # when I want to abort an command to do something in between and then finish
 340 # typing the command.
 341 #
 342 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 343 # starting with - don't cause errors.
 344 TRAPINT() {
 345     # Store the current buffer in the history.
 346     zle && print -s -- $BUFFER
 347
 348     # Return the default exit code so zsh aborts the current command.
 349     return $1
 350 }
 351
 352 # Colorize stderr. Very useful when looking for errors. Thanks to
 353 # http://gentoo-wiki.com/wiki/Zsh
 354 exec 2>>(while read line; do
 355     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
 356
 357 # Make sure aliases are expanded when using sudo.
 358 alias sudo='sudo '
 359
 360 # Global aliases for often used commands used in the command line.
 361 alias -g E='2>&1'
 362 alias -g L='E | less'
 363 alias -g D='E | colordiff L'
 364 alias -g G='| grep'
 365 alias -g S='| sort'
 366
 367 # Make going up directories simple.
 368 alias -g ...='../..'
 369 alias -g ....='../../..'
 370 alias -g .....='../../../..'
 371
 372 # Shortcuts for often used programs.
 373 alias c='clear'
 374 alias e='elinks'
 375 alias g='git'
 376 alias m='mutt'
 377 alias v='vim'
 378 alias vi='vim'
 379
 380 # Improved ls which displays the files in columns (-C), visualizes
 381 # directories, links and other special files (-F) and pages everything through
 382 # less (L).
 383 #
 384 # If available use GNU ls with colorized output. If it isn't available use
 385 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 386 # pager.
 387 ls --color &> /dev/null
 388 if [[ $? -eq 0 ]]; then
 389     alias ls='ls --color'
 390 else
 391     alias ls='CLICOLOR_FORCE=1 ls -G'
 392 fi
 393 # Main ls function.
 394 function ls() {
 395     command ls -C -F $* L
 396 }
 397 # Helper function to list all files.
 398 function la() {
 399     ls -a $*
 400 }
 401 # Helper function to list all files in list format with access rights, etc.
 402 function ll() {
 403     la -l $*
 404 }
 405
 406 # If the window naming feature is used (see above) then use ".zsh" (leading
 407 # dot) as title name after running clear so it's clear to me that the window
 408 # is empty. I open so much windows that I don't know in which I have something
 409 # important. This helps me to remember which windows are empty (I run clear
 410 # after I finished my work in a window).
 411 if [[ -n $window_reset ]]; then
 412     alias clear='clear; window_reset=yes; window_precmd reset'
 413 fi
 414
 415 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 416 # shell.
 417 alias :q='echo "This is not Vim!" >&2'
 418
 419 # Automatically use unified diffs.
 420 alias diff='diff -u'
 421
 422 # Display all files and use human readable sizes.
 423 alias du='du -sh'
 424
 425 # Use human readable sizes.
 426 alias df='df -h'
 427
 428 # Edit the mercurial patch queue series file for the current mercurial
 429 # repository in Vim. Also change Vim's pwd to the patches directory so other
 430 # patches can easily be opened.
 431 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 432
 433 # Display all branches (except stash) in gitk but only 200 commits as this is
 434 # much faster. Also put in the background and disown. Thanks to sitaram in
 435 # #git on Freenode (2009-04-20 15:51).
 436 gitk() {
 437     command gitk \
 438         --max-count=200 \
 439         $(git rev-parse --symbolic-full-name --remotes --branches) \
 440         $@ &
 441     disown %command
 442 }
 443 # Same for tig (except the disown part as it's no GUI program).
 444 tig() {
 445     command tig \
 446         --max-count=200 \
 447         $(git rev-parse --symbolic-full-name --remotes --branches) \
 448         $@
 449 }
 450
 451
 452 # RUN COMMANDS
 453
 454 # If not already in screen reattach to a running session or create a new one.
 455 #
 456 # screen* is necessary as `screen` uses screen.linux for example for a linux
 457 # console which would otherwise cause an infinite loop.
 458 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 459     # Get running detached sessions.
 460     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 461     # Create a new session if none is running.
 462     if [[ -z $session ]]; then
 463         screen
 464     # Reattach to a running session.
 465     else
 466         screen -r $session
 467     fi
 468 fi
 469
 470
 471 # Load rc file for current OS.
 472 source_config ~/.zsh os rc $(uname) nolocal
 473 # Load rc file for current hostname (first part before a dot) or rc.local.
 474 source_config ~/.zsh host rc ${$(hostname)//.*/}
 475
 476 source_debug "finished sourcing ~/.zsh/rc"
 477
 478 # vim: ft=zsh